arch/x86/boot/compressed/head_32.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  *  linux/boot/head.S
   4  *
   5  *  Copyright (C) 1991, 1992, 1993  Linus Torvalds
   6  */
   7
   8 /*
   9  *  head.S contains the 32-bit startup code.
  10  *
  11  * NOTE!!! Startup happens at absolute address 0x00001000, which is also where
  12  * the page directory will exist. The startup code will be overwritten by
  13  * the page directory. [According to comments etc elsewhere on a compressed
  14  * kernel it will end up at 0x1000 + 1Mb I hope so as I assume this. - AC]
  15  *
  16  * Page 0 is deliberately kept safe, since System Management Mode code in
  17  * laptops may need to access the BIOS data stored there.  This is also
  18  * useful for future device drivers that either access the BIOS via VM86
  19  * mode.
  20  */
  21
  22 /*
  23  * High loaded stuff by Hans Lermen & Werner Almesberger, Feb. 1996
  24  */
  25         .text
  26
  27 #include <linux/init.h>
  28 #include <linux/linkage.h>
  29 #include <asm/segment.h>
  30 #include <asm/page_types.h>
  31 #include <asm/boot.h>
  32 #include <asm/asm-offsets.h>
  33 #include <asm/bootparam.h>
  34
  35 /*
  36  * The 32-bit x86 assembler in binutils 2.26 will generate R_386_GOT32X
  37  * relocation to get the symbol address in PIC.  When the compressed x86
  38  * kernel isn't built as PIC, the linker optimizes R_386_GOT32X
  39  * relocations to their fixed symbol addresses.  However, when the
  40  * compressed x86 kernel is loaded at a different address, it leads
  41  * to the following load failure:
  42  *
  43  *   Failed to allocate space for phdrs
  44  *
  45  * during the decompression stage.
  46  *
  47  * If the compressed x86 kernel is relocatable at run-time, it should be
  48  * compiled with -fPIE, instead of -fPIC, if possible and should be built as
  49  * Position Independent Executable (PIE) so that linker won't optimize
  50  * R_386_GOT32X relocation to its fixed symbol address.  Older
  51  * linkers generate R_386_32 relocations against locally defined symbols,
  52  * _bss, _ebss, _got and _egot, in PIE.  It isn't wrong, just less
  53  * optimal than R_386_RELATIVE.  But the x86 kernel fails to properly handle
  54  * R_386_32 relocations when relocating the kernel.  To generate
  55  * R_386_RELATIVE relocations, we mark _bss, _ebss, _got and _egot as
  56  * hidden:
  57  */
  58         .hidden _bss
  59         .hidden _ebss
  60         .hidden _got
  61         .hidden _egot
  62
  63         __HEAD
  64 SYM_FUNC_START(startup_32)
  65         cld
  66         /*
  67          * Test KEEP_SEGMENTS flag to see if the bootloader is asking
  68          * us to not reload segments
  69          */
  70         testb   $KEEP_SEGMENTS, BP_loadflags(%esi)
  71         jnz     1f
  72
  73         cli
  74         movl    $__BOOT_DS, %eax
  75         movl    %eax, %ds
  76         movl    %eax, %es
  77         movl    %eax, %fs
  78         movl    %eax, %gs
  79         movl    %eax, %ss
  80 1:
  81
  82 /*
  83  * Calculate the delta between where we were compiled to run
  84  * at and where we were actually loaded at.  This can only be done
  85  * with a short local call on x86.  Nothing  else will tell us what
  86  * address we are running at.  The reserved chunk of the real-mode
  87  * data at 0x1e4 (defined as a scratch field) are used as the stack
  88  * for this calculation. Only 4 bytes are needed.
  89  */
  90         leal    (BP_scratch+4)(%esi), %esp
  91         call    1f
  92 1:      popl    %ebp
  93         subl    $1b, %ebp
  94
  95 /*
  96  * %ebp contains the address we are loaded at by the boot loader and %ebx
  97  * contains the address where we should move the kernel image temporarily
  98  * for safe in-place decompression.
  99  */
 100
 101 #ifdef CONFIG_RELOCATABLE
 102         movl    %ebp, %ebx
 103         movl    BP_kernel_alignment(%esi), %eax
 104         decl    %eax
 105         addl    %eax, %ebx
 106         notl    %eax
 107         andl    %eax, %ebx
 108         cmpl    $LOAD_PHYSICAL_ADDR, %ebx
 109         jge     1f
 110 #endif
 111         movl    $LOAD_PHYSICAL_ADDR, %ebx
 112 1:
 113
 114         /* Target address to relocate to for decompression */
 115         movl    BP_init_size(%esi), %eax
 116         subl    $_end, %eax
 117         addl    %eax, %ebx
 118
 119         /* Set up the stack */
 120         leal    boot_stack_end(%ebx), %esp
 121
 122         /* Zero EFLAGS */
 123         pushl   $0
 124         popfl
 125
 126 /*
 127  * Copy the compressed kernel to the end of our buffer
 128  * where decompression in place becomes safe.
 129  */
 130         pushl   %esi
 131         leal    (_bss-4)(%ebp), %esi
 132         leal    (_bss-4)(%ebx), %edi
 133         movl    $(_bss - startup_32), %ecx
 134         shrl    $2, %ecx
 135         std
 136         rep     movsl
 137         cld
 138         popl    %esi
 139
 140 /*
 141  * Jump to the relocated address.
 142  */
 143         leal    .Lrelocated(%ebx), %eax
 144         jmp     *%eax
 145 SYM_FUNC_END(startup_32)
 146
 147 #ifdef CONFIG_EFI_STUB
 148 SYM_FUNC_START(efi32_stub_entry)
 149 SYM_FUNC_START_ALIAS(efi_stub_entry)
 150         add     $0x4, %esp
 151         call    efi_main
 152         movl    %eax, %esi
 153         movl    BP_code32_start(%esi), %eax
 154         leal    startup_32(%eax), %eax
 155         jmp     *%eax
 156 SYM_FUNC_END(efi32_stub_entry)
 157 SYM_FUNC_END_ALIAS(efi_stub_entry)
 158 #endif
 159
 160         .text
 161 SYM_FUNC_START_LOCAL_NOALIGN(.Lrelocated)
 162
 163 /*
 164  * Clear BSS (stack is currently empty)
 165  */
 166         xorl    %eax, %eax
 167         leal    _bss(%ebx), %edi
 168         leal    _ebss(%ebx), %ecx
 169         subl    %edi, %ecx
 170         shrl    $2, %ecx
 171         rep     stosl
 172
 173 /*
 174  * Adjust our own GOT
 175  */
 176         leal    _got(%ebx), %edx
 177         leal    _egot(%ebx), %ecx
 178 1:
 179         cmpl    %ecx, %edx
 180         jae     2f
 181         addl    %ebx, (%edx)
 182         addl    $4, %edx
 183         jmp     1b
 184 2:
 185
 186 /*
 187  * Do the extraction, and jump to the new kernel..
 188  */
 189                                 /* push arguments for extract_kernel: */
 190         pushl   $z_output_len   /* decompressed length, end of relocs */
 191
 192         leal    _end(%ebx), %eax
 193         subl    BP_init_size(%esi), %eax
 194         pushl   %eax            /* output address */
 195
 196         pushl   $z_input_len    /* input_len */
 197         leal    input_data(%ebx), %eax
 198         pushl   %eax            /* input_data */
 199         leal    boot_heap(%ebx), %eax
 200         pushl   %eax            /* heap area */
 201         pushl   %esi            /* real mode pointer */
 202         call    extract_kernel  /* returns kernel location in %eax */
 203         addl    $24, %esp
 204
 205 /*
 206  * Jump to the extracted kernel.
 207  */
 208         xorl    %ebx, %ebx
 209         jmp     *%eax
 210 SYM_FUNC_END(.Lrelocated)
 211
 212 /*
 213  * Stack and heap for uncompression
 214  */
 215         .bss
 216         .balign 4
 217 boot_heap:
 218         .fill BOOT_HEAP_SIZE, 1, 0
 219 boot_stack:
 220         .fill BOOT_STACK_SIZE, 1, 0
 221 boot_stack_end: