define-proto.lisp

   1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   2 ;;;                                                                  ;;;
   3 ;;; Confidential and proprietary information of ITA Software, Inc.   ;;;
   4 ;;;                                                                  ;;;
   5 ;;; Copyright (c) 2012 ITA Software, Inc.  All rights reserved.      ;;;
   6 ;;;                                                                  ;;;
   7 ;;; Original author: Scott McKay                                     ;;;
   8 ;;;                                                                  ;;;
   9 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  10
  11 (in-package "PROTO-IMPL")
  12
  13
  14 ;;; Protocol buffer defining macros
  15
  16 ;; Define a schema named 'type', corresponding to a .proto file of that name
  17 (defmacro define-proto (type (&key name syntax package lisp-package import optimize options documentation)
  18                         &body messages &environment env)
  19   "Define a schema named 'type', corresponding to a .proto file of that name.
  20    'name' can be used to override the defaultly generated Protobufs name.
  21    'syntax' and 'package' are as they would be in a .proto file.
  22    'lisp-package' can be used to specify a Lisp package if it is different from
  23    the Protobufs package given by 'package'.
  24    'import' is a list of pathname strings to be imported.
  25    'optimize' can be either :space (the default) or :speed; if it is :speed, the
  26    serialization code will be much faster, but much less compact.
  27    'options' is a property list, i.e., (\"key1\" \"val1\" \"key2\" \"val2\" ...).
  28
  29    The body consists of 'define-enum', 'define-message' or 'define-service' forms."
  30   (let* ((name     (or name (class-name->proto type)))
  31          (package  (and package (if (stringp package) package (string-downcase (string package)))))
  32          (lisp-pkg (and lisp-package (if (stringp lisp-package) lisp-package (string lisp-package))))
  33          (options  (loop for (key val) on options by #'cddr
  34                          collect (make-instance 'protobuf-option
  35                                    :name  key
  36                                    :value val)))
  37          (imports  (if (listp import) import (list import)))
  38          (protobuf (make-instance 'protobuf
  39                      :class    type
  40                      :name     name
  41                      :syntax   (or syntax "proto2")
  42                      :package  package
  43                      :lisp-package (or lisp-pkg package)
  44                      :imports  imports
  45                      :options  (if optimize
  46                                  (append options (list (make-instance 'protobuf-option
  47                                                          :name  "optimize_for"
  48                                                          :value (if (eq optimize :speed) "SPEED" "CODE_SIZE")
  49                                                          :type  'symbol)))
  50                                  options)
  51                      :documentation documentation))
  52          (*protobuf* protobuf)
  53          (*protobuf-package* (or (find-package lisp-pkg)
  54                                  (find-package (string-upcase lisp-pkg))
  55                                  *package*)))
  56     (apply #'process-imports imports)
  57     (with-collectors ((forms collect-form))
  58       (dolist (msg messages)
  59         (assert (and (listp msg)
  60                      (member (car msg) '(define-enum define-message define-extend define-service))) ()
  61                 "The body of ~S must be one of ~{~S~^ or ~}"
  62                 'define-proto '(define-enum define-message define-extend define-service))
  63         ;; The macro-expander will return a form that consists
  64         ;; of 'progn' followed by a symbol naming what we've expanded
  65         ;; (define-enum, define-message, define-extend, define-service),
  66         ;; followed by the Lisp model object created by the defining form,
  67         ;; followed by other defining forms (e.g., deftype, defclass)
  68         (destructuring-bind (&optional progn type model definers)
  69             (macroexpand-1 msg env)
  70           (assert (eq progn 'progn) ()
  71                   "The macroexpansion for ~S failed" msg)
  72           (map () #'collect-form definers)
  73           (ecase type
  74             ((define-enum)
  75              (setf (proto-enums protobuf) (nconc (proto-enums protobuf) (list model))))
  76             ((define-message define-extend)
  77              (setf (proto-parent model) protobuf)
  78              (setf (proto-messages protobuf) (nconc (proto-messages protobuf) (list model)))
  79              (when (eq (proto-message-type model) :extends)
  80                (setf (proto-extenders protobuf) (nconc (proto-extenders protobuf) (list model)))))
  81             ((define-service)
  82              (setf (proto-services protobuf) (nconc (proto-services protobuf) (list model)))))))
  83       (let ((var (intern (format nil "*~A*" type) *protobuf-package*)))
  84         `(progn
  85            ,@forms
  86            (defvar ,var nil)
  87            (let* ((old-proto ,var)
  88                   (new-proto ,protobuf))
  89              (when old-proto
  90                (multiple-value-bind (upgradable warnings)
  91                    (protobuf-upgradable old-proto new-proto)
  92                  (unless upgradable
  93                    (protobufs-warn "The old schema for ~S (~A) can't be safely upgraded; proceeding anyway"
  94                                    ',type ',name)
  95                    (map () #'protobufs-warn warnings))))
  96              (setq ,var new-proto)
  97              ,@(when (eq optimize :speed)
  98                  (with-collectors ((messages collect-message))
  99                    (labels ((collect-messages (message)
 100                               (collect-message message)
 101                               (map () #'collect-messages (proto-messages message))))
 102                    (map () #'collect-messages (proto-messages protobuf)))
 103                    (append (mapcar #'generate-object-size  messages)
 104                            (mapcar #'generate-serializer   messages)
 105                            (mapcar #'generate-deserializer messages))))
 106              new-proto))))))
 107
 108 ;; Define an enum type named 'type' and a Lisp 'deftype'
 109 (defmacro define-enum (type (&key name conc-name alias-for options documentation)
 110                        &body values)
 111   "Define a Protobufs enum type and a Lisp 'deftype' named 'type'.
 112    'name' can be used to override the defaultly generated Protobufs enum name.
 113    'conc-name' will be used as the prefix to the Lisp enum names, if it's supplied.
 114    If 'alias-for' is given, no Lisp 'deftype' will be defined. Instead, the enum
 115    will be used as an alias for an enum type that already exists in Lisp.
 116    'options' is a set of keyword/value pairs, both of which are strings.
 117
 118    The body consists of the enum values in the form 'name' or (name index)."
 119   (let* ((name    (or name (class-name->proto type)))
 120          (options (loop for (key val) on options by #'cddr
 121                         collect (make-instance 'protobuf-option
 122                                   :name  key
 123                                   :value val)))
 124          (index -1)
 125          (enum  (make-instance 'protobuf-enum
 126                   :class  type
 127                   :name   name
 128                   :alias-for alias-for
 129                   :options options
 130                   :documentation documentation)))
 131     (with-collectors ((vals  collect-val)
 132                       (forms collect-form))
 133       (dolist (val values)
 134         (let* ((idx  (if (listp val) (second val) (incf index)))
 135                (name (if (listp val) (first val)  val))
 136                (val-name  (kintern (if conc-name (format nil "~A~A" conc-name name) (symbol-name name))))
 137                (enum-name (if conc-name (format nil "~A~A" conc-name name) (symbol-name name)))
 138                (enum-val  (make-instance 'protobuf-enum-value
 139                             :name  (enum-name->proto enum-name)
 140                             :index idx
 141                             :value val-name)))
 142           (collect-val val-name)
 143           (setf (proto-values enum) (nconc (proto-values enum) (list enum-val)))))
 144       (if alias-for
 145         ;; If we've got an alias, define a a type that is the subtype of
 146         ;; the Lisp enum so that typep and subtypep work
 147         (unless (eq type alias-for)
 148           (collect-form `(deftype ,type () ',alias-for)))
 149         ;; If no alias, define the Lisp enum type now
 150         (collect-form `(deftype ,type () '(member ,@vals))))
 151       `(progn
 152          define-enum
 153          ,enum
 154          ,forms))))
 155
 156 ;; Define a message named 'name' and a Lisp 'defclass'
 157 (defmacro define-message (type (&key name conc-name alias-for options documentation)
 158                           &body fields &environment env)
 159   "Define a message named 'type' and a Lisp 'defclass'.
 160    'name' can be used to override the defaultly generated Protobufs message name.
 161    The body consists of fields, or 'define-enum' or 'define-message' forms.
 162    'conc-name' will be used as the prefix to the Lisp slot accessors, if it's supplied.
 163    If 'alias-for' is given, no Lisp class is defined. Instead, the message will be
 164    used as an alias for a class that already exists in Lisp. This feature is intended
 165    to be used to define messages that will be serialized from existing Lisp classes;
 166    unless you get the slot names or readers exactly right for each field, it will be
 167    the case that trying to (de)serialize into a Lisp object won't work.
 168    'options' is a set of keyword/value pairs, both of which are strings.
 169
 170    Fields take the form (slot &key type name default reader)
 171    'slot' can be either a symbol giving the field name, or a list whose
 172    first element is the slot name and whose second element is the index.
 173    'type' is the type of the slot.
 174    'name' can be used to override the defaultly generated Protobufs field name.
 175    'default' is the default value for the slot.
 176    'reader' is a Lisp slot reader function to use to get the value, instead of
 177    using 'slot-value'; this is often used when aliasing an existing class.
 178    'writer' is a Lisp slot writer function to use to set the value."
 179   (let* ((name    (or name (class-name->proto type)))
 180          (options (loop for (key val) on options by #'cddr
 181                         collect (make-instance 'protobuf-option
 182                                   :name  key
 183                                   :value val)))
 184          (message (make-instance 'protobuf-message
 185                     :class type
 186                     :name  name
 187                     :alias-for alias-for
 188                     :conc-name (and conc-name (string conc-name))
 189                     :options  options
 190                     :documentation documentation))
 191          (index 0)
 192          (*protobuf* message))
 193     (with-collectors ((slots collect-slot)
 194                       (forms collect-form))
 195       (dolist (field fields)
 196         (case (car field)
 197           ((define-enum define-message define-extend define-extension define-group)
 198            (destructuring-bind (&optional progn type model definers extra-field extra-slot)
 199                (macroexpand-1 field env)
 200              (assert (eq progn 'progn) ()
 201                      "The macroexpansion for ~S failed" field)
 202              (map () #'collect-form definers)
 203              (ecase type
 204                ((define-enum)
 205                 (setf (proto-enums message) (nconc (proto-enums message) (list model))))
 206                ((define-message define-extend)
 207                 (setf (proto-parent model) message)
 208                 (setf (proto-messages message) (nconc (proto-messages message) (list model)))
 209                 (when (eq (proto-message-type model) :extends)
 210                   (setf (proto-extenders message) (nconc (proto-extenders message) (list model)))))
 211                ((define-group)
 212                 (setf (proto-parent model) message)
 213                 (setf (proto-messages message) (nconc (proto-messages message) (list model)))
 214                 (when extra-slot
 215                   (collect-slot extra-slot))
 216                 (setf (proto-fields message) (nconc (proto-fields message) (list extra-field))))
 217                ((define-extension)
 218                 (setf (proto-extensions message) (nconc (proto-extensions message) (list model)))))))
 219           (otherwise
 220            (multiple-value-bind (field slot idx)
 221                (process-field field index :conc-name conc-name :alias-for alias-for)
 222              (assert (not (find (proto-index field) (proto-fields message) :key #'proto-index)) ()
 223                      "The field ~S overlaps with another field in ~S"
 224                      (proto-value field) (proto-class message))
 225              (setq index idx)
 226              (when slot
 227                (collect-slot slot))
 228              (setf (proto-fields message) (nconc (proto-fields message) (list field)))))))
 229       (if alias-for
 230         ;; If we've got an alias, define a a type that is the subtype of
 231         ;; the Lisp class that typep and subtypep work
 232         (unless (or (eq type alias-for) (find-class type nil))
 233           (collect-form `(deftype ,type () ',alias-for)))
 234         ;; If no alias, define the class now
 235         (collect-form `(defclass ,type () (,@slots)
 236                          ,@(and documentation `((:documentation ,documentation))))))
 237       `(progn
 238          define-message
 239          ,message
 240          ,forms))))
 241
 242 (defmacro define-extend (type (&key name options documentation)
 243                           &body fields &environment env)
 244   "Define an extension to the message named 'type'.
 245    'name' can be used to override the defaultly generated Protobufs message name.
 246    The body consists only  of fields.
 247    'options' is a set of keyword/value pairs, both of which are strings.
 248
 249    Fields take the form (slot &key type name default reader)
 250    'slot' can be either a symbol giving the field name, or a list whose
 251    first element is the slot name and whose second element is the index.
 252    'type' is the type of the slot.
 253    'name' can be used to override the defaultly generated Protobufs field name.
 254    'default' is the default value for the slot.
 255    'reader' is a Lisp slot reader function to use to get the value, instead of
 256    using 'slot-value'; this is often used when aliasing an existing class.
 257    'writer' is a Lisp slot writer function to use to set the value."
 258   (declare (ignore env))
 259   (let* ((name    (or name (class-name->proto type)))
 260          (options (loop for (key val) on options by #'cddr
 261                         collect (make-instance 'protobuf-option
 262                                   :name  key
 263                                   :value val)))
 264          (message   (find-message *protobuf* name))
 265          (conc-name (and message (proto-conc-name message)))
 266          (alias-for (and message (proto-alias-for message)))
 267          (extends (and message
 268                        (make-instance 'protobuf-message
 269                          :class  type
 270                          :name   name
 271                          :parent (proto-parent message)
 272                          :conc-name conc-name
 273                          :alias-for alias-for
 274                          :enums    (copy-list (proto-enums message))
 275                          :messages (copy-list (proto-messages message))
 276                          :fields   (copy-list (proto-fields message))
 277                          :options  (or options (copy-list (proto-options message)))
 278                          :message-type :extends         ;this message is an extension
 279                          :documentation documentation)))
 280          (index 0))
 281     (assert message ()
 282             "There is no message named ~A to extend" name)
 283     (assert (eq type (proto-class message)) ()
 284             "The type ~S doesn't match the type of the message being extended ~S"
 285             type message)
 286     (with-collectors ((forms collect-form))
 287       (dolist (field fields)
 288         (assert (not (member (car field)
 289                              '(define-enum define-message define-extend define-extension define-group))) ()
 290                 "The body of ~S can only contain field definitions" 'define-extend)
 291         (multiple-value-bind (field slot idx)
 292             (process-field field index :conc-name conc-name :alias-for alias-for)
 293           (assert (not (find (proto-index field) (proto-fields extends) :key #'proto-index)) ()
 294                   "The field ~S overlaps with another field in ~S"
 295                   (proto-value field) (proto-class extends))
 296           (assert (index-within-extensions-p idx message) ()
 297                   "The index ~D is not in range for extending ~S"
 298                   idx (proto-class message))
 299           (setq index idx)
 300           (when slot
 301             (let* ((inits (cdr slot))
 302                    (sname (car slot))
 303                    (stype (getf inits :type))
 304                    (reader (or (getf inits :accessor)
 305                                (getf inits :reader)
 306                                (intern (if conc-name (format nil "~A~A" conc-name sname) (symbol-name sname))
 307                                        (symbol-package sname))))
 308                    (writer (or (getf inits :writer)
 309                                (intern (format nil "~A-~A" reader 'setter)
 310                                        (symbol-package sname))))
 311                    (default (getf inits :initform)))
 312               ;;--- Can we avoid having to use a hash table?
 313               ;;--- Maybe the table should be in each instance, keyed by slot name?
 314               (collect-form `(let ((,sname (make-hash-table :test #'eq :weak t)))
 315                                (defmethod ,reader ((object ,type))
 316                                  (gethash object ,sname ,default))
 317                                (defmethod ,writer ((object ,type) value)
 318                                  (declare (type ,stype value))
 319                                  (setf (gethash object ,sname) value))
 320                                (defsetf ,reader ,writer)))
 321               ;; This so that (de)serialization works
 322               (setf (proto-reader field) reader
 323                     (proto-writer field) writer)))
 324           (setf (proto-message-type field) :extends)    ;this field is an extension
 325           (setf (proto-fields extends) (nconc (proto-fields extends) (list field)))))
 326       `(progn
 327          define-extend
 328          ,extends
 329          ,forms))))
 330
 331 (defmacro define-group (type (&key index arity name conc-name alias-for options documentation)
 332                         &body fields &environment env)
 333   "Define a message named 'type' and a Lisp 'defclass', *and* a field named type.
 334    This is deprecated in Protobufs, but if you have to use it, you must give
 335    'index' as the field index and 'arity' of :required, :optional or :repeated.
 336    'name' can be used to override the defaultly generated Protobufs message name.
 337    The body consists of fields, or 'define-enum' or 'define-message' forms.
 338    'conc-name' will be used as the prefix to the Lisp slot accessors, if it's supplied.
 339    If 'alias-for' is given, no Lisp class is defined. Instead, the message will be
 340    used as an alias for a class that already exists in Lisp. This feature is intended
 341    to be used to define messages that will be serialized from existing Lisp classes;
 342    unless you get the slot names or readers exactly right for each field, it will be
 343    the case that trying to (de)serialize into a Lisp object won't work.
 344    'options' is a set of keyword/value pairs, both of which are strings.
 345
 346    Fields take the form (slot &key type name default reader)
 347    'slot' can be either a symbol giving the field name, or a list whose
 348    first element is the slot name and whose second element is the index.
 349    'type' is the type of the slot.
 350    'name' can be used to override the defaultly generated Protobufs field name.
 351    'default' is the default value for the slot.
 352    'reader' is a Lisp slot reader function to use to get the value, instead of
 353    using 'slot-value'; this is often used when aliasing an existing class.
 354    'writer' is a Lisp slot writer function to use to set the value."
 355   (check-type index integer)
 356   (check-type arity (member :required :optional :repeated))
 357   (let* ((slot    (or (and name (proto->slot-name name)) type))
 358          (name    (or name (class-name->proto type)))
 359          (options (loop for (key val) on options by #'cddr
 360                         collect (make-instance 'protobuf-option
 361                                   :name  key
 362                                   :value val)))
 363          (mslot   (unless alias-for
 364                     `(,slot ,@(case arity
 365                                 (:required
 366                                  `(:type ,type))
 367                                 (:optional
 368                                  `(:type (or ,type null)
 369                                    :initform nil))
 370                                 (:repeated
 371                                  `(:type (list-of ,type)
 372                                    :initform ())))
 373                             :initarg ,(kintern (symbol-name slot)))))
 374          (mfield  (make-instance 'protobuf-field
 375                     :name  (slot-name->proto slot)
 376                     :value slot
 377                     :type  name
 378                     :class type
 379                     ;; One of :required, :optional or :repeated
 380                     :required arity
 381                     :index index
 382                     :message-type :group))
 383          (message (make-instance 'protobuf-message
 384                     :class type
 385                     :name  name
 386                     :alias-for alias-for
 387                     :conc-name (and conc-name (string conc-name))
 388                     :options  options
 389                     :message-type :group                ;this message is a group
 390                     :documentation documentation))
 391          (index 0)
 392          (*protobuf* message))
 393     (with-collectors ((slots collect-slot)
 394                       (forms collect-form))
 395       (dolist (field fields)
 396         (case (car field)
 397           ((define-enum define-message define-extend define-extension define-group)
 398            (destructuring-bind (&optional progn type model definers extra-field extra-slot)
 399                (macroexpand-1 field env)
 400              (assert (eq progn 'progn) ()
 401                      "The macroexpansion for ~S failed" field)
 402              (map () #'collect-form definers)
 403              (ecase type
 404                ((define-enum)
 405                 (setf (proto-enums message) (nconc (proto-enums message) (list model))))
 406                ((define-message define-extend)
 407                 (setf (proto-parent model) message)
 408                 (setf (proto-messages message) (nconc (proto-messages message) (list model)))
 409                 (when (eq (proto-message-type model) :extends)
 410                   (setf (proto-extenders message) (nconc (proto-extenders message) (list model)))))
 411                ((define-group)
 412                 (setf (proto-parent model) message)
 413                 (setf (proto-messages message) (nconc (proto-messages message) (list model)))
 414                 (when extra-slot
 415                   (collect-slot extra-slot))
 416                 (setf (proto-fields message) (nconc (proto-fields message) (list extra-field))))
 417                ((define-extension)
 418                 (setf (proto-extensions message) (nconc (proto-extensions message) (list model)))))))
 419           (otherwise
 420            (multiple-value-bind (field slot idx)
 421                (process-field field index :conc-name conc-name :alias-for alias-for)
 422              (assert (not (find (proto-index field) (proto-fields message) :key #'proto-index)) ()
 423                      "The field ~S overlaps with another field in ~S"
 424                      (proto-value field) (proto-class message))
 425              (setq index idx)
 426              (when slot
 427                (collect-slot slot))
 428              (setf (proto-fields message) (nconc (proto-fields message) (list field)))))))
 429       (if alias-for
 430         ;; If we've got an alias, define a a type that is the subtype of
 431         ;; the Lisp class that typep and subtypep work
 432         (unless (or (eq type alias-for) (find-class type nil))
 433           (collect-form `(deftype ,type () ',alias-for)))
 434         ;; If no alias, define the class now
 435         (collect-form `(defclass ,type () (,@slots)
 436                          ,@(and documentation `((:documentation ,documentation))))))
 437       `(progn
 438          define-group
 439          ,message
 440          ,forms
 441          ,mfield
 442          ,mslot))))
 443
 444 (defun process-field (field index &key conc-name alias-for)
 445   "Process one field descriptor within 'define-message' or 'define-extend'.
 446    Returns a 'proto-field' object, a CLOS slot form and the incremented field index."
 447   (when (i= index 18999)                                ;skip over the restricted range
 448     (setq index 19999))
 449   (destructuring-bind (slot &key type (default nil default-p) reader writer name documentation) field
 450     (let* ((idx  (if (listp slot) (second slot) (iincf index)))
 451            (slot (if (listp slot) (first slot) slot))
 452            (reqd (clos-type-to-protobuf-required type))
 453            (reader (if (eq reader 't)
 454                      (intern (if conc-name (format nil "~A~A" conc-name slot) (symbol-name slot))
 455                              (symbol-package slot))
 456                      reader)))
 457       (multiple-value-bind (ptype pclass)
 458           (clos-type-to-protobuf-type type)
 459         (let ((slot (unless alias-for
 460                       `(,slot :type ,type
 461                               ,@(and reader
 462                                      (if writer
 463                                        `(:reader ,reader)
 464                                        `(:accessor ,reader)))
 465                               ,@(and writer
 466                                      `(:writer ,writer))
 467                               :initarg ,(kintern (symbol-name slot))
 468                               ,@(cond ((and (not default-p)
 469                                             (eq reqd :repeated))
 470                                        `(:initform ()))
 471                                       ((and (not default-p)
 472                                             (eq reqd :optional)
 473                                             ;; Use unbound for booleans only
 474                                             (not (eq pclass :bool)))
 475                                        `(:initform nil))
 476                                       (default-p
 477                                         `(:initform ,default))))))
 478               (field (make-instance 'protobuf-field
 479                        :name  (or name (slot-name->proto slot))
 480                        :type  ptype
 481                        :class pclass
 482                        :required reqd
 483                        :index  idx
 484                        :value  slot
 485                        :reader reader
 486                        :writer writer
 487                        :default (and default (format nil "~A" default))
 488                        :packed  (and (eq reqd :repeated)
 489                                      (packed-type-p pclass))
 490                        :documentation documentation)))
 491           (values field slot idx))))))
 492
 493 (defun index-within-extensions-p (index message)
 494   (let ((extensions (proto-extensions message)))
 495     (some #'(lambda (ext)
 496               (and (i>= index (proto-extension-from ext))
 497                    (i<= index (proto-extension-to ext))))
 498           extensions)))
 499
 500 (defmacro define-extension (from to)
 501   "Define an extension range within a message.
 502    The \"body\" is the start and end of the range, both inclusive."
 503   `(progn
 504      define-extension
 505      ,(make-instance 'protobuf-extension
 506         :from from
 507         :to   (if (eq to 'max) #.(1- (ash 1 29)) to))
 508      ()))
 509
 510 ;; Define a service named 'type' with generic functions declared for
 511 ;; each of the methods within the service
 512 (defmacro define-service (type (&key name options documentation)
 513                           &body method-specs)
 514   "Define a service named 'type' and Lisp 'defgeneric' for all its methods.
 515    'name' can be used to override the defaultly generated Protobufs service name.
 516    'options' is a set of keyword/value pairs, both of which are strings.
 517
 518    The body is a set of method specs of the form (name (input-type output-type) &key options).
 519    'input-type' and 'output-type' may also be of the form (type &key name)."
 520   (let* ((name    (or name (class-name->proto type)))
 521          (options (loop for (key val) on options by #'cddr
 522                         collect (make-instance 'protobuf-option
 523                                   :name  key
 524                                   :value val)))
 525          (service (make-instance 'protobuf-service
 526                     :class type
 527                     :name  name
 528                     :options options
 529                     :documentation documentation)))
 530     (with-collectors ((forms collect-form))
 531       (dolist (method method-specs)
 532         (destructuring-bind (function (input-type output-type) &key name options documentation) method
 533           (let* ((input-name (and (listp input-type)
 534                                   (getf (cdr input-type) :name)))
 535                  (input-type (if (listp input-type) (car input-type) input-type))
 536                  (output-name (and (listp output-type)
 537                                    (getf (cdr output-type) :name)))
 538                  (output-type (if (listp output-type) (car output-type) output-type))
 539                  (options (loop for (key val) on options by #'cddr
 540                                 collect (make-instance 'protobuf-option
 541                                           :name  key
 542                                           :value val)))
 543                  (method  (make-instance 'protobuf-method
 544                             :class function
 545                             :name  (or name (class-name->proto function))
 546                             :input-type  input-type
 547                             :input-name  (or input-name (class-name->proto input-type))
 548                             :output-type output-type
 549                             :output-name (or output-name (class-name->proto output-type))
 550                             :options options
 551                             :documentation documentation)))
 552             (setf (proto-methods service) (nconc (proto-methods service) (list method)))
 553             ;; The following are the hooks to CL-Stubby
 554             (let* ((package   (symbol-package function))
 555                    (client-fn function)
 556                    (server-fn (intern (format nil "~A-~A" 'do function) package))
 557                    (vinput    (intern (format nil "~A-~A" (symbol-name input-type) 'in) package))
 558                    (voutput   (intern (format nil "~A-~A" (symbol-name output-type) 'out) package))
 559                    (vchannel  (intern (symbol-name 'channel) package))
 560                    (vcallback (intern (symbol-name 'callback) package)))
 561               ;; The client side stub, e.g., 'read-air-reservation'.
 562               ;; The expectation is that CL-Stubby will provide macrology to make it
 563               ;; easy to implement a method for this on each kind of channel (HTTP, TCP socket,
 564               ;; IPC, etc). Unlike C++/Java/Python, we don't need a client-side subclass,
 565               ;; because we can just use multi-methods.
 566               ;; The CL-Stubby macros take care of serializing the input, transmitting the
 567               ;; request over the wire, waiting for input (or not if it's asynchronous),
 568               ;; filling in the output, and calling the callback (if it's synchronous).
 569               ;; It's not very Lispy to side-effect an output object, but it makes
 570               ;; asynchronous calls simpler.
 571               (collect-form `(defgeneric ,client-fn (,vchannel ,vinput ,voutput &key ,vcallback)
 572                                ,@(and documentation `((:documentation ,documentation)))
 573                                (declare (values ,output-type))))
 574               ;; The server side stub, e.g., 'do-read-air-reservation'.
 575               ;; The expectation is that the server-side program will implement
 576               ;; a method with the business logic for this on each kind of channel
 577               ;; (HTTP, TCP socket, IPC, etc), possibly on a server-side subclass
 578               ;; of the input class
 579               ;; The business logic is expected to perform the correct operations on
 580               ;; the input object, which arrived via Protobufs, and produce an output
 581               ;; of the given type, which will be serialized as a result.
 582               ;; The channel objects hold client identity information, deadline info,
 583               ;; etc, and can be side-effected to indicate success or failure
 584               ;; CL-Stubby provides the channel classes and does (de)serialization, etc
 585               (collect-form `(defgeneric ,server-fn (,vchannel ,vinput ,voutput &key ,vcallback)
 586                                ,@(and documentation `((:documentation ,documentation)))
 587                                (declare (values ,output-type))))))))
 588       `(progn
 589          define-service
 590          ,service
 591          ,forms))))
 592
 593 \f
 594 ;;; Ensure everything in a Protobufs schema is defined
 595
 596 (defvar *undefined-messages*)
 597
 598 ;; A very useful tool during development...
 599 (defun ensure-all-protobufs ()
 600   (let ((protos (sort
 601                  (delete-duplicates
 602                   (loop for p being the hash-values of *all-protobufs*
 603                         collect p))
 604                  #'string< :key #'proto-name)))
 605     (mapcan #'ensure-protobuf protos)))
 606
 607 (defmethod ensure-protobuf ((proto protobuf))
 608   "Ensure that all of the types are defined in the Protobufs schema 'proto'.
 609    This returns two values:
 610     - A list whose elements are (<undefined-type> \"message:field\" ...)
 611     - The accumulated warnings table that has the same information as objects."
 612   (let ((*undefined-messages* (make-hash-table))
 613         (trace (list proto)))
 614     (map () (curry #'ensure-message trace) (proto-messages proto))
 615     (map () (curry #'ensure-service trace) (proto-services proto))
 616     (loop for type being the hash-keys of *undefined-messages*
 617             using (hash-value things)
 618           collect (list* type
 619                          (mapcar #'(lambda (thing)
 620                                      (format nil "~A:~A" (proto-name (car thing)) (proto-name (cdr thing))))
 621                                  things)) into warnings
 622           finally (return (values warnings *undefined-messages*)))))
 623
 624 (defmethod ensure-message (trace (message protobuf-message))
 625   (let ((trace (cons message trace)))
 626     (map () (curry #'ensure-message trace) (proto-messages message))
 627     (map () (curry #'ensure-field trace message) (proto-fields message))))
 628
 629 (defmethod ensure-field (trace message (field protobuf-field))
 630   (ensure-type trace message field (proto-class field)))
 631
 632 (defmethod ensure-service (trace (service protobuf-service))
 633   (map () (curry #'ensure-method trace service) (proto-methods service)))
 634
 635 (defmethod ensure-method (trace service (method protobuf-method))
 636   (ensure-type trace service method (proto-input-type method))
 637   (ensure-type trace service method (proto-output-type method)))
 638
 639 ;; 'message' and 'field' can be a message and a field or a service and a method
 640 (defun ensure-type (trace message field type)
 641   (unless (keywordp type)
 642     (let ((msg (loop for p in trace
 643                      thereis (or (find-message p type)
 644                                  (find-enum p type)))))
 645       (unless msg
 646         (push (cons message field) (gethash type *undefined-messages*))))))