asdf-support.lisp

   1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   2 ;;;                                                                  ;;;
   3 ;;; Free Software published under an MIT-like license. See LICENSE   ;;;
   4 ;;;                                                                  ;;;
   5 ;;; Copyright (c) 2012 Google, Inc.  All rights reserved.            ;;;
   6 ;;;                                                                  ;;;
   7 ;;; Original author: Scott McKay                                     ;;;
   8 ;;; Based on work by: Robert Brown, Francois-Rene Rideau             ;;;
   9 ;;;                                                                  ;;;
  10 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  11
  12 (in-package "ASDF")
  13
  14
  15 ;;; ASDF support for CL-Protobufs
  16
  17 (defclass protobuf-file (cl-source-file)
  18   ((type :initform "proto")             ;default file type
  19    ;; If non-nil, use this relative pathname
  20    (proto-pathname :accessor proto-relative-pathname
  21                    :initform nil
  22                    :initarg :proto-pathname
  23                    :documentation "Relative pathname giving the location of the .proto file")
  24    ;; A search path to try when looking for system-provided .proto files
  25    (search-path :accessor proto-search-path
  26                 :initform ()
  27                 :initarg :search-path
  28                 :documentation
  29                 "List of directories where the protocol buffer compiler should search
  30                  for imported protobuf files.  Relative pathnames are treated as relative
  31                  to the directory containing the DEFSYSTEM form in which they appear.")
  32    (conc-name :accessor proto-conc-name
  33               :initform ""
  34               :initarg :conc-name))
  35   (:documentation
  36    "This ASDF component defines PROTO-TO-LISP, COMPILE-OP and LOAD-OP
  37     operations that compile the .proto file into a .lisp file. The .lisp
  38     file is then compiled, and possibly loaded, as well."))
  39
  40 (defclass proto-to-lisp (compile-op) ()
  41   (:documentation
  42    "The ASDF operation that compiles a .proto file containing Protocol Buffers
  43     definitions into a .lisp source file."))
  44
  45 (defmethod component-depends-on ((op compile-op) (component protobuf-file))
  46   "Compiling a protocol buffer file depends on generating Lisp source code for it."
  47   (if (typep op 'proto-to-lisp)
  48     (call-next-method)
  49     `((proto-to-lisp ,(component-name component))
  50       ,@(call-next-method))))
  51
  52 (defmethod component-depends-on ((op load-op) (component protobuf-file))
  53   "Loading a protocol buffer file depends on generating Lisp source code for it."
  54   `((proto-to-lisp ,(component-name component))
  55     ,@(call-next-method)))
  56
  57 (defmethod component-self-dependencies :around ((op load-op) (component protobuf-file))
  58   (remove-if #'(lambda (x)
  59                  (eq (car x) 'proto-to-lisp))
  60              (call-next-method)))
  61
  62 (defun protobuf-input-file (component)
  63   "Returns the pathname of the protocol buffer definition file that must be
  64    translated into Lisp source code for this PROTO-FILE component."
  65   (check-type component protobuf-file)
  66   (if (proto-relative-pathname component)
  67     ;; Path was specified with ':proto-pathname'
  68     (subpathname (component-pathname (component-parent component))
  69                  (proto-relative-pathname component)
  70                  :type "proto")
  71     ;; No ':proto-pathname', the path of the protobuf file
  72     ;; defaults to the component-pathname, with its automatic type "proto"
  73     (component-pathname component)))
  74
  75 (defun resolve-search-path (component)
  76   (check-type component protobuf-file)
  77   (let* ((search-path (proto-search-path component))
  78          (parent-path (component-pathname (component-parent component))))
  79     (mapcar #'(lambda (path)
  80                 (resolve-relative-pathname path parent-path))
  81             search-path)))
  82
  83 (defun resolve-relative-pathname (path parent-path)
  84   "When 'path' doesn't have an absolute directory component,
  85    treat it as relative to 'parent-path'."
  86   (pathname-directory-pathname
  87    (merge-pathnames* path parent-path)))
  88
  89 (defmethod input-files ((op proto-to-lisp) (component protobuf-file))
  90   "The input file is just the .proto file."
  91   (declare (ignorable op))
  92   (list (protobuf-input-file component)))
  93
  94 (defmethod output-files ((op proto-to-lisp) (component protobuf-file))
  95   "The output file is a .lisp file and a .proto-imports file with dependency data,
  96    stored where .fasl files are stored"
  97   (declare (ignorable op))
  98   (let ((lisp-file (lispize-pathname (component-pathname component))))
  99     (values (list lisp-file
 100                   (make-pathname :type "proto-imports"
 101                                  :defaults lisp-file))
 102             nil)))
 103
 104 (defmethod perform ((op proto-to-lisp) (component protobuf-file))
 105   (let* ((input  (protobuf-input-file component))
 106          (output (first (output-files op component)))
 107          (paths  (cons (directory-namestring input) (resolve-search-path component)))
 108          (proto-impl:*protobuf-search-path* paths)
 109          (proto-impl:*protobuf-output-path* output))
 110     (dolist (path paths (error 'compile-failed
 111                           :component component :operation op))
 112       (let ((proto (make-pathname :type "proto" :defaults (merge-pathnames* path (pathname input)))))
 113         (destructuring-bind (lisp imports)
 114             (output-files op component)
 115           (when (probe-file proto)
 116             (return-from perform
 117               (proto-impl:parse-protobuf-file proto lisp imports
 118                                               :conc-name (proto-conc-name component)))))))))
 119
 120 (defmethod operation-description ((op proto-to-lisp) (component protobuf-file))
 121   (format nil (compatfmt "~@<proto-compiling ~3i~_~A~@:>")
 122           (first (input-files op component))))
 123
 124 (defmethod input-files ((op compile-op) (component protobuf-file))
 125   "The input files are the .lisp and .proto-imports files."
 126   (declare (ignorable op))
 127   (output-files (make-instance 'proto-to-lisp) component))
 128
 129 (defmethod perform ((op compile-op) (component protobuf-file))
 130   (destructuring-bind (lisp-file imports-file) (input-files op component)
 131     (destructuring-bind (fasl-file &optional warnings-file) (output-files op component)
 132       (let* ((paths  (cons (directory-namestring lisp-file)
 133                            (resolve-search-path component)))
 134              (proto-impl:*protobuf-search-path* paths)
 135              (proto-impl:*protobuf-output-path* fasl-file)
 136              (*compile-file-warnings-behaviour* (operation-on-warnings op))
 137              (*compile-file-failure-behaviour* (operation-on-failure op)))
 138         (proto-impl:process-imports-from-file imports-file)
 139         (multiple-value-bind (output warnings-p failure-p)
 140             (apply #'compile-file* lisp-file
 141                    :output-file fasl-file
 142                    #+asdf3 #+asdf3
 143                    :warnings-file warnings-file
 144                    (compile-op-flags op))
 145           (when warnings-p
 146             (case (operation-on-warnings op)
 147               (:warn  (warn "~@<COMPILE-FILE warned while performing ~A on ~A.~@:>" op component))
 148               (:error (error 'compile-warned
 149                              :component component :operation op))
 150               (:ignore nil)))
 151           (when failure-p
 152             (case (operation-on-failure op)
 153               (:warn  (warn "~@<COMPILE-FILE failed while performing ~A on ~A.~@:>" op component))
 154               (:error (error 'compile-failed
 155                              :component component :operation op))
 156               (:ignore nil)))
 157           (unless output
 158             (error 'compile-error
 159                    :component component :operation op)))))))
 160
 161 (defmethod input-files ((op load-op) (component protobuf-file))
 162   "The input files are the .fasl and .proto-imports files."
 163   (declare (ignorable op))
 164   (list (first (output-files (make-instance 'compile-op) component))       ;fasl
 165         (second (output-files (make-instance 'proto-to-lisp) component)))) ;proto-imports
 166
 167 (defmethod perform ((op load-op) (component protobuf-file))
 168   (let* ((input  (protobuf-input-file component))
 169          (paths  (cons (directory-namestring input) (resolve-search-path component)))
 170          (proto-impl:*protobuf-search-path* paths)
 171          (proto-impl:*protobuf-output-path* (first (input-files op component))))
 172     (destructuring-bind (fasl proto-imports)
 173         (input-files op component)
 174       (proto-impl:process-imports-from-file proto-imports)
 175       (load fasl))))
 176
 177 (defmethod operation-description ((op compile-op) (component protobuf-file))
 178   (format nil (compatfmt "~@<compiling ~3i~_~A~@:>")
 179           (first (input-files op component))))
 180
 181 \f
 182 ;;; Processing of imports
 183
 184 (in-package "PROTO-IMPL")
 185
 186 (defun parse-protobuf-file (protobuf-file lisp-file imports-file &key (conc-name ""))
 187   (let ((schema (parse-schema-from-file protobuf-file :conc-name conc-name)))
 188     (with-open-file (stream lisp-file
 189                      :direction :output
 190                      :if-exists :supersede
 191                      :external-format :utf-8
 192                      :element-type 'character)
 193       (write-schema schema :stream stream :type :lisp))
 194     (with-open-file (stream imports-file
 195                      :direction :output
 196                      :if-exists :supersede
 197                      :external-format :utf-8
 198                      :element-type 'character)
 199       (with-standard-io-syntax
 200         (format stream "~W~%" (proto-imports schema)))))
 201   lisp-file)
 202
 203 ;; Process 'import' lines
 204 (defun process-imports (schema imports)
 205   "Imports all of the files given by 'imports'.
 206    If the file is a .proto file, it first parses it and writes a .lisp file.
 207    The .lisp file is the compiled and loaded."
 208   (dolist (import imports)
 209     (block import-one
 210       (let* ((import      (pathname import))
 211              (import-name (pathname-name import))
 212              (imported    (find-schema (class-name->proto import-name))))
 213         ;; If this schema has already been imported somewhere else,
 214         ;; mark it as imported here and carry on
 215         (when imported
 216           (setf (proto-imported-schemas schema)
 217                 (nconc (proto-imported-schemas schema) (list imported)))
 218           (return-from import-one))
 219         (do-process-import import import-name)
 220         (let* ((imported (find-schema (class-name->proto import-name))))
 221           (when imported
 222             (setf (proto-imported-schemas schema)
 223                   (nconc (proto-imported-schemas schema) (list imported))))
 224           (return-from import-one))))))
 225
 226 (defun process-imports-from-file (imports-file)
 227   (when (probe-file imports-file)
 228     (let ((imports (with-open-file (stream imports-file
 229                                     :direction :input
 230                                     :external-format :utf-8
 231                                     :element-type 'character)
 232                      (with-standard-io-syntax (read stream)))))
 233       (dolist (import imports)
 234         (let* ((import      (pathname import))
 235                (import-name (pathname-name import)))
 236           ;; If this schema has already been loaded, we're done.
 237           (unless (find-schema (class-name->proto import-name))
 238             (do-process-import import import-name)))))))
 239
 240 (defun do-process-import (import import-name
 241                           &key (search-path *protobuf-search-path*)
 242                                (output-path *protobuf-output-path*))
 243   (dolist (path search-path (error "Could not import ~S" import))
 244     (let* ((base-path  (asdf::merge-pathnames* import path))
 245            (proto-file (make-pathname :name import-name :type "proto"
 246                                       :defaults base-path))
 247            (lisp-file  (asdf::lispize-pathname
 248                         (if output-path
 249                             (make-pathname :name import-name
 250                                            :directory (pathname-directory output-path))
 251                             base-path)))
 252            (imports-file (make-pathname :type "proto-imports"
 253                                         :defaults lisp-file))
 254            (fasl-file  (compile-file-pathname lisp-file))
 255            (asdf:*asdf-verbose* nil)    ;for safe-file-write-date
 256            (proto-date (asdf::safe-file-write-date proto-file))
 257            (lisp-date  (asdf::safe-file-write-date lisp-file))
 258            (fasl-date  (asdf::safe-file-write-date fasl-file))
 259            (imports-date  (asdf::safe-file-write-date imports-file)))
 260       (when (probe-file proto-file)
 261         (let ((*protobuf-pathname* proto-file))
 262           (when (string= (pathname-type base-path) "proto")
 263             ;; The user asked to import a .proto file
 264             ;; If there's no .lisp file or an older .lisp file, or no
 265             ;; .proto-imports file or an older .proto-imports file parse
 266             ;; the .proto file now
 267             ;; If we did not parse the .proto file, process the generated
 268             ;; .proto-imports file now.
 269             (cond ((not proto-date)
 270                    (warn "Could not find the .proto file to be imported: ~A" proto-file))
 271                   ((or (not (and lisp-date imports-date))
 272                        (< lisp-date proto-date)
 273                        (< imports-date proto-date))
 274                    (parse-protobuf-file proto-file lisp-file imports-file)
 275                    (setq lisp-date (file-write-date lisp-file))
 276                    (setq imports-date (file-write-date imports-file)))
 277                   (t
 278                    (process-imports-from-file imports-file))))
 279           ;; Compile the .lisp file, if necessary
 280           (cond ((not lisp-date)
 281                  (unless (string= (pathname-type base-path) "proto")
 282                    (warn "Could not find the .lisp file to be compiled: ~A" lisp-file)))
 283                 (t
 284                  (when (or (not fasl-date)
 285                            (< fasl-date lisp-date))
 286                    (let ((*compile-file-pathname* lisp-file)
 287                          (*load-pathname* nil))
 288                      (setq fasl-file (compile-file lisp-file)))
 289                    (setq fasl-date (file-write-date fasl-file)))))
 290           ;; Load the .fasl file
 291           (cond ((not fasl-date)
 292                  (unless (string= (pathname-type base-path) "proto")
 293                    (warn "Could not find the .fasl file to be loaded: ~A" fasl-file)))
 294                 (t
 295                  (let ((*compile-file-pathname* nil)
 296                        (*load-pathname* fasl-file))
 297                    (load fasl-file)))))
 298         (return (values))))))