configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([git], [1.4.1], [git@vger.kernel.org])
   6
   7 AC_CONFIG_SRCDIR([git.c])
   8
   9 config_file=config.mak.autogen
  10 config_append=config.mak.append
  11 config_in=config.mak.in
  12
  13 echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16 ## Definitions of macros
  17 # GIT_CONF_APPEND_LINE(LINE)
  18 # --------------------------
  19 # Append LINE to file ${config_append}
  20 AC_DEFUN([GIT_CONF_APPEND_LINE],
  21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22 #
  23 # GIT_ARG_SET_PATH(PROGRAM)
  24 # -------------------------
  25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26 AC_DEFUN([GIT_ARG_SET_PATH],
  27 [AC_ARG_WITH([$1],
  28  [AS_HELP_STRING([--with-$1=PATH],
  29                  [provide PATH to $1])],
  30  [GIT_CONF_APPEND_PATH($1)],[])
  31 ])# GIT_ARG_SET_PATH
  32 #
  33 # GIT_CONF_APPEND_PATH(PROGRAM)
  34 # ------------------------------
  35 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36 # Used by GIT_ARG_SET_PATH(PROGRAM)
  37 AC_DEFUN([GIT_CONF_APPEND_PATH],
  38 [PROGRAM=m4_toupper($1); \
  39 if test "$withval" = "no"; then \
  40         AC_MSG_WARN([You cannot use git without $1]); \
  41 else \
  42         if test "$withval" = "yes"; then \
  43                 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44         else \
  45                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  46         fi; \
  47 fi; \
  48 ]) # GIT_CONF_APPEND_PATH
  49
  50
  51 ## Checks for programs.
  52 AC_MSG_NOTICE([CHECKS for programs])
  53 #
  54 GIT_ARG_SET_PATH(shell)
  55 GIT_ARG_SET_PATH(perl)
  56 #
  57 # Define NO_PYTHON if you want to lose all benefits of the recursive merge.
  58 # Define PYTHON_PATH to provide path to Python.
  59 AC_PROG_CC
  60 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
  61 AC_CHECK_TOOL(AR, ar, :)
  62 AC_CHECK_PROGS(TAR, [gtar tar])
  63
  64
  65 ## Checks for libraries.
  66 AC_MSG_NOTICE([CHECKS for libraries])
  67 #
  68 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
  69 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
  70 AC_CHECK_LIB([ssl], [SHA1_Init],[],
  71 [AC_CHECK_LIB([crypto], [SHA1_INIT],
  72  [GIT_CONF_APPEND_LINE(NEEDS_SSL_WITH_CRYPTO=YesPlease)],
  73  [GIT_CONF_APPEND_LINE(NO_OPENSSL=YesPlease)])])
  74 #
  75 # Define NO_CURL if you do not have curl installed.  git-http-pull and
  76 # git-http-push are not built, and you cannot use http:// and https://
  77 # transports.
  78 AC_CHECK_LIB([curl], [curl_global_init],[],
  79 [GIT_CONF_APPEND_LINE(NO_CURL=YesPlease)])
  80 #
  81 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
  82 # not built, and you cannot push using http:// and https:// transports.
  83 AC_CHECK_LIB([expat], [XML_ParserCreate],[],
  84 [GIT_CONF_APPEND_LINE(NO_EXPAT=YesPlease)])
  85 #
  86 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin).
  87 AC_CHECK_LIB([c], [iconv],[],
  88 [AC_CHECK_LIB([iconv],[iconv],
  89  [GIT_CONF_APPEND_LINE(NEEDS_LIBICONV=YesPlease)],[])])
  90 #
  91 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
  92 # Patrick Mauritz).
  93 AC_CHECK_LIB([c], [socket],[],
  94 [AC_CHECK_LIB([socket],[socket],
  95  [GIT_CONF_APPEND_LINE(NEEDS_SOCKET=YesPlease)],[])])
  96
  97
  98 ## Checks for header files.
  99
 100
 101 ## Checks for typedefs, structures, and compiler characteristics.
 102 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 103 #
 104 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 105 AC_CHECK_MEMBER(struct dirent.d_ino,[],
 106 [GIT_CONF_APPEND_LINE(NO_D_INO_IN_DIRENT=YesPlease)],
 107 [#include <dirent.h>])
 108 #
 109 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 110 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 111 AC_CHECK_MEMBER(struct dirent.d_type,[],
 112 [GIT_CONF_APPEND_LINE(NO_D_TYPE_IN_DIRENT=YesPlease)],
 113 [#include <dirent.h>])
 114 #
 115 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 116 # sockaddr_storage.
 117 AC_CHECK_TYPE(struct sockaddr_storage,[],
 118 [GIT_CONF_APPEND_LINE(NO_SOCKADDR_STORAGE=YesPlease)],
 119 [#include <netinet/in.h>])
 120
 121
 122 ## Checks for library functions.
 123 ## (in default C library and libraries checked by AC_CHECK_LIB)
 124 AC_MSG_NOTICE([CHECKS for library functions])
 125 #
 126 # Define NO_STRCASESTR if you don't have strcasestr.
 127 AC_CHECK_FUNC(strcasestr,[],
 128 [GIT_CONF_APPEND_LINE(NO_STRCASESTR=YesPlease)])
 129 #
 130 # Define NO_STRLCPY if you don't have strlcpy.
 131 AC_CHECK_FUNC(strlcpy,[],
 132 [GIT_CONF_APPEND_LINE(NO_STRLCPY=YesPlease)])
 133 #
 134 # Define NO_SETENV if you don't have setenv in the C library.
 135 AC_CHECK_FUNC(setenv,[],
 136 [GIT_CONF_APPEND_LINE(NO_SETENV=YesPlease)])
 137 #
 138 # Define NO_MMAP if you want to avoid mmap.
 139 #
 140 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 141 #
 142 # Define NO_ICONV if your libc does not properly support iconv.
 143
 144
 145 ## Other checks.
 146 # Define USE_PIC if you need the main git objects to be built with -fPIC
 147 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 148 #
 149 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 150 # Enable it on Windows.  By default, symrefs are still used.
 151 #
 152 # Define WITH_OWN_SUBPROCESS_PY if you want to use with python 2.3.
 153 #
 154 # Define NO_ACCURATE_DIFF if your diff program at least sometimes misses
 155 # a missing newline at the end of the file.
 156
 157
 158 ## Site configuration
 159 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 160 #
 161 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interopability
 162 # tests.  These tests take up a significant amount of the total test time
 163 # but are not needed unless you plan to talk to SVN repos.
 164 #
 165 # Define MOZILLA_SHA1 environment variable when running make to make use of
 166 # a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
 167 # on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
 168 # choice) has very fast version optimized for i586.
 169 #
 170 # Define PPC_SHA1 environment variable when running make to make use of
 171 # a bundled SHA1 routine optimized for PowerPC.
 172 #
 173 # Define ARM_SHA1 environment variable when running make to make use of
 174 # a bundled SHA1 routine optimized for ARM.
 175 #
 176 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 177 # This also implies MOZILLA_SHA1.
 178 #
 179 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 180 # git-http-push are not built, and you cannot use http:// and https://
 181 # transports.
 182 #
 183 # Define CURLDIR=/foo/bar if your curl header and library files are in
 184 # /foo/bar/include and /foo/bar/lib directories.
 185 #
 186 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 187 # not built, and you cannot push using http:// and https:// transports.
 188 #
 189 # Define NO_MMAP if you want to avoid mmap.
 190 #
 191 # Define NO_PYTHON if you want to loose all benefits of the recursive merge.
 192 #
 193 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 194 # Define COLLISION_CHECK below if you believe that SHA1's
 195 # 1461501637330902918203684832716283019655932542976 hashes do not give you
 196 # sufficient guarantee that no collisions between objects will ever happen.
 197 #
 198 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 199 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 200 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 201 # randomly break unless your underlying filesystem supports those sub-second
 202 # times (my ext3 doesn't).
 203 #
 204 # Define USE_STDEV below if you want git to care about the underlying device
 205 # change being considered an inode change from the update-cache perspective.
 206
 207
 208 ## Output files
 209 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 210 AC_OUTPUT
 211
 212
 213 ## Cleanup
 214 rm -f "${config_append}"