arch/x86/entry/entry_32.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  *  Copyright (C) 1991,1992  Linus Torvalds
   4  *
   5  * entry_32.S contains the system-call and low-level fault and trap handling routines.
   6  *
   7  * Stack layout while running C code:
   8  *      ptrace needs to have all registers on the stack.
   9  *      If the order here is changed, it needs to be
  10  *      updated in fork.c:copy_process(), signal.c:do_signal(),
  11  *      ptrace.c and ptrace.h
  12  *
  13  *       0(%esp) - %ebx
  14  *       4(%esp) - %ecx
  15  *       8(%esp) - %edx
  16  *       C(%esp) - %esi
  17  *      10(%esp) - %edi
  18  *      14(%esp) - %ebp
  19  *      18(%esp) - %eax
  20  *      1C(%esp) - %ds
  21  *      20(%esp) - %es
  22  *      24(%esp) - %fs
  23  *      28(%esp) - %gs          saved iff !CONFIG_X86_32_LAZY_GS
  24  *      2C(%esp) - orig_eax
  25  *      30(%esp) - %eip
  26  *      34(%esp) - %cs
  27  *      38(%esp) - %eflags
  28  *      3C(%esp) - %oldesp
  29  *      40(%esp) - %oldss
  30  */
  31
  32 #include <linux/linkage.h>
  33 #include <linux/err.h>
  34 #include <asm/thread_info.h>
  35 #include <asm/irqflags.h>
  36 #include <asm/errno.h>
  37 #include <asm/segment.h>
  38 #include <asm/smp.h>
  39 #include <asm/percpu.h>
  40 #include <asm/processor-flags.h>
  41 #include <asm/irq_vectors.h>
  42 #include <asm/cpufeatures.h>
  43 #include <asm/alternative-asm.h>
  44 #include <asm/asm.h>
  45 #include <asm/smap.h>
  46 #include <asm/frame.h>
  47 #include <asm/nospec-branch.h>
  48
  49 #include "calling.h"
  50
  51         .section .entry.text, "ax"
  52
  53 /*
  54  * We use macros for low-level operations which need to be overridden
  55  * for paravirtualization.  The following will never clobber any registers:
  56  *   INTERRUPT_RETURN (aka. "iret")
  57  *   GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
  58  *   ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
  59  *
  60  * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
  61  * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
  62  * Allowing a register to be clobbered can shrink the paravirt replacement
  63  * enough to patch inline, increasing performance.
  64  */
  65
  66 #ifdef CONFIG_PREEMPTION
  67 # define preempt_stop(clobbers) DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
  68 #else
  69 # define preempt_stop(clobbers)
  70 #endif
  71
  72 .macro TRACE_IRQS_IRET
  73 #ifdef CONFIG_TRACE_IRQFLAGS
  74         testl   $X86_EFLAGS_IF, PT_EFLAGS(%esp)     # interrupts off?
  75         jz      1f
  76         TRACE_IRQS_ON
  77 1:
  78 #endif
  79 .endm
  80
  81 #define PTI_SWITCH_MASK         (1 << PAGE_SHIFT)
  82
  83 /*
  84  * User gs save/restore
  85  *
  86  * %gs is used for userland TLS and kernel only uses it for stack
  87  * canary which is required to be at %gs:20 by gcc.  Read the comment
  88  * at the top of stackprotector.h for more info.
  89  *
  90  * Local labels 98 and 99 are used.
  91  */
  92 #ifdef CONFIG_X86_32_LAZY_GS
  93
  94  /* unfortunately push/pop can't be no-op */
  95 .macro PUSH_GS
  96         pushl   $0
  97 .endm
  98 .macro POP_GS pop=0
  99         addl    $(4 + \pop), %esp
 100 .endm
 101 .macro POP_GS_EX
 102 .endm
 103
 104  /* all the rest are no-op */
 105 .macro PTGS_TO_GS
 106 .endm
 107 .macro PTGS_TO_GS_EX
 108 .endm
 109 .macro GS_TO_REG reg
 110 .endm
 111 .macro REG_TO_PTGS reg
 112 .endm
 113 .macro SET_KERNEL_GS reg
 114 .endm
 115
 116 #else   /* CONFIG_X86_32_LAZY_GS */
 117
 118 .macro PUSH_GS
 119         pushl   %gs
 120 .endm
 121
 122 .macro POP_GS pop=0
 123 98:     popl    %gs
 124   .if \pop <> 0
 125         add     $\pop, %esp
 126   .endif
 127 .endm
 128 .macro POP_GS_EX
 129 .pushsection .fixup, "ax"
 130 99:     movl    $0, (%esp)
 131         jmp     98b
 132 .popsection
 133         _ASM_EXTABLE(98b, 99b)
 134 .endm
 135
 136 .macro PTGS_TO_GS
 137 98:     mov     PT_GS(%esp), %gs
 138 .endm
 139 .macro PTGS_TO_GS_EX
 140 .pushsection .fixup, "ax"
 141 99:     movl    $0, PT_GS(%esp)
 142         jmp     98b
 143 .popsection
 144         _ASM_EXTABLE(98b, 99b)
 145 .endm
 146
 147 .macro GS_TO_REG reg
 148         movl    %gs, \reg
 149 .endm
 150 .macro REG_TO_PTGS reg
 151         movl    \reg, PT_GS(%esp)
 152 .endm
 153 .macro SET_KERNEL_GS reg
 154         movl    $(__KERNEL_STACK_CANARY), \reg
 155         movl    \reg, %gs
 156 .endm
 157
 158 #endif /* CONFIG_X86_32_LAZY_GS */
 159
 160 /* Unconditionally switch to user cr3 */
 161 .macro SWITCH_TO_USER_CR3 scratch_reg:req
 162         ALTERNATIVE "jmp .Lend_\@", "", X86_FEATURE_PTI
 163
 164         movl    %cr3, \scratch_reg
 165         orl     $PTI_SWITCH_MASK, \scratch_reg
 166         movl    \scratch_reg, %cr3
 167 .Lend_\@:
 168 .endm
 169
 170 .macro BUG_IF_WRONG_CR3 no_user_check=0
 171 #ifdef CONFIG_DEBUG_ENTRY
 172         ALTERNATIVE "jmp .Lend_\@", "", X86_FEATURE_PTI
 173         .if \no_user_check == 0
 174         /* coming from usermode? */
 175         testl   $USER_SEGMENT_RPL_MASK, PT_CS(%esp)
 176         jz      .Lend_\@
 177         .endif
 178         /* On user-cr3? */
 179         movl    %cr3, %eax
 180         testl   $PTI_SWITCH_MASK, %eax
 181         jnz     .Lend_\@
 182         /* From userspace with kernel cr3 - BUG */
 183         ud2
 184 .Lend_\@:
 185 #endif
 186 .endm
 187
 188 /*
 189  * Switch to kernel cr3 if not already loaded and return current cr3 in
 190  * \scratch_reg
 191  */
 192 .macro SWITCH_TO_KERNEL_CR3 scratch_reg:req
 193         ALTERNATIVE "jmp .Lend_\@", "", X86_FEATURE_PTI
 194         movl    %cr3, \scratch_reg
 195         /* Test if we are already on kernel CR3 */
 196         testl   $PTI_SWITCH_MASK, \scratch_reg
 197         jz      .Lend_\@
 198         andl    $(~PTI_SWITCH_MASK), \scratch_reg
 199         movl    \scratch_reg, %cr3
 200         /* Return original CR3 in \scratch_reg */
 201         orl     $PTI_SWITCH_MASK, \scratch_reg
 202 .Lend_\@:
 203 .endm
 204
 205 #define CS_FROM_ENTRY_STACK     (1 << 31)
 206 #define CS_FROM_USER_CR3        (1 << 30)
 207 #define CS_FROM_KERNEL          (1 << 29)
 208 #define CS_FROM_ESPFIX          (1 << 28)
 209
 210 .macro FIXUP_FRAME
 211         /*
 212          * The high bits of the CS dword (__csh) are used for CS_FROM_*.
 213          * Clear them in case hardware didn't do this for us.
 214          */
 215         andl    $0x0000ffff, 4*4(%esp)
 216
 217 #ifdef CONFIG_VM86
 218         testl   $X86_EFLAGS_VM, 5*4(%esp)
 219         jnz     .Lfrom_usermode_no_fixup_\@
 220 #endif
 221         testl   $USER_SEGMENT_RPL_MASK, 4*4(%esp)
 222         jnz     .Lfrom_usermode_no_fixup_\@
 223
 224         orl     $CS_FROM_KERNEL, 4*4(%esp)
 225
 226         /*
 227          * When we're here from kernel mode; the (exception) stack looks like:
 228          *
 229          *  6*4(%esp) - <previous context>
 230          *  5*4(%esp) - flags
 231          *  4*4(%esp) - cs
 232          *  3*4(%esp) - ip
 233          *  2*4(%esp) - orig_eax
 234          *  1*4(%esp) - gs / function
 235          *  0*4(%esp) - fs
 236          *
 237          * Lets build a 5 entry IRET frame after that, such that struct pt_regs
 238          * is complete and in particular regs->sp is correct. This gives us
 239          * the original 6 enties as gap:
 240          *
 241          * 14*4(%esp) - <previous context>
 242          * 13*4(%esp) - gap / flags
 243          * 12*4(%esp) - gap / cs
 244          * 11*4(%esp) - gap / ip
 245          * 10*4(%esp) - gap / orig_eax
 246          *  9*4(%esp) - gap / gs / function
 247          *  8*4(%esp) - gap / fs
 248          *  7*4(%esp) - ss
 249          *  6*4(%esp) - sp
 250          *  5*4(%esp) - flags
 251          *  4*4(%esp) - cs
 252          *  3*4(%esp) - ip
 253          *  2*4(%esp) - orig_eax
 254          *  1*4(%esp) - gs / function
 255          *  0*4(%esp) - fs
 256          */
 257
 258         pushl   %ss             # ss
 259         pushl   %esp            # sp (points at ss)
 260         addl    $7*4, (%esp)    # point sp back at the previous context
 261         pushl   7*4(%esp)       # flags
 262         pushl   7*4(%esp)       # cs
 263         pushl   7*4(%esp)       # ip
 264         pushl   7*4(%esp)       # orig_eax
 265         pushl   7*4(%esp)       # gs / function
 266         pushl   7*4(%esp)       # fs
 267 .Lfrom_usermode_no_fixup_\@:
 268 .endm
 269
 270 .macro IRET_FRAME
 271         /*
 272          * We're called with %ds, %es, %fs, and %gs from the interrupted
 273          * frame, so we shouldn't use them.  Also, we may be in ESPFIX
 274          * mode and therefore have a nonzero SS base and an offset ESP,
 275          * so any attempt to access the stack needs to use SS.  (except for
 276          * accesses through %esp, which automatically use SS.)
 277          */
 278         testl $CS_FROM_KERNEL, 1*4(%esp)
 279         jz .Lfinished_frame_\@
 280
 281         /*
 282          * Reconstruct the 3 entry IRET frame right after the (modified)
 283          * regs->sp without lowering %esp in between, such that an NMI in the
 284          * middle doesn't scribble our stack.
 285          */
 286         pushl   %eax
 287         pushl   %ecx
 288         movl    5*4(%esp), %eax         # (modified) regs->sp
 289
 290         movl    4*4(%esp), %ecx         # flags
 291         movl    %ecx, %ss:-1*4(%eax)
 292
 293         movl    3*4(%esp), %ecx         # cs
 294         andl    $0x0000ffff, %ecx
 295         movl    %ecx, %ss:-2*4(%eax)
 296
 297         movl    2*4(%esp), %ecx         # ip
 298         movl    %ecx, %ss:-3*4(%eax)
 299
 300         movl    1*4(%esp), %ecx         # eax
 301         movl    %ecx, %ss:-4*4(%eax)
 302
 303         popl    %ecx
 304         lea     -4*4(%eax), %esp
 305         popl    %eax
 306 .Lfinished_frame_\@:
 307 .endm
 308
 309 .macro SAVE_ALL pt_regs_ax=%eax switch_stacks=0 skip_gs=0 unwind_espfix=0
 310         cld
 311 .if \skip_gs == 0
 312         PUSH_GS
 313 .endif
 314         pushl   %fs
 315
 316         pushl   %eax
 317         movl    $(__KERNEL_PERCPU), %eax
 318         movl    %eax, %fs
 319 .if \unwind_espfix > 0
 320         UNWIND_ESPFIX_STACK
 321 .endif
 322         popl    %eax
 323
 324         FIXUP_FRAME
 325         pushl   %es
 326         pushl   %ds
 327         pushl   \pt_regs_ax
 328         pushl   %ebp
 329         pushl   %edi
 330         pushl   %esi
 331         pushl   %edx
 332         pushl   %ecx
 333         pushl   %ebx
 334         movl    $(__USER_DS), %edx
 335         movl    %edx, %ds
 336         movl    %edx, %es
 337 .if \skip_gs == 0
 338         SET_KERNEL_GS %edx
 339 .endif
 340         /* Switch to kernel stack if necessary */
 341 .if \switch_stacks > 0
 342         SWITCH_TO_KERNEL_STACK
 343 .endif
 344 .endm
 345
 346 .macro SAVE_ALL_NMI cr3_reg:req unwind_espfix=0
 347         SAVE_ALL unwind_espfix=\unwind_espfix
 348
 349         BUG_IF_WRONG_CR3
 350
 351         /*
 352          * Now switch the CR3 when PTI is enabled.
 353          *
 354          * We can enter with either user or kernel cr3, the code will
 355          * store the old cr3 in \cr3_reg and switches to the kernel cr3
 356          * if necessary.
 357          */
 358         SWITCH_TO_KERNEL_CR3 scratch_reg=\cr3_reg
 359
 360 .Lend_\@:
 361 .endm
 362
 363 .macro RESTORE_INT_REGS
 364         popl    %ebx
 365         popl    %ecx
 366         popl    %edx
 367         popl    %esi
 368         popl    %edi
 369         popl    %ebp
 370         popl    %eax
 371 .endm
 372
 373 .macro RESTORE_REGS pop=0
 374         RESTORE_INT_REGS
 375 1:      popl    %ds
 376 2:      popl    %es
 377 3:      popl    %fs
 378         POP_GS \pop
 379         IRET_FRAME
 380 .pushsection .fixup, "ax"
 381 4:      movl    $0, (%esp)
 382         jmp     1b
 383 5:      movl    $0, (%esp)
 384         jmp     2b
 385 6:      movl    $0, (%esp)
 386         jmp     3b
 387 .popsection
 388         _ASM_EXTABLE(1b, 4b)
 389         _ASM_EXTABLE(2b, 5b)
 390         _ASM_EXTABLE(3b, 6b)
 391         POP_GS_EX
 392 .endm
 393
 394 .macro RESTORE_ALL_NMI cr3_reg:req pop=0
 395         /*
 396          * Now switch the CR3 when PTI is enabled.
 397          *
 398          * We enter with kernel cr3 and switch the cr3 to the value
 399          * stored on \cr3_reg, which is either a user or a kernel cr3.
 400          */
 401         ALTERNATIVE "jmp .Lswitched_\@", "", X86_FEATURE_PTI
 402
 403         testl   $PTI_SWITCH_MASK, \cr3_reg
 404         jz      .Lswitched_\@
 405
 406         /* User cr3 in \cr3_reg - write it to hardware cr3 */
 407         movl    \cr3_reg, %cr3
 408
 409 .Lswitched_\@:
 410
 411         BUG_IF_WRONG_CR3
 412
 413         RESTORE_REGS pop=\pop
 414 .endm
 415
 416 .macro CHECK_AND_APPLY_ESPFIX
 417 #ifdef CONFIG_X86_ESPFIX32
 418 #define GDT_ESPFIX_SS PER_CPU_VAR(gdt_page) + (GDT_ENTRY_ESPFIX_SS * 8)
 419
 420         ALTERNATIVE     "jmp .Lend_\@", "", X86_BUG_ESPFIX
 421
 422         movl    PT_EFLAGS(%esp), %eax           # mix EFLAGS, SS and CS
 423         /*
 424          * Warning: PT_OLDSS(%esp) contains the wrong/random values if we
 425          * are returning to the kernel.
 426          * See comments in process.c:copy_thread() for details.
 427          */
 428         movb    PT_OLDSS(%esp), %ah
 429         movb    PT_CS(%esp), %al
 430         andl    $(X86_EFLAGS_VM | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
 431         cmpl    $((SEGMENT_LDT << 8) | USER_RPL), %eax
 432         jne     .Lend_\@        # returning to user-space with LDT SS
 433
 434         /*
 435          * Setup and switch to ESPFIX stack
 436          *
 437          * We're returning to userspace with a 16 bit stack. The CPU will not
 438          * restore the high word of ESP for us on executing iret... This is an
 439          * "official" bug of all the x86-compatible CPUs, which we can work
 440          * around to make dosemu and wine happy. We do this by preloading the
 441          * high word of ESP with the high word of the userspace ESP while
 442          * compensating for the offset by changing to the ESPFIX segment with
 443          * a base address that matches for the difference.
 444          */
 445         mov     %esp, %edx                      /* load kernel esp */
 446         mov     PT_OLDESP(%esp), %eax           /* load userspace esp */
 447         mov     %dx, %ax                        /* eax: new kernel esp */
 448         sub     %eax, %edx                      /* offset (low word is 0) */
 449         shr     $16, %edx
 450         mov     %dl, GDT_ESPFIX_SS + 4          /* bits 16..23 */
 451         mov     %dh, GDT_ESPFIX_SS + 7          /* bits 24..31 */
 452         pushl   $__ESPFIX_SS
 453         pushl   %eax                            /* new kernel esp */
 454         /*
 455          * Disable interrupts, but do not irqtrace this section: we
 456          * will soon execute iret and the tracer was already set to
 457          * the irqstate after the IRET:
 458          */
 459         DISABLE_INTERRUPTS(CLBR_ANY)
 460         lss     (%esp), %esp                    /* switch to espfix segment */
 461 .Lend_\@:
 462 #endif /* CONFIG_X86_ESPFIX32 */
 463 .endm
 464
 465 /*
 466  * Called with pt_regs fully populated and kernel segments loaded,
 467  * so we can access PER_CPU and use the integer registers.
 468  *
 469  * We need to be very careful here with the %esp switch, because an NMI
 470  * can happen everywhere. If the NMI handler finds itself on the
 471  * entry-stack, it will overwrite the task-stack and everything we
 472  * copied there. So allocate the stack-frame on the task-stack and
 473  * switch to it before we do any copying.
 474  */
 475
 476 .macro SWITCH_TO_KERNEL_STACK
 477
 478         ALTERNATIVE     "", "jmp .Lend_\@", X86_FEATURE_XENPV
 479
 480         BUG_IF_WRONG_CR3
 481
 482         SWITCH_TO_KERNEL_CR3 scratch_reg=%eax
 483
 484         /*
 485          * %eax now contains the entry cr3 and we carry it forward in
 486          * that register for the time this macro runs
 487          */
 488
 489         /* Are we on the entry stack? Bail out if not! */
 490         movl    PER_CPU_VAR(cpu_entry_area), %ecx
 491         addl    $CPU_ENTRY_AREA_entry_stack + SIZEOF_entry_stack, %ecx
 492         subl    %esp, %ecx      /* ecx = (end of entry_stack) - esp */
 493         cmpl    $SIZEOF_entry_stack, %ecx
 494         jae     .Lend_\@
 495
 496         /* Load stack pointer into %esi and %edi */
 497         movl    %esp, %esi
 498         movl    %esi, %edi
 499
 500         /* Move %edi to the top of the entry stack */
 501         andl    $(MASK_entry_stack), %edi
 502         addl    $(SIZEOF_entry_stack), %edi
 503
 504         /* Load top of task-stack into %edi */
 505         movl    TSS_entry2task_stack(%edi), %edi
 506
 507         /* Special case - entry from kernel mode via entry stack */
 508 #ifdef CONFIG_VM86
 509         movl    PT_EFLAGS(%esp), %ecx           # mix EFLAGS and CS
 510         movb    PT_CS(%esp), %cl
 511         andl    $(X86_EFLAGS_VM | SEGMENT_RPL_MASK), %ecx
 512 #else
 513         movl    PT_CS(%esp), %ecx
 514         andl    $SEGMENT_RPL_MASK, %ecx
 515 #endif
 516         cmpl    $USER_RPL, %ecx
 517         jb      .Lentry_from_kernel_\@
 518
 519         /* Bytes to copy */
 520         movl    $PTREGS_SIZE, %ecx
 521
 522 #ifdef CONFIG_VM86
 523         testl   $X86_EFLAGS_VM, PT_EFLAGS(%esi)
 524         jz      .Lcopy_pt_regs_\@
 525
 526         /*
 527          * Stack-frame contains 4 additional segment registers when
 528          * coming from VM86 mode
 529          */
 530         addl    $(4 * 4), %ecx
 531
 532 #endif
 533 .Lcopy_pt_regs_\@:
 534
 535         /* Allocate frame on task-stack */
 536         subl    %ecx, %edi
 537
 538         /* Switch to task-stack */
 539         movl    %edi, %esp
 540
 541         /*
 542          * We are now on the task-stack and can safely copy over the
 543          * stack-frame
 544          */
 545         shrl    $2, %ecx
 546         cld
 547         rep movsl
 548
 549         jmp .Lend_\@
 550
 551 .Lentry_from_kernel_\@:
 552
 553         /*
 554          * This handles the case when we enter the kernel from
 555          * kernel-mode and %esp points to the entry-stack. When this
 556          * happens we need to switch to the task-stack to run C code,
 557          * but switch back to the entry-stack again when we approach
 558          * iret and return to the interrupted code-path. This usually
 559          * happens when we hit an exception while restoring user-space
 560          * segment registers on the way back to user-space or when the
 561          * sysenter handler runs with eflags.tf set.
 562          *
 563          * When we switch to the task-stack here, we can't trust the
 564          * contents of the entry-stack anymore, as the exception handler
 565          * might be scheduled out or moved to another CPU. Therefore we
 566          * copy the complete entry-stack to the task-stack and set a
 567          * marker in the iret-frame (bit 31 of the CS dword) to detect
 568          * what we've done on the iret path.
 569          *
 570          * On the iret path we copy everything back and switch to the
 571          * entry-stack, so that the interrupted kernel code-path
 572          * continues on the same stack it was interrupted with.
 573          *
 574          * Be aware that an NMI can happen anytime in this code.
 575          *
 576          * %esi: Entry-Stack pointer (same as %esp)
 577          * %edi: Top of the task stack
 578          * %eax: CR3 on kernel entry
 579          */
 580
 581         /* Calculate number of bytes on the entry stack in %ecx */
 582         movl    %esi, %ecx
 583
 584         /* %ecx to the top of entry-stack */
 585         andl    $(MASK_entry_stack), %ecx
 586         addl    $(SIZEOF_entry_stack), %ecx
 587
 588         /* Number of bytes on the entry stack to %ecx */
 589         sub     %esi, %ecx
 590
 591         /* Mark stackframe as coming from entry stack */
 592         orl     $CS_FROM_ENTRY_STACK, PT_CS(%esp)
 593
 594         /*
 595          * Test the cr3 used to enter the kernel and add a marker
 596          * so that we can switch back to it before iret.
 597          */
 598         testl   $PTI_SWITCH_MASK, %eax
 599         jz      .Lcopy_pt_regs_\@
 600         orl     $CS_FROM_USER_CR3, PT_CS(%esp)
 601
 602         /*
 603          * %esi and %edi are unchanged, %ecx contains the number of
 604          * bytes to copy. The code at .Lcopy_pt_regs_\@ will allocate
 605          * the stack-frame on task-stack and copy everything over
 606          */
 607         jmp .Lcopy_pt_regs_\@
 608
 609 .Lend_\@:
 610 .endm
 611
 612 /*
 613  * Switch back from the kernel stack to the entry stack.
 614  *
 615  * The %esp register must point to pt_regs on the task stack. It will
 616  * first calculate the size of the stack-frame to copy, depending on
 617  * whether we return to VM86 mode or not. With that it uses 'rep movsl'
 618  * to copy the contents of the stack over to the entry stack.
 619  *
 620  * We must be very careful here, as we can't trust the contents of the
 621  * task-stack once we switched to the entry-stack. When an NMI happens
 622  * while on the entry-stack, the NMI handler will switch back to the top
 623  * of the task stack, overwriting our stack-frame we are about to copy.
 624  * Therefore we switch the stack only after everything is copied over.
 625  */
 626 .macro SWITCH_TO_ENTRY_STACK
 627
 628         ALTERNATIVE     "", "jmp .Lend_\@", X86_FEATURE_XENPV
 629
 630         /* Bytes to copy */
 631         movl    $PTREGS_SIZE, %ecx
 632
 633 #ifdef CONFIG_VM86
 634         testl   $(X86_EFLAGS_VM), PT_EFLAGS(%esp)
 635         jz      .Lcopy_pt_regs_\@
 636
 637         /* Additional 4 registers to copy when returning to VM86 mode */
 638         addl    $(4 * 4), %ecx
 639
 640 .Lcopy_pt_regs_\@:
 641 #endif
 642
 643         /* Initialize source and destination for movsl */
 644         movl    PER_CPU_VAR(cpu_tss_rw + TSS_sp0), %edi
 645         subl    %ecx, %edi
 646         movl    %esp, %esi
 647
 648         /* Save future stack pointer in %ebx */
 649         movl    %edi, %ebx
 650
 651         /* Copy over the stack-frame */
 652         shrl    $2, %ecx
 653         cld
 654         rep movsl
 655
 656         /*
 657          * Switch to entry-stack - needs to happen after everything is
 658          * copied because the NMI handler will overwrite the task-stack
 659          * when on entry-stack
 660          */
 661         movl    %ebx, %esp
 662
 663 .Lend_\@:
 664 .endm
 665
 666 /*
 667  * This macro handles the case when we return to kernel-mode on the iret
 668  * path and have to switch back to the entry stack and/or user-cr3
 669  *
 670  * See the comments below the .Lentry_from_kernel_\@ label in the
 671  * SWITCH_TO_KERNEL_STACK macro for more details.
 672  */
 673 .macro PARANOID_EXIT_TO_KERNEL_MODE
 674
 675         /*
 676          * Test if we entered the kernel with the entry-stack. Most
 677          * likely we did not, because this code only runs on the
 678          * return-to-kernel path.
 679          */
 680         testl   $CS_FROM_ENTRY_STACK, PT_CS(%esp)
 681         jz      .Lend_\@
 682
 683         /* Unlikely slow-path */
 684
 685         /* Clear marker from stack-frame */
 686         andl    $(~CS_FROM_ENTRY_STACK), PT_CS(%esp)
 687
 688         /* Copy the remaining task-stack contents to entry-stack */
 689         movl    %esp, %esi
 690         movl    PER_CPU_VAR(cpu_tss_rw + TSS_sp0), %edi
 691
 692         /* Bytes on the task-stack to ecx */
 693         movl    PER_CPU_VAR(cpu_tss_rw + TSS_sp1), %ecx
 694         subl    %esi, %ecx
 695
 696         /* Allocate stack-frame on entry-stack */
 697         subl    %ecx, %edi
 698
 699         /*
 700          * Save future stack-pointer, we must not switch until the
 701          * copy is done, otherwise the NMI handler could destroy the
 702          * contents of the task-stack we are about to copy.
 703          */
 704         movl    %edi, %ebx
 705
 706         /* Do the copy */
 707         shrl    $2, %ecx
 708         cld
 709         rep movsl
 710
 711         /* Safe to switch to entry-stack now */
 712         movl    %ebx, %esp
 713
 714         /*
 715          * We came from entry-stack and need to check if we also need to
 716          * switch back to user cr3.
 717          */
 718         testl   $CS_FROM_USER_CR3, PT_CS(%esp)
 719         jz      .Lend_\@
 720
 721         /* Clear marker from stack-frame */
 722         andl    $(~CS_FROM_USER_CR3), PT_CS(%esp)
 723
 724         SWITCH_TO_USER_CR3 scratch_reg=%eax
 725
 726 .Lend_\@:
 727 .endm
 728 /*
 729  * %eax: prev task
 730  * %edx: next task
 731  */
 732 ENTRY(__switch_to_asm)
 733         /*
 734          * Save callee-saved registers
 735          * This must match the order in struct inactive_task_frame
 736          */
 737         pushl   %ebp
 738         pushl   %ebx
 739         pushl   %edi
 740         pushl   %esi
 741         pushfl
 742
 743         /* switch stack */
 744         movl    %esp, TASK_threadsp(%eax)
 745         movl    TASK_threadsp(%edx), %esp
 746
 747 #ifdef CONFIG_STACKPROTECTOR
 748         movl    TASK_stack_canary(%edx), %ebx
 749         movl    %ebx, PER_CPU_VAR(stack_canary)+stack_canary_offset
 750 #endif
 751
 752 #ifdef CONFIG_RETPOLINE
 753         /*
 754          * When switching from a shallower to a deeper call stack
 755          * the RSB may either underflow or use entries populated
 756          * with userspace addresses. On CPUs where those concerns
 757          * exist, overwrite the RSB with entries which capture
 758          * speculative execution to prevent attack.
 759          */
 760         FILL_RETURN_BUFFER %ebx, RSB_CLEAR_LOOPS, X86_FEATURE_RSB_CTXSW
 761 #endif
 762
 763         /* restore callee-saved registers */
 764         popfl
 765         popl    %esi
 766         popl    %edi
 767         popl    %ebx
 768         popl    %ebp
 769
 770         jmp     __switch_to
 771 END(__switch_to_asm)
 772
 773 /*
 774  * The unwinder expects the last frame on the stack to always be at the same
 775  * offset from the end of the page, which allows it to validate the stack.
 776  * Calling schedule_tail() directly would break that convention because its an
 777  * asmlinkage function so its argument has to be pushed on the stack.  This
 778  * wrapper creates a proper "end of stack" frame header before the call.
 779  */
 780 ENTRY(schedule_tail_wrapper)
 781         FRAME_BEGIN
 782
 783         pushl   %eax
 784         call    schedule_tail
 785         popl    %eax
 786
 787         FRAME_END
 788         ret
 789 ENDPROC(schedule_tail_wrapper)
 790 /*
 791  * A newly forked process directly context switches into this address.
 792  *
 793  * eax: prev task we switched from
 794  * ebx: kernel thread func (NULL for user thread)
 795  * edi: kernel thread arg
 796  */
 797 ENTRY(ret_from_fork)
 798         call    schedule_tail_wrapper
 799
 800         testl   %ebx, %ebx
 801         jnz     1f              /* kernel threads are uncommon */
 802
 803 2:
 804         /* When we fork, we trace the syscall return in the child, too. */
 805         movl    %esp, %eax
 806         call    syscall_return_slowpath
 807         STACKLEAK_ERASE
 808         jmp     restore_all
 809
 810         /* kernel thread */
 811 1:      movl    %edi, %eax
 812         CALL_NOSPEC %ebx
 813         /*
 814          * A kernel thread is allowed to return here after successfully
 815          * calling do_execve().  Exit to userspace to complete the execve()
 816          * syscall.
 817          */
 818         movl    $0, PT_EAX(%esp)
 819         jmp     2b
 820 END(ret_from_fork)
 821
 822 /*
 823  * Return to user mode is not as complex as all this looks,
 824  * but we want the default path for a system call return to
 825  * go as quickly as possible which is why some of this is
 826  * less clear than it otherwise should be.
 827  */
 828
 829         # userspace resumption stub bypassing syscall exit tracing
 830         ALIGN
 831 ret_from_exception:
 832         preempt_stop(CLBR_ANY)
 833 ret_from_intr:
 834 #ifdef CONFIG_VM86
 835         movl    PT_EFLAGS(%esp), %eax           # mix EFLAGS and CS
 836         movb    PT_CS(%esp), %al
 837         andl    $(X86_EFLAGS_VM | SEGMENT_RPL_MASK), %eax
 838 #else
 839         /*
 840          * We can be coming here from child spawned by kernel_thread().
 841          */
 842         movl    PT_CS(%esp), %eax
 843         andl    $SEGMENT_RPL_MASK, %eax
 844 #endif
 845         cmpl    $USER_RPL, %eax
 846         jb      restore_all_kernel              # not returning to v8086 or userspace
 847
 848 ENTRY(resume_userspace)
 849         DISABLE_INTERRUPTS(CLBR_ANY)
 850         TRACE_IRQS_OFF
 851         movl    %esp, %eax
 852         call    prepare_exit_to_usermode
 853         jmp     restore_all
 854 END(ret_from_exception)
 855
 856 GLOBAL(__begin_SYSENTER_singlestep_region)
 857 /*
 858  * All code from here through __end_SYSENTER_singlestep_region is subject
 859  * to being single-stepped if a user program sets TF and executes SYSENTER.
 860  * There is absolutely nothing that we can do to prevent this from happening
 861  * (thanks Intel!).  To keep our handling of this situation as simple as
 862  * possible, we handle TF just like AC and NT, except that our #DB handler
 863  * will ignore all of the single-step traps generated in this range.
 864  */
 865
 866 #ifdef CONFIG_XEN_PV
 867 /*
 868  * Xen doesn't set %esp to be precisely what the normal SYSENTER
 869  * entry point expects, so fix it up before using the normal path.
 870  */
 871 ENTRY(xen_sysenter_target)
 872         addl    $5*4, %esp                      /* remove xen-provided frame */
 873         jmp     .Lsysenter_past_esp
 874 #endif
 875
 876 /*
 877  * 32-bit SYSENTER entry.
 878  *
 879  * 32-bit system calls through the vDSO's __kernel_vsyscall enter here
 880  * if X86_FEATURE_SEP is available.  This is the preferred system call
 881  * entry on 32-bit systems.
 882  *
 883  * The SYSENTER instruction, in principle, should *only* occur in the
 884  * vDSO.  In practice, a small number of Android devices were shipped
 885  * with a copy of Bionic that inlined a SYSENTER instruction.  This
 886  * never happened in any of Google's Bionic versions -- it only happened
 887  * in a narrow range of Intel-provided versions.
 888  *
 889  * SYSENTER loads SS, ESP, CS, and EIP from previously programmed MSRs.
 890  * IF and VM in RFLAGS are cleared (IOW: interrupts are off).
 891  * SYSENTER does not save anything on the stack,
 892  * and does not save old EIP (!!!), ESP, or EFLAGS.
 893  *
 894  * To avoid losing track of EFLAGS.VM (and thus potentially corrupting
 895  * user and/or vm86 state), we explicitly disable the SYSENTER
 896  * instruction in vm86 mode by reprogramming the MSRs.
 897  *
 898  * Arguments:
 899  * eax  system call number
 900  * ebx  arg1
 901  * ecx  arg2
 902  * edx  arg3
 903  * esi  arg4
 904  * edi  arg5
 905  * ebp  user stack
 906  * 0(%ebp) arg6
 907  */
 908 ENTRY(entry_SYSENTER_32)
 909         /*
 910          * On entry-stack with all userspace-regs live - save and
 911          * restore eflags and %eax to use it as scratch-reg for the cr3
 912          * switch.
 913          */
 914         pushfl
 915         pushl   %eax
 916         BUG_IF_WRONG_CR3 no_user_check=1
 917         SWITCH_TO_KERNEL_CR3 scratch_reg=%eax
 918         popl    %eax
 919         popfl
 920
 921         /* Stack empty again, switch to task stack */
 922         movl    TSS_entry2task_stack(%esp), %esp
 923
 924 .Lsysenter_past_esp:
 925         pushl   $__USER_DS              /* pt_regs->ss */
 926         pushl   %ebp                    /* pt_regs->sp (stashed in bp) */
 927         pushfl                          /* pt_regs->flags (except IF = 0) */
 928         orl     $X86_EFLAGS_IF, (%esp)  /* Fix IF */
 929         pushl   $__USER_CS              /* pt_regs->cs */
 930         pushl   $0                      /* pt_regs->ip = 0 (placeholder) */
 931         pushl   %eax                    /* pt_regs->orig_ax */
 932         SAVE_ALL pt_regs_ax=$-ENOSYS    /* save rest, stack already switched */
 933
 934         /*
 935          * SYSENTER doesn't filter flags, so we need to clear NT, AC
 936          * and TF ourselves.  To save a few cycles, we can check whether
 937          * either was set instead of doing an unconditional popfq.
 938          * This needs to happen before enabling interrupts so that
 939          * we don't get preempted with NT set.
 940          *
 941          * If TF is set, we will single-step all the way to here -- do_debug
 942          * will ignore all the traps.  (Yes, this is slow, but so is
 943          * single-stepping in general.  This allows us to avoid having
 944          * a more complicated code to handle the case where a user program
 945          * forces us to single-step through the SYSENTER entry code.)
 946          *
 947          * NB.: .Lsysenter_fix_flags is a label with the code under it moved
 948          * out-of-line as an optimization: NT is unlikely to be set in the
 949          * majority of the cases and instead of polluting the I$ unnecessarily,
 950          * we're keeping that code behind a branch which will predict as
 951          * not-taken and therefore its instructions won't be fetched.
 952          */
 953         testl   $X86_EFLAGS_NT|X86_EFLAGS_AC|X86_EFLAGS_TF, PT_EFLAGS(%esp)
 954         jnz     .Lsysenter_fix_flags
 955 .Lsysenter_flags_fixed:
 956
 957         /*
 958          * User mode is traced as though IRQs are on, and SYSENTER
 959          * turned them off.
 960          */
 961         TRACE_IRQS_OFF
 962
 963         movl    %esp, %eax
 964         call    do_fast_syscall_32
 965         /* XEN PV guests always use IRET path */
 966         ALTERNATIVE "testl %eax, %eax; jz .Lsyscall_32_done", \
 967                     "jmp .Lsyscall_32_done", X86_FEATURE_XENPV
 968
 969         STACKLEAK_ERASE
 970
 971 /* Opportunistic SYSEXIT */
 972         TRACE_IRQS_ON                   /* User mode traces as IRQs on. */
 973
 974         /*
 975          * Setup entry stack - we keep the pointer in %eax and do the
 976          * switch after almost all user-state is restored.
 977          */
 978
 979         /* Load entry stack pointer and allocate frame for eflags/eax */
 980         movl    PER_CPU_VAR(cpu_tss_rw + TSS_sp0), %eax
 981         subl    $(2*4), %eax
 982
 983         /* Copy eflags and eax to entry stack */
 984         movl    PT_EFLAGS(%esp), %edi
 985         movl    PT_EAX(%esp), %esi
 986         movl    %edi, (%eax)
 987         movl    %esi, 4(%eax)
 988
 989         /* Restore user registers and segments */
 990         movl    PT_EIP(%esp), %edx      /* pt_regs->ip */
 991         movl    PT_OLDESP(%esp), %ecx   /* pt_regs->sp */
 992 1:      mov     PT_FS(%esp), %fs
 993         PTGS_TO_GS
 994
 995         popl    %ebx                    /* pt_regs->bx */
 996         addl    $2*4, %esp              /* skip pt_regs->cx and pt_regs->dx */
 997         popl    %esi                    /* pt_regs->si */
 998         popl    %edi                    /* pt_regs->di */
 999         popl    %ebp                    /* pt_regs->bp */
1000
1001         /* Switch to entry stack */
1002         movl    %eax, %esp
1003
1004         /* Now ready to switch the cr3 */
1005         SWITCH_TO_USER_CR3 scratch_reg=%eax
1006
1007         /*
1008          * Restore all flags except IF. (We restore IF separately because
1009          * STI gives a one-instruction window in which we won't be interrupted,
1010          * whereas POPF does not.)
1011          */
1012         btrl    $X86_EFLAGS_IF_BIT, (%esp)
1013         BUG_IF_WRONG_CR3 no_user_check=1
1014         popfl
1015         popl    %eax
1016
1017         /*
1018          * Return back to the vDSO, which will pop ecx and edx.
1019          * Don't bother with DS and ES (they already contain __USER_DS).
1020          */
1021         sti
1022         sysexit
1023
1024 .pushsection .fixup, "ax"
1025 2:      movl    $0, PT_FS(%esp)
1026         jmp     1b
1027 .popsection
1028         _ASM_EXTABLE(1b, 2b)
1029         PTGS_TO_GS_EX
1030
1031 .Lsysenter_fix_flags:
1032         pushl   $X86_EFLAGS_FIXED
1033         popfl
1034         jmp     .Lsysenter_flags_fixed
1035 GLOBAL(__end_SYSENTER_singlestep_region)
1036 ENDPROC(entry_SYSENTER_32)
1037
1038 /*
1039  * 32-bit legacy system call entry.
1040  *
1041  * 32-bit x86 Linux system calls traditionally used the INT $0x80
1042  * instruction.  INT $0x80 lands here.
1043  *
1044  * This entry point can be used by any 32-bit perform system calls.
1045  * Instances of INT $0x80 can be found inline in various programs and
1046  * libraries.  It is also used by the vDSO's __kernel_vsyscall
1047  * fallback for hardware that doesn't support a faster entry method.
1048  * Restarted 32-bit system calls also fall back to INT $0x80
1049  * regardless of what instruction was originally used to do the system
1050  * call.  (64-bit programs can use INT $0x80 as well, but they can
1051  * only run on 64-bit kernels and therefore land in
1052  * entry_INT80_compat.)
1053  *
1054  * This is considered a slow path.  It is not used by most libc
1055  * implementations on modern hardware except during process startup.
1056  *
1057  * Arguments:
1058  * eax  system call number
1059  * ebx  arg1
1060  * ecx  arg2
1061  * edx  arg3
1062  * esi  arg4
1063  * edi  arg5
1064  * ebp  arg6
1065  */
1066 ENTRY(entry_INT80_32)
1067         ASM_CLAC
1068         pushl   %eax                    /* pt_regs->orig_ax */
1069
1070         SAVE_ALL pt_regs_ax=$-ENOSYS switch_stacks=1    /* save rest */
1071
1072         /*
1073          * User mode is traced as though IRQs are on, and the interrupt gate
1074          * turned them off.
1075          */
1076         TRACE_IRQS_OFF
1077
1078         movl    %esp, %eax
1079         call    do_int80_syscall_32
1080 .Lsyscall_32_done:
1081
1082         STACKLEAK_ERASE
1083
1084 restore_all:
1085         TRACE_IRQS_IRET
1086         SWITCH_TO_ENTRY_STACK
1087 .Lrestore_all_notrace:
1088         CHECK_AND_APPLY_ESPFIX
1089 .Lrestore_nocheck:
1090         /* Switch back to user CR3 */
1091         SWITCH_TO_USER_CR3 scratch_reg=%eax
1092
1093         BUG_IF_WRONG_CR3
1094
1095         /* Restore user state */
1096         RESTORE_REGS pop=4                      # skip orig_eax/error_code
1097 .Lirq_return:
1098         /*
1099          * ARCH_HAS_MEMBARRIER_SYNC_CORE rely on IRET core serialization
1100          * when returning from IPI handler and when returning from
1101          * scheduler to user-space.
1102          */
1103         INTERRUPT_RETURN
1104
1105 restore_all_kernel:
1106 #ifdef CONFIG_PREEMPTION
1107         DISABLE_INTERRUPTS(CLBR_ANY)
1108         cmpl    $0, PER_CPU_VAR(__preempt_count)
1109         jnz     .Lno_preempt
1110         testl   $X86_EFLAGS_IF, PT_EFLAGS(%esp) # interrupts off (exception path) ?
1111         jz      .Lno_preempt
1112         call    preempt_schedule_irq
1113 .Lno_preempt:
1114 #endif
1115         TRACE_IRQS_IRET
1116         PARANOID_EXIT_TO_KERNEL_MODE
1117         BUG_IF_WRONG_CR3
1118         RESTORE_REGS 4
1119         jmp     .Lirq_return
1120
1121 .section .fixup, "ax"
1122 ENTRY(iret_exc  )
1123         pushl   $0                              # no error code
1124         pushl   $do_iret_error
1125
1126 #ifdef CONFIG_DEBUG_ENTRY
1127         /*
1128          * The stack-frame here is the one that iret faulted on, so its a
1129          * return-to-user frame. We are on kernel-cr3 because we come here from
1130          * the fixup code. This confuses the CR3 checker, so switch to user-cr3
1131          * as the checker expects it.
1132          */
1133         pushl   %eax
1134         SWITCH_TO_USER_CR3 scratch_reg=%eax
1135         popl    %eax
1136 #endif
1137
1138         jmp     common_exception
1139 .previous
1140         _ASM_EXTABLE(.Lirq_return, iret_exc)
1141 ENDPROC(entry_INT80_32)
1142
1143 .macro FIXUP_ESPFIX_STACK
1144 /*
1145  * Switch back for ESPFIX stack to the normal zerobased stack
1146  *
1147  * We can't call C functions using the ESPFIX stack. This code reads
1148  * the high word of the segment base from the GDT and swiches to the
1149  * normal stack and adjusts ESP with the matching offset.
1150  */
1151 #ifdef CONFIG_X86_ESPFIX32
1152         /* fixup the stack */
1153         mov     GDT_ESPFIX_SS + 4, %al /* bits 16..23 */
1154         mov     GDT_ESPFIX_SS + 7, %ah /* bits 24..31 */
1155         shl     $16, %eax
1156         addl    %esp, %eax                      /* the adjusted stack pointer */
1157         pushl   $__KERNEL_DS
1158         pushl   %eax
1159         lss     (%esp), %esp                    /* switch to the normal stack segment */
1160 #endif
1161 .endm
1162
1163 .macro UNWIND_ESPFIX_STACK
1164         /* It's safe to clobber %eax, all other regs need to be preserved */
1165 #ifdef CONFIG_X86_ESPFIX32
1166         movl    %ss, %eax
1167         /* see if on espfix stack */
1168         cmpw    $__ESPFIX_SS, %ax
1169         jne     .Lno_fixup_\@
1170         /* switch to normal stack */
1171         FIXUP_ESPFIX_STACK
1172 .Lno_fixup_\@:
1173 #endif
1174 .endm
1175
1176 /*
1177  * Build the entry stubs with some assembler magic.
1178  * We pack 1 stub into every 8-byte block.
1179  */
1180         .align 8
1181 ENTRY(irq_entries_start)
1182     vector=FIRST_EXTERNAL_VECTOR
1183     .rept (FIRST_SYSTEM_VECTOR - FIRST_EXTERNAL_VECTOR)
1184         pushl   $(~vector+0x80)                 /* Note: always in signed byte range */
1185     vector=vector+1
1186         jmp     common_interrupt
1187         .align  8
1188     .endr
1189 END(irq_entries_start)
1190
1191 #ifdef CONFIG_X86_LOCAL_APIC
1192         .align 8
1193 ENTRY(spurious_entries_start)
1194     vector=FIRST_SYSTEM_VECTOR
1195     .rept (NR_VECTORS - FIRST_SYSTEM_VECTOR)
1196         pushl   $(~vector+0x80)                 /* Note: always in signed byte range */
1197     vector=vector+1
1198         jmp     common_spurious
1199         .align  8
1200     .endr
1201 END(spurious_entries_start)
1202
1203 common_spurious:
1204         ASM_CLAC
1205         addl    $-0x80, (%esp)                  /* Adjust vector into the [-256, -1] range */
1206         SAVE_ALL switch_stacks=1
1207         ENCODE_FRAME_POINTER
1208         TRACE_IRQS_OFF
1209         movl    %esp, %eax
1210         call    smp_spurious_interrupt
1211         jmp     ret_from_intr
1212 ENDPROC(common_spurious)
1213 #endif
1214
1215 /*
1216  * the CPU automatically disables interrupts when executing an IRQ vector,
1217  * so IRQ-flags tracing has to follow that:
1218  */
1219         .p2align CONFIG_X86_L1_CACHE_SHIFT
1220 common_interrupt:
1221         ASM_CLAC
1222         addl    $-0x80, (%esp)                  /* Adjust vector into the [-256, -1] range */
1223
1224         SAVE_ALL switch_stacks=1
1225         ENCODE_FRAME_POINTER
1226         TRACE_IRQS_OFF
1227         movl    %esp, %eax
1228         call    do_IRQ
1229         jmp     ret_from_intr
1230 ENDPROC(common_interrupt)
1231
1232 #define BUILD_INTERRUPT3(name, nr, fn)                  \
1233 ENTRY(name)                                             \
1234         ASM_CLAC;                                       \
1235         pushl   $~(nr);                                 \
1236         SAVE_ALL switch_stacks=1;                       \
1237         ENCODE_FRAME_POINTER;                           \
1238         TRACE_IRQS_OFF                                  \
1239         movl    %esp, %eax;                             \
1240         call    fn;                                     \
1241         jmp     ret_from_intr;                          \
1242 ENDPROC(name)
1243
1244 #define BUILD_INTERRUPT(name, nr)               \
1245         BUILD_INTERRUPT3(name, nr, smp_##name); \
1246
1247 /* The include is where all of the SMP etc. interrupts come from */
1248 #include <asm/entry_arch.h>
1249
1250 ENTRY(coprocessor_error)
1251         ASM_CLAC
1252         pushl   $0
1253         pushl   $do_coprocessor_error
1254         jmp     common_exception
1255 END(coprocessor_error)
1256
1257 ENTRY(simd_coprocessor_error)
1258         ASM_CLAC
1259         pushl   $0
1260 #ifdef CONFIG_X86_INVD_BUG
1261         /* AMD 486 bug: invd from userspace calls exception 19 instead of #GP */
1262         ALTERNATIVE "pushl      $do_general_protection",        \
1263                     "pushl      $do_simd_coprocessor_error",    \
1264                     X86_FEATURE_XMM
1265 #else
1266         pushl   $do_simd_coprocessor_error
1267 #endif
1268         jmp     common_exception
1269 END(simd_coprocessor_error)
1270
1271 ENTRY(device_not_available)
1272         ASM_CLAC
1273         pushl   $-1                             # mark this as an int
1274         pushl   $do_device_not_available
1275         jmp     common_exception
1276 END(device_not_available)
1277
1278 #ifdef CONFIG_PARAVIRT
1279 ENTRY(native_iret)
1280         iret
1281         _ASM_EXTABLE(native_iret, iret_exc)
1282 END(native_iret)
1283 #endif
1284
1285 ENTRY(overflow)
1286         ASM_CLAC
1287         pushl   $0
1288         pushl   $do_overflow
1289         jmp     common_exception
1290 END(overflow)
1291
1292 ENTRY(bounds)
1293         ASM_CLAC
1294         pushl   $0
1295         pushl   $do_bounds
1296         jmp     common_exception
1297 END(bounds)
1298
1299 ENTRY(invalid_op)
1300         ASM_CLAC
1301         pushl   $0
1302         pushl   $do_invalid_op
1303         jmp     common_exception
1304 END(invalid_op)
1305
1306 ENTRY(coprocessor_segment_overrun)
1307         ASM_CLAC
1308         pushl   $0
1309         pushl   $do_coprocessor_segment_overrun
1310         jmp     common_exception
1311 END(coprocessor_segment_overrun)
1312
1313 ENTRY(invalid_TSS)
1314         ASM_CLAC
1315         pushl   $do_invalid_TSS
1316         jmp     common_exception
1317 END(invalid_TSS)
1318
1319 ENTRY(segment_not_present)
1320         ASM_CLAC
1321         pushl   $do_segment_not_present
1322         jmp     common_exception
1323 END(segment_not_present)
1324
1325 ENTRY(stack_segment)
1326         ASM_CLAC
1327         pushl   $do_stack_segment
1328         jmp     common_exception
1329 END(stack_segment)
1330
1331 ENTRY(alignment_check)
1332         ASM_CLAC
1333         pushl   $do_alignment_check
1334         jmp     common_exception
1335 END(alignment_check)
1336
1337 ENTRY(divide_error)
1338         ASM_CLAC
1339         pushl   $0                              # no error code
1340         pushl   $do_divide_error
1341         jmp     common_exception
1342 END(divide_error)
1343
1344 #ifdef CONFIG_X86_MCE
1345 ENTRY(machine_check)
1346         ASM_CLAC
1347         pushl   $0
1348         pushl   machine_check_vector
1349         jmp     common_exception
1350 END(machine_check)
1351 #endif
1352
1353 ENTRY(spurious_interrupt_bug)
1354         ASM_CLAC
1355         pushl   $0
1356         pushl   $do_spurious_interrupt_bug
1357         jmp     common_exception
1358 END(spurious_interrupt_bug)
1359
1360 #ifdef CONFIG_XEN_PV
1361 ENTRY(xen_hypervisor_callback)
1362         /*
1363          * Check to see if we got the event in the critical
1364          * region in xen_iret_direct, after we've reenabled
1365          * events and checked for pending events.  This simulates
1366          * iret instruction's behaviour where it delivers a
1367          * pending interrupt when enabling interrupts:
1368          */
1369         cmpl    $xen_iret_start_crit, (%esp)
1370         jb      1f
1371         cmpl    $xen_iret_end_crit, (%esp)
1372         jae     1f
1373         call    xen_iret_crit_fixup
1374 1:
1375         pushl   $-1                             /* orig_ax = -1 => not a system call */
1376         SAVE_ALL
1377         ENCODE_FRAME_POINTER
1378         TRACE_IRQS_OFF
1379         mov     %esp, %eax
1380         call    xen_evtchn_do_upcall
1381 #ifndef CONFIG_PREEMPTION
1382         call    xen_maybe_preempt_hcall
1383 #endif
1384         jmp     ret_from_intr
1385 ENDPROC(xen_hypervisor_callback)
1386
1387 /*
1388  * Hypervisor uses this for application faults while it executes.
1389  * We get here for two reasons:
1390  *  1. Fault while reloading DS, ES, FS or GS
1391  *  2. Fault while executing IRET
1392  * Category 1 we fix up by reattempting the load, and zeroing the segment
1393  * register if the load fails.
1394  * Category 2 we fix up by jumping to do_iret_error. We cannot use the
1395  * normal Linux return path in this case because if we use the IRET hypercall
1396  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1397  * We distinguish between categories by maintaining a status value in EAX.
1398  */
1399 ENTRY(xen_failsafe_callback)
1400         pushl   %eax
1401         movl    $1, %eax
1402 1:      mov     4(%esp), %ds
1403 2:      mov     8(%esp), %es
1404 3:      mov     12(%esp), %fs
1405 4:      mov     16(%esp), %gs
1406         /* EAX == 0 => Category 1 (Bad segment)
1407            EAX != 0 => Category 2 (Bad IRET) */
1408         testl   %eax, %eax
1409         popl    %eax
1410         lea     16(%esp), %esp
1411         jz      5f
1412         jmp     iret_exc
1413 5:      pushl   $-1                             /* orig_ax = -1 => not a system call */
1414         SAVE_ALL
1415         ENCODE_FRAME_POINTER
1416         jmp     ret_from_exception
1417
1418 .section .fixup, "ax"
1419 6:      xorl    %eax, %eax
1420         movl    %eax, 4(%esp)
1421         jmp     1b
1422 7:      xorl    %eax, %eax
1423         movl    %eax, 8(%esp)
1424         jmp     2b
1425 8:      xorl    %eax, %eax
1426         movl    %eax, 12(%esp)
1427         jmp     3b
1428 9:      xorl    %eax, %eax
1429         movl    %eax, 16(%esp)
1430         jmp     4b
1431 .previous
1432         _ASM_EXTABLE(1b, 6b)
1433         _ASM_EXTABLE(2b, 7b)
1434         _ASM_EXTABLE(3b, 8b)
1435         _ASM_EXTABLE(4b, 9b)
1436 ENDPROC(xen_failsafe_callback)
1437 #endif /* CONFIG_XEN_PV */
1438
1439 #ifdef CONFIG_XEN_PVHVM
1440 BUILD_INTERRUPT3(xen_hvm_callback_vector, HYPERVISOR_CALLBACK_VECTOR,
1441                  xen_evtchn_do_upcall)
1442 #endif
1443
1444
1445 #if IS_ENABLED(CONFIG_HYPERV)
1446
1447 BUILD_INTERRUPT3(hyperv_callback_vector, HYPERVISOR_CALLBACK_VECTOR,
1448                  hyperv_vector_handler)
1449
1450 BUILD_INTERRUPT3(hyperv_reenlightenment_vector, HYPERV_REENLIGHTENMENT_VECTOR,
1451                  hyperv_reenlightenment_intr)
1452
1453 BUILD_INTERRUPT3(hv_stimer0_callback_vector, HYPERV_STIMER0_VECTOR,
1454                  hv_stimer0_vector_handler)
1455
1456 #endif /* CONFIG_HYPERV */
1457
1458 ENTRY(page_fault)
1459         ASM_CLAC
1460         pushl   $do_page_fault
1461         jmp     common_exception_read_cr2
1462 END(page_fault)
1463
1464 common_exception_read_cr2:
1465         /* the function address is in %gs's slot on the stack */
1466         SAVE_ALL switch_stacks=1 skip_gs=1 unwind_espfix=1
1467
1468         ENCODE_FRAME_POINTER
1469
1470         /* fixup %gs */
1471         GS_TO_REG %ecx
1472         movl    PT_GS(%esp), %edi
1473         REG_TO_PTGS %ecx
1474         SET_KERNEL_GS %ecx
1475
1476         GET_CR2_INTO(%ecx)                      # might clobber %eax
1477
1478         /* fixup orig %eax */
1479         movl    PT_ORIG_EAX(%esp), %edx         # get the error code
1480         movl    $-1, PT_ORIG_EAX(%esp)          # no syscall to restart
1481
1482         TRACE_IRQS_OFF
1483         movl    %esp, %eax                      # pt_regs pointer
1484         CALL_NOSPEC %edi
1485         jmp     ret_from_exception
1486 END(common_exception_read_cr2)
1487
1488 common_exception:
1489         /* the function address is in %gs's slot on the stack */
1490         SAVE_ALL switch_stacks=1 skip_gs=1 unwind_espfix=1
1491         ENCODE_FRAME_POINTER
1492
1493         /* fixup %gs */
1494         GS_TO_REG %ecx
1495         movl    PT_GS(%esp), %edi               # get the function address
1496         REG_TO_PTGS %ecx
1497         SET_KERNEL_GS %ecx
1498
1499         /* fixup orig %eax */
1500         movl    PT_ORIG_EAX(%esp), %edx         # get the error code
1501         movl    $-1, PT_ORIG_EAX(%esp)          # no syscall to restart
1502
1503         TRACE_IRQS_OFF
1504         movl    %esp, %eax                      # pt_regs pointer
1505         CALL_NOSPEC %edi
1506         jmp     ret_from_exception
1507 END(common_exception)
1508
1509 ENTRY(debug)
1510         /*
1511          * Entry from sysenter is now handled in common_exception
1512          */
1513         ASM_CLAC
1514         pushl   $-1                             # mark this as an int
1515         pushl   $do_debug
1516         jmp     common_exception
1517 END(debug)
1518
1519 /*
1520  * NMI is doubly nasty.  It can happen on the first instruction of
1521  * entry_SYSENTER_32 (just like #DB), but it can also interrupt the beginning
1522  * of the #DB handler even if that #DB in turn hit before entry_SYSENTER_32
1523  * switched stacks.  We handle both conditions by simply checking whether we
1524  * interrupted kernel code running on the SYSENTER stack.
1525  */
1526 ENTRY(nmi)
1527         ASM_CLAC
1528
1529 #ifdef CONFIG_X86_ESPFIX32
1530         /*
1531          * ESPFIX_SS is only ever set on the return to user path
1532          * after we've switched to the entry stack.
1533          */
1534         pushl   %eax
1535         movl    %ss, %eax
1536         cmpw    $__ESPFIX_SS, %ax
1537         popl    %eax
1538         je      .Lnmi_espfix_stack
1539 #endif
1540
1541         pushl   %eax                            # pt_regs->orig_ax
1542         SAVE_ALL_NMI cr3_reg=%edi
1543         ENCODE_FRAME_POINTER
1544         xorl    %edx, %edx                      # zero error code
1545         movl    %esp, %eax                      # pt_regs pointer
1546
1547         /* Are we currently on the SYSENTER stack? */
1548         movl    PER_CPU_VAR(cpu_entry_area), %ecx
1549         addl    $CPU_ENTRY_AREA_entry_stack + SIZEOF_entry_stack, %ecx
1550         subl    %eax, %ecx      /* ecx = (end of entry_stack) - esp */
1551         cmpl    $SIZEOF_entry_stack, %ecx
1552         jb      .Lnmi_from_sysenter_stack
1553
1554         /* Not on SYSENTER stack. */
1555         call    do_nmi
1556         jmp     .Lnmi_return
1557
1558 .Lnmi_from_sysenter_stack:
1559         /*
1560          * We're on the SYSENTER stack.  Switch off.  No one (not even debug)
1561          * is using the thread stack right now, so it's safe for us to use it.
1562          */
1563         movl    %esp, %ebx
1564         movl    PER_CPU_VAR(cpu_current_top_of_stack), %esp
1565         call    do_nmi
1566         movl    %ebx, %esp
1567
1568 .Lnmi_return:
1569 #ifdef CONFIG_X86_ESPFIX32
1570         testl   $CS_FROM_ESPFIX, PT_CS(%esp)
1571         jnz     .Lnmi_from_espfix
1572 #endif
1573
1574         CHECK_AND_APPLY_ESPFIX
1575         RESTORE_ALL_NMI cr3_reg=%edi pop=4
1576         jmp     .Lirq_return
1577
1578 #ifdef CONFIG_X86_ESPFIX32
1579 .Lnmi_espfix_stack:
1580         /*
1581          * Create the pointer to LSS back
1582          */
1583         pushl   %ss
1584         pushl   %esp
1585         addl    $4, (%esp)
1586
1587         /* Copy the (short) IRET frame */
1588         pushl   4*4(%esp)       # flags
1589         pushl   4*4(%esp)       # cs
1590         pushl   4*4(%esp)       # ip
1591
1592         pushl   %eax            # orig_ax
1593
1594         SAVE_ALL_NMI cr3_reg=%edi unwind_espfix=1
1595         ENCODE_FRAME_POINTER
1596
1597         /* clear CS_FROM_KERNEL, set CS_FROM_ESPFIX */
1598         xorl    $(CS_FROM_ESPFIX | CS_FROM_KERNEL), PT_CS(%esp)
1599
1600         xorl    %edx, %edx                      # zero error code
1601         movl    %esp, %eax                      # pt_regs pointer
1602         jmp     .Lnmi_from_sysenter_stack
1603
1604 .Lnmi_from_espfix:
1605         RESTORE_ALL_NMI cr3_reg=%edi
1606         /*
1607          * Because we cleared CS_FROM_KERNEL, IRET_FRAME 'forgot' to
1608          * fix up the gap and long frame:
1609          *
1610          *  3 - original frame  (exception)
1611          *  2 - ESPFIX block    (above)
1612          *  6 - gap             (FIXUP_FRAME)
1613          *  5 - long frame      (FIXUP_FRAME)
1614          *  1 - orig_ax
1615          */
1616         lss     (1+5+6)*4(%esp), %esp                   # back to espfix stack
1617         jmp     .Lirq_return
1618 #endif
1619 END(nmi)
1620
1621 ENTRY(int3)
1622         ASM_CLAC
1623         pushl   $-1                             # mark this as an int
1624
1625         SAVE_ALL switch_stacks=1
1626         ENCODE_FRAME_POINTER
1627         TRACE_IRQS_OFF
1628         xorl    %edx, %edx                      # zero error code
1629         movl    %esp, %eax                      # pt_regs pointer
1630         call    do_int3
1631         jmp     ret_from_exception
1632 END(int3)
1633
1634 ENTRY(general_protection)
1635         pushl   $do_general_protection
1636         jmp     common_exception
1637 END(general_protection)
1638
1639 #ifdef CONFIG_KVM_GUEST
1640 ENTRY(async_page_fault)
1641         ASM_CLAC
1642         pushl   $do_async_page_fault
1643         jmp     common_exception_read_cr2
1644 END(async_page_fault)
1645 #endif
1646
1647 ENTRY(rewind_stack_do_exit)
1648         /* Prevent any naive code from trying to unwind to our caller. */
1649         xorl    %ebp, %ebp
1650
1651         movl    PER_CPU_VAR(cpu_current_top_of_stack), %esi
1652         leal    -TOP_OF_KERNEL_STACK_PADDING-PTREGS_SIZE(%esi), %esp
1653
1654         call    do_exit
1655 1:      jmp 1b
1656 END(rewind_stack_do_exit)