asdf-support.lisp

   1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   2 ;;;                                                                  ;;;
   3 ;;; Free Software published under an MIT-like license. See LICENSE   ;;;
   4 ;;;                                                                  ;;;
   5 ;;; Copyright (c) 2012 Google, Inc.  All rights reserved.            ;;;
   6 ;;;                                                                  ;;;
   7 ;;; Original author: Scott McKay                                     ;;;
   8 ;;; Based on work by: Robert Brown, Francois-Rene Rideau             ;;;
   9 ;;;                                                                  ;;;
  10 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  11
  12 (in-package "ASDF")
  13
  14
  15 ;;; ASDF support for CL-Protobufs
  16
  17 (defclass protobuf-file (cl-source-file)
  18   ((type :initform "proto")             ;default file type
  19    ;; If non-nil, use this relative pathname
  20    (proto-pathname :accessor proto-relative-pathname
  21                    :initform nil
  22                    :initarg :proto-pathname
  23                    :documentation "Relative pathname giving the location of the .proto file")
  24    ;; A search path to try when looking for system-provided .proto files
  25    (search-path :accessor proto-search-path
  26                 :initform ()
  27                 :initarg :search-path
  28                 :documentation
  29                 "List of directories where the protocol buffer compiler should search
  30                  for imported protobuf files.  Relative pathnames are treated as relative
  31                  to the directory containing the DEFSYSTEM form in which they appear.")
  32    (conc-name :accessor proto-conc-name
  33               :initform ""
  34               :initarg :conc-name))
  35   (:documentation
  36    "This ASDF component defines PROTO-TO-LISP, COMPILE-OP and LOAD-OP
  37     operations that compile the .proto file into a .lisp file. The .lisp
  38     file is then compiled, and possibly loaded, as well."))
  39
  40 (defclass proto-to-lisp (compile-op) ()
  41   (:documentation
  42    "The ASDF operation that compiles a .proto file containing Protocol Buffers
  43     definitions into a .lisp source file."))
  44
  45 (defmethod component-depends-on ((op compile-op) (component protobuf-file))
  46   "Compiling a protocol buffer file depends on generating Lisp source code for it."
  47   (if (typep op 'proto-to-lisp)
  48     (call-next-method)
  49     `((proto-to-lisp ,(component-name component))
  50       ,@(call-next-method))))
  51
  52 (defmethod component-depends-on ((op load-op) (component protobuf-file))
  53   "Loading a protocol buffer file depends on generating Lisp source code for it."
  54   `((proto-to-lisp ,(component-name component))
  55     ,@(call-next-method)))
  56
  57 (defmethod component-self-dependencies :around ((op load-op) (component protobuf-file))
  58   (remove-if #'(lambda (x)
  59                  (eq (car x) 'proto-to-lisp))
  60              (call-next-method)))
  61
  62 (defun protobuf-input-file (component)
  63   "Returns the pathname of the protocol buffer definition file that must be
  64    translated into Lisp source code for this PROTO-FILE component."
  65   (check-type component protobuf-file)
  66   (if (proto-relative-pathname component)
  67     ;; Path was specified with ':proto-pathname'
  68     (subpathname (component-pathname (component-parent component))
  69                  (proto-relative-pathname component)
  70                  :type (source-explicit-file-type component))
  71     ;; No ':proto-pathname', the path of the protobuf file
  72     ;; defaults to the component-pathname, with its automatic type "proto"
  73     (component-pathname component)))
  74
  75 (defun resolve-search-path (component)
  76   (check-type component protobuf-file)
  77   (let* ((search-path (proto-search-path component))
  78          (parent-path (component-pathname (component-parent component))))
  79     (mapcar #'(lambda (path)
  80                 (resolve-relative-pathname path parent-path))
  81             search-path)))
  82
  83 (defun resolve-relative-pathname (path parent-path)
  84   "When 'path' doesn't have an absolute directory component,
  85    treat it as relative to 'parent-path'."
  86   (pathname-directory-pathname
  87    (merge-pathnames* path parent-path)))
  88
  89 (defun protobuf-mangle-name (input-file)
  90   (let ((directory (pathname-directory input-file)))
  91     (format nil "~{~A-~}~A-~A"
  92             (if (eq (first directory) :absolute)
  93               (rest directory)
  94               directory)
  95             (pathname-name input-file)
  96             (pathname-type input-file))))
  97
  98 (defun protobuf-lispize-pathname (input-file)
  99   (make-pathname
 100    :name (protobuf-mangle-name input-file)
 101    :type "lisp"
 102    :defaults input-file))
 103
 104 (defmethod input-files ((op proto-to-lisp) (component protobuf-file))
 105   "The input file is just the .proto file."
 106   (declare (ignorable op))
 107   (list (protobuf-input-file component)))
 108
 109 (defmethod output-files ((op proto-to-lisp) (component protobuf-file))
 110   "The output file is a .lisp file and a .proto-imports file with dependency data,
 111    stored where .fasl files are stored"
 112   (declare (ignorable op))
 113   (let* ((base-pathname (component-pathname component))
 114          (lisp-file (protobuf-lispize-pathname base-pathname)))
 115     (values (list lisp-file
 116                   (make-pathname :type "proto-imports"
 117                                  :defaults lisp-file))
 118             nil)))
 119
 120 (defmethod perform ((op proto-to-lisp) (component protobuf-file))
 121   (let* ((input  (protobuf-input-file component))
 122          (output (first (output-files op component)))
 123          (paths  (cons (directory-namestring input) (resolve-search-path component)))
 124          (proto-impl:*protobuf-search-path* paths)
 125          (proto-impl:*protobuf-output-path* output))
 126     (dolist (path paths (error 'compile-failed
 127                           :component component :operation op))
 128       (let ((proto (merge-pathnames* path input)))
 129         (destructuring-bind (lisp imports)
 130             (output-files op component)
 131           (when (probe-file proto)
 132             (return-from perform
 133               (proto-impl:parse-protobuf-file proto lisp imports
 134                                               :conc-name (proto-conc-name component)))))))))
 135
 136 (defmethod operation-description ((op proto-to-lisp) (component protobuf-file))
 137   (format nil (compatfmt "~@<proto-compiling ~3i~_~A~@:>")
 138           (first (input-files op component))))
 139
 140 (defmethod input-files ((op compile-op) (component protobuf-file))
 141   "The input files are the .lisp and .proto-imports files."
 142   (declare (ignorable op))
 143   (output-files (make-instance 'proto-to-lisp) component))
 144
 145 (defmethod perform ((op compile-op) (component protobuf-file))
 146   (destructuring-bind (lisp-file imports-file) (input-files op component)
 147     (destructuring-bind (fasl-file
 148                          &optional
 149                            #+clisp lib-file
 150                            #+(or ecl mkcl) object-file
 151                            #+asdf3 warnings-file)
 152         (output-files op component)
 153       (let* ((proto-file (protobuf-input-file component))
 154              (paths  (cons (directory-namestring proto-file)
 155                            (resolve-search-path component)))
 156              (proto-impl:*protobuf-search-path* paths)
 157              (proto-impl:*protobuf-output-path* fasl-file)
 158              (*compile-file-warnings-behaviour* (operation-on-warnings op))
 159              (*compile-file-failure-behaviour* (operation-on-failure op)))
 160         (proto-impl:process-imports-from-file imports-file)
 161         (multiple-value-bind (output warnings-p failure-p)
 162             (apply #'compile-file* lisp-file
 163                    :output-file fasl-file
 164                    #+asdf3 #+asdf3
 165                    :warnings-file warnings-file
 166                    (append
 167                     #+clisp (list :lib-file lib-file)
 168                     #+(or ecl mkcl) (list :object-file object-file)
 169                     (compile-op-flags op)))
 170           #+asdf3
 171           (check-lisp-compile-results output warnings-p failure-p
 172                                       "~/asdf-action::format-action/" (list (cons op component)))
 173           #-asdf3
 174           (progn
 175             (when warnings-p
 176               (case (operation-on-warnings op)
 177                 (:warn  (warn "~@<COMPILE-FILE warned while performing ~A on ~A.~@:>" op component))
 178                 (:error (error 'compile-warned
 179                                :component component :operation op))
 180                 (:ignore nil)))
 181             (when failure-p
 182               (case (operation-on-failure op)
 183                 (:warn  (warn "~@<COMPILE-FILE failed while performing ~A on ~A.~@:>" op component))
 184                 (:error (error 'compile-failed
 185                                :component component :operation op))
 186                 (:ignore nil)))
 187             (unless output
 188               (error 'compile-error
 189                      :component component :operation op))))))))
 190
 191 (defmethod input-files ((op load-op) (component protobuf-file))
 192   "The input files are the .fasl and .proto-imports files."
 193   (declare (ignorable op))
 194   (list (first (output-files (make-instance 'compile-op) component))       ;fasl
 195         (second (output-files (make-instance 'proto-to-lisp) component)))) ;proto-imports
 196
 197 (defmethod perform ((op load-op) (component protobuf-file))
 198   (let* ((input  (protobuf-input-file component))
 199          (paths  (cons (directory-namestring input) (resolve-search-path component)))
 200          (proto-impl:*protobuf-search-path* paths)
 201          (proto-impl:*protobuf-output-path* (first (input-files op component))))
 202     (destructuring-bind (fasl proto-imports)
 203         (input-files op component)
 204       (proto-impl:process-imports-from-file proto-imports)
 205       (load fasl))))
 206
 207 (defmethod operation-description ((op compile-op) (component protobuf-file))
 208   (format nil (compatfmt "~@<compiling ~3i~_~A~@:>")
 209           (first (input-files op component))))
 210
 211 \f
 212 ;;; Processing of imports
 213
 214 (in-package "PROTO-IMPL")
 215
 216 (defun parse-protobuf-file (protobuf-file lisp-file imports-file &key (conc-name ""))
 217   (let ((schema (parse-schema-from-file protobuf-file :conc-name conc-name)))
 218     (with-open-file (stream lisp-file
 219                      :direction :output
 220                      :if-exists :supersede
 221                      :external-format :utf-8
 222                      :element-type 'character)
 223       (write-schema schema :stream stream :type :lisp))
 224     (with-open-file (stream imports-file
 225                      :direction :output
 226                      :if-exists :supersede
 227                      :external-format :utf-8
 228                      :element-type 'character)
 229       (with-standard-io-syntax
 230         (format stream "~W~%" (proto-imports schema)))))
 231   lisp-file)
 232
 233 ;; Process 'import' lines
 234 (defun process-imports (schema imports)
 235   "Imports all of the files given by 'imports'.
 236    If the file is a .proto file, it first parses it and writes a .lisp file.
 237    The .lisp file is the compiled and loaded."
 238   (dolist (import imports)
 239     (block import-one
 240       (let* ((import      (pathname import))
 241              (import-name (pathname-name import))
 242              (proto-file  (do-process-import import import-name))
 243              (imported    (find-schema proto-file)))
 244         (when imported
 245           (appendf (proto-imported-schemas schema) (list imported)))
 246         (return-from import-one)))))
 247
 248 (defun process-imports-from-file (imports-file)
 249   (when (probe-file imports-file)
 250     (let ((imports (with-open-file (stream imports-file
 251                                     :direction :input
 252                                     :external-format :utf-8
 253                                     :element-type 'character)
 254                      (with-standard-io-syntax (read stream)))))
 255       (dolist (import imports)
 256         (let* ((import      (pathname import))
 257                (import-name (pathname-name import)))
 258           (do-process-import import import-name))))))
 259
 260 (defun do-process-import (import import-name
 261                           &key (search-path *protobuf-search-path*)
 262                                (output-path *protobuf-output-path*))
 263   (dolist (path search-path (error "Could not import ~S" import))
 264     (let* ((base-path  (asdf::merge-pathnames* import path))
 265            (proto-file (make-pathname :name import-name :type "proto"
 266                                       :defaults base-path))
 267            (lisp-file (if output-path
 268                         (asdf::lispize-pathname
 269                          (make-pathname :name (asdf::protobuf-mangle-name base-path)
 270                                         :directory (pathname-directory output-path)))
 271                         (asdf::protobuf-lispize-pathname base-path)))
 272            (imports-file (make-pathname :type "proto-imports"
 273                                         :defaults lisp-file))
 274            (fasl-file  (compile-file-pathname lisp-file))
 275            (asdf:*asdf-verbose* nil)    ;for safe-file-write-date
 276            (proto-date (asdf::safe-file-write-date proto-file))
 277            (lisp-date  (asdf::safe-file-write-date lisp-file))
 278            (fasl-date  (asdf::safe-file-write-date fasl-file))
 279            (imports-date  (asdf::safe-file-write-date imports-file)))
 280       (when (probe-file proto-file)
 281         (when (find-schema proto-file)
 282           (return proto-file))
 283         (let ((*protobuf-pathname* proto-file))
 284           (when (string= (pathname-type base-path) "proto")
 285             ;; The user asked to import a .proto file
 286             ;; If there's no .lisp file or an older .lisp file, or no
 287             ;; .proto-imports file or an older .proto-imports file parse
 288             ;; the .proto file now
 289             ;; If we did not parse the .proto file, process the generated
 290             ;; .proto-imports file now.
 291             (cond ((not proto-date)
 292                    (warn "Could not find the .proto file to be imported: ~A" proto-file))
 293                   ((or (not (and lisp-date imports-date))
 294                        (< lisp-date proto-date)
 295                        (< imports-date proto-date))
 296                    (parse-protobuf-file proto-file lisp-file imports-file)
 297                    (setq lisp-date (file-write-date lisp-file))
 298                    (setq imports-date (file-write-date imports-file)))
 299                   (t
 300                    (process-imports-from-file imports-file))))
 301           ;; Compile the .lisp file, if necessary
 302           (cond ((not lisp-date)
 303                  (unless (string= (pathname-type base-path) "proto")
 304                    (warn "Could not find the .lisp file to be compiled: ~A" lisp-file)))
 305                 (t
 306                  (when (or (not fasl-date)
 307                            (< fasl-date lisp-date))
 308                    (let ((*compile-file-pathname* lisp-file)
 309                          (*load-pathname* nil))
 310                      (setq fasl-file (compile-file lisp-file)))
 311                    (setq fasl-date (file-write-date fasl-file)))))
 312           ;; Load the .fasl file
 313           (cond ((not fasl-date)
 314                  (unless (string= (pathname-type base-path) "proto")
 315                    (warn "Could not find the .fasl file to be loaded: ~A" fasl-file)))
 316                 (t
 317                  (let ((*compile-file-pathname* nil)
 318                        (*load-pathname* fasl-file))
 319                    (load fasl-file)))))
 320         (return proto-file)))))