define-proto.lisp

   1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   2 ;;;                                                                  ;;;
   3 ;;; Confidential and proprietary information of ITA Software, Inc.   ;;;
   4 ;;;                                                                  ;;;
   5 ;;; Copyright (c) 2012 ITA Software, Inc.  All rights reserved.      ;;;
   6 ;;;                                                                  ;;;
   7 ;;; Original author: Scott McKay                                     ;;;
   8 ;;;                                                                  ;;;
   9 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  10
  11 (in-package "PROTO-IMPL")
  12
  13
  14 ;;; Protocol buffer defining macros
  15
  16 ;; Define a schema named 'type', corresponding to a .proto file of that name
  17 (defmacro define-proto (type (&key name syntax package lisp-package import optimize options documentation)
  18                         &body messages &environment env)
  19   "Define a schema named 'type', corresponding to a .proto file of that name.
  20    'name' can be used to override the defaultly generated Protobufs name.
  21    'syntax' and 'package' are as they would be in a .proto file.
  22    'lisp-package' can be used to specify a Lisp package if it is different from
  23    the Protobufs package given by 'package'.
  24    'import' is a list of pathname strings to be imported.
  25    'optimize' can be either :space (the default) or :speed; if it is :speed, the
  26    serialization code will be much faster, but much less compact.
  27    'options' is a property list, i.e., (\"key1\" \"val1\" \"key2\" \"val2\" ...).
  28
  29    The body consists of 'define-enum', 'define-message' or 'define-service' forms."
  30   (let* ((name     (or name (class-name->proto type)))
  31          (package  (and package (if (stringp package) package (string-downcase (string package)))))
  32          (lisp-pkg (and lisp-package (if (stringp lisp-package) lisp-package (string lisp-package))))
  33          (options  (loop for (key val) on options by #'cddr
  34                          collect (make-instance 'protobuf-option
  35                                    :name  key
  36                                    :value val)))
  37          (imports  (if (listp import) import (list import)))
  38          (protobuf (make-instance 'protobuf
  39                      :class    type
  40                      :name     name
  41                      :syntax   (or syntax "proto2")
  42                      :package  package
  43                      :lisp-package (or lisp-pkg package)
  44                      :imports  imports
  45                      :options  (if optimize
  46                                  (append options (list (make-instance 'protobuf-option
  47                                                          :name  "optimize_for"
  48                                                          :value (if (eq optimize :speed) "SPEED" "CODE_SIZE")
  49                                                          :type  'symbol)))
  50                                  options)
  51                      :documentation documentation))
  52          (*protobuf* protobuf)
  53          (*protobuf-package* (or (find-package lisp-pkg)
  54                                  (find-package (string-upcase lisp-pkg))
  55                                  *package*)))
  56     (apply #'process-imports imports)
  57     (with-collectors ((forms collect-form))
  58       (dolist (msg messages)
  59         (assert (and (listp msg)
  60                      (member (car msg) '(define-enum define-message define-extend define-service))) ()
  61                 "The body of ~S must be one of ~{~S~^ or ~}"
  62                 'define-proto '(define-enum define-message define-extend define-service))
  63         ;; The macro-expander will return a form that consists
  64         ;; of 'progn' followed by a symbol naming what we've expanded
  65         ;; (define-enum, define-message, define-extend, define-service),
  66         ;; followed by the Lisp model object created by the defining form,
  67         ;; followed by other defining forms (e.g., deftype, defclass)
  68         (destructuring-bind (&optional progn type model definers)
  69             (macroexpand-1 msg env)
  70           (assert (eq progn 'progn) ()
  71                   "The macroexpansion for ~S failed" msg)
  72           (map () #'collect-form definers)
  73           (ecase type
  74             ((define-enum)
  75              (setf (proto-enums protobuf) (nconc (proto-enums protobuf) (list model))))
  76             ((define-message define-extend)
  77              (setf (proto-parent model) protobuf)
  78              (setf (proto-messages protobuf) (nconc (proto-messages protobuf) (list model)))
  79              (when (eq (proto-message-type model) :extends)
  80                (setf (proto-extenders protobuf) (nconc (proto-extenders protobuf) (list model)))))
  81             ((define-service)
  82              (setf (proto-services protobuf) (nconc (proto-services protobuf) (list model)))))))
  83       (let ((var (intern (format nil "*~A*" type) *protobuf-package*)))
  84         `(progn
  85            ,@forms
  86            (defvar ,var nil)
  87            (let* ((old-proto ,var)
  88                   (new-proto ,protobuf))
  89              (when old-proto
  90                (multiple-value-bind (upgradable warnings)
  91                    (protobuf-upgradable old-proto new-proto)
  92                  (unless upgradable
  93                    (protobufs-warn "The old schema for ~S (~A) can't be safely upgraded; proceeding anyway"
  94                                    ',type ',name)
  95                    (map () #'protobufs-warn warnings))))
  96              (setq ,var new-proto)
  97              ,@(when (eq optimize :speed)
  98                  (with-collectors ((messages collect-message))
  99                    (labels ((collect-messages (message)
 100                               (collect-message message)
 101                               (map () #'collect-messages (proto-messages message))))
 102                    (map () #'collect-messages (proto-messages protobuf)))
 103                    (append (mapcar #'generate-object-size  messages)
 104                            (mapcar #'generate-serializer   messages)
 105                            (mapcar #'generate-deserializer messages))))
 106              new-proto))))))
 107
 108 ;; Define an enum type named 'type' and a Lisp 'deftype'
 109 (defmacro define-enum (type (&key name conc-name alias-for options documentation)
 110                        &body values)
 111   "Define a Protobufs enum type and a Lisp 'deftype' named 'type'.
 112    'name' can be used to override the defaultly generated Protobufs enum name.
 113    'conc-name' will be used as the prefix to the Lisp enum names, if it's supplied.
 114    If 'alias-for' is given, no Lisp 'deftype' will be defined. Instead, the enum
 115    will be used as an alias for an enum type that already exists in Lisp.
 116    'options' is a set of keyword/value pairs, both of which are strings.
 117
 118    The body consists of the enum values in the form 'name' or (name index)."
 119   (let* ((name    (or name (class-name->proto type)))
 120          (options (loop for (key val) on options by #'cddr
 121                         collect (make-instance 'protobuf-option
 122                                   :name  key
 123                                   :value val)))
 124          (index -1)
 125          (enum  (make-instance 'protobuf-enum
 126                   :class  type
 127                   :name   name
 128                   :alias-for alias-for
 129                   :options options
 130                   :documentation documentation)))
 131     (with-collectors ((vals  collect-val)
 132                       (forms collect-form))
 133       (dolist (val values)
 134         (let* ((idx  (if (listp val) (second val) (incf index)))
 135                (name (if (listp val) (first val)  val))
 136                (val-name  (kintern (if conc-name (format nil "~A~A" conc-name name) (symbol-name name))))
 137                (enum-name (if conc-name (format nil "~A~A" conc-name name) (symbol-name name)))
 138                (enum-val  (make-instance 'protobuf-enum-value
 139                             :name  (enum-name->proto enum-name)
 140                             :index idx
 141                             :value val-name)))
 142           (collect-val val-name)
 143           (setf (proto-values enum) (nconc (proto-values enum) (list enum-val)))))
 144       (if alias-for
 145         ;; If we've got an alias, define a a type that is the subtype of
 146         ;; the Lisp enum so that typep and subtypep work
 147         (unless (eq type alias-for)
 148           (collect-form `(deftype ,type () ',alias-for)))
 149         ;; If no alias, define the Lisp enum type now
 150         (collect-form `(deftype ,type () '(member ,@vals))))
 151       `(progn
 152          define-enum
 153          ,enum
 154          ,forms))))
 155
 156 ;; Define a message named 'name' and a Lisp 'defclass'
 157 (defmacro define-message (type (&key name conc-name alias-for options documentation)
 158                           &body fields &environment env)
 159   "Define a message named 'type' and a Lisp 'defclass'.
 160    'name' can be used to override the defaultly generated Protobufs message name.
 161    The body consists of fields, or 'define-enum' or 'define-message' forms.
 162    'conc-name' will be used as the prefix to the Lisp slot accessors, if it's supplied.
 163    If 'alias-for' is given, no Lisp class is defined. Instead, the message will be
 164    used as an alias for a class that already exists in Lisp. This feature is intended
 165    to be used to define messages that will be serialized from existing Lisp classes;
 166    unless you get the slot names or readers exactly right for each field, it will be
 167    the case that trying to (de)serialize into a Lisp object won't work.
 168    'options' is a set of keyword/value pairs, both of which are strings.
 169
 170    Fields take the form (slot &key type name default reader)
 171    'slot' can be either a symbol giving the field name, or a list whose
 172    first element is the slot name and whose second element is the index.
 173    'type' is the type of the slot.
 174    'name' can be used to override the defaultly generated Protobufs field name.
 175    'default' is the default value for the slot.
 176    'reader' is a Lisp slot reader function to use to get the value, instead of
 177    using 'slot-value'; this is often used when aliasing an existing class.
 178    'writer' is a Lisp slot writer function to use to set the value."
 179   (let* ((name    (or name (class-name->proto type)))
 180          (options (loop for (key val) on options by #'cddr
 181                         collect (make-instance 'protobuf-option
 182                                   :name  key
 183                                   :value val)))
 184          (message (make-instance 'protobuf-message
 185                     :class type
 186                     :name  name
 187                     :alias-for alias-for
 188                     :conc-name (and conc-name (string conc-name))
 189                     :options  options
 190                     :documentation documentation))
 191          (index 0)
 192          (*protobuf* message))
 193     (with-collectors ((slots collect-slot)
 194                       (forms collect-form))
 195       (dolist (field fields)
 196         (case (car field)
 197           ((define-enum define-message define-extend define-extension define-group)
 198            (destructuring-bind (&optional progn type model definers extra-field extra-slot)
 199                (macroexpand-1 field env)
 200              (assert (eq progn 'progn) ()
 201                      "The macroexpansion for ~S failed" field)
 202              (map () #'collect-form definers)
 203              (ecase type
 204                ((define-enum)
 205                 (setf (proto-enums message) (nconc (proto-enums message) (list model))))
 206                ((define-message define-extend)
 207                 (setf (proto-parent model) message)
 208                 (setf (proto-messages message) (nconc (proto-messages message) (list model)))
 209                 (when (eq (proto-message-type model) :extends)
 210                   (setf (proto-extenders message) (nconc (proto-extenders message) (list model)))))
 211                ((define-group)
 212                 (setf (proto-parent model) message)
 213                 (setf (proto-messages message) (nconc (proto-messages message) (list model)))
 214                 (when extra-slot
 215                   (collect-slot extra-slot))
 216                 (setf (proto-fields message) (nconc (proto-fields message) (list extra-field))))
 217                ((define-extension)
 218                 (setf (proto-extensions message) (nconc (proto-extensions message) (list model)))))))
 219           (otherwise
 220            (multiple-value-bind (field slot idx)
 221                (process-field field index :conc-name conc-name :alias-for alias-for)
 222              (assert (not (find (proto-index field) (proto-fields message) :key #'proto-index)) ()
 223                      "The field ~S overlaps with another field in ~S"
 224                      (proto-value field) (proto-class message))
 225              (setq index idx)
 226              (when slot
 227                (collect-slot slot))
 228              (setf (proto-fields message) (nconc (proto-fields message) (list field)))))))
 229       (if alias-for
 230         ;; If we've got an alias, define a a type that is the subtype of
 231         ;; the Lisp class that typep and subtypep work
 232         (unless (or (eq type alias-for) (find-class type nil))
 233           (collect-form `(deftype ,type () ',alias-for)))
 234         ;; If no alias, define the class now
 235         (collect-form `(defclass ,type () (,@slots)
 236                          ,@(and documentation `((:documentation ,documentation))))))
 237       `(progn
 238          define-message
 239          ,message
 240          ,forms))))
 241
 242 (defmacro define-extension (from to)
 243   "Define an extension range within a message.
 244    The \"body\" is the start and end of the range, both inclusive."
 245   `(progn
 246      define-extension
 247      ,(make-instance 'protobuf-extension
 248         :from from
 249         :to   (if (eq to 'max) #.(1- (ash 1 29)) to))
 250      ()))
 251
 252 (defmacro define-extend (type (&key name options documentation)
 253                          &body fields &environment env)
 254   "Define an extension to the message named 'type'.
 255    'name' can be used to override the defaultly generated Protobufs message name.
 256    The body consists only  of fields.
 257    'options' is a set of keyword/value pairs, both of which are strings.
 258
 259    Fields take the form (slot &key type name default reader)
 260    'slot' can be either a symbol giving the field name, or a list whose
 261    first element is the slot name and whose second element is the index.
 262    'type' is the type of the slot.
 263    'name' can be used to override the defaultly generated Protobufs field name.
 264    'default' is the default value for the slot.
 265    'reader' is a Lisp slot reader function to use to get the value, instead of
 266    using 'slot-value'; this is often used when aliasing an existing class.
 267    'writer' is a Lisp slot writer function to use to set the value."
 268   (declare (ignore env))
 269   (let* ((name    (or name (class-name->proto type)))
 270          (options (loop for (key val) on options by #'cddr
 271                         collect (make-instance 'protobuf-option
 272                                   :name  key
 273                                   :value val)))
 274          (message   (find-message *protobuf* name))
 275          (conc-name (and message (proto-conc-name message)))
 276          (alias-for (and message (proto-alias-for message)))
 277          (extends (and message
 278                        (make-instance 'protobuf-message
 279                          :class  type
 280                          :name   name
 281                          :parent (proto-parent message)
 282                          :conc-name conc-name
 283                          :alias-for alias-for
 284                          :enums    (copy-list (proto-enums message))
 285                          :messages (copy-list (proto-messages message))
 286                          :fields   (copy-list (proto-fields message))
 287                          :options  (or options (copy-list (proto-options message)))
 288                          :extensions (copy-list (proto-extensions message))
 289                          :message-type :extends         ;this message is an extension
 290                          :documentation documentation)))
 291          (index 0))
 292     (assert message ()
 293             "There is no message named ~A to extend" name)
 294     (assert (eq type (proto-class message)) ()
 295             "The type ~S doesn't match the type of the message being extended ~S"
 296             type message)
 297     (with-collectors ((forms collect-form))
 298       (dolist (field fields)
 299         (assert (not (member (car field)
 300                              '(define-enum define-message define-extend define-extension define-group))) ()
 301                 "The body of ~S can only contain field definitions" 'define-extend)
 302         (multiple-value-bind (field slot idx)
 303             (process-field field index :conc-name conc-name :alias-for alias-for)
 304           (assert (not (find (proto-index field) (proto-fields extends) :key #'proto-index)) ()
 305                   "The field ~S overlaps with another field in ~S"
 306                   (proto-value field) (proto-class extends))
 307           (assert (index-within-extensions-p idx message) ()
 308                   "The index ~D is not in range for extending ~S"
 309                   idx (proto-class message))
 310           (setq index idx)
 311           (when slot
 312             (let* ((inits  (cdr slot))
 313                    (sname  (car slot))
 314                    (stable (fintern "~A-VALUES" sname))
 315                    (stype  (getf inits :type))
 316                    (reader (or (getf inits :accessor)
 317                                (getf inits :reader)
 318                                (intern (if conc-name (format nil "~A~A" conc-name sname) (symbol-name sname))
 319                                        (symbol-package sname))))
 320                    (writer (or (getf inits :writer)
 321                                (intern (format nil "~A-~A" reader 'setter)
 322                                        (symbol-package sname))))
 323                    (default (getf inits :initform)))
 324               ;; For the extended slots, each slot gets its own table
 325               ;; keyed by the object, which lets us avoid having a slot in each
 326               ;; instance that holds a table keyed by the slot name
 327               ;; Multiple 'define-extends' on the same class in the same image
 328               ;; will result in harmless redefinitions, so squelch the warnings
 329               (collect-form `(without-redefinition-warnings ()
 330                                (let ((,stable (make-hash-table :test #'eq :weak t)))
 331                                  (defmethod ,reader ((object ,type))
 332                                    (gethash object ,stable ,default))
 333                                  (defmethod ,writer ((object ,type) value)
 334                                    (declare (type ,stype value))
 335                                    (setf (gethash object ,stable) value))
 336                                  ;; For Python compatibility
 337                                  (defmethod get-extension ((object ,type) (slot (eql ',sname)))
 338                                    (values (gethash object ,stable ,default)))
 339                                  (defmethod set-extension ((object ,type) (slot (eql ',sname)) value)
 340                                    (setf (gethash object ,stable) value))
 341                                  (defmethod has-extension ((object ,type) (slot (eql ',sname)))
 342                                    (multiple-value-bind (value foundp)
 343                                        (gethash object ,stable ,default)
 344                                      (declare (ignore value))
 345                                      foundp))
 346                                  (defmethod clear-extension ((object ,type) (slot (eql ',sname)))
 347                                    (remhash object ,stable))
 348                                  (defsetf ,reader ,writer))))
 349               ;; This so that (de)serialization works
 350               (setf (proto-reader field) reader
 351                     (proto-writer field) writer)))
 352           (setf (proto-message-type field) :extends)    ;this field is an extension
 353           (setf (proto-fields extends) (nconc (proto-fields extends) (list field)))))
 354       `(progn
 355          define-extend
 356          ,extends
 357          ,forms))))
 358
 359 (defun index-within-extensions-p (index message)
 360   (let ((extensions (proto-extensions message)))
 361     (some #'(lambda (ext)
 362               (and (i>= index (proto-extension-from ext))
 363                    (i<= index (proto-extension-to ext))))
 364           extensions)))
 365
 366 (defmacro define-group (type (&key index arity name conc-name alias-for options documentation)
 367                         &body fields &environment env)
 368   "Define a message named 'type' and a Lisp 'defclass', *and* a field named type.
 369    This is deprecated in Protobufs, but if you have to use it, you must give
 370    'index' as the field index and 'arity' of :required, :optional or :repeated.
 371    'name' can be used to override the defaultly generated Protobufs message name.
 372    The body consists of fields, or 'define-enum' or 'define-message' forms.
 373    'conc-name' will be used as the prefix to the Lisp slot accessors, if it's supplied.
 374    If 'alias-for' is given, no Lisp class is defined. Instead, the message will be
 375    used as an alias for a class that already exists in Lisp. This feature is intended
 376    to be used to define messages that will be serialized from existing Lisp classes;
 377    unless you get the slot names or readers exactly right for each field, it will be
 378    the case that trying to (de)serialize into a Lisp object won't work.
 379    'options' is a set of keyword/value pairs, both of which are strings.
 380
 381    Fields take the form (slot &key type name default reader)
 382    'slot' can be either a symbol giving the field name, or a list whose
 383    first element is the slot name and whose second element is the index.
 384    'type' is the type of the slot.
 385    'name' can be used to override the defaultly generated Protobufs field name.
 386    'default' is the default value for the slot.
 387    'reader' is a Lisp slot reader function to use to get the value, instead of
 388    using 'slot-value'; this is often used when aliasing an existing class.
 389    'writer' is a Lisp slot writer function to use to set the value."
 390   (check-type index integer)
 391   (check-type arity (member :required :optional :repeated))
 392   (let* ((slot    (or (and name (proto->slot-name name)) type))
 393          (name    (or name (class-name->proto type)))
 394          (options (loop for (key val) on options by #'cddr
 395                         collect (make-instance 'protobuf-option
 396                                   :name  key
 397                                   :value val)))
 398          (mslot   (unless alias-for
 399                     `(,slot ,@(case arity
 400                                 (:required
 401                                  `(:type ,type))
 402                                 (:optional
 403                                  `(:type (or ,type null)
 404                                    :initform nil))
 405                                 (:repeated
 406                                  `(:type (list-of ,type)
 407                                    :initform ())))
 408                             :initarg ,(kintern (symbol-name slot)))))
 409          (mfield  (make-instance 'protobuf-field
 410                     :name  (slot-name->proto slot)
 411                     :value slot
 412                     :type  name
 413                     :class type
 414                     ;; One of :required, :optional or :repeated
 415                     :required arity
 416                     :index index
 417                     :message-type :group))
 418          (message (make-instance 'protobuf-message
 419                     :class type
 420                     :name  name
 421                     :alias-for alias-for
 422                     :conc-name (and conc-name (string conc-name))
 423                     :options  options
 424                     :message-type :group                ;this message is a group
 425                     :documentation documentation))
 426          (index 0)
 427          (*protobuf* message))
 428     (with-collectors ((slots collect-slot)
 429                       (forms collect-form))
 430       (dolist (field fields)
 431         (case (car field)
 432           ((define-enum define-message define-extend define-extension define-group)
 433            (destructuring-bind (&optional progn type model definers extra-field extra-slot)
 434                (macroexpand-1 field env)
 435              (assert (eq progn 'progn) ()
 436                      "The macroexpansion for ~S failed" field)
 437              (map () #'collect-form definers)
 438              (ecase type
 439                ((define-enum)
 440                 (setf (proto-enums message) (nconc (proto-enums message) (list model))))
 441                ((define-message define-extend)
 442                 (setf (proto-parent model) message)
 443                 (setf (proto-messages message) (nconc (proto-messages message) (list model)))
 444                 (when (eq (proto-message-type model) :extends)
 445                   (setf (proto-extenders message) (nconc (proto-extenders message) (list model)))))
 446                ((define-group)
 447                 (setf (proto-parent model) message)
 448                 (setf (proto-messages message) (nconc (proto-messages message) (list model)))
 449                 (when extra-slot
 450                   (collect-slot extra-slot))
 451                 (setf (proto-fields message) (nconc (proto-fields message) (list extra-field))))
 452                ((define-extension)
 453                 (setf (proto-extensions message) (nconc (proto-extensions message) (list model)))))))
 454           (otherwise
 455            (multiple-value-bind (field slot idx)
 456                (process-field field index :conc-name conc-name :alias-for alias-for)
 457              (assert (not (find (proto-index field) (proto-fields message) :key #'proto-index)) ()
 458                      "The field ~S overlaps with another field in ~S"
 459                      (proto-value field) (proto-class message))
 460              (setq index idx)
 461              (when slot
 462                (collect-slot slot))
 463              (setf (proto-fields message) (nconc (proto-fields message) (list field)))))))
 464       (if alias-for
 465         ;; If we've got an alias, define a a type that is the subtype of
 466         ;; the Lisp class that typep and subtypep work
 467         (unless (or (eq type alias-for) (find-class type nil))
 468           (collect-form `(deftype ,type () ',alias-for)))
 469         ;; If no alias, define the class now
 470         (collect-form `(defclass ,type () (,@slots)
 471                          ,@(and documentation `((:documentation ,documentation))))))
 472       `(progn
 473          define-group
 474          ,message
 475          ,forms
 476          ,mfield
 477          ,mslot))))
 478
 479 (defun process-field (field index &key conc-name alias-for)
 480   "Process one field descriptor within 'define-message' or 'define-extend'.
 481    Returns a 'proto-field' object, a CLOS slot form and the incremented field index."
 482   (when (i= index 18999)                                ;skip over the restricted range
 483     (setq index 19999))
 484   (destructuring-bind (slot &key type (default nil default-p) reader writer name documentation) field
 485     (let* ((idx  (if (listp slot) (second slot) (iincf index)))
 486            (slot (if (listp slot) (first slot) slot))
 487            (reqd (clos-type-to-protobuf-required type))
 488            (reader (if (eq reader 't)
 489                      (intern (if conc-name (format nil "~A~A" conc-name slot) (symbol-name slot))
 490                              (symbol-package slot))
 491                      reader)))
 492       (multiple-value-bind (ptype pclass)
 493           (clos-type-to-protobuf-type type)
 494         (let ((slot (unless alias-for
 495                       `(,slot :type ,type
 496                               ,@(and reader
 497                                      (if writer
 498                                        `(:reader ,reader)
 499                                        `(:accessor ,reader)))
 500                               ,@(and writer
 501                                      `(:writer ,writer))
 502                               :initarg ,(kintern (symbol-name slot))
 503                               ,@(cond ((and (not default-p)
 504                                             (eq reqd :repeated))
 505                                        `(:initform ()))
 506                                       ((and (not default-p)
 507                                             (eq reqd :optional)
 508                                             ;; Use unbound for booleans only
 509                                             (not (eq pclass :bool)))
 510                                        `(:initform nil))
 511                                       (default-p
 512                                         `(:initform ,(protobuf-default-to-clos-init default type)))))))
 513               (field (make-instance 'protobuf-field
 514                        :name  (or name (slot-name->proto slot))
 515                        :type  ptype
 516                        :class pclass
 517                        :required reqd
 518                        :index  idx
 519                        :value  slot
 520                        :reader reader
 521                        :writer writer
 522                        :default default
 523                        :packed  (and (eq reqd :repeated)
 524                                      (packed-type-p pclass))
 525                        :documentation documentation)))
 526           (values field slot idx))))))
 527
 528 ;; Define a service named 'type' with generic functions declared for
 529 ;; each of the methods within the service
 530 (defmacro define-service (type (&key name options documentation)
 531                           &body method-specs)
 532   "Define a service named 'type' and Lisp 'defgeneric' for all its methods.
 533    'name' can be used to override the defaultly generated Protobufs service name.
 534    'options' is a set of keyword/value pairs, both of which are strings.
 535
 536    The body is a set of method specs of the form (name (input-type output-type) &key options).
 537    'input-type' and 'output-type' may also be of the form (type &key name)."
 538   (let* ((name    (or name (class-name->proto type)))
 539          (options (loop for (key val) on options by #'cddr
 540                         collect (make-instance 'protobuf-option
 541                                   :name  key
 542                                   :value val)))
 543          (service (make-instance 'protobuf-service
 544                     :class type
 545                     :name  name
 546                     :options options
 547                     :documentation documentation)))
 548     (with-collectors ((forms collect-form))
 549       (dolist (method method-specs)
 550         (destructuring-bind (function (input-type output-type) &key name options documentation) method
 551           (let* ((input-name (and (listp input-type)
 552                                   (getf (cdr input-type) :name)))
 553                  (input-type (if (listp input-type) (car input-type) input-type))
 554                  (output-name (and (listp output-type)
 555                                    (getf (cdr output-type) :name)))
 556                  (output-type (if (listp output-type) (car output-type) output-type))
 557                  (options (loop for (key val) on options by #'cddr
 558                                 collect (make-instance 'protobuf-option
 559                                           :name  key
 560                                           :value val)))
 561                  (method  (make-instance 'protobuf-method
 562                             :class function
 563                             :name  (or name (class-name->proto function))
 564                             :input-type  input-type
 565                             :input-name  (or input-name (class-name->proto input-type))
 566                             :output-type output-type
 567                             :output-name (or output-name (class-name->proto output-type))
 568                             :options options
 569                             :documentation documentation)))
 570             (setf (proto-methods service) (nconc (proto-methods service) (list method)))
 571             ;; The following are the hooks to CL-Stubby
 572             (let* ((package   (symbol-package function))
 573                    (client-fn function)
 574                    (server-fn (intern (format nil "~A-~A" 'do function) package))
 575                    (vinput    (intern (format nil "~A-~A" (symbol-name input-type) 'in) package))
 576                    (voutput   (intern (format nil "~A-~A" (symbol-name output-type) 'out) package))
 577                    (vchannel  (intern (symbol-name 'channel) package))
 578                    (vcallback (intern (symbol-name 'callback) package)))
 579               ;; The client side stub, e.g., 'read-air-reservation'.
 580               ;; The expectation is that CL-Stubby will provide macrology to make it
 581               ;; easy to implement a method for this on each kind of channel (HTTP, TCP socket,
 582               ;; IPC, etc). Unlike C++/Java/Python, we don't need a client-side subclass,
 583               ;; because we can just use multi-methods.
 584               ;; The CL-Stubby macros take care of serializing the input, transmitting the
 585               ;; request over the wire, waiting for input (or not if it's asynchronous),
 586               ;; filling in the output, and calling the callback (if it's synchronous).
 587               ;; It's not very Lispy to side-effect an output object, but it makes
 588               ;; asynchronous calls simpler.
 589               (collect-form `(defgeneric ,client-fn (,vchannel ,vinput ,voutput &key ,vcallback)
 590                                ,@(and documentation `((:documentation ,documentation)))
 591                                (declare (values ,output-type))))
 592               ;; The server side stub, e.g., 'do-read-air-reservation'.
 593               ;; The expectation is that the server-side program will implement
 594               ;; a method with the business logic for this on each kind of channel
 595               ;; (HTTP, TCP socket, IPC, etc), possibly on a server-side subclass
 596               ;; of the input class
 597               ;; The business logic is expected to perform the correct operations on
 598               ;; the input object, which arrived via Protobufs, and produce an output
 599               ;; of the given type, which will be serialized as a result.
 600               ;; The channel objects hold client identity information, deadline info,
 601               ;; etc, and can be side-effected to indicate success or failure
 602               ;; CL-Stubby provides the channel classes and does (de)serialization, etc
 603               (collect-form `(defgeneric ,server-fn (,vchannel ,vinput ,voutput &key ,vcallback)
 604                                ,@(and documentation `((:documentation ,documentation)))
 605                                (declare (values ,output-type))))))))
 606       `(progn
 607          define-service
 608          ,service
 609          ,forms))))
 610
 611 \f
 612 ;;; Ensure everything in a Protobufs schema is defined
 613
 614 (defvar *undefined-messages*)
 615
 616 ;; A very useful tool during development...
 617 (defun ensure-all-protobufs ()
 618   (let ((protos (sort
 619                  (delete-duplicates
 620                   (loop for p being the hash-values of *all-protobufs*
 621                         collect p))
 622                  #'string< :key #'proto-name)))
 623     (mapcan #'ensure-protobuf protos)))
 624
 625 (defmethod ensure-protobuf ((proto protobuf))
 626   "Ensure that all of the types are defined in the Protobufs schema 'proto'.
 627    This returns two values:
 628     - A list whose elements are (<undefined-type> \"message:field\" ...)
 629     - The accumulated warnings table that has the same information as objects."
 630   (let ((*undefined-messages* (make-hash-table))
 631         (trace (list proto)))
 632     (map () (curry #'ensure-message trace) (proto-messages proto))
 633     (map () (curry #'ensure-service trace) (proto-services proto))
 634     (loop for type being the hash-keys of *undefined-messages*
 635             using (hash-value things)
 636           collect (list* type
 637                          (mapcar #'(lambda (thing)
 638                                      (format nil "~A:~A" (proto-name (car thing)) (proto-name (cdr thing))))
 639                                  things)) into warnings
 640           finally (return (values warnings *undefined-messages*)))))
 641
 642 (defmethod ensure-message (trace (message protobuf-message))
 643   (let ((trace (cons message trace)))
 644     (map () (curry #'ensure-message trace) (proto-messages message))
 645     (map () (curry #'ensure-field trace message) (proto-fields message))))
 646
 647 (defmethod ensure-field (trace message (field protobuf-field))
 648   (ensure-type trace message field (proto-class field)))
 649
 650 (defmethod ensure-service (trace (service protobuf-service))
 651   (map () (curry #'ensure-method trace service) (proto-methods service)))
 652
 653 (defmethod ensure-method (trace service (method protobuf-method))
 654   (ensure-type trace service method (proto-input-type method))
 655   (ensure-type trace service method (proto-output-type method)))
 656
 657 ;; 'message' and 'field' can be a message and a field or a service and a method
 658 (defun ensure-type (trace message field type)
 659   (unless (keywordp type)
 660     (let ((msg (loop for p in trace
 661                      thereis (or (find-message p type)
 662                                  (find-enum p type)))))
 663       (unless msg
 664         (push (cons message field) (gethash type *undefined-messages*))))))