arch/arm64/kernel/entry.S

   1 /*
   2  * Low-level exception handling code
   3  *
   4  * Copyright (C) 2012 ARM Ltd.
   5  * Authors:     Catalin Marinas <catalin.marinas@arm.com>
   6  *              Will Deacon <will.deacon@arm.com>
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19  */
  20
  21 #include <linux/init.h>
  22 #include <linux/linkage.h>
  23
  24 #include <asm/alternative.h>
  25 #include <asm/assembler.h>
  26 #include <asm/asm-offsets.h>
  27 #include <asm/cpufeature.h>
  28 #include <asm/errno.h>
  29 #include <asm/esr.h>
  30 #include <asm/irq.h>
  31 #include <asm/memory.h>
  32 #include <asm/ptrace.h>
  33 #include <asm/thread_info.h>
  34 #include <asm/asm-uaccess.h>
  35 #include <asm/unistd.h>
  36
  37 /*
  38  * Context tracking subsystem.  Used to instrument transitions
  39  * between user and kernel mode.
  40  */
  41         .macro ct_user_exit, syscall = 0
  42 #ifdef CONFIG_CONTEXT_TRACKING
  43         bl      context_tracking_user_exit
  44         .if \syscall == 1
  45         /*
  46          * Save/restore needed during syscalls.  Restore syscall arguments from
  47          * the values already saved on stack during kernel_entry.
  48          */
  49         ldp     x0, x1, [sp]
  50         ldp     x2, x3, [sp, #S_X2]
  51         ldp     x4, x5, [sp, #S_X4]
  52         ldp     x6, x7, [sp, #S_X6]
  53         .endif
  54 #endif
  55         .endm
  56
  57         .macro ct_user_enter
  58 #ifdef CONFIG_CONTEXT_TRACKING
  59         bl      context_tracking_user_enter
  60 #endif
  61         .endm
  62
  63 /*
  64  * Bad Abort numbers
  65  *-----------------
  66  */
  67 #define BAD_SYNC        0
  68 #define BAD_IRQ         1
  69 #define BAD_FIQ         2
  70 #define BAD_ERROR       3
  71
  72         .macro  kernel_entry, el, regsize = 64
  73         sub     sp, sp, #S_FRAME_SIZE
  74         .if     \regsize == 32
  75         mov     w0, w0                          // zero upper 32 bits of x0
  76         .endif
  77         stp     x0, x1, [sp, #16 * 0]
  78         stp     x2, x3, [sp, #16 * 1]
  79         stp     x4, x5, [sp, #16 * 2]
  80         stp     x6, x7, [sp, #16 * 3]
  81         stp     x8, x9, [sp, #16 * 4]
  82         stp     x10, x11, [sp, #16 * 5]
  83         stp     x12, x13, [sp, #16 * 6]
  84         stp     x14, x15, [sp, #16 * 7]
  85         stp     x16, x17, [sp, #16 * 8]
  86         stp     x18, x19, [sp, #16 * 9]
  87         stp     x20, x21, [sp, #16 * 10]
  88         stp     x22, x23, [sp, #16 * 11]
  89         stp     x24, x25, [sp, #16 * 12]
  90         stp     x26, x27, [sp, #16 * 13]
  91         stp     x28, x29, [sp, #16 * 14]
  92
  93         .if     \el == 0
  94         mrs     x21, sp_el0
  95         ldr_this_cpu    tsk, __entry_task, x20  // Ensure MDSCR_EL1.SS is clear,
  96         ldr     x19, [tsk, #TSK_TI_FLAGS]       // since we can unmask debug
  97         disable_step_tsk x19, x20               // exceptions when scheduling.
  98
  99         mov     x29, xzr                        // fp pointed to user-space
 100         .else
 101         add     x21, sp, #S_FRAME_SIZE
 102         get_thread_info tsk
 103         /* Save the task's original addr_limit and set USER_DS (TASK_SIZE_64) */
 104         ldr     x20, [tsk, #TSK_TI_ADDR_LIMIT]
 105         str     x20, [sp, #S_ORIG_ADDR_LIMIT]
 106         mov     x20, #TASK_SIZE_64
 107         str     x20, [tsk, #TSK_TI_ADDR_LIMIT]
 108         /* No need to reset PSTATE.UAO, hardware's already set it to 0 for us */
 109         .endif /* \el == 0 */
 110         mrs     x22, elr_el1
 111         mrs     x23, spsr_el1
 112         stp     lr, x21, [sp, #S_LR]
 113
 114         /*
 115          * In order to be able to dump the contents of struct pt_regs at the
 116          * time the exception was taken (in case we attempt to walk the call
 117          * stack later), chain it together with the stack frames.
 118          */
 119         .if \el == 0
 120         stp     xzr, xzr, [sp, #S_STACKFRAME]
 121         .else
 122         stp     x29, x22, [sp, #S_STACKFRAME]
 123         .endif
 124         add     x29, sp, #S_STACKFRAME
 125
 126 #ifdef CONFIG_ARM64_SW_TTBR0_PAN
 127         /*
 128          * Set the TTBR0 PAN bit in SPSR. When the exception is taken from
 129          * EL0, there is no need to check the state of TTBR0_EL1 since
 130          * accesses are always enabled.
 131          * Note that the meaning of this bit differs from the ARMv8.1 PAN
 132          * feature as all TTBR0_EL1 accesses are disabled, not just those to
 133          * user mappings.
 134          */
 135 alternative_if ARM64_HAS_PAN
 136         b       1f                              // skip TTBR0 PAN
 137 alternative_else_nop_endif
 138
 139         .if     \el != 0
 140         mrs     x21, ttbr0_el1
 141         tst     x21, #0xffff << 48              // Check for the reserved ASID
 142         orr     x23, x23, #PSR_PAN_BIT          // Set the emulated PAN in the saved SPSR
 143         b.eq    1f                              // TTBR0 access already disabled
 144         and     x23, x23, #~PSR_PAN_BIT         // Clear the emulated PAN in the saved SPSR
 145         .endif
 146
 147         __uaccess_ttbr0_disable x21
 148 1:
 149 #endif
 150
 151         stp     x22, x23, [sp, #S_PC]
 152
 153         /* Not in a syscall by default (el0_svc overwrites for real syscall) */
 154         .if     \el == 0
 155         mov     w21, #NO_SYSCALL
 156         str     w21, [sp, #S_SYSCALLNO]
 157         .endif
 158
 159         /*
 160          * Set sp_el0 to current thread_info.
 161          */
 162         .if     \el == 0
 163         msr     sp_el0, tsk
 164         .endif
 165
 166         /*
 167          * Registers that may be useful after this macro is invoked:
 168          *
 169          * x21 - aborted SP
 170          * x22 - aborted PC
 171          * x23 - aborted PSTATE
 172         */
 173         .endm
 174
 175         .macro  kernel_exit, el
 176         .if     \el != 0
 177         /* Restore the task's original addr_limit. */
 178         ldr     x20, [sp, #S_ORIG_ADDR_LIMIT]
 179         str     x20, [tsk, #TSK_TI_ADDR_LIMIT]
 180
 181         /* No need to restore UAO, it will be restored from SPSR_EL1 */
 182         .endif
 183
 184         ldp     x21, x22, [sp, #S_PC]           // load ELR, SPSR
 185         .if     \el == 0
 186         ct_user_enter
 187         .endif
 188
 189 #ifdef CONFIG_ARM64_SW_TTBR0_PAN
 190         /*
 191          * Restore access to TTBR0_EL1. If returning to EL0, no need for SPSR
 192          * PAN bit checking.
 193          */
 194 alternative_if ARM64_HAS_PAN
 195         b       2f                              // skip TTBR0 PAN
 196 alternative_else_nop_endif
 197
 198         .if     \el != 0
 199         tbnz    x22, #22, 1f                    // Skip re-enabling TTBR0 access if the PSR_PAN_BIT is set
 200         .endif
 201
 202         __uaccess_ttbr0_enable x0
 203
 204         .if     \el == 0
 205         /*
 206          * Enable errata workarounds only if returning to user. The only
 207          * workaround currently required for TTBR0_EL1 changes are for the
 208          * Cavium erratum 27456 (broadcast TLBI instructions may cause I-cache
 209          * corruption).
 210          */
 211         post_ttbr0_update_workaround
 212         .endif
 213 1:
 214         .if     \el != 0
 215         and     x22, x22, #~PSR_PAN_BIT         // ARMv8.0 CPUs do not understand this bit
 216         .endif
 217 2:
 218 #endif
 219
 220         .if     \el == 0
 221         ldr     x23, [sp, #S_SP]                // load return stack pointer
 222         msr     sp_el0, x23
 223 #ifdef CONFIG_ARM64_ERRATUM_845719
 224 alternative_if ARM64_WORKAROUND_845719
 225         tbz     x22, #4, 1f
 226 #ifdef CONFIG_PID_IN_CONTEXTIDR
 227         mrs     x29, contextidr_el1
 228         msr     contextidr_el1, x29
 229 #else
 230         msr contextidr_el1, xzr
 231 #endif
 232 1:
 233 alternative_else_nop_endif
 234 #endif
 235         .endif
 236
 237         msr     elr_el1, x21                    // set up the return data
 238         msr     spsr_el1, x22
 239         ldp     x0, x1, [sp, #16 * 0]
 240         ldp     x2, x3, [sp, #16 * 1]
 241         ldp     x4, x5, [sp, #16 * 2]
 242         ldp     x6, x7, [sp, #16 * 3]
 243         ldp     x8, x9, [sp, #16 * 4]
 244         ldp     x10, x11, [sp, #16 * 5]
 245         ldp     x12, x13, [sp, #16 * 6]
 246         ldp     x14, x15, [sp, #16 * 7]
 247         ldp     x16, x17, [sp, #16 * 8]
 248         ldp     x18, x19, [sp, #16 * 9]
 249         ldp     x20, x21, [sp, #16 * 10]
 250         ldp     x22, x23, [sp, #16 * 11]
 251         ldp     x24, x25, [sp, #16 * 12]
 252         ldp     x26, x27, [sp, #16 * 13]
 253         ldp     x28, x29, [sp, #16 * 14]
 254         ldr     lr, [sp, #S_LR]
 255         add     sp, sp, #S_FRAME_SIZE           // restore sp
 256         eret                                    // return to kernel
 257         .endm
 258
 259         .macro  irq_stack_entry
 260         mov     x19, sp                 // preserve the original sp
 261
 262         /*
 263          * Compare sp with the base of the task stack.
 264          * If the top ~(THREAD_SIZE - 1) bits match, we are on a task stack,
 265          * and should switch to the irq stack.
 266          */
 267         ldr     x25, [tsk, TSK_STACK]
 268         eor     x25, x25, x19
 269         and     x25, x25, #~(THREAD_SIZE - 1)
 270         cbnz    x25, 9998f
 271
 272         adr_this_cpu x25, irq_stack, x26
 273         mov     x26, #IRQ_STACK_START_SP
 274         add     x26, x25, x26
 275
 276         /* switch to the irq stack */
 277         mov     sp, x26
 278 9998:
 279         .endm
 280
 281         /*
 282          * x19 should be preserved between irq_stack_entry and
 283          * irq_stack_exit.
 284          */
 285         .macro  irq_stack_exit
 286         mov     sp, x19
 287         .endm
 288
 289 /*
 290  * These are the registers used in the syscall handler, and allow us to
 291  * have in theory up to 7 arguments to a function - x0 to x6.
 292  *
 293  * x7 is reserved for the system call number in 32-bit mode.
 294  */
 295 wsc_nr  .req    w25             // number of system calls
 296 wscno   .req    w26             // syscall number
 297 xscno   .req    x26             // syscall number (zero-extended)
 298 stbl    .req    x27             // syscall table pointer
 299 tsk     .req    x28             // current thread_info
 300
 301 /*
 302  * Interrupt handling.
 303  */
 304         .macro  irq_handler
 305         ldr_l   x1, handle_arch_irq
 306         mov     x0, sp
 307         irq_stack_entry
 308         blr     x1
 309         irq_stack_exit
 310         .endm
 311
 312         .text
 313
 314 /*
 315  * Exception vectors.
 316  */
 317         .pushsection ".entry.text", "ax"
 318
 319         .align  11
 320 ENTRY(vectors)
 321         ventry  el1_sync_invalid                // Synchronous EL1t
 322         ventry  el1_irq_invalid                 // IRQ EL1t
 323         ventry  el1_fiq_invalid                 // FIQ EL1t
 324         ventry  el1_error_invalid               // Error EL1t
 325
 326         ventry  el1_sync                        // Synchronous EL1h
 327         ventry  el1_irq                         // IRQ EL1h
 328         ventry  el1_fiq_invalid                 // FIQ EL1h
 329         ventry  el1_error_invalid               // Error EL1h
 330
 331         ventry  el0_sync                        // Synchronous 64-bit EL0
 332         ventry  el0_irq                         // IRQ 64-bit EL0
 333         ventry  el0_fiq_invalid                 // FIQ 64-bit EL0
 334         ventry  el0_error_invalid               // Error 64-bit EL0
 335
 336 #ifdef CONFIG_COMPAT
 337         ventry  el0_sync_compat                 // Synchronous 32-bit EL0
 338         ventry  el0_irq_compat                  // IRQ 32-bit EL0
 339         ventry  el0_fiq_invalid_compat          // FIQ 32-bit EL0
 340         ventry  el0_error_invalid_compat        // Error 32-bit EL0
 341 #else
 342         ventry  el0_sync_invalid                // Synchronous 32-bit EL0
 343         ventry  el0_irq_invalid                 // IRQ 32-bit EL0
 344         ventry  el0_fiq_invalid                 // FIQ 32-bit EL0
 345         ventry  el0_error_invalid               // Error 32-bit EL0
 346 #endif
 347 END(vectors)
 348
 349 /*
 350  * Invalid mode handlers
 351  */
 352         .macro  inv_entry, el, reason, regsize = 64
 353         kernel_entry \el, \regsize
 354         mov     x0, sp
 355         mov     x1, #\reason
 356         mrs     x2, esr_el1
 357         bl      bad_mode
 358         ASM_BUG()
 359         .endm
 360
 361 el0_sync_invalid:
 362         inv_entry 0, BAD_SYNC
 363 ENDPROC(el0_sync_invalid)
 364
 365 el0_irq_invalid:
 366         inv_entry 0, BAD_IRQ
 367 ENDPROC(el0_irq_invalid)
 368
 369 el0_fiq_invalid:
 370         inv_entry 0, BAD_FIQ
 371 ENDPROC(el0_fiq_invalid)
 372
 373 el0_error_invalid:
 374         inv_entry 0, BAD_ERROR
 375 ENDPROC(el0_error_invalid)
 376
 377 #ifdef CONFIG_COMPAT
 378 el0_fiq_invalid_compat:
 379         inv_entry 0, BAD_FIQ, 32
 380 ENDPROC(el0_fiq_invalid_compat)
 381
 382 el0_error_invalid_compat:
 383         inv_entry 0, BAD_ERROR, 32
 384 ENDPROC(el0_error_invalid_compat)
 385 #endif
 386
 387 el1_sync_invalid:
 388         inv_entry 1, BAD_SYNC
 389 ENDPROC(el1_sync_invalid)
 390
 391 el1_irq_invalid:
 392         inv_entry 1, BAD_IRQ
 393 ENDPROC(el1_irq_invalid)
 394
 395 el1_fiq_invalid:
 396         inv_entry 1, BAD_FIQ
 397 ENDPROC(el1_fiq_invalid)
 398
 399 el1_error_invalid:
 400         inv_entry 1, BAD_ERROR
 401 ENDPROC(el1_error_invalid)
 402
 403 /*
 404  * EL1 mode handlers.
 405  */
 406         .align  6
 407 el1_sync:
 408         kernel_entry 1
 409         mrs     x1, esr_el1                     // read the syndrome register
 410         lsr     x24, x1, #ESR_ELx_EC_SHIFT      // exception class
 411         cmp     x24, #ESR_ELx_EC_DABT_CUR       // data abort in EL1
 412         b.eq    el1_da
 413         cmp     x24, #ESR_ELx_EC_IABT_CUR       // instruction abort in EL1
 414         b.eq    el1_ia
 415         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 416         b.eq    el1_undef
 417         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 418         b.eq    el1_sp_pc
 419         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 420         b.eq    el1_sp_pc
 421         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL1
 422         b.eq    el1_undef
 423         cmp     x24, #ESR_ELx_EC_BREAKPT_CUR    // debug exception in EL1
 424         b.ge    el1_dbg
 425         b       el1_inv
 426
 427 el1_ia:
 428         /*
 429          * Fall through to the Data abort case
 430          */
 431 el1_da:
 432         /*
 433          * Data abort handling
 434          */
 435         mrs     x3, far_el1
 436         enable_dbg
 437         // re-enable interrupts if they were enabled in the aborted context
 438         tbnz    x23, #7, 1f                     // PSR_I_BIT
 439         enable_irq
 440 1:
 441         clear_address_tag x0, x3
 442         mov     x2, sp                          // struct pt_regs
 443         bl      do_mem_abort
 444
 445         // disable interrupts before pulling preserved data off the stack
 446         disable_irq
 447         kernel_exit 1
 448 el1_sp_pc:
 449         /*
 450          * Stack or PC alignment exception handling
 451          */
 452         mrs     x0, far_el1
 453         enable_dbg
 454         mov     x2, sp
 455         bl      do_sp_pc_abort
 456         ASM_BUG()
 457 el1_undef:
 458         /*
 459          * Undefined instruction
 460          */
 461         enable_dbg
 462         mov     x0, sp
 463         bl      do_undefinstr
 464         ASM_BUG()
 465 el1_dbg:
 466         /*
 467          * Debug exception handling
 468          */
 469         cmp     x24, #ESR_ELx_EC_BRK64          // if BRK64
 470         cinc    x24, x24, eq                    // set bit '0'
 471         tbz     x24, #0, el1_inv                // EL1 only
 472         mrs     x0, far_el1
 473         mov     x2, sp                          // struct pt_regs
 474         bl      do_debug_exception
 475         kernel_exit 1
 476 el1_inv:
 477         // TODO: add support for undefined instructions in kernel mode
 478         enable_dbg
 479         mov     x0, sp
 480         mov     x2, x1
 481         mov     x1, #BAD_SYNC
 482         bl      bad_mode
 483         ASM_BUG()
 484 ENDPROC(el1_sync)
 485
 486         .align  6
 487 el1_irq:
 488         kernel_entry 1
 489         enable_dbg
 490 #ifdef CONFIG_TRACE_IRQFLAGS
 491         bl      trace_hardirqs_off
 492 #endif
 493
 494         irq_handler
 495
 496 #ifdef CONFIG_PREEMPT
 497         ldr     w24, [tsk, #TSK_TI_PREEMPT]     // get preempt count
 498         cbnz    w24, 1f                         // preempt count != 0
 499         ldr     x0, [tsk, #TSK_TI_FLAGS]        // get flags
 500         tbz     x0, #TIF_NEED_RESCHED, 1f       // needs rescheduling?
 501         bl      el1_preempt
 502 1:
 503 #endif
 504 #ifdef CONFIG_TRACE_IRQFLAGS
 505         bl      trace_hardirqs_on
 506 #endif
 507         kernel_exit 1
 508 ENDPROC(el1_irq)
 509
 510 #ifdef CONFIG_PREEMPT
 511 el1_preempt:
 512         mov     x24, lr
 513 1:      bl      preempt_schedule_irq            // irq en/disable is done inside
 514         ldr     x0, [tsk, #TSK_TI_FLAGS]        // get new tasks TI_FLAGS
 515         tbnz    x0, #TIF_NEED_RESCHED, 1b       // needs rescheduling?
 516         ret     x24
 517 #endif
 518
 519 /*
 520  * EL0 mode handlers.
 521  */
 522         .align  6
 523 el0_sync:
 524         kernel_entry 0
 525         mrs     x25, esr_el1                    // read the syndrome register
 526         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 527         cmp     x24, #ESR_ELx_EC_SVC64          // SVC in 64-bit state
 528         b.eq    el0_svc
 529         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 530         b.eq    el0_da
 531         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 532         b.eq    el0_ia
 533         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 534         b.eq    el0_fpsimd_acc
 535         cmp     x24, #ESR_ELx_EC_FP_EXC64       // FP/ASIMD exception
 536         b.eq    el0_fpsimd_exc
 537         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 538         b.eq    el0_sys
 539         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 540         b.eq    el0_sp_pc
 541         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 542         b.eq    el0_sp_pc
 543         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 544         b.eq    el0_undef
 545         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 546         b.ge    el0_dbg
 547         b       el0_inv
 548
 549 #ifdef CONFIG_COMPAT
 550         .align  6
 551 el0_sync_compat:
 552         kernel_entry 0, 32
 553         mrs     x25, esr_el1                    // read the syndrome register
 554         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 555         cmp     x24, #ESR_ELx_EC_SVC32          // SVC in 32-bit state
 556         b.eq    el0_svc_compat
 557         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 558         b.eq    el0_da
 559         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 560         b.eq    el0_ia
 561         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 562         b.eq    el0_fpsimd_acc
 563         cmp     x24, #ESR_ELx_EC_FP_EXC32       // FP/ASIMD exception
 564         b.eq    el0_fpsimd_exc
 565         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 566         b.eq    el0_sp_pc
 567         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 568         b.eq    el0_undef
 569         cmp     x24, #ESR_ELx_EC_CP15_32        // CP15 MRC/MCR trap
 570         b.eq    el0_undef
 571         cmp     x24, #ESR_ELx_EC_CP15_64        // CP15 MRRC/MCRR trap
 572         b.eq    el0_undef
 573         cmp     x24, #ESR_ELx_EC_CP14_MR        // CP14 MRC/MCR trap
 574         b.eq    el0_undef
 575         cmp     x24, #ESR_ELx_EC_CP14_LS        // CP14 LDC/STC trap
 576         b.eq    el0_undef
 577         cmp     x24, #ESR_ELx_EC_CP14_64        // CP14 MRRC/MCRR trap
 578         b.eq    el0_undef
 579         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 580         b.ge    el0_dbg
 581         b       el0_inv
 582 el0_svc_compat:
 583         /*
 584          * AArch32 syscall handling
 585          */
 586         adrp    stbl, compat_sys_call_table     // load compat syscall table pointer
 587         mov     wscno, w7                       // syscall number in w7 (r7)
 588         mov     wsc_nr, #__NR_compat_syscalls
 589         b       el0_svc_naked
 590
 591         .align  6
 592 el0_irq_compat:
 593         kernel_entry 0, 32
 594         b       el0_irq_naked
 595 #endif
 596
 597 el0_da:
 598         /*
 599          * Data abort handling
 600          */
 601         mrs     x26, far_el1
 602         // enable interrupts before calling the main handler
 603         enable_dbg_and_irq
 604         ct_user_exit
 605         clear_address_tag x0, x26
 606         mov     x1, x25
 607         mov     x2, sp
 608         bl      do_mem_abort
 609         b       ret_to_user
 610 el0_ia:
 611         /*
 612          * Instruction abort handling
 613          */
 614         mrs     x26, far_el1
 615         // enable interrupts before calling the main handler
 616         enable_dbg_and_irq
 617         ct_user_exit
 618         mov     x0, x26
 619         mov     x1, x25
 620         mov     x2, sp
 621         bl      do_mem_abort
 622         b       ret_to_user
 623 el0_fpsimd_acc:
 624         /*
 625          * Floating Point or Advanced SIMD access
 626          */
 627         enable_dbg
 628         ct_user_exit
 629         mov     x0, x25
 630         mov     x1, sp
 631         bl      do_fpsimd_acc
 632         b       ret_to_user
 633 el0_fpsimd_exc:
 634         /*
 635          * Floating Point or Advanced SIMD exception
 636          */
 637         enable_dbg
 638         ct_user_exit
 639         mov     x0, x25
 640         mov     x1, sp
 641         bl      do_fpsimd_exc
 642         b       ret_to_user
 643 el0_sp_pc:
 644         /*
 645          * Stack or PC alignment exception handling
 646          */
 647         mrs     x26, far_el1
 648         // enable interrupts before calling the main handler
 649         enable_dbg_and_irq
 650         ct_user_exit
 651         mov     x0, x26
 652         mov     x1, x25
 653         mov     x2, sp
 654         bl      do_sp_pc_abort
 655         b       ret_to_user
 656 el0_undef:
 657         /*
 658          * Undefined instruction
 659          */
 660         // enable interrupts before calling the main handler
 661         enable_dbg_and_irq
 662         ct_user_exit
 663         mov     x0, sp
 664         bl      do_undefinstr
 665         b       ret_to_user
 666 el0_sys:
 667         /*
 668          * System instructions, for trapped cache maintenance instructions
 669          */
 670         enable_dbg_and_irq
 671         ct_user_exit
 672         mov     x0, x25
 673         mov     x1, sp
 674         bl      do_sysinstr
 675         b       ret_to_user
 676 el0_dbg:
 677         /*
 678          * Debug exception handling
 679          */
 680         tbnz    x24, #0, el0_inv                // EL0 only
 681         mrs     x0, far_el1
 682         mov     x1, x25
 683         mov     x2, sp
 684         bl      do_debug_exception
 685         enable_dbg
 686         ct_user_exit
 687         b       ret_to_user
 688 el0_inv:
 689         enable_dbg
 690         ct_user_exit
 691         mov     x0, sp
 692         mov     x1, #BAD_SYNC
 693         mov     x2, x25
 694         bl      bad_el0_sync
 695         b       ret_to_user
 696 ENDPROC(el0_sync)
 697
 698         .align  6
 699 el0_irq:
 700         kernel_entry 0
 701 el0_irq_naked:
 702         enable_dbg
 703 #ifdef CONFIG_TRACE_IRQFLAGS
 704         bl      trace_hardirqs_off
 705 #endif
 706
 707         ct_user_exit
 708         irq_handler
 709
 710 #ifdef CONFIG_TRACE_IRQFLAGS
 711         bl      trace_hardirqs_on
 712 #endif
 713         b       ret_to_user
 714 ENDPROC(el0_irq)
 715
 716 /*
 717  * This is the fast syscall return path.  We do as little as possible here,
 718  * and this includes saving x0 back into the kernel stack.
 719  */
 720 ret_fast_syscall:
 721         disable_irq                             // disable interrupts
 722         str     x0, [sp, #S_X0]                 // returned x0
 723         ldr     x1, [tsk, #TSK_TI_FLAGS]        // re-check for syscall tracing
 724         and     x2, x1, #_TIF_SYSCALL_WORK
 725         cbnz    x2, ret_fast_syscall_trace
 726         and     x2, x1, #_TIF_WORK_MASK
 727         cbnz    x2, work_pending
 728         enable_step_tsk x1, x2
 729         kernel_exit 0
 730 ret_fast_syscall_trace:
 731         enable_irq                              // enable interrupts
 732         b       __sys_trace_return_skipped      // we already saved x0
 733
 734 /*
 735  * Ok, we need to do extra processing, enter the slow path.
 736  */
 737 work_pending:
 738         mov     x0, sp                          // 'regs'
 739         bl      do_notify_resume
 740 #ifdef CONFIG_TRACE_IRQFLAGS
 741         bl      trace_hardirqs_on               // enabled while in userspace
 742 #endif
 743         ldr     x1, [tsk, #TSK_TI_FLAGS]        // re-check for single-step
 744         b       finish_ret_to_user
 745 /*
 746  * "slow" syscall return path.
 747  */
 748 ret_to_user:
 749         disable_irq                             // disable interrupts
 750         ldr     x1, [tsk, #TSK_TI_FLAGS]
 751         and     x2, x1, #_TIF_WORK_MASK
 752         cbnz    x2, work_pending
 753 finish_ret_to_user:
 754         enable_step_tsk x1, x2
 755         kernel_exit 0
 756 ENDPROC(ret_to_user)
 757
 758 /*
 759  * SVC handler.
 760  */
 761         .align  6
 762 el0_svc:
 763         adrp    stbl, sys_call_table            // load syscall table pointer
 764         mov     wscno, w8                       // syscall number in w8
 765         mov     wsc_nr, #__NR_syscalls
 766 el0_svc_naked:                                  // compat entry point
 767         stp     x0, xscno, [sp, #S_ORIG_X0]     // save the original x0 and syscall number
 768         enable_dbg_and_irq
 769         ct_user_exit 1
 770
 771         ldr     x16, [tsk, #TSK_TI_FLAGS]       // check for syscall hooks
 772         tst     x16, #_TIF_SYSCALL_WORK
 773         b.ne    __sys_trace
 774         cmp     wscno, wsc_nr                   // check upper syscall limit
 775         b.hs    ni_sys
 776         ldr     x16, [stbl, xscno, lsl #3]      // address in the syscall table
 777         blr     x16                             // call sys_* routine
 778         b       ret_fast_syscall
 779 ni_sys:
 780         mov     x0, sp
 781         bl      do_ni_syscall
 782         b       ret_fast_syscall
 783 ENDPROC(el0_svc)
 784
 785         /*
 786          * This is the really slow path.  We're going to be doing context
 787          * switches, and waiting for our parent to respond.
 788          */
 789 __sys_trace:
 790         cmp     wscno, #NO_SYSCALL              // user-issued syscall(-1)?
 791         b.ne    1f
 792         mov     x0, #-ENOSYS                    // set default errno if so
 793         str     x0, [sp, #S_X0]
 794 1:      mov     x0, sp
 795         bl      syscall_trace_enter
 796         cmp     w0, #NO_SYSCALL                 // skip the syscall?
 797         b.eq    __sys_trace_return_skipped
 798         mov     wscno, w0                       // syscall number (possibly new)
 799         mov     x1, sp                          // pointer to regs
 800         cmp     wscno, wsc_nr                   // check upper syscall limit
 801         b.hs    __ni_sys_trace
 802         ldp     x0, x1, [sp]                    // restore the syscall args
 803         ldp     x2, x3, [sp, #S_X2]
 804         ldp     x4, x5, [sp, #S_X4]
 805         ldp     x6, x7, [sp, #S_X6]
 806         ldr     x16, [stbl, xscno, lsl #3]      // address in the syscall table
 807         blr     x16                             // call sys_* routine
 808
 809 __sys_trace_return:
 810         str     x0, [sp, #S_X0]                 // save returned x0
 811 __sys_trace_return_skipped:
 812         mov     x0, sp
 813         bl      syscall_trace_exit
 814         b       ret_to_user
 815
 816 __ni_sys_trace:
 817         mov     x0, sp
 818         bl      do_ni_syscall
 819         b       __sys_trace_return
 820
 821         .popsection                             // .entry.text
 822
 823 /*
 824  * Special system call wrappers.
 825  */
 826 ENTRY(sys_rt_sigreturn_wrapper)
 827         mov     x0, sp
 828         b       sys_rt_sigreturn
 829 ENDPROC(sys_rt_sigreturn_wrapper)
 830
 831 /*
 832  * Register switch for AArch64. The callee-saved registers need to be saved
 833  * and restored. On entry:
 834  *   x0 = previous task_struct (must be preserved across the switch)
 835  *   x1 = next task_struct
 836  * Previous and next are guaranteed not to be the same.
 837  *
 838  */
 839 ENTRY(cpu_switch_to)
 840         mov     x10, #THREAD_CPU_CONTEXT
 841         add     x8, x0, x10
 842         mov     x9, sp
 843         stp     x19, x20, [x8], #16             // store callee-saved registers
 844         stp     x21, x22, [x8], #16
 845         stp     x23, x24, [x8], #16
 846         stp     x25, x26, [x8], #16
 847         stp     x27, x28, [x8], #16
 848         stp     x29, x9, [x8], #16
 849         str     lr, [x8]
 850         add     x8, x1, x10
 851         ldp     x19, x20, [x8], #16             // restore callee-saved registers
 852         ldp     x21, x22, [x8], #16
 853         ldp     x23, x24, [x8], #16
 854         ldp     x25, x26, [x8], #16
 855         ldp     x27, x28, [x8], #16
 856         ldp     x29, x9, [x8], #16
 857         ldr     lr, [x8]
 858         mov     sp, x9
 859         msr     sp_el0, x1
 860         ret
 861 ENDPROC(cpu_switch_to)
 862 NOKPROBE(cpu_switch_to)
 863
 864 /*
 865  * This is how we return from a fork.
 866  */
 867 ENTRY(ret_from_fork)
 868         bl      schedule_tail
 869         cbz     x19, 1f                         // not a kernel thread
 870         mov     x0, x20
 871         blr     x19
 872 1:      get_thread_info tsk
 873         b       ret_to_user
 874 ENDPROC(ret_from_fork)
 875 NOKPROBE(ret_from_fork)