git-gui

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3 exec wish "$0" -- "$@"
   4
   5 set copyright {
   6 Copyright © 2006 Shawn Pearce, Paul Mackerras.
   7
   8 All rights reserved.
   9
  10 This program is free software; it may be used, copied, modified
  11 and distributed under the terms of the GNU General Public Licence,
  12 either version 2, or (at your option) any later version.}
  13
  14 set appname [lindex [file split $argv0] end]
  15 set gitdir {}
  16
  17 ######################################################################
  18 ##
  19 ## config
  20
  21 proc is_many_config {name} {
  22         switch -glob -- $name {
  23         remote.*.fetch -
  24         remote.*.push
  25                 {return 1}
  26         *
  27                 {return 0}
  28         }
  29 }
  30
  31 proc load_config {include_global} {
  32         global repo_config global_config default_config
  33
  34         array unset global_config
  35         if {$include_global} {
  36                 catch {
  37                         set fd_rc [open "| git repo-config --global --list" r]
  38                         while {[gets $fd_rc line] >= 0} {
  39                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  40                                         if {[is_many_config $name]} {
  41                                                 lappend global_config($name) $value
  42                                         } else {
  43                                                 set global_config($name) $value
  44                                         }
  45                                 }
  46                         }
  47                         close $fd_rc
  48                 }
  49         }
  50
  51         array unset repo_config
  52         catch {
  53                 set fd_rc [open "| git repo-config --list" r]
  54                 while {[gets $fd_rc line] >= 0} {
  55                         if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  56                                 if {[is_many_config $name]} {
  57                                         lappend repo_config($name) $value
  58                                 } else {
  59                                         set repo_config($name) $value
  60                                 }
  61                         }
  62                 }
  63                 close $fd_rc
  64         }
  65
  66         foreach name [array names default_config] {
  67                 if {[catch {set v $global_config($name)}]} {
  68                         set global_config($name) $default_config($name)
  69                 }
  70                 if {[catch {set v $repo_config($name)}]} {
  71                         set repo_config($name) $default_config($name)
  72                 }
  73         }
  74 }
  75
  76 proc save_config {} {
  77         global default_config font_descs
  78         global repo_config global_config
  79         global repo_config_new global_config_new
  80
  81         foreach option $font_descs {
  82                 set name [lindex $option 0]
  83                 set font [lindex $option 1]
  84                 font configure $font \
  85                         -family $global_config_new(gui.$font^^family) \
  86                         -size $global_config_new(gui.$font^^size)
  87                 font configure ${font}bold \
  88                         -family $global_config_new(gui.$font^^family) \
  89                         -size $global_config_new(gui.$font^^size)
  90                 set global_config_new(gui.$name) [font configure $font]
  91                 unset global_config_new(gui.$font^^family)
  92                 unset global_config_new(gui.$font^^size)
  93         }
  94
  95         foreach name [array names default_config] {
  96                 set value $global_config_new($name)
  97                 if {$value ne $global_config($name)} {
  98                         if {$value eq $default_config($name)} {
  99                                 catch {exec git repo-config --global --unset $name}
 100                         } else {
 101                                 regsub -all "\[{}\]" $value {"} value
 102                                 exec git repo-config --global $name $value
 103                         }
 104                         set global_config($name) $value
 105                         if {$value eq $repo_config($name)} {
 106                                 catch {exec git repo-config --unset $name}
 107                                 set repo_config($name) $value
 108                         }
 109                 }
 110         }
 111
 112         foreach name [array names default_config] {
 113                 set value $repo_config_new($name)
 114                 if {$value ne $repo_config($name)} {
 115                         if {$value eq $global_config($name)} {
 116                                 catch {exec git repo-config --unset $name}
 117                         } else {
 118                                 regsub -all "\[{}\]" $value {"} value
 119                                 exec git repo-config $name $value
 120                         }
 121                         set repo_config($name) $value
 122                 }
 123         }
 124 }
 125
 126 proc error_popup {msg} {
 127         global gitdir appname
 128
 129         set title $appname
 130         if {$gitdir ne {}} {
 131                 append title { (}
 132                 append title [lindex \
 133                         [file split [file normalize [file dirname $gitdir]]] \
 134                         end]
 135                 append title {)}
 136         }
 137         set cmd [list tk_messageBox \
 138                 -icon error \
 139                 -type ok \
 140                 -title "$title: error" \
 141                 -message $msg]
 142         if {[winfo ismapped .]} {
 143                 lappend cmd -parent .
 144         }
 145         eval $cmd
 146 }
 147
 148 proc warn_popup {msg} {
 149         global gitdir appname
 150
 151         set title $appname
 152         if {$gitdir ne {}} {
 153                 append title { (}
 154                 append title [lindex \
 155                         [file split [file normalize [file dirname $gitdir]]] \
 156                         end]
 157                 append title {)}
 158         }
 159         set cmd [list tk_messageBox \
 160                 -icon warning \
 161                 -type ok \
 162                 -title "$title: warning" \
 163                 -message $msg]
 164         if {[winfo ismapped .]} {
 165                 lappend cmd -parent .
 166         }
 167         eval $cmd
 168 }
 169
 170 proc info_popup {msg} {
 171         global gitdir appname
 172
 173         set title $appname
 174         if {$gitdir ne {}} {
 175                 append title { (}
 176                 append title [lindex \
 177                         [file split [file normalize [file dirname $gitdir]]] \
 178                         end]
 179                 append title {)}
 180         }
 181         tk_messageBox \
 182                 -parent . \
 183                 -icon info \
 184                 -type ok \
 185                 -title $title \
 186                 -message $msg
 187 }
 188
 189 ######################################################################
 190 ##
 191 ## repository setup
 192
 193 if {   [catch {set gitdir $env(GIT_DIR)}]
 194         && [catch {set gitdir [exec git rev-parse --git-dir]} err]} {
 195         catch {wm withdraw .}
 196         error_popup "Cannot find the git directory:\n\n$err"
 197         exit 1
 198 }
 199 if {![file isdirectory $gitdir]} {
 200         catch {wm withdraw .}
 201         error_popup "Git directory not found:\n\n$gitdir"
 202         exit 1
 203 }
 204 if {[lindex [file split $gitdir] end] ne {.git}} {
 205         catch {wm withdraw .}
 206         error_popup "Cannot use funny .git directory:\n\n$gitdir"
 207         exit 1
 208 }
 209 if {[catch {cd [file dirname $gitdir]} err]} {
 210         catch {wm withdraw .}
 211         error_popup "No working directory [file dirname $gitdir]:\n\n$err"
 212         exit 1
 213 }
 214
 215 set single_commit 0
 216 if {$appname eq {git-citool}} {
 217         set single_commit 1
 218 }
 219
 220 ######################################################################
 221 ##
 222 ## task management
 223
 224 set rescan_active 0
 225 set diff_active 0
 226 set last_clicked {}
 227
 228 set disable_on_lock [list]
 229 set index_lock_type none
 230
 231 proc lock_index {type} {
 232         global index_lock_type disable_on_lock
 233
 234         if {$index_lock_type eq {none}} {
 235                 set index_lock_type $type
 236                 foreach w $disable_on_lock {
 237                         uplevel #0 $w disabled
 238                 }
 239                 return 1
 240         } elseif {$index_lock_type eq "begin-$type"} {
 241                 set index_lock_type $type
 242                 return 1
 243         }
 244         return 0
 245 }
 246
 247 proc unlock_index {} {
 248         global index_lock_type disable_on_lock
 249
 250         set index_lock_type none
 251         foreach w $disable_on_lock {
 252                 uplevel #0 $w normal
 253         }
 254 }
 255
 256 ######################################################################
 257 ##
 258 ## status
 259
 260 proc repository_state {ctvar hdvar mhvar} {
 261         global gitdir current_branch
 262         upvar $ctvar ct $hdvar hd $mhvar mh
 263
 264         set mh [list]
 265
 266         if {[catch {set current_branch [exec git symbolic-ref HEAD]}]} {
 267                 set current_branch {}
 268         } else {
 269                 regsub ^refs/((heads|tags|remotes)/)? \
 270                         $current_branch \
 271                         {} \
 272                         current_branch
 273         }
 274
 275         if {[catch {set hd [exec git rev-parse --verify HEAD]}]} {
 276                 set hd {}
 277                 set ct initial
 278                 return
 279         }
 280
 281         set merge_head [file join $gitdir MERGE_HEAD]
 282         if {[file exists $merge_head]} {
 283                 set ct merge
 284                 set fd_mh [open $merge_head r]
 285                 while {[gets $fd_mh line] >= 0} {
 286                         lappend mh $line
 287                 }
 288                 close $fd_mh
 289                 return
 290         }
 291
 292         set ct normal
 293 }
 294
 295 proc PARENT {} {
 296         global PARENT empty_tree
 297
 298         set p [lindex $PARENT 0]
 299         if {$p ne {}} {
 300                 return $p
 301         }
 302         if {$empty_tree eq {}} {
 303                 set empty_tree [exec git mktree << {}]
 304         }
 305         return $empty_tree
 306 }
 307
 308 proc rescan {after} {
 309         global HEAD PARENT MERGE_HEAD commit_type
 310         global ui_index ui_other ui_status_value ui_comm
 311         global rescan_active file_states
 312         global repo_config
 313
 314         if {$rescan_active > 0 || ![lock_index read]} return
 315
 316         repository_state newType newHEAD newMERGE_HEAD
 317         if {[string match amend* $commit_type]
 318                 && $newType eq {normal}
 319                 && $newHEAD eq $HEAD} {
 320         } else {
 321                 set HEAD $newHEAD
 322                 set PARENT $newHEAD
 323                 set MERGE_HEAD $newMERGE_HEAD
 324                 set commit_type $newType
 325         }
 326
 327         array unset file_states
 328
 329         if {![$ui_comm edit modified]
 330                 || [string trim [$ui_comm get 0.0 end]] eq {}} {
 331                 if {[load_message GITGUI_MSG]} {
 332                 } elseif {[load_message MERGE_MSG]} {
 333                 } elseif {[load_message SQUASH_MSG]} {
 334                 }
 335                 $ui_comm edit reset
 336                 $ui_comm edit modified false
 337         }
 338
 339         if {$repo_config(gui.trustmtime) eq {true}} {
 340                 rescan_stage2 {} $after
 341         } else {
 342                 set rescan_active 1
 343                 set ui_status_value {Refreshing file status...}
 344                 set cmd [list git update-index]
 345                 lappend cmd -q
 346                 lappend cmd --unmerged
 347                 lappend cmd --ignore-missing
 348                 lappend cmd --refresh
 349                 set fd_rf [open "| $cmd" r]
 350                 fconfigure $fd_rf -blocking 0 -translation binary
 351                 fileevent $fd_rf readable \
 352                         [list rescan_stage2 $fd_rf $after]
 353         }
 354 }
 355
 356 proc rescan_stage2 {fd after} {
 357         global gitdir ui_status_value
 358         global rescan_active buf_rdi buf_rdf buf_rlo
 359
 360         if {$fd ne {}} {
 361                 read $fd
 362                 if {![eof $fd]} return
 363                 close $fd
 364         }
 365
 366         set ls_others [list | git ls-files --others -z \
 367                 --exclude-per-directory=.gitignore]
 368         set info_exclude [file join $gitdir info exclude]
 369         if {[file readable $info_exclude]} {
 370                 lappend ls_others "--exclude-from=$info_exclude"
 371         }
 372
 373         set buf_rdi {}
 374         set buf_rdf {}
 375         set buf_rlo {}
 376
 377         set rescan_active 3
 378         set ui_status_value {Scanning for modified files ...}
 379         set fd_di [open "| git diff-index --cached -z [PARENT]" r]
 380         set fd_df [open "| git diff-files -z" r]
 381         set fd_lo [open $ls_others r]
 382
 383         fconfigure $fd_di -blocking 0 -translation binary
 384         fconfigure $fd_df -blocking 0 -translation binary
 385         fconfigure $fd_lo -blocking 0 -translation binary
 386         fileevent $fd_di readable [list read_diff_index $fd_di $after]
 387         fileevent $fd_df readable [list read_diff_files $fd_df $after]
 388         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
 389 }
 390
 391 proc load_message {file} {
 392         global gitdir ui_comm
 393
 394         set f [file join $gitdir $file]
 395         if {[file isfile $f]} {
 396                 if {[catch {set fd [open $f r]}]} {
 397                         return 0
 398                 }
 399                 set content [string trim [read $fd]]
 400                 close $fd
 401                 $ui_comm delete 0.0 end
 402                 $ui_comm insert end $content
 403                 return 1
 404         }
 405         return 0
 406 }
 407
 408 proc read_diff_index {fd after} {
 409         global buf_rdi
 410
 411         append buf_rdi [read $fd]
 412         set c 0
 413         set n [string length $buf_rdi]
 414         while {$c < $n} {
 415                 set z1 [string first "\0" $buf_rdi $c]
 416                 if {$z1 == -1} break
 417                 incr z1
 418                 set z2 [string first "\0" $buf_rdi $z1]
 419                 if {$z2 == -1} break
 420
 421                 incr c
 422                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
 423                 merge_state \
 424                         [string range $buf_rdi $z1 [expr {$z2 - 1}]] \
 425                         [lindex $i 4]? \
 426                         [list [lindex $i 0] [lindex $i 2]] \
 427                         [list]
 428                 set c $z2
 429                 incr c
 430         }
 431         if {$c < $n} {
 432                 set buf_rdi [string range $buf_rdi $c end]
 433         } else {
 434                 set buf_rdi {}
 435         }
 436
 437         rescan_done $fd buf_rdi $after
 438 }
 439
 440 proc read_diff_files {fd after} {
 441         global buf_rdf
 442
 443         append buf_rdf [read $fd]
 444         set c 0
 445         set n [string length $buf_rdf]
 446         while {$c < $n} {
 447                 set z1 [string first "\0" $buf_rdf $c]
 448                 if {$z1 == -1} break
 449                 incr z1
 450                 set z2 [string first "\0" $buf_rdf $z1]
 451                 if {$z2 == -1} break
 452
 453                 incr c
 454                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
 455                 merge_state \
 456                         [string range $buf_rdf $z1 [expr {$z2 - 1}]] \
 457                         ?[lindex $i 4] \
 458                         [list] \
 459                         [list [lindex $i 0] [lindex $i 2]]
 460                 set c $z2
 461                 incr c
 462         }
 463         if {$c < $n} {
 464                 set buf_rdf [string range $buf_rdf $c end]
 465         } else {
 466                 set buf_rdf {}
 467         }
 468
 469         rescan_done $fd buf_rdf $after
 470 }
 471
 472 proc read_ls_others {fd after} {
 473         global buf_rlo
 474
 475         append buf_rlo [read $fd]
 476         set pck [split $buf_rlo "\0"]
 477         set buf_rlo [lindex $pck end]
 478         foreach p [lrange $pck 0 end-1] {
 479                 merge_state $p ?O
 480         }
 481         rescan_done $fd buf_rlo $after
 482 }
 483
 484 proc rescan_done {fd buf after} {
 485         global rescan_active
 486         global file_states repo_config
 487         upvar $buf to_clear
 488
 489         if {![eof $fd]} return
 490         set to_clear {}
 491         close $fd
 492         if {[incr rescan_active -1] > 0} return
 493
 494         prune_selection
 495         unlock_index
 496         display_all_files
 497
 498         if {$repo_config(gui.partialinclude) ne {true}} {
 499                 set pathList [list]
 500                 foreach path [array names file_states] {
 501                         switch -- [lindex $file_states($path) 0] {
 502                         AM -
 503                         MM {lappend pathList $path}
 504                         }
 505                 }
 506                 if {$pathList ne {}} {
 507                         update_index \
 508                                 "Updating included files" \
 509                                 $pathList \
 510                                 [concat {reshow_diff;} $after]
 511                         return
 512                 }
 513         }
 514
 515         reshow_diff
 516         uplevel #0 $after
 517 }
 518
 519 proc prune_selection {} {
 520         global file_states selected_paths
 521
 522         foreach path [array names selected_paths] {
 523                 if {[catch {set still_here $file_states($path)}]} {
 524                         unset selected_paths($path)
 525                 }
 526         }
 527 }
 528
 529 ######################################################################
 530 ##
 531 ## diff
 532
 533 proc clear_diff {} {
 534         global ui_diff current_diff ui_index ui_other
 535
 536         $ui_diff conf -state normal
 537         $ui_diff delete 0.0 end
 538         $ui_diff conf -state disabled
 539
 540         set current_diff {}
 541
 542         $ui_index tag remove in_diff 0.0 end
 543         $ui_other tag remove in_diff 0.0 end
 544 }
 545
 546 proc reshow_diff {} {
 547         global current_diff ui_status_value file_states
 548
 549         if {$current_diff eq {}
 550                 || [catch {set s $file_states($current_diff)}]} {
 551                 clear_diff
 552         } else {
 553                 show_diff $current_diff
 554         }
 555 }
 556
 557 proc handle_empty_diff {} {
 558         global current_diff file_states file_lists
 559
 560         set path $current_diff
 561         set s $file_states($path)
 562         if {[lindex $s 0] ne {_M}} return
 563
 564         info_popup "No differences detected.
 565
 566 [short_path $path] has no changes.
 567
 568 The modification date of this file was updated
 569 by another application and you currently have
 570 the Trust File Modification Timestamps option
 571 enabled, so Git did not automatically detect
 572 that there are no content differences in this
 573 file.
 574
 575 This file will now be removed from the modified
 576 files list, to prevent possible confusion.
 577 "
 578         if {[catch {exec git update-index -- $path} err]} {
 579                 error_popup "Failed to refresh index:\n\n$err"
 580         }
 581
 582         clear_diff
 583         set old_w [mapcol [lindex $file_states($path) 0] $path]
 584         set lno [lsearch -sorted $file_lists($old_w) $path]
 585         if {$lno >= 0} {
 586                 set file_lists($old_w) \
 587                         [lreplace $file_lists($old_w) $lno $lno]
 588                 incr lno
 589                 $old_w conf -state normal
 590                 $old_w delete $lno.0 [expr {$lno + 1}].0
 591                 $old_w conf -state disabled
 592         }
 593 }
 594
 595 proc show_diff {path {w {}} {lno {}}} {
 596         global file_states file_lists
 597         global is_3way_diff diff_active repo_config
 598         global ui_diff current_diff ui_status_value
 599
 600         if {$diff_active || ![lock_index read]} return
 601
 602         clear_diff
 603         if {$w eq {} || $lno == {}} {
 604                 foreach w [array names file_lists] {
 605                         set lno [lsearch -sorted $file_lists($w) $path]
 606                         if {$lno >= 0} {
 607                                 incr lno
 608                                 break
 609                         }
 610                 }
 611         }
 612         if {$w ne {} && $lno >= 1} {
 613                 $w tag add in_diff $lno.0 [expr {$lno + 1}].0
 614         }
 615
 616         set s $file_states($path)
 617         set m [lindex $s 0]
 618         set is_3way_diff 0
 619         set diff_active 1
 620         set current_diff $path
 621         set ui_status_value "Loading diff of [escape_path $path]..."
 622
 623         set cmd [list | git diff-index]
 624         lappend cmd --no-color
 625         if {$repo_config(gui.diffcontext) > 0} {
 626                 lappend cmd "-U$repo_config(gui.diffcontext)"
 627         }
 628         lappend cmd -p
 629
 630         switch $m {
 631         MM {
 632                 lappend cmd -c
 633         }
 634         _O {
 635                 if {[catch {
 636                                 set fd [open $path r]
 637                                 set content [read $fd]
 638                                 close $fd
 639                         } err ]} {
 640                         set diff_active 0
 641                         unlock_index
 642                         set ui_status_value "Unable to display [escape_path $path]"
 643                         error_popup "Error loading file:\n\n$err"
 644                         return
 645                 }
 646                 $ui_diff conf -state normal
 647                 $ui_diff insert end $content
 648                 $ui_diff conf -state disabled
 649                 set diff_active 0
 650                 unlock_index
 651                 set ui_status_value {Ready.}
 652                 return
 653         }
 654         }
 655
 656         lappend cmd [PARENT]
 657         lappend cmd --
 658         lappend cmd $path
 659
 660         if {[catch {set fd [open $cmd r]} err]} {
 661                 set diff_active 0
 662                 unlock_index
 663                 set ui_status_value "Unable to display [escape_path $path]"
 664                 error_popup "Error loading diff:\n\n$err"
 665                 return
 666         }
 667
 668         fconfigure $fd -blocking 0 -translation auto
 669         fileevent $fd readable [list read_diff $fd]
 670 }
 671
 672 proc read_diff {fd} {
 673         global ui_diff ui_status_value is_3way_diff diff_active
 674         global repo_config
 675
 676         $ui_diff conf -state normal
 677         while {[gets $fd line] >= 0} {
 678                 # -- Cleanup uninteresting diff header lines.
 679                 #
 680                 if {[string match {diff --git *}      $line]} continue
 681                 if {[string match {diff --combined *} $line]} continue
 682                 if {[string match {--- *}             $line]} continue
 683                 if {[string match {+++ *}             $line]} continue
 684                 if {$line eq {deleted file mode 120000}} {
 685                         set line "deleted symlink"
 686                 }
 687
 688                 # -- Automatically detect if this is a 3 way diff.
 689                 #
 690                 if {[string match {@@@ *} $line]} {set is_3way_diff 1}
 691
 692                 # -- Reformat a 3 way diff, 'cause its too weird.
 693                 #
 694                 if {$is_3way_diff} {
 695                         set op [string range $line 0 1]
 696                         switch -- $op {
 697                         {@@} {set tags d_@}
 698                         {++} {set tags d_+ ; set op { +}}
 699                         {--} {set tags d_- ; set op { -}}
 700                         { +} {set tags d_++; set op {++}}
 701                         { -} {set tags d_--; set op {--}}
 702                         {+ } {set tags d_-+; set op {-+}}
 703                         {- } {set tags d_+-; set op {+-}}
 704                         default {set tags {}}
 705                         }
 706                         set line [string replace $line 0 1 $op]
 707                 } else {
 708                         switch -- [string index $line 0] {
 709                         @ {set tags d_@}
 710                         + {set tags d_+}
 711                         - {set tags d_-}
 712                         default {set tags {}}
 713                         }
 714                 }
 715                 $ui_diff insert end $line $tags
 716                 $ui_diff insert end "\n" $tags
 717         }
 718         $ui_diff conf -state disabled
 719
 720         if {[eof $fd]} {
 721                 close $fd
 722                 set diff_active 0
 723                 unlock_index
 724                 set ui_status_value {Ready.}
 725
 726                 if {$repo_config(gui.trustmtime) eq {true}
 727                         && [$ui_diff index end] eq {2.0}} {
 728                         handle_empty_diff
 729                 }
 730         }
 731 }
 732
 733 ######################################################################
 734 ##
 735 ## commit
 736
 737 proc load_last_commit {} {
 738         global HEAD PARENT MERGE_HEAD commit_type ui_comm
 739
 740         if {[llength $PARENT] == 0} {
 741                 error_popup {There is nothing to amend.
 742
 743 You are about to create the initial commit.
 744 There is no commit before this to amend.
 745 }
 746                 return
 747         }
 748
 749         repository_state curType curHEAD curMERGE_HEAD
 750         if {$curType eq {merge}} {
 751                 error_popup {Cannot amend while merging.
 752
 753 You are currently in the middle of a merge that
 754 has not been fully completed.  You cannot amend
 755 the prior commit unless you first abort the
 756 current merge activity.
 757 }
 758                 return
 759         }
 760
 761         set msg {}
 762         set parents [list]
 763         if {[catch {
 764                         set fd [open "| git cat-file commit $curHEAD" r]
 765                         while {[gets $fd line] > 0} {
 766                                 if {[string match {parent *} $line]} {
 767                                         lappend parents [string range $line 7 end]
 768                                 }
 769                         }
 770                         set msg [string trim [read $fd]]
 771                         close $fd
 772                 } err]} {
 773                 error_popup "Error loading commit data for amend:\n\n$err"
 774                 return
 775         }
 776
 777         set HEAD $curHEAD
 778         set PARENT $parents
 779         set MERGE_HEAD [list]
 780         switch -- [llength $parents] {
 781         0       {set commit_type amend-initial}
 782         1       {set commit_type amend}
 783         default {set commit_type amend-merge}
 784         }
 785
 786         $ui_comm delete 0.0 end
 787         $ui_comm insert end $msg
 788         $ui_comm edit reset
 789         $ui_comm edit modified false
 790         rescan {set ui_status_value {Ready.}}
 791 }
 792
 793 proc create_new_commit {} {
 794         global commit_type ui_comm
 795
 796         set commit_type normal
 797         $ui_comm delete 0.0 end
 798         $ui_comm edit reset
 799         $ui_comm edit modified false
 800         rescan {set ui_status_value {Ready.}}
 801 }
 802
 803 set GIT_COMMITTER_IDENT {}
 804
 805 proc committer_ident {} {
 806         global GIT_COMMITTER_IDENT
 807
 808         if {$GIT_COMMITTER_IDENT eq {}} {
 809                 if {[catch {set me [exec git var GIT_COMMITTER_IDENT]} err]} {
 810                         error_popup "Unable to obtain your identity:\n\n$err"
 811                         return {}
 812                 }
 813                 if {![regexp {^(.*) [0-9]+ [-+0-9]+$} \
 814                         $me me GIT_COMMITTER_IDENT]} {
 815                         error_popup "Invalid GIT_COMMITTER_IDENT:\n\n$me"
 816                         return {}
 817                 }
 818         }
 819
 820         return $GIT_COMMITTER_IDENT
 821 }
 822
 823 proc commit_tree {} {
 824         global HEAD commit_type file_states ui_comm repo_config
 825
 826         if {![lock_index update]} return
 827         if {[committer_ident] eq {}} return
 828
 829         # -- Our in memory state should match the repository.
 830         #
 831         repository_state curType curHEAD curMERGE_HEAD
 832         if {[string match amend* $commit_type]
 833                 && $curType eq {normal}
 834                 && $curHEAD eq $HEAD} {
 835         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
 836                 info_popup {Last scanned state does not match repository state.
 837
 838 Another Git program has modified this repository
 839 since the last scan.  A rescan must be performed
 840 before another commit can be created.
 841
 842 The rescan will be automatically started now.
 843 }
 844                 unlock_index
 845                 rescan {set ui_status_value {Ready.}}
 846                 return
 847         }
 848
 849         # -- At least one file should differ in the index.
 850         #
 851         set files_ready 0
 852         foreach path [array names file_states] {
 853                 switch -glob -- [lindex $file_states($path) 0] {
 854                 _? {continue}
 855                 A? -
 856                 D? -
 857                 M? {set files_ready 1; break}
 858                 U? {
 859                         error_popup "Unmerged files cannot be committed.
 860
 861 File [short_path $path] has merge conflicts.
 862 You must resolve them and include the file before committing.
 863 "
 864                         unlock_index
 865                         return
 866                 }
 867                 default {
 868                         error_popup "Unknown file state [lindex $s 0] detected.
 869
 870 File [short_path $path] cannot be committed by this program.
 871 "
 872                 }
 873                 }
 874         }
 875         if {!$files_ready} {
 876                 error_popup {No included files to commit.
 877
 878 You must include at least 1 file before you can commit.
 879 }
 880                 unlock_index
 881                 return
 882         }
 883
 884         # -- A message is required.
 885         #
 886         set msg [string trim [$ui_comm get 1.0 end]]
 887         if {$msg eq {}} {
 888                 error_popup {Please supply a commit message.
 889
 890 A good commit message has the following format:
 891
 892 - First line: Describe in one sentance what you did.
 893 - Second line: Blank
 894 - Remaining lines: Describe why this change is good.
 895 }
 896                 unlock_index
 897                 return
 898         }
 899
 900         # -- Update included files if partialincludes are off.
 901         #
 902         if {$repo_config(gui.partialinclude) ne {true}} {
 903                 set pathList [list]
 904                 foreach path [array names file_states] {
 905                         switch -glob -- [lindex $file_states($path) 0] {
 906                         A? -
 907                         M? {lappend pathList $path}
 908                         }
 909                 }
 910                 if {$pathList ne {}} {
 911                         unlock_index
 912                         update_index \
 913                                 "Updating included files" \
 914                                 $pathList \
 915                                 [concat {lock_index update;} \
 916                                         [list commit_prehook $curHEAD $msg]]
 917                         return
 918                 }
 919         }
 920
 921         commit_prehook $curHEAD $msg
 922 }
 923
 924 proc commit_prehook {curHEAD msg} {
 925         global gitdir ui_status_value pch_error
 926
 927         set pchook [file join $gitdir hooks pre-commit]
 928
 929         # On Cygwin [file executable] might lie so we need to ask
 930         # the shell if the hook is executable.  Yes that's annoying.
 931         #
 932         if {[is_Windows] && [file isfile $pchook]} {
 933                 set pchook [list sh -c [concat \
 934                         "if test -x \"$pchook\";" \
 935                         "then exec \"$pchook\" 2>&1;" \
 936                         "fi"]]
 937         } elseif {[file executable $pchook]} {
 938                 set pchook [list $pchook |& cat]
 939         } else {
 940                 commit_writetree $curHEAD $msg
 941                 return
 942         }
 943
 944         set ui_status_value {Calling pre-commit hook...}
 945         set pch_error {}
 946         set fd_ph [open "| $pchook" r]
 947         fconfigure $fd_ph -blocking 0 -translation binary
 948         fileevent $fd_ph readable \
 949                 [list commit_prehook_wait $fd_ph $curHEAD $msg]
 950 }
 951
 952 proc commit_prehook_wait {fd_ph curHEAD msg} {
 953         global pch_error ui_status_value
 954
 955         append pch_error [read $fd_ph]
 956         fconfigure $fd_ph -blocking 1
 957         if {[eof $fd_ph]} {
 958                 if {[catch {close $fd_ph}]} {
 959                         set ui_status_value {Commit declined by pre-commit hook.}
 960                         hook_failed_popup pre-commit $pch_error
 961                         unlock_index
 962                 } else {
 963                         commit_writetree $curHEAD $msg
 964                 }
 965                 set pch_error {}
 966                 return
 967         }
 968         fconfigure $fd_ph -blocking 0
 969 }
 970
 971 proc commit_writetree {curHEAD msg} {
 972         global ui_status_value
 973
 974         set ui_status_value {Committing changes...}
 975         set fd_wt [open "| git write-tree" r]
 976         fileevent $fd_wt readable \
 977                 [list commit_committree $fd_wt $curHEAD $msg]
 978 }
 979
 980 proc commit_committree {fd_wt curHEAD msg} {
 981         global HEAD PARENT MERGE_HEAD commit_type
 982         global single_commit gitdir
 983         global ui_status_value ui_comm selected_commit_type
 984         global file_states selected_paths rescan_active
 985
 986         gets $fd_wt tree_id
 987         if {$tree_id eq {} || [catch {close $fd_wt} err]} {
 988                 error_popup "write-tree failed:\n\n$err"
 989                 set ui_status_value {Commit failed.}
 990                 unlock_index
 991                 return
 992         }
 993
 994         # -- Create the commit.
 995         #
 996         set cmd [list git commit-tree $tree_id]
 997         set parents [concat $PARENT $MERGE_HEAD]
 998         if {[llength $parents] > 0} {
 999                 foreach p $parents {
1000                         lappend cmd -p $p
1001                 }
1002         } else {
1003                 # git commit-tree writes to stderr during initial commit.
1004                 lappend cmd 2>/dev/null
1005         }
1006         lappend cmd << $msg
1007         if {[catch {set cmt_id [eval exec $cmd]} err]} {
1008                 error_popup "commit-tree failed:\n\n$err"
1009                 set ui_status_value {Commit failed.}
1010                 unlock_index
1011                 return
1012         }
1013
1014         # -- Update the HEAD ref.
1015         #
1016         set reflogm commit
1017         if {$commit_type ne {normal}} {
1018                 append reflogm " ($commit_type)"
1019         }
1020         set i [string first "\n" $msg]
1021         if {$i >= 0} {
1022                 append reflogm {: } [string range $msg 0 [expr {$i - 1}]]
1023         } else {
1024                 append reflogm {: } $msg
1025         }
1026         set cmd [list git update-ref -m $reflogm HEAD $cmt_id $curHEAD]
1027         if {[catch {eval exec $cmd} err]} {
1028                 error_popup "update-ref failed:\n\n$err"
1029                 set ui_status_value {Commit failed.}
1030                 unlock_index
1031                 return
1032         }
1033
1034         # -- Cleanup after ourselves.
1035         #
1036         catch {file delete [file join $gitdir MERGE_HEAD]}
1037         catch {file delete [file join $gitdir MERGE_MSG]}
1038         catch {file delete [file join $gitdir SQUASH_MSG]}
1039         catch {file delete [file join $gitdir GITGUI_MSG]}
1040
1041         # -- Let rerere do its thing.
1042         #
1043         if {[file isdirectory [file join $gitdir rr-cache]]} {
1044                 catch {exec git rerere}
1045         }
1046
1047         # -- Run the post-commit hook.
1048         #
1049         set pchook [file join $gitdir hooks post-commit]
1050         if {[is_Windows] && [file isfile $pchook]} {
1051                 set pchook [list sh -c [concat \
1052                         "if test -x \"$pchook\";" \
1053                         "then exec \"$pchook\";" \
1054                         "fi"]]
1055         } elseif {![file executable $pchook]} {
1056                 set pchook {}
1057         }
1058         if {$pchook ne {}} {
1059                 catch {exec $pchook &}
1060         }
1061
1062         $ui_comm delete 0.0 end
1063         $ui_comm edit reset
1064         $ui_comm edit modified false
1065
1066         if {$single_commit} do_quit
1067
1068         # -- Update in memory status
1069         #
1070         set selected_commit_type new
1071         set commit_type normal
1072         set HEAD $cmt_id
1073         set PARENT $cmt_id
1074         set MERGE_HEAD [list]
1075
1076         foreach path [array names file_states] {
1077                 set s $file_states($path)
1078                 set m [lindex $s 0]
1079                 switch -glob -- $m {
1080                 _O -
1081                 _M -
1082                 _D {continue}
1083                 __ -
1084                 A_ -
1085                 M_ -
1086                 DD {
1087                         unset file_states($path)
1088                         catch {unset selected_paths($path)}
1089                 }
1090                 DO {
1091                         set file_states($path) [list _O [lindex $s 1] {} {}]
1092                 }
1093                 AM -
1094                 AD -
1095                 MM -
1096                 MD -
1097                 DM {
1098                         set file_states($path) [list \
1099                                 _[string index $m 1] \
1100                                 [lindex $s 1] \
1101                                 [lindex $s 3] \
1102                                 {}]
1103                 }
1104                 }
1105         }
1106
1107         display_all_files
1108         unlock_index
1109         reshow_diff
1110         set ui_status_value \
1111                 "Changes committed as [string range $cmt_id 0 7]."
1112 }
1113
1114 ######################################################################
1115 ##
1116 ## fetch pull push
1117
1118 proc fetch_from {remote} {
1119         set w [new_console "fetch $remote" \
1120                 "Fetching new changes from $remote"]
1121         set cmd [list git fetch]
1122         lappend cmd $remote
1123         console_exec $w $cmd
1124 }
1125
1126 proc pull_remote {remote branch} {
1127         global HEAD commit_type file_states repo_config
1128
1129         if {![lock_index update]} return
1130
1131         # -- Our in memory state should match the repository.
1132         #
1133         repository_state curType curHEAD curMERGE_HEAD
1134         if {$commit_type ne $curType || $HEAD ne $curHEAD} {
1135                 info_popup {Last scanned state does not match repository state.
1136
1137 Another Git program has modified this repository
1138 since the last scan.  A rescan must be performed
1139 before a pull operation can be started.
1140
1141 The rescan will be automatically started now.
1142 }
1143                 unlock_index
1144                 rescan {set ui_status_value {Ready.}}
1145                 return
1146         }
1147
1148         # -- No differences should exist before a pull.
1149         #
1150         if {[array size file_states] != 0} {
1151                 error_popup {Uncommitted but modified files are present.
1152
1153 You should not perform a pull with unmodified
1154 files in your working directory as Git will be
1155 unable to recover from an incorrect merge.
1156
1157 You should commit or revert all changes before
1158 starting a pull operation.
1159 }
1160                 unlock_index
1161                 return
1162         }
1163
1164         set w [new_console "pull $remote $branch" \
1165                 "Pulling new changes from branch $branch in $remote"]
1166         set cmd [list git pull]
1167         if {$repo_config(gui.pullsummary) eq {false}} {
1168                 lappend cmd --no-summary
1169         }
1170         lappend cmd $remote
1171         lappend cmd $branch
1172         console_exec $w $cmd [list post_pull_remote $remote $branch]
1173 }
1174
1175 proc post_pull_remote {remote branch success} {
1176         global HEAD PARENT MERGE_HEAD commit_type selected_commit_type
1177         global ui_status_value
1178
1179         unlock_index
1180         if {$success} {
1181                 repository_state commit_type HEAD MERGE_HEAD
1182                 set PARENT $HEAD
1183                 set selected_commit_type new
1184                 set ui_status_value "Pulling $branch from $remote complete."
1185         } else {
1186                 rescan [list set ui_status_value \
1187                         "Conflicts detected while pulling $branch from $remote."]
1188         }
1189 }
1190
1191 proc push_to {remote} {
1192         set w [new_console "push $remote" \
1193                 "Pushing changes to $remote"]
1194         set cmd [list git push]
1195         lappend cmd $remote
1196         console_exec $w $cmd
1197 }
1198
1199 ######################################################################
1200 ##
1201 ## ui helpers
1202
1203 proc mapcol {state path} {
1204         global all_cols ui_other
1205
1206         if {[catch {set r $all_cols($state)}]} {
1207                 puts "error: no column for state={$state} $path"
1208                 return $ui_other
1209         }
1210         return $r
1211 }
1212
1213 proc mapicon {state path} {
1214         global all_icons
1215
1216         if {[catch {set r $all_icons($state)}]} {
1217                 puts "error: no icon for state={$state} $path"
1218                 return file_plain
1219         }
1220         return $r
1221 }
1222
1223 proc mapdesc {state path} {
1224         global all_descs
1225
1226         if {[catch {set r $all_descs($state)}]} {
1227                 puts "error: no desc for state={$state} $path"
1228                 return $state
1229         }
1230         return $r
1231 }
1232
1233 proc escape_path {path} {
1234         regsub -all "\n" $path "\\n" path
1235         return $path
1236 }
1237
1238 proc short_path {path} {
1239         return [escape_path [lindex [file split $path] end]]
1240 }
1241
1242 set next_icon_id 0
1243 set null_sha1 [string repeat 0 40]
1244
1245 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1246         global file_states next_icon_id null_sha1
1247
1248         set s0 [string index $new_state 0]
1249         set s1 [string index $new_state 1]
1250
1251         if {[catch {set info $file_states($path)}]} {
1252                 set state __
1253                 set icon n[incr next_icon_id]
1254         } else {
1255                 set state [lindex $info 0]
1256                 set icon [lindex $info 1]
1257                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1258                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1259         }
1260
1261         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1262         elseif {$s0 eq {_}} {set s0 _}
1263
1264         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1265         elseif {$s1 eq {_}} {set s1 _}
1266
1267         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1268                 set head_info [list 0 $null_sha1]
1269         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1270                 && $head_info eq {}} {
1271                 set head_info $index_info
1272         }
1273
1274         set file_states($path) [list $s0$s1 $icon \
1275                 $head_info $index_info \
1276                 ]
1277         return $state
1278 }
1279
1280 proc display_file {path state} {
1281         global file_states file_lists selected_paths
1282
1283         set old_m [merge_state $path $state]
1284         set s $file_states($path)
1285         set new_m [lindex $s 0]
1286         set new_w [mapcol $new_m $path]
1287         set old_w [mapcol $old_m $path]
1288         set new_icon [mapicon $new_m $path]
1289
1290         if {$new_m eq {__}} {
1291                 set lno [lsearch -sorted $file_lists($old_w) $path]
1292                 if {$lno >= 0} {
1293                         set file_lists($old_w) \
1294                                 [lreplace $file_lists($old_w) $lno $lno]
1295                         incr lno
1296                         $old_w conf -state normal
1297                         $old_w delete $lno.0 [expr {$lno + 1}].0
1298                         $old_w conf -state disabled
1299                 }
1300                 unset file_states($path)
1301                 catch {unset selected_paths($path)}
1302                 return
1303         }
1304
1305         if {$new_w ne $old_w} {
1306                 set lno [lsearch -sorted $file_lists($old_w) $path]
1307                 if {$lno >= 0} {
1308                         set file_lists($old_w) \
1309                                 [lreplace $file_lists($old_w) $lno $lno]
1310                         incr lno
1311                         $old_w conf -state normal
1312                         $old_w delete $lno.0 [expr {$lno + 1}].0
1313                         $old_w conf -state disabled
1314                 }
1315
1316                 lappend file_lists($new_w) $path
1317                 set file_lists($new_w) [lsort $file_lists($new_w)]
1318                 set lno [lsearch -sorted $file_lists($new_w) $path]
1319                 incr lno
1320                 $new_w conf -state normal
1321                 $new_w image create $lno.0 \
1322                         -align center -padx 5 -pady 1 \
1323                         -name [lindex $s 1] \
1324                         -image $new_icon
1325                 $new_w insert $lno.1 "[escape_path $path]\n"
1326                 if {[catch {set in_sel $selected_paths($path)}]} {
1327                         set in_sel 0
1328                 }
1329                 if {$in_sel} {
1330                         $new_w tag add in_sel $lno.0 [expr {$lno + 1}].0
1331                 }
1332                 $new_w conf -state disabled
1333         } elseif {$new_icon ne [mapicon $old_m $path]} {
1334                 $new_w conf -state normal
1335                 $new_w image conf [lindex $s 1] -image $new_icon
1336                 $new_w conf -state disabled
1337         }
1338 }
1339
1340 proc display_all_files {} {
1341         global ui_index ui_other
1342         global file_states file_lists
1343         global last_clicked selected_paths
1344
1345         $ui_index conf -state normal
1346         $ui_other conf -state normal
1347
1348         $ui_index delete 0.0 end
1349         $ui_other delete 0.0 end
1350         set last_clicked {}
1351
1352         set file_lists($ui_index) [list]
1353         set file_lists($ui_other) [list]
1354
1355         foreach path [lsort [array names file_states]] {
1356                 set s $file_states($path)
1357                 set m [lindex $s 0]
1358                 set w [mapcol $m $path]
1359                 lappend file_lists($w) $path
1360                 set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1361                 $w image create end \
1362                         -align center -padx 5 -pady 1 \
1363                         -name [lindex $s 1] \
1364                         -image [mapicon $m $path]
1365                 $w insert end "[escape_path $path]\n"
1366                 if {[catch {set in_sel $selected_paths($path)}]} {
1367                         set in_sel 0
1368                 }
1369                 if {$in_sel} {
1370                         $w tag add in_sel $lno.0 [expr {$lno + 1}].0
1371                 }
1372         }
1373
1374         $ui_index conf -state disabled
1375         $ui_other conf -state disabled
1376 }
1377
1378 proc update_indexinfo {msg pathList after} {
1379         global update_index_cp ui_status_value
1380
1381         if {![lock_index update]} return
1382
1383         set update_index_cp 0
1384         set pathList [lsort $pathList]
1385         set totalCnt [llength $pathList]
1386         set batch [expr {int($totalCnt * .01) + 1}]
1387         if {$batch > 25} {set batch 25}
1388
1389         set ui_status_value [format \
1390                 "$msg... %i/%i files (%.2f%%)" \
1391                 $update_index_cp \
1392                 $totalCnt \
1393                 0.0]
1394         set fd [open "| git update-index -z --index-info" w]
1395         fconfigure $fd \
1396                 -blocking 0 \
1397                 -buffering full \
1398                 -buffersize 512 \
1399                 -translation binary
1400         fileevent $fd writable [list \
1401                 write_update_indexinfo \
1402                 $fd \
1403                 $pathList \
1404                 $totalCnt \
1405                 $batch \
1406                 $msg \
1407                 $after \
1408                 ]
1409 }
1410
1411 proc write_update_indexinfo {fd pathList totalCnt batch msg after} {
1412         global update_index_cp ui_status_value
1413         global file_states current_diff
1414
1415         if {$update_index_cp >= $totalCnt} {
1416                 close $fd
1417                 unlock_index
1418                 uplevel #0 $after
1419                 return
1420         }
1421
1422         for {set i $batch} \
1423                 {$update_index_cp < $totalCnt && $i > 0} \
1424                 {incr i -1} {
1425                 set path [lindex $pathList $update_index_cp]
1426                 incr update_index_cp
1427
1428                 set s $file_states($path)
1429                 switch -glob -- [lindex $s 0] {
1430                 A? {set new _O}
1431                 M? {set new _M}
1432                 D? {set new _?}
1433                 ?? {continue}
1434                 }
1435                 set info [lindex $s 2]
1436                 if {$info eq {}} continue
1437
1438                 puts -nonewline $fd $info
1439                 puts -nonewline $fd "\t"
1440                 puts -nonewline $fd $path
1441                 puts -nonewline $fd "\0"
1442                 display_file $path $new
1443         }
1444
1445         set ui_status_value [format \
1446                 "$msg... %i/%i files (%.2f%%)" \
1447                 $update_index_cp \
1448                 $totalCnt \
1449                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1450 }
1451
1452 proc update_index {msg pathList after} {
1453         global update_index_cp ui_status_value
1454
1455         if {![lock_index update]} return
1456
1457         set update_index_cp 0
1458         set pathList [lsort $pathList]
1459         set totalCnt [llength $pathList]
1460         set batch [expr {int($totalCnt * .01) + 1}]
1461         if {$batch > 25} {set batch 25}
1462
1463         set ui_status_value [format \
1464                 "$msg... %i/%i files (%.2f%%)" \
1465                 $update_index_cp \
1466                 $totalCnt \
1467                 0.0]
1468         set fd [open "| git update-index --add --remove -z --stdin" w]
1469         fconfigure $fd \
1470                 -blocking 0 \
1471                 -buffering full \
1472                 -buffersize 512 \
1473                 -translation binary
1474         fileevent $fd writable [list \
1475                 write_update_index \
1476                 $fd \
1477                 $pathList \
1478                 $totalCnt \
1479                 $batch \
1480                 $msg \
1481                 $after \
1482                 ]
1483 }
1484
1485 proc write_update_index {fd pathList totalCnt batch msg after} {
1486         global update_index_cp ui_status_value
1487         global file_states current_diff
1488
1489         if {$update_index_cp >= $totalCnt} {
1490                 close $fd
1491                 unlock_index
1492                 uplevel #0 $after
1493                 return
1494         }
1495
1496         for {set i $batch} \
1497                 {$update_index_cp < $totalCnt && $i > 0} \
1498                 {incr i -1} {
1499                 set path [lindex $pathList $update_index_cp]
1500                 incr update_index_cp
1501
1502                 switch -glob -- [lindex $file_states($path) 0] {
1503                 AD -
1504                 MD -
1505                 _D {set new DD}
1506
1507                 _M -
1508                 MM -
1509                 M_ {set new M_}
1510
1511                 _O -
1512                 AM -
1513                 A_ {set new A_}
1514
1515                 ?? {continue}
1516                 }
1517
1518                 puts -nonewline $fd $path
1519                 puts -nonewline $fd "\0"
1520                 display_file $path $new
1521         }
1522
1523         set ui_status_value [format \
1524                 "$msg... %i/%i files (%.2f%%)" \
1525                 $update_index_cp \
1526                 $totalCnt \
1527                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1528 }
1529
1530 proc checkout_index {msg pathList after} {
1531         global update_index_cp ui_status_value
1532
1533         if {![lock_index update]} return
1534
1535         set update_index_cp 0
1536         set pathList [lsort $pathList]
1537         set totalCnt [llength $pathList]
1538         set batch [expr {int($totalCnt * .01) + 1}]
1539         if {$batch > 25} {set batch 25}
1540
1541         set ui_status_value [format \
1542                 "$msg... %i/%i files (%.2f%%)" \
1543                 $update_index_cp \
1544                 $totalCnt \
1545                 0.0]
1546         set cmd [list git checkout-index]
1547         lappend cmd --index
1548         lappend cmd --quiet
1549         lappend cmd --force
1550         lappend cmd -z
1551         lappend cmd --stdin
1552         set fd [open "| $cmd " w]
1553         fconfigure $fd \
1554                 -blocking 0 \
1555                 -buffering full \
1556                 -buffersize 512 \
1557                 -translation binary
1558         fileevent $fd writable [list \
1559                 write_checkout_index \
1560                 $fd \
1561                 $pathList \
1562                 $totalCnt \
1563                 $batch \
1564                 $msg \
1565                 $after \
1566                 ]
1567 }
1568
1569 proc write_checkout_index {fd pathList totalCnt batch msg after} {
1570         global update_index_cp ui_status_value
1571         global file_states current_diff
1572
1573         if {$update_index_cp >= $totalCnt} {
1574                 close $fd
1575                 unlock_index
1576                 uplevel #0 $after
1577                 return
1578         }
1579
1580         for {set i $batch} \
1581                 {$update_index_cp < $totalCnt && $i > 0} \
1582                 {incr i -1} {
1583                 set path [lindex $pathList $update_index_cp]
1584                 incr update_index_cp
1585
1586                 switch -glob -- [lindex $file_states($path) 0] {
1587                 AM -
1588                 AD {set new A_}
1589                 MM -
1590                 MD {set new M_}
1591                 _M -
1592                 _D {set new __}
1593                 ?? {continue}
1594                 }
1595
1596                 puts -nonewline $fd $path
1597                 puts -nonewline $fd "\0"
1598                 display_file $path $new
1599         }
1600
1601         set ui_status_value [format \
1602                 "$msg... %i/%i files (%.2f%%)" \
1603                 $update_index_cp \
1604                 $totalCnt \
1605                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1606 }
1607
1608 ######################################################################
1609 ##
1610 ## branch management
1611
1612 proc load_all_heads {} {
1613         global all_heads tracking_branches
1614
1615         set all_heads [list]
1616         set cmd [list git for-each-ref]
1617         lappend cmd --format=%(refname)
1618         lappend cmd refs/heads
1619         set fd [open "| $cmd" r]
1620         while {[gets $fd line] > 0} {
1621                 if {![catch {set info $tracking_branches($line)}]} continue
1622                 if {![regsub ^refs/heads/ $line {} name]} continue
1623                 lappend all_heads $name
1624         }
1625         close $fd
1626
1627         set all_heads [lsort $all_heads]
1628 }
1629
1630 proc populate_branch_menu {m} {
1631         global all_heads disable_on_lock
1632
1633         $m add separator
1634         foreach b $all_heads {
1635                 $m add radiobutton \
1636                         -label $b \
1637                         -command [list switch_branch $b] \
1638                         -variable current_branch \
1639                         -value $b \
1640                         -font font_ui
1641                 lappend disable_on_lock \
1642                         [list $m entryconf [$m index last] -state]
1643         }
1644 }
1645
1646 proc do_create_branch {} {
1647         error "NOT IMPLEMENTED"
1648 }
1649
1650 proc do_delete_branch {} {
1651         error "NOT IMPLEMENTED"
1652 }
1653
1654 proc switch_branch {b} {
1655         global HEAD commit_type file_states current_branch
1656         global selected_commit_type ui_comm
1657
1658         if {![lock_index switch]} return
1659
1660         # -- Backup the selected branch (repository_state resets it)
1661         #
1662         set new_branch $current_branch
1663
1664         # -- Our in memory state should match the repository.
1665         #
1666         repository_state curType curHEAD curMERGE_HEAD
1667         if {[string match amend* $commit_type]
1668                 && $curType eq {normal}
1669                 && $curHEAD eq $HEAD} {
1670         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
1671                 info_popup {Last scanned state does not match repository state.
1672
1673 Another Git program has modified this repository
1674 since the last scan.  A rescan must be performed
1675 before the current branch can be changed.
1676
1677 The rescan will be automatically started now.
1678 }
1679                 unlock_index
1680                 rescan {set ui_status_value {Ready.}}
1681                 return
1682         }
1683
1684         # -- Toss the message buffer if we are in amend mode.
1685         #
1686         if {[string match amend* $curType]} {
1687                 $ui_comm delete 0.0 end
1688                 $ui_comm edit reset
1689                 $ui_comm edit modified false
1690         }
1691
1692         set selected_commit_type new
1693         set current_branch $new_branch
1694
1695         unlock_index
1696         error "NOT FINISHED"
1697 }
1698
1699 ######################################################################
1700 ##
1701 ## remote management
1702
1703 proc load_all_remotes {} {
1704         global gitdir repo_config
1705         global all_remotes tracking_branches
1706
1707         set all_remotes [list]
1708         array unset tracking_branches
1709
1710         set rm_dir [file join $gitdir remotes]
1711         if {[file isdirectory $rm_dir]} {
1712                 set all_remotes [glob \
1713                         -types f \
1714                         -tails \
1715                         -nocomplain \
1716                         -directory $rm_dir *]
1717
1718                 foreach name $all_remotes {
1719                         catch {
1720                                 set fd [open [file join $rm_dir $name] r]
1721                                 while {[gets $fd line] >= 0} {
1722                                         if {![regexp {^Pull:[   ]*([^:]+):(.+)$} \
1723                                                 $line line src dst]} continue
1724                                         if {![regexp ^refs/ $dst]} {
1725                                                 set dst "refs/heads/$dst"
1726                                         }
1727                                         set tracking_branches($dst) [list $name $src]
1728                                 }
1729                                 close $fd
1730                         }
1731                 }
1732         }
1733
1734         foreach line [array names repo_config remote.*.url] {
1735                 if {![regexp ^remote\.(.*)\.url\$ $line line name]} continue
1736                 lappend all_remotes $name
1737
1738                 if {[catch {set fl $repo_config(remote.$name.fetch)}]} {
1739                         set fl {}
1740                 }
1741                 foreach line $fl {
1742                         if {![regexp {^([^:]+):(.+)$} $line line src dst]} continue
1743                         if {![regexp ^refs/ $dst]} {
1744                                 set dst "refs/heads/$dst"
1745                         }
1746                         set tracking_branches($dst) [list $name $src]
1747                 }
1748         }
1749
1750         set all_remotes [lsort -unique $all_remotes]
1751 }
1752
1753 proc populate_fetch_menu {m} {
1754         global gitdir all_remotes repo_config
1755
1756         foreach r $all_remotes {
1757                 set enable 0
1758                 if {![catch {set a $repo_config(remote.$r.url)}]} {
1759                         if {![catch {set a $repo_config(remote.$r.fetch)}]} {
1760                                 set enable 1
1761                         }
1762                 } else {
1763                         catch {
1764                                 set fd [open [file join $gitdir remotes $r] r]
1765                                 while {[gets $fd n] >= 0} {
1766                                         if {[regexp {^Pull:[ \t]*([^:]+):} $n]} {
1767                                                 set enable 1
1768                                                 break
1769                                         }
1770                                 }
1771                                 close $fd
1772                         }
1773                 }
1774
1775                 if {$enable} {
1776                         $m add command \
1777                                 -label "Fetch from $r..." \
1778                                 -command [list fetch_from $r] \
1779                                 -font font_ui
1780                 }
1781         }
1782 }
1783
1784 proc populate_push_menu {m} {
1785         global gitdir all_remotes repo_config
1786
1787         foreach r $all_remotes {
1788                 set enable 0
1789                 if {![catch {set a $repo_config(remote.$r.url)}]} {
1790                         if {![catch {set a $repo_config(remote.$r.push)}]} {
1791                                 set enable 1
1792                         }
1793                 } else {
1794                         catch {
1795                                 set fd [open [file join $gitdir remotes $r] r]
1796                                 while {[gets $fd n] >= 0} {
1797                                         if {[regexp {^Push:[ \t]*([^:]+):} $n]} {
1798                                                 set enable 1
1799                                                 break
1800                                         }
1801                                 }
1802                                 close $fd
1803                         }
1804                 }
1805
1806                 if {$enable} {
1807                         $m add command \
1808                                 -label "Push to $r..." \
1809                                 -command [list push_to $r] \
1810                                 -font font_ui
1811                 }
1812         }
1813 }
1814
1815 proc populate_pull_menu {m} {
1816         global gitdir repo_config all_remotes disable_on_lock
1817
1818         foreach remote $all_remotes {
1819                 set rb {}
1820                 if {[array get repo_config remote.$remote.url] ne {}} {
1821                         if {[array get repo_config remote.$remote.fetch] ne {}} {
1822                                 regexp {^([^:]+):} \
1823                                         [lindex $repo_config(remote.$remote.fetch) 0] \
1824                                         line rb
1825                         }
1826                 } else {
1827                         catch {
1828                                 set fd [open [file join $gitdir remotes $remote] r]
1829                                 while {[gets $fd line] >= 0} {
1830                                         if {[regexp {^Pull:[ \t]*([^:]+):} $line line rb]} {
1831                                                 break
1832                                         }
1833                                 }
1834                                 close $fd
1835                         }
1836                 }
1837
1838                 set rb_short $rb
1839                 regsub ^refs/heads/ $rb {} rb_short
1840                 if {$rb_short ne {}} {
1841                         $m add command \
1842                                 -label "Branch $rb_short from $remote..." \
1843                                 -command [list pull_remote $remote $rb] \
1844                                 -font font_ui
1845                         lappend disable_on_lock \
1846                                 [list $m entryconf [$m index last] -state]
1847                 }
1848         }
1849 }
1850
1851 ######################################################################
1852 ##
1853 ## icons
1854
1855 set filemask {
1856 #define mask_width 14
1857 #define mask_height 15
1858 static unsigned char mask_bits[] = {
1859    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1860    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1861    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1862 }
1863
1864 image create bitmap file_plain -background white -foreground black -data {
1865 #define plain_width 14
1866 #define plain_height 15
1867 static unsigned char plain_bits[] = {
1868    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1869    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1870    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1871 } -maskdata $filemask
1872
1873 image create bitmap file_mod -background white -foreground blue -data {
1874 #define mod_width 14
1875 #define mod_height 15
1876 static unsigned char mod_bits[] = {
1877    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1878    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1879    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1880 } -maskdata $filemask
1881
1882 image create bitmap file_fulltick -background white -foreground "#007000" -data {
1883 #define file_fulltick_width 14
1884 #define file_fulltick_height 15
1885 static unsigned char file_fulltick_bits[] = {
1886    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1887    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1888    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1889 } -maskdata $filemask
1890
1891 image create bitmap file_parttick -background white -foreground "#005050" -data {
1892 #define parttick_width 14
1893 #define parttick_height 15
1894 static unsigned char parttick_bits[] = {
1895    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1896    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
1897    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1898 } -maskdata $filemask
1899
1900 image create bitmap file_question -background white -foreground black -data {
1901 #define file_question_width 14
1902 #define file_question_height 15
1903 static unsigned char file_question_bits[] = {
1904    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1905    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1906    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1907 } -maskdata $filemask
1908
1909 image create bitmap file_removed -background white -foreground red -data {
1910 #define file_removed_width 14
1911 #define file_removed_height 15
1912 static unsigned char file_removed_bits[] = {
1913    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1914    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1915    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1916 } -maskdata $filemask
1917
1918 image create bitmap file_merge -background white -foreground blue -data {
1919 #define file_merge_width 14
1920 #define file_merge_height 15
1921 static unsigned char file_merge_bits[] = {
1922    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1923    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1924    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1925 } -maskdata $filemask
1926
1927 set ui_index .vpane.files.index.list
1928 set ui_other .vpane.files.other.list
1929 set max_status_desc 0
1930 foreach i {
1931                 {__ i plain    "Unmodified"}
1932                 {_M i mod      "Modified"}
1933                 {M_ i fulltick "Included in commit"}
1934                 {MM i parttick "Partially included"}
1935                 {MD i question "Included (but gone)"}
1936
1937                 {_O o plain    "Untracked"}
1938                 {A_ o fulltick "Added by commit"}
1939                 {AM o parttick "Partially added"}
1940                 {AD o question "Added (but gone)"}
1941
1942                 {_D i question "Missing"}
1943                 {DD i removed  "Removed by commit"}
1944                 {DO i removed  "Removed (still exists)"}
1945                 {DM i removed  "Removed (but modified)"}
1946
1947                 {UD i merge    "Merge conflicts"}
1948                 {UM i merge    "Merge conflicts"}
1949                 {U_ i merge    "Merge conflicts"}
1950         } {
1951         if {$max_status_desc < [string length [lindex $i 3]]} {
1952                 set max_status_desc [string length [lindex $i 3]]
1953         }
1954         if {[lindex $i 1] eq {i}} {
1955                 set all_cols([lindex $i 0]) $ui_index
1956         } else {
1957                 set all_cols([lindex $i 0]) $ui_other
1958         }
1959         set all_icons([lindex $i 0]) file_[lindex $i 2]
1960         set all_descs([lindex $i 0]) [lindex $i 3]
1961 }
1962 unset filemask i
1963
1964 ######################################################################
1965 ##
1966 ## util
1967
1968 proc is_MacOSX {} {
1969         global tcl_platform tk_library
1970         if {[tk windowingsystem] eq {aqua}} {
1971                 return 1
1972         }
1973         return 0
1974 }
1975
1976 proc is_Windows {} {
1977         global tcl_platform
1978         if {$tcl_platform(platform) eq {windows}} {
1979                 return 1
1980         }
1981         return 0
1982 }
1983
1984 proc bind_button3 {w cmd} {
1985         bind $w <Any-Button-3> $cmd
1986         if {[is_MacOSX]} {
1987                 bind $w <Control-Button-1> $cmd
1988         }
1989 }
1990
1991 proc incr_font_size {font {amt 1}} {
1992         set sz [font configure $font -size]
1993         incr sz $amt
1994         font configure $font -size $sz
1995         font configure ${font}bold -size $sz
1996 }
1997
1998 proc hook_failed_popup {hook msg} {
1999         global gitdir appname
2000
2001         set w .hookfail
2002         toplevel $w
2003
2004         frame $w.m
2005         label $w.m.l1 -text "$hook hook failed:" \
2006                 -anchor w \
2007                 -justify left \
2008                 -font font_uibold
2009         text $w.m.t \
2010                 -background white -borderwidth 1 \
2011                 -relief sunken \
2012                 -width 80 -height 10 \
2013                 -font font_diff \
2014                 -yscrollcommand [list $w.m.sby set]
2015         label $w.m.l2 \
2016                 -text {You must correct the above errors before committing.} \
2017                 -anchor w \
2018                 -justify left \
2019                 -font font_uibold
2020         scrollbar $w.m.sby -command [list $w.m.t yview]
2021         pack $w.m.l1 -side top -fill x
2022         pack $w.m.l2 -side bottom -fill x
2023         pack $w.m.sby -side right -fill y
2024         pack $w.m.t -side left -fill both -expand 1
2025         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2026
2027         $w.m.t insert 1.0 $msg
2028         $w.m.t conf -state disabled
2029
2030         button $w.ok -text OK \
2031                 -width 15 \
2032                 -font font_ui \
2033                 -command "destroy $w"
2034         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2035
2036         bind $w <Visibility> "grab $w; focus $w"
2037         bind $w <Key-Return> "destroy $w"
2038         wm title $w "$appname ([lindex [file split \
2039                 [file normalize [file dirname $gitdir]]] \
2040                 end]): error"
2041         tkwait window $w
2042 }
2043
2044 set next_console_id 0
2045
2046 proc new_console {short_title long_title} {
2047         global next_console_id console_data
2048         set w .console[incr next_console_id]
2049         set console_data($w) [list $short_title $long_title]
2050         return [console_init $w]
2051 }
2052
2053 proc console_init {w} {
2054         global console_cr console_data
2055         global gitdir appname M1B
2056
2057         set console_cr($w) 1.0
2058         toplevel $w
2059         frame $w.m
2060         label $w.m.l1 -text "[lindex $console_data($w) 1]:" \
2061                 -anchor w \
2062                 -justify left \
2063                 -font font_uibold
2064         text $w.m.t \
2065                 -background white -borderwidth 1 \
2066                 -relief sunken \
2067                 -width 80 -height 10 \
2068                 -font font_diff \
2069                 -state disabled \
2070                 -yscrollcommand [list $w.m.sby set]
2071         label $w.m.s -text {Working... please wait...} \
2072                 -anchor w \
2073                 -justify left \
2074                 -font font_uibold
2075         scrollbar $w.m.sby -command [list $w.m.t yview]
2076         pack $w.m.l1 -side top -fill x
2077         pack $w.m.s -side bottom -fill x
2078         pack $w.m.sby -side right -fill y
2079         pack $w.m.t -side left -fill both -expand 1
2080         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2081
2082         menu $w.ctxm -tearoff 0
2083         $w.ctxm add command -label "Copy" \
2084                 -font font_ui \
2085                 -command "tk_textCopy $w.m.t"
2086         $w.ctxm add command -label "Select All" \
2087                 -font font_ui \
2088                 -command "$w.m.t tag add sel 0.0 end"
2089         $w.ctxm add command -label "Copy All" \
2090                 -font font_ui \
2091                 -command "
2092                         $w.m.t tag add sel 0.0 end
2093                         tk_textCopy $w.m.t
2094                         $w.m.t tag remove sel 0.0 end
2095                 "
2096
2097         button $w.ok -text {Close} \
2098                 -font font_ui \
2099                 -state disabled \
2100                 -command "destroy $w"
2101         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2102
2103         bind_button3 $w.m.t "tk_popup $w.ctxm %X %Y"
2104         bind $w.m.t <$M1B-Key-a> "$w.m.t tag add sel 0.0 end;break"
2105         bind $w.m.t <$M1B-Key-A> "$w.m.t tag add sel 0.0 end;break"
2106         bind $w <Visibility> "focus $w"
2107         wm title $w "$appname ([lindex [file split \
2108                 [file normalize [file dirname $gitdir]]] \
2109                 end]): [lindex $console_data($w) 0]"
2110         return $w
2111 }
2112
2113 proc console_exec {w cmd {after {}}} {
2114         # -- Windows tosses the enviroment when we exec our child.
2115         #    But most users need that so we have to relogin. :-(
2116         #
2117         if {[is_Windows]} {
2118                 set cmd [list sh --login -c "cd \"[pwd]\" && [join $cmd { }]"]
2119         }
2120
2121         # -- Tcl won't let us redirect both stdout and stderr to
2122         #    the same pipe.  So pass it through cat...
2123         #
2124         set cmd [concat | $cmd |& cat]
2125
2126         set fd_f [open $cmd r]
2127         fconfigure $fd_f -blocking 0 -translation binary
2128         fileevent $fd_f readable [list console_read $w $fd_f $after]
2129 }
2130
2131 proc console_read {w fd after} {
2132         global console_cr console_data
2133
2134         set buf [read $fd]
2135         if {$buf ne {}} {
2136                 if {![winfo exists $w]} {console_init $w}
2137                 $w.m.t conf -state normal
2138                 set c 0
2139                 set n [string length $buf]
2140                 while {$c < $n} {
2141                         set cr [string first "\r" $buf $c]
2142                         set lf [string first "\n" $buf $c]
2143                         if {$cr < 0} {set cr [expr {$n + 1}]}
2144                         if {$lf < 0} {set lf [expr {$n + 1}]}
2145
2146                         if {$lf < $cr} {
2147                                 $w.m.t insert end [string range $buf $c $lf]
2148                                 set console_cr($w) [$w.m.t index {end -1c}]
2149                                 set c $lf
2150                                 incr c
2151                         } else {
2152                                 $w.m.t delete $console_cr($w) end
2153                                 $w.m.t insert end "\n"
2154                                 $w.m.t insert end [string range $buf $c $cr]
2155                                 set c $cr
2156                                 incr c
2157                         }
2158                 }
2159                 $w.m.t conf -state disabled
2160                 $w.m.t see end
2161         }
2162
2163         fconfigure $fd -blocking 1
2164         if {[eof $fd]} {
2165                 if {[catch {close $fd}]} {
2166                         if {![winfo exists $w]} {console_init $w}
2167                         $w.m.s conf -background red -text {Error: Command Failed}
2168                         $w.ok conf -state normal
2169                         set ok 0
2170                 } elseif {[winfo exists $w]} {
2171                         $w.m.s conf -background green -text {Success}
2172                         $w.ok conf -state normal
2173                         set ok 1
2174                 }
2175                 array unset console_cr $w
2176                 array unset console_data $w
2177                 if {$after ne {}} {
2178                         uplevel #0 $after $ok
2179                 }
2180                 return
2181         }
2182         fconfigure $fd -blocking 0
2183 }
2184
2185 ######################################################################
2186 ##
2187 ## ui commands
2188
2189 set starting_gitk_msg {Please wait... Starting gitk...}
2190
2191 proc do_gitk {revs} {
2192         global ui_status_value starting_gitk_msg
2193
2194         set cmd gitk
2195         if {$revs ne {}} {
2196                 append cmd { }
2197                 append cmd $revs
2198         }
2199         if {[is_Windows]} {
2200                 set cmd "sh -c \"exec $cmd\""
2201         }
2202         append cmd { &}
2203
2204         if {[catch {eval exec $cmd} err]} {
2205                 error_popup "Failed to start gitk:\n\n$err"
2206         } else {
2207                 set ui_status_value $starting_gitk_msg
2208                 after 10000 {
2209                         if {$ui_status_value eq $starting_gitk_msg} {
2210                                 set ui_status_value {Ready.}
2211                         }
2212                 }
2213         }
2214 }
2215
2216 proc do_repack {} {
2217         set w [new_console {repack} \
2218                 {Repacking the object database}]
2219         set cmd [list git repack]
2220         lappend cmd -a
2221         lappend cmd -d
2222         console_exec $w $cmd
2223 }
2224
2225 proc do_fsck_objects {} {
2226         set w [new_console {fsck-objects} \
2227                 {Verifying the object database with fsck-objects}]
2228         set cmd [list git fsck-objects]
2229         lappend cmd --full
2230         lappend cmd --cache
2231         lappend cmd --strict
2232         console_exec $w $cmd
2233 }
2234
2235 set is_quitting 0
2236
2237 proc do_quit {} {
2238         global gitdir ui_comm is_quitting repo_config commit_type
2239
2240         if {$is_quitting} return
2241         set is_quitting 1
2242
2243         # -- Stash our current commit buffer.
2244         #
2245         set save [file join $gitdir GITGUI_MSG]
2246         set msg [string trim [$ui_comm get 0.0 end]]
2247         if {![string match amend* $commit_type]
2248                 && [$ui_comm edit modified]
2249                 && $msg ne {}} {
2250                 catch {
2251                         set fd [open $save w]
2252                         puts $fd [string trim [$ui_comm get 0.0 end]]
2253                         close $fd
2254                 }
2255         } else {
2256                 catch {file delete $save}
2257         }
2258
2259         # -- Stash our current window geometry into this repository.
2260         #
2261         set cfg_geometry [list]
2262         lappend cfg_geometry [wm geometry .]
2263         lappend cfg_geometry [lindex [.vpane sash coord 0] 1]
2264         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 0]
2265         if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2266                 set rc_geometry {}
2267         }
2268         if {$cfg_geometry ne $rc_geometry} {
2269                 catch {exec git repo-config gui.geometry $cfg_geometry}
2270         }
2271
2272         destroy .
2273 }
2274
2275 proc do_rescan {} {
2276         rescan {set ui_status_value {Ready.}}
2277 }
2278
2279 proc remove_helper {txt paths} {
2280         global file_states current_diff
2281
2282         if {![lock_index begin-update]} return
2283
2284         set pathList [list]
2285         set after {}
2286         foreach path $paths {
2287                 switch -glob -- [lindex $file_states($path) 0] {
2288                 A? -
2289                 M? -
2290                 D? {
2291                         lappend pathList $path
2292                         if {$path eq $current_diff} {
2293                                 set after {reshow_diff;}
2294                         }
2295                 }
2296                 }
2297         }
2298         if {$pathList eq {}} {
2299                 unlock_index
2300         } else {
2301                 update_indexinfo \
2302                         $txt \
2303                         $pathList \
2304                         [concat $after {set ui_status_value {Ready.}}]
2305         }
2306 }
2307
2308 proc do_remove_selection {} {
2309         global current_diff selected_paths
2310
2311         if {[array size selected_paths] > 0} {
2312                 remove_helper \
2313                         {Removing selected files from commit} \
2314                         [array names selected_paths]
2315         } elseif {$current_diff ne {}} {
2316                 remove_helper \
2317                         "Removing [short_path $current_diff] from commit" \
2318                         [list $current_diff]
2319         }
2320 }
2321
2322 proc include_helper {txt paths} {
2323         global file_states current_diff
2324
2325         if {![lock_index begin-update]} return
2326
2327         set pathList [list]
2328         set after {}
2329         foreach path $paths {
2330                 switch -glob -- [lindex $file_states($path) 0] {
2331                 AM -
2332                 AD -
2333                 MM -
2334                 MD -
2335                 U? -
2336                 _M -
2337                 _D -
2338                 _O {
2339                         lappend pathList $path
2340                         if {$path eq $current_diff} {
2341                                 set after {reshow_diff;}
2342                         }
2343                 }
2344                 }
2345         }
2346         if {$pathList eq {}} {
2347                 unlock_index
2348         } else {
2349                 update_index \
2350                         $txt \
2351                         $pathList \
2352                         [concat $after {set ui_status_value {Ready to commit.}}]
2353         }
2354 }
2355
2356 proc do_include_selection {} {
2357         global current_diff selected_paths
2358
2359         if {[array size selected_paths] > 0} {
2360                 include_helper \
2361                         {Including selected files} \
2362                         [array names selected_paths]
2363         } elseif {$current_diff ne {}} {
2364                 include_helper \
2365                         "Including [short_path $current_diff]" \
2366                         [list $current_diff]
2367         }
2368 }
2369
2370 proc do_include_all {} {
2371         global file_states
2372
2373         set paths [list]
2374         foreach path [array names file_states] {
2375                 switch -- [lindex $file_states($path) 0] {
2376                 AM -
2377                 AD -
2378                 MM -
2379                 MD -
2380                 _M -
2381                 _D {lappend paths $path}
2382                 }
2383         }
2384         include_helper \
2385                 {Including all modified files} \
2386                 $paths
2387 }
2388
2389 proc revert_helper {txt paths} {
2390         global gitdir appname
2391         global file_states current_diff
2392
2393         if {![lock_index begin-update]} return
2394
2395         set pathList [list]
2396         set after {}
2397         foreach path $paths {
2398                 switch -glob -- [lindex $file_states($path) 0] {
2399                 AM -
2400                 AD -
2401                 MM -
2402                 MD -
2403                 _M -
2404                 _D {
2405                         lappend pathList $path
2406                         if {$path eq $current_diff} {
2407                                 set after {reshow_diff;}
2408                         }
2409                 }
2410                 }
2411         }
2412
2413         set n [llength $pathList]
2414         if {$n == 0} {
2415                 unlock_index
2416                 return
2417         } elseif {$n == 1} {
2418                 set s "[short_path [lindex $pathList]]"
2419         } else {
2420                 set s "these $n files"
2421         }
2422
2423         set reponame [lindex [file split \
2424                 [file normalize [file dirname $gitdir]]] \
2425                 end]
2426
2427         set reply [tk_dialog \
2428                 .confirm_revert \
2429                 "$appname ($reponame)" \
2430                 "Revert unincluded changes in $s?
2431
2432 Any unincluded changes will be permanently lost by the revert." \
2433                 question \
2434                 1 \
2435                 {Do Nothing} \
2436                 {Revert Changes} \
2437                 ]
2438         if {$reply == 1} {
2439                 checkout_index \
2440                         $txt \
2441                         $pathList \
2442                         [concat $after {set ui_status_value {Ready.}}]
2443         } else {
2444                 unlock_index
2445         }
2446 }
2447
2448 proc do_revert_selection {} {
2449         global current_diff selected_paths
2450
2451         if {[array size selected_paths] > 0} {
2452                 revert_helper \
2453                         {Reverting selected files} \
2454                         [array names selected_paths]
2455         } elseif {$current_diff ne {}} {
2456                 revert_helper \
2457                         "Reverting [short_path $current_diff]" \
2458                         [list $current_diff]
2459         }
2460 }
2461
2462 proc do_signoff {} {
2463         global ui_comm
2464
2465         set me [committer_ident]
2466         if {$me eq {}} return
2467
2468         set sob "Signed-off-by: $me"
2469         set last [$ui_comm get {end -1c linestart} {end -1c}]
2470         if {$last ne $sob} {
2471                 $ui_comm edit separator
2472                 if {$last ne {}
2473                         && ![regexp {^[A-Z][A-Za-z]*-[A-Za-z-]+: *} $last]} {
2474                         $ui_comm insert end "\n"
2475                 }
2476                 $ui_comm insert end "\n$sob"
2477                 $ui_comm edit separator
2478                 $ui_comm see end
2479         }
2480 }
2481
2482 proc do_select_commit_type {} {
2483         global commit_type selected_commit_type
2484
2485         if {$selected_commit_type eq {new}
2486                 && [string match amend* $commit_type]} {
2487                 create_new_commit
2488         } elseif {$selected_commit_type eq {amend}
2489                 && ![string match amend* $commit_type]} {
2490                 load_last_commit
2491
2492                 # The amend request was rejected...
2493                 #
2494                 if {![string match amend* $commit_type]} {
2495                         set selected_commit_type new
2496                 }
2497         }
2498 }
2499
2500 proc do_commit {} {
2501         commit_tree
2502 }
2503
2504 proc do_about {} {
2505         global appname copyright
2506         global tcl_patchLevel tk_patchLevel
2507
2508         set w .about_dialog
2509         toplevel $w
2510         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2511
2512         label $w.header -text "About $appname" \
2513                 -font font_uibold
2514         pack $w.header -side top -fill x
2515
2516         frame $w.buttons
2517         button $w.buttons.close -text {Close} \
2518                 -font font_ui \
2519                 -command [list destroy $w]
2520         pack $w.buttons.close -side right
2521         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2522
2523         label $w.desc \
2524                 -text "$appname - a commit creation tool for Git.
2525 $copyright" \
2526                 -padx 5 -pady 5 \
2527                 -justify left \
2528                 -anchor w \
2529                 -borderwidth 1 \
2530                 -relief solid \
2531                 -font font_ui
2532         pack $w.desc -side top -fill x -padx 5 -pady 5
2533
2534         set v [exec git --version]
2535         append v "\n\n"
2536         if {$tcl_patchLevel eq $tk_patchLevel} {
2537                 append v "Tcl/Tk version $tcl_patchLevel"
2538         } else {
2539                 append v "Tcl version $tcl_patchLevel"
2540                 append v ", Tk version $tk_patchLevel"
2541         }
2542
2543         label $w.vers \
2544                 -text $v \
2545                 -padx 5 -pady 5 \
2546                 -justify left \
2547                 -anchor w \
2548                 -borderwidth 1 \
2549                 -relief solid \
2550                 -font font_ui
2551         pack $w.vers -side top -fill x -padx 5 -pady 5
2552
2553         bind $w <Visibility> "grab $w; focus $w"
2554         bind $w <Key-Escape> "destroy $w"
2555         wm title $w "About $appname"
2556         tkwait window $w
2557 }
2558
2559 proc do_options {} {
2560         global appname gitdir font_descs
2561         global repo_config global_config
2562         global repo_config_new global_config_new
2563
2564         array unset repo_config_new
2565         array unset global_config_new
2566         foreach name [array names repo_config] {
2567                 set repo_config_new($name) $repo_config($name)
2568         }
2569         load_config 1
2570         foreach name [array names repo_config] {
2571                 switch -- $name {
2572                 gui.diffcontext {continue}
2573                 }
2574                 set repo_config_new($name) $repo_config($name)
2575         }
2576         foreach name [array names global_config] {
2577                 set global_config_new($name) $global_config($name)
2578         }
2579         set reponame [lindex [file split \
2580                 [file normalize [file dirname $gitdir]]] \
2581                 end]
2582
2583         set w .options_editor
2584         toplevel $w
2585         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2586
2587         label $w.header -text "$appname Options" \
2588                 -font font_uibold
2589         pack $w.header -side top -fill x
2590
2591         frame $w.buttons
2592         button $w.buttons.restore -text {Restore Defaults} \
2593                 -font font_ui \
2594                 -command do_restore_defaults
2595         pack $w.buttons.restore -side left
2596         button $w.buttons.save -text Save \
2597                 -font font_ui \
2598                 -command [list do_save_config $w]
2599         pack $w.buttons.save -side right
2600         button $w.buttons.cancel -text {Cancel} \
2601                 -font font_ui \
2602                 -command [list destroy $w]
2603         pack $w.buttons.cancel -side right
2604         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2605
2606         labelframe $w.repo -text "$reponame Repository" \
2607                 -font font_ui \
2608                 -relief raised -borderwidth 2
2609         labelframe $w.global -text {Global (All Repositories)} \
2610                 -font font_ui \
2611                 -relief raised -borderwidth 2
2612         pack $w.repo -side left -fill both -expand 1 -pady 5 -padx 5
2613         pack $w.global -side right -fill both -expand 1 -pady 5 -padx 5
2614
2615         foreach option {
2616                 {b partialinclude {Allow Partially Included Files}}
2617                 {b pullsummary {Show Pull Summary}}
2618                 {b trustmtime  {Trust File Modification Timestamps}}
2619                 {i diffcontext {Number of Diff Context Lines}}
2620                 } {
2621                 set type [lindex $option 0]
2622                 set name [lindex $option 1]
2623                 set text [lindex $option 2]
2624                 foreach f {repo global} {
2625                         switch $type {
2626                         b {
2627                                 checkbutton $w.$f.$name -text $text \
2628                                         -variable ${f}_config_new(gui.$name) \
2629                                         -onvalue true \
2630                                         -offvalue false \
2631                                         -font font_ui
2632                                 pack $w.$f.$name -side top -anchor w
2633                         }
2634                         i {
2635                                 frame $w.$f.$name
2636                                 label $w.$f.$name.l -text "$text:" -font font_ui
2637                                 pack $w.$f.$name.l -side left -anchor w -fill x
2638                                 spinbox $w.$f.$name.v \
2639                                         -textvariable ${f}_config_new(gui.$name) \
2640                                         -from 1 -to 99 -increment 1 \
2641                                         -width 3 \
2642                                         -font font_ui
2643                                 pack $w.$f.$name.v -side right -anchor e
2644                                 pack $w.$f.$name -side top -anchor w -fill x
2645                         }
2646                         }
2647                 }
2648         }
2649
2650         set all_fonts [lsort [font families]]
2651         foreach option $font_descs {
2652                 set name [lindex $option 0]
2653                 set font [lindex $option 1]
2654                 set text [lindex $option 2]
2655
2656                 set global_config_new(gui.$font^^family) \
2657                         [font configure $font -family]
2658                 set global_config_new(gui.$font^^size) \
2659                         [font configure $font -size]
2660
2661                 frame $w.global.$name
2662                 label $w.global.$name.l -text "$text:" -font font_ui
2663                 pack $w.global.$name.l -side left -anchor w -fill x
2664                 eval tk_optionMenu $w.global.$name.family \
2665                         global_config_new(gui.$font^^family) \
2666                         $all_fonts
2667                 spinbox $w.global.$name.size \
2668                         -textvariable global_config_new(gui.$font^^size) \
2669                         -from 2 -to 80 -increment 1 \
2670                         -width 3 \
2671                         -font font_ui
2672                 pack $w.global.$name.size -side right -anchor e
2673                 pack $w.global.$name.family -side right -anchor e
2674                 pack $w.global.$name -side top -anchor w -fill x
2675         }
2676
2677         bind $w <Visibility> "grab $w; focus $w"
2678         bind $w <Key-Escape> "destroy $w"
2679         wm title $w "$appname ($reponame): Options"
2680         tkwait window $w
2681 }
2682
2683 proc do_restore_defaults {} {
2684         global font_descs default_config repo_config
2685         global repo_config_new global_config_new
2686
2687         foreach name [array names default_config] {
2688                 set repo_config_new($name) $default_config($name)
2689                 set global_config_new($name) $default_config($name)
2690         }
2691
2692         foreach option $font_descs {
2693                 set name [lindex $option 0]
2694                 set repo_config(gui.$name) $default_config(gui.$name)
2695         }
2696         apply_config
2697
2698         foreach option $font_descs {
2699                 set name [lindex $option 0]
2700                 set font [lindex $option 1]
2701                 set global_config_new(gui.$font^^family) \
2702                         [font configure $font -family]
2703                 set global_config_new(gui.$font^^size) \
2704                         [font configure $font -size]
2705         }
2706 }
2707
2708 proc do_save_config {w} {
2709         if {[catch {save_config} err]} {
2710                 error_popup "Failed to completely save options:\n\n$err"
2711         }
2712         reshow_diff
2713         destroy $w
2714 }
2715
2716 proc do_windows_shortcut {} {
2717         global gitdir appname argv0
2718
2719         set reponame [lindex [file split \
2720                 [file normalize [file dirname $gitdir]]] \
2721                 end]
2722
2723         if {[catch {
2724                 set desktop [exec cygpath \
2725                         --windows \
2726                         --absolute \
2727                         --long-name \
2728                         --desktop]
2729                 }]} {
2730                         set desktop .
2731         }
2732         set fn [tk_getSaveFile \
2733                 -parent . \
2734                 -title "$appname ($reponame): Create Desktop Icon" \
2735                 -initialdir $desktop \
2736                 -initialfile "Git $reponame.bat"]
2737         if {$fn != {}} {
2738                 if {[catch {
2739                                 set fd [open $fn w]
2740                                 set sh [exec cygpath \
2741                                         --windows \
2742                                         --absolute \
2743                                         --long-name \
2744                                         /bin/sh]
2745                                 set me [exec cygpath \
2746                                         --unix \
2747                                         --absolute \
2748                                         $argv0]
2749                                 set gd [exec cygpath \
2750                                         --unix \
2751                                         --absolute \
2752                                         $gitdir]
2753                                 regsub -all ' $me "'\\''" me
2754                                 regsub -all ' $gd "'\\''" gd
2755                                 puts -nonewline $fd "\"$sh\" --login -c \""
2756                                 puts -nonewline $fd "GIT_DIR='$gd'"
2757                                 puts -nonewline $fd " '$me'"
2758                                 puts $fd "&\""
2759                                 close $fd
2760                         } err]} {
2761                         error_popup "Cannot write script:\n\n$err"
2762                 }
2763         }
2764 }
2765
2766 proc do_macosx_app {} {
2767         global gitdir appname argv0 env
2768
2769         set reponame [lindex [file split \
2770                 [file normalize [file dirname $gitdir]]] \
2771                 end]
2772
2773         set fn [tk_getSaveFile \
2774                 -parent . \
2775                 -title "$appname ($reponame): Create Desktop Icon" \
2776                 -initialdir [file join $env(HOME) Desktop] \
2777                 -initialfile "Git $reponame.app"]
2778         if {$fn != {}} {
2779                 if {[catch {
2780                                 set Contents [file join $fn Contents]
2781                                 set MacOS [file join $Contents MacOS]
2782                                 set exe [file join $MacOS git-gui]
2783
2784                                 file mkdir $MacOS
2785
2786                                 set fd [open [file join $Contents Info.plist] w]
2787                                 puts $fd {<?xml version="1.0" encoding="UTF-8"?>
2788 <!DOCTYPE plist PUBLIC "-//Apple Computer//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
2789 <plist version="1.0">
2790 <dict>
2791         <key>CFBundleDevelopmentRegion</key>
2792         <string>English</string>
2793         <key>CFBundleExecutable</key>
2794         <string>git-gui</string>
2795         <key>CFBundleIdentifier</key>
2796         <string>org.spearce.git-gui</string>
2797         <key>CFBundleInfoDictionaryVersion</key>
2798         <string>6.0</string>
2799         <key>CFBundlePackageType</key>
2800         <string>APPL</string>
2801         <key>CFBundleSignature</key>
2802         <string>????</string>
2803         <key>CFBundleVersion</key>
2804         <string>1.0</string>
2805         <key>NSPrincipalClass</key>
2806         <string>NSApplication</string>
2807 </dict>
2808 </plist>}
2809                                 close $fd
2810
2811                                 set fd [open $exe w]
2812                                 set gd [file normalize $gitdir]
2813                                 set ep [file normalize [exec git --exec-path]]
2814                                 regsub -all ' $gd "'\\''" gd
2815                                 regsub -all ' $ep "'\\''" ep
2816                                 puts $fd "#!/bin/sh"
2817                                 foreach name [array names env] {
2818                                         if {[string match GIT_* $name]} {
2819                                                 regsub -all ' $env($name) "'\\''" v
2820                                                 puts $fd "export $name='$v'"
2821                                         }
2822                                 }
2823                                 puts $fd "export PATH='$ep':\$PATH"
2824                                 puts $fd "export GIT_DIR='$gd'"
2825                                 puts $fd "exec [file normalize $argv0]"
2826                                 close $fd
2827
2828                                 file attributes $exe -permissions u+x,g+x,o+x
2829                         } err]} {
2830                         error_popup "Cannot write icon:\n\n$err"
2831                 }
2832         }
2833 }
2834
2835 proc toggle_or_diff {w x y} {
2836         global file_states file_lists current_diff ui_index ui_other
2837         global last_clicked selected_paths
2838
2839         set pos [split [$w index @$x,$y] .]
2840         set lno [lindex $pos 0]
2841         set col [lindex $pos 1]
2842         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2843         if {$path eq {}} {
2844                 set last_clicked {}
2845                 return
2846         }
2847
2848         set last_clicked [list $w $lno]
2849         array unset selected_paths
2850         $ui_index tag remove in_sel 0.0 end
2851         $ui_other tag remove in_sel 0.0 end
2852
2853         if {$col == 0} {
2854                 if {$current_diff eq $path} {
2855                         set after {reshow_diff;}
2856                 } else {
2857                         set after {}
2858                 }
2859                 switch -glob -- [lindex $file_states($path) 0] {
2860                 A_ -
2861                 M_ -
2862                 DD -
2863                 DO -
2864                 DM {
2865                         update_indexinfo \
2866                                 "Removing [short_path $path] from commit" \
2867                                 [list $path] \
2868                                 [concat $after {set ui_status_value {Ready.}}]
2869                 }
2870                 ?? {
2871                         update_index \
2872                                 "Including [short_path $path]" \
2873                                 [list $path] \
2874                                 [concat $after {set ui_status_value {Ready.}}]
2875                 }
2876                 }
2877         } else {
2878                 show_diff $path $w $lno
2879         }
2880 }
2881
2882 proc add_one_to_selection {w x y} {
2883         global file_lists
2884         global last_clicked selected_paths
2885
2886         set pos [split [$w index @$x,$y] .]
2887         set lno [lindex $pos 0]
2888         set col [lindex $pos 1]
2889         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2890         if {$path eq {}} {
2891                 set last_clicked {}
2892                 return
2893         }
2894
2895         set last_clicked [list $w $lno]
2896         if {[catch {set in_sel $selected_paths($path)}]} {
2897                 set in_sel 0
2898         }
2899         if {$in_sel} {
2900                 unset selected_paths($path)
2901                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2902         } else {
2903                 set selected_paths($path) 1
2904                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2905         }
2906 }
2907
2908 proc add_range_to_selection {w x y} {
2909         global file_lists
2910         global last_clicked selected_paths
2911
2912         if {[lindex $last_clicked 0] ne $w} {
2913                 toggle_or_diff $w $x $y
2914                 return
2915         }
2916
2917         set pos [split [$w index @$x,$y] .]
2918         set lno [lindex $pos 0]
2919         set lc [lindex $last_clicked 1]
2920         if {$lc < $lno} {
2921                 set begin $lc
2922                 set end $lno
2923         } else {
2924                 set begin $lno
2925                 set end $lc
2926         }
2927
2928         foreach path [lrange $file_lists($w) \
2929                 [expr {$begin - 1}] \
2930                 [expr {$end - 1}]] {
2931                 set selected_paths($path) 1
2932         }
2933         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2934 }
2935
2936 ######################################################################
2937 ##
2938 ## config defaults
2939
2940 set cursor_ptr arrow
2941 font create font_diff -family Courier -size 10
2942 font create font_ui
2943 catch {
2944         label .dummy
2945         eval font configure font_ui [font actual [.dummy cget -font]]
2946         destroy .dummy
2947 }
2948
2949 font create font_uibold
2950 font create font_diffbold
2951
2952 if {[is_Windows]} {
2953         set M1B Control
2954         set M1T Ctrl
2955 } elseif {[is_MacOSX]} {
2956         set M1B M1
2957         set M1T Cmd
2958 } else {
2959         set M1B M1
2960         set M1T M1
2961 }
2962
2963 proc apply_config {} {
2964         global repo_config font_descs
2965
2966         foreach option $font_descs {
2967                 set name [lindex $option 0]
2968                 set font [lindex $option 1]
2969                 if {[catch {
2970                         foreach {cn cv} $repo_config(gui.$name) {
2971                                 font configure $font $cn $cv
2972                         }
2973                         } err]} {
2974                         error_popup "Invalid font specified in gui.$name:\n\n$err"
2975                 }
2976                 foreach {cn cv} [font configure $font] {
2977                         font configure ${font}bold $cn $cv
2978                 }
2979                 font configure ${font}bold -weight bold
2980         }
2981 }
2982
2983 set default_config(gui.trustmtime) false
2984 set default_config(gui.pullsummary) true
2985 set default_config(gui.partialinclude) false
2986 set default_config(gui.diffcontext) 5
2987 set default_config(gui.fontui) [font configure font_ui]
2988 set default_config(gui.fontdiff) [font configure font_diff]
2989 set font_descs {
2990         {fontui   font_ui   {Main Font}}
2991         {fontdiff font_diff {Diff/Console Font}}
2992 }
2993 load_config 0
2994 apply_config
2995
2996 ######################################################################
2997 ##
2998 ## ui construction
2999
3000 # -- Menu Bar
3001 #
3002 menu .mbar -tearoff 0
3003 .mbar add cascade -label Repository -menu .mbar.repository
3004 .mbar add cascade -label Edit -menu .mbar.edit
3005 if {!$single_commit} {
3006         .mbar add cascade -label Branch -menu .mbar.branch
3007 }
3008 .mbar add cascade -label Commit -menu .mbar.commit
3009 if {!$single_commit} {
3010         .mbar add cascade -label Fetch -menu .mbar.fetch
3011         .mbar add cascade -label Pull -menu .mbar.pull
3012         .mbar add cascade -label Push -menu .mbar.push
3013 }
3014 . configure -menu .mbar
3015
3016 # -- Repository Menu
3017 #
3018 menu .mbar.repository
3019 .mbar.repository add command \
3020         -label {Visualize Current Branch} \
3021         -command {do_gitk {}} \
3022         -font font_ui
3023 if {![is_MacOSX]} {
3024         .mbar.repository add command \
3025                 -label {Visualize All Branches} \
3026                 -command {do_gitk {--all}} \
3027                 -font font_ui
3028 }
3029 .mbar.repository add separator
3030
3031 if {!$single_commit} {
3032         .mbar.repository add command -label {Repack Database} \
3033                 -command do_repack \
3034                 -font font_ui
3035
3036         .mbar.repository add command -label {Verify Database} \
3037                 -command do_fsck_objects \
3038                 -font font_ui
3039
3040         .mbar.repository add separator
3041
3042         if {[is_Windows]} {
3043                 .mbar.repository add command \
3044                         -label {Create Desktop Icon} \
3045                         -command do_windows_shortcut \
3046                         -font font_ui
3047         } elseif {[is_MacOSX]} {
3048                 .mbar.repository add command \
3049                         -label {Create Desktop Icon} \
3050                         -command do_macosx_app \
3051                         -font font_ui
3052         }
3053 }
3054
3055 .mbar.repository add command -label Quit \
3056         -command do_quit \
3057         -accelerator $M1T-Q \
3058         -font font_ui
3059
3060 # -- Edit Menu
3061 #
3062 menu .mbar.edit
3063 .mbar.edit add command -label Undo \
3064         -command {catch {[focus] edit undo}} \
3065         -accelerator $M1T-Z \
3066         -font font_ui
3067 .mbar.edit add command -label Redo \
3068         -command {catch {[focus] edit redo}} \
3069         -accelerator $M1T-Y \
3070         -font font_ui
3071 .mbar.edit add separator
3072 .mbar.edit add command -label Cut \
3073         -command {catch {tk_textCut [focus]}} \
3074         -accelerator $M1T-X \
3075         -font font_ui
3076 .mbar.edit add command -label Copy \
3077         -command {catch {tk_textCopy [focus]}} \
3078         -accelerator $M1T-C \
3079         -font font_ui
3080 .mbar.edit add command -label Paste \
3081         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
3082         -accelerator $M1T-V \
3083         -font font_ui
3084 .mbar.edit add command -label Delete \
3085         -command {catch {[focus] delete sel.first sel.last}} \
3086         -accelerator Del \
3087         -font font_ui
3088 .mbar.edit add separator
3089 .mbar.edit add command -label {Select All} \
3090         -command {catch {[focus] tag add sel 0.0 end}} \
3091         -accelerator $M1T-A \
3092         -font font_ui
3093
3094 # -- Branch Menu
3095 #
3096 if {!$single_commit} {
3097         menu .mbar.branch
3098
3099         .mbar.branch add command -label {Create...} \
3100                 -command do_create_branch \
3101                 -font font_ui
3102         lappend disable_on_lock [list .mbar.branch entryconf \
3103                 [.mbar.branch index last] -state]
3104
3105         .mbar.branch add command -label {Delete...} \
3106                 -command do_delete_branch \
3107                 -font font_ui
3108         lappend disable_on_lock [list .mbar.branch entryconf \
3109                 [.mbar.branch index last] -state]
3110 }
3111
3112 # -- Commit Menu
3113 #
3114 menu .mbar.commit
3115
3116 .mbar.commit add radiobutton \
3117         -label {New Commit} \
3118         -command do_select_commit_type \
3119         -variable selected_commit_type \
3120         -value new \
3121         -font font_ui
3122 lappend disable_on_lock \
3123         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3124
3125 .mbar.commit add radiobutton \
3126         -label {Amend Last Commit} \
3127         -command do_select_commit_type \
3128         -variable selected_commit_type \
3129         -value amend \
3130         -font font_ui
3131 lappend disable_on_lock \
3132         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3133
3134 .mbar.commit add separator
3135
3136 .mbar.commit add command -label Rescan \
3137         -command do_rescan \
3138         -accelerator F5 \
3139         -font font_ui
3140 lappend disable_on_lock \
3141         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3142
3143 .mbar.commit add command -label {Include In Commit} \
3144         -command do_include_selection \
3145         -font font_ui
3146 lappend disable_on_lock \
3147         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3148
3149 .mbar.commit add command -label {Include All In Commit} \
3150         -command do_include_all \
3151         -accelerator $M1T-I \
3152         -font font_ui
3153 lappend disable_on_lock \
3154         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3155
3156 .mbar.commit add command -label {Remove From Commit} \
3157         -command do_remove_selection \
3158         -font font_ui
3159 lappend disable_on_lock \
3160         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3161
3162 .mbar.commit add command -label {Revert Changes} \
3163         -command do_revert_selection \
3164         -font font_ui
3165 lappend disable_on_lock \
3166         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3167
3168 .mbar.commit add separator
3169
3170 .mbar.commit add command -label {Sign Off} \
3171         -command do_signoff \
3172         -accelerator $M1T-S \
3173         -font font_ui
3174
3175 .mbar.commit add command -label Commit \
3176         -command do_commit \
3177         -accelerator $M1T-Return \
3178         -font font_ui
3179 lappend disable_on_lock \
3180         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3181
3182 # -- Transport menus
3183 #
3184 if {!$single_commit} {
3185         menu .mbar.fetch
3186         menu .mbar.pull
3187         menu .mbar.push
3188 }
3189
3190 if {[is_MacOSX]} {
3191         # -- Apple Menu (Mac OS X only)
3192         #
3193         .mbar add cascade -label Apple -menu .mbar.apple
3194         menu .mbar.apple
3195
3196         .mbar.apple add command -label "About $appname" \
3197                 -command do_about \
3198                 -font font_ui
3199         .mbar.apple add command -label "$appname Options..." \
3200                 -command do_options \
3201                 -font font_ui
3202 } else {
3203         # -- Edit Menu
3204         #
3205         .mbar.edit add separator
3206         .mbar.edit add command -label {Options...} \
3207                 -command do_options \
3208                 -font font_ui
3209
3210         # -- Help Menu
3211         #
3212         .mbar add cascade -label Help -menu .mbar.help
3213         menu .mbar.help
3214
3215         .mbar.help add command -label "About $appname" \
3216                 -command do_about \
3217                 -font font_ui
3218 }
3219
3220
3221 # -- Branch Control
3222 #
3223 frame .branch \
3224         -borderwidth 1 \
3225         -relief sunken
3226 label .branch.l1 \
3227         -text {Current Branch:} \
3228         -anchor w \
3229         -justify left \
3230         -font font_ui
3231 label .branch.cb \
3232         -textvariable current_branch \
3233         -anchor w \
3234         -justify left \
3235         -font font_ui
3236 pack .branch.l1 -side left
3237 pack .branch.cb -side left -fill x
3238 pack .branch -side top -fill x
3239
3240 # -- Main Window Layout
3241 #
3242 panedwindow .vpane -orient vertical
3243 panedwindow .vpane.files -orient horizontal
3244 .vpane add .vpane.files -sticky nsew -height 100 -width 400
3245 pack .vpane -anchor n -side top -fill both -expand 1
3246
3247 # -- Index File List
3248 #
3249 frame .vpane.files.index -height 100 -width 400
3250 label .vpane.files.index.title -text {Modified Files} \
3251         -background green \
3252         -font font_ui
3253 text $ui_index -background white -borderwidth 0 \
3254         -width 40 -height 10 \
3255         -font font_ui \
3256         -cursor $cursor_ptr \
3257         -yscrollcommand {.vpane.files.index.sb set} \
3258         -state disabled
3259 scrollbar .vpane.files.index.sb -command [list $ui_index yview]
3260 pack .vpane.files.index.title -side top -fill x
3261 pack .vpane.files.index.sb -side right -fill y
3262 pack $ui_index -side left -fill both -expand 1
3263 .vpane.files add .vpane.files.index -sticky nsew
3264
3265 # -- Other (Add) File List
3266 #
3267 frame .vpane.files.other -height 100 -width 100
3268 label .vpane.files.other.title -text {Untracked Files} \
3269         -background red \
3270         -font font_ui
3271 text $ui_other -background white -borderwidth 0 \
3272         -width 40 -height 10 \
3273         -font font_ui \
3274         -cursor $cursor_ptr \
3275         -yscrollcommand {.vpane.files.other.sb set} \
3276         -state disabled
3277 scrollbar .vpane.files.other.sb -command [list $ui_other yview]
3278 pack .vpane.files.other.title -side top -fill x
3279 pack .vpane.files.other.sb -side right -fill y
3280 pack $ui_other -side left -fill both -expand 1
3281 .vpane.files add .vpane.files.other -sticky nsew
3282
3283 foreach i [list $ui_index $ui_other] {
3284         $i tag conf in_diff -font font_uibold
3285         $i tag conf in_sel \
3286                 -background [$i cget -foreground] \
3287                 -foreground [$i cget -background]
3288 }
3289 unset i
3290
3291 # -- Diff and Commit Area
3292 #
3293 frame .vpane.lower -height 300 -width 400
3294 frame .vpane.lower.commarea
3295 frame .vpane.lower.diff -relief sunken -borderwidth 1
3296 pack .vpane.lower.commarea -side top -fill x
3297 pack .vpane.lower.diff -side bottom -fill both -expand 1
3298 .vpane add .vpane.lower -stick nsew
3299
3300 # -- Commit Area Buttons
3301 #
3302 frame .vpane.lower.commarea.buttons
3303 label .vpane.lower.commarea.buttons.l -text {} \
3304         -anchor w \
3305         -justify left \
3306         -font font_ui
3307 pack .vpane.lower.commarea.buttons.l -side top -fill x
3308 pack .vpane.lower.commarea.buttons -side left -fill y
3309
3310 button .vpane.lower.commarea.buttons.rescan -text {Rescan} \
3311         -command do_rescan \
3312         -font font_ui
3313 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3314 lappend disable_on_lock \
3315         {.vpane.lower.commarea.buttons.rescan conf -state}
3316
3317 button .vpane.lower.commarea.buttons.incall -text {Include All} \
3318         -command do_include_all \
3319         -font font_ui
3320 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3321 lappend disable_on_lock \
3322         {.vpane.lower.commarea.buttons.incall conf -state}
3323
3324 button .vpane.lower.commarea.buttons.signoff -text {Sign Off} \
3325         -command do_signoff \
3326         -font font_ui
3327 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3328
3329 button .vpane.lower.commarea.buttons.commit -text {Commit} \
3330         -command do_commit \
3331         -font font_ui
3332 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3333 lappend disable_on_lock \
3334         {.vpane.lower.commarea.buttons.commit conf -state}
3335
3336 # -- Commit Message Buffer
3337 #
3338 frame .vpane.lower.commarea.buffer
3339 frame .vpane.lower.commarea.buffer.header
3340 set ui_comm .vpane.lower.commarea.buffer.t
3341 set ui_coml .vpane.lower.commarea.buffer.header.l
3342 radiobutton .vpane.lower.commarea.buffer.header.new \
3343         -text {New Commit} \
3344         -command do_select_commit_type \
3345         -variable selected_commit_type \
3346         -value new \
3347         -font font_ui
3348 lappend disable_on_lock \
3349         [list .vpane.lower.commarea.buffer.header.new conf -state]
3350 radiobutton .vpane.lower.commarea.buffer.header.amend \
3351         -text {Amend Last Commit} \
3352         -command do_select_commit_type \
3353         -variable selected_commit_type \
3354         -value amend \
3355         -font font_ui
3356 lappend disable_on_lock \
3357         [list .vpane.lower.commarea.buffer.header.amend conf -state]
3358 label $ui_coml \
3359         -anchor w \
3360         -justify left \
3361         -font font_ui
3362 proc trace_commit_type {varname args} {
3363         global ui_coml commit_type
3364         switch -glob -- $commit_type {
3365         initial       {set txt {Initial Commit Message:}}
3366         amend         {set txt {Amended Commit Message:}}
3367         amend-initial {set txt {Amended Initial Commit Message:}}
3368         amend-merge   {set txt {Amended Merge Commit Message:}}
3369         merge         {set txt {Merge Commit Message:}}
3370         *             {set txt {Commit Message:}}
3371         }
3372         $ui_coml conf -text $txt
3373 }
3374 trace add variable commit_type write trace_commit_type
3375 pack $ui_coml -side left -fill x
3376 pack .vpane.lower.commarea.buffer.header.amend -side right
3377 pack .vpane.lower.commarea.buffer.header.new -side right
3378
3379 text $ui_comm -background white -borderwidth 1 \
3380         -undo true \
3381         -maxundo 20 \
3382         -autoseparators true \
3383         -relief sunken \
3384         -width 75 -height 9 -wrap none \
3385         -font font_diff \
3386         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3387 scrollbar .vpane.lower.commarea.buffer.sby \
3388         -command [list $ui_comm yview]
3389 pack .vpane.lower.commarea.buffer.header -side top -fill x
3390 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3391 pack $ui_comm -side left -fill y
3392 pack .vpane.lower.commarea.buffer -side left -fill y
3393
3394 # -- Commit Message Buffer Context Menu
3395 #
3396 set ctxm .vpane.lower.commarea.buffer.ctxm
3397 menu $ctxm -tearoff 0
3398 $ctxm add command \
3399         -label {Cut} \
3400         -font font_ui \
3401         -command {tk_textCut $ui_comm}
3402 $ctxm add command \
3403         -label {Copy} \
3404         -font font_ui \
3405         -command {tk_textCopy $ui_comm}
3406 $ctxm add command \
3407         -label {Paste} \
3408         -font font_ui \
3409         -command {tk_textPaste $ui_comm}
3410 $ctxm add command \
3411         -label {Delete} \
3412         -font font_ui \
3413         -command {$ui_comm delete sel.first sel.last}
3414 $ctxm add separator
3415 $ctxm add command \
3416         -label {Select All} \
3417         -font font_ui \
3418         -command {$ui_comm tag add sel 0.0 end}
3419 $ctxm add command \
3420         -label {Copy All} \
3421         -font font_ui \
3422         -command {
3423                 $ui_comm tag add sel 0.0 end
3424                 tk_textCopy $ui_comm
3425                 $ui_comm tag remove sel 0.0 end
3426         }
3427 $ctxm add separator
3428 $ctxm add command \
3429         -label {Sign Off} \
3430         -font font_ui \
3431         -command do_signoff
3432 bind_button3 $ui_comm "tk_popup $ctxm %X %Y"
3433
3434 # -- Diff Header
3435 #
3436 set current_diff {}
3437 set diff_actions [list]
3438 proc trace_current_diff {varname args} {
3439         global current_diff diff_actions file_states
3440         if {$current_diff eq {}} {
3441                 set s {}
3442                 set f {}
3443                 set p {}
3444                 set o disabled
3445         } else {
3446                 set p $current_diff
3447                 set s [mapdesc [lindex $file_states($p) 0] $p]
3448                 set f {File:}
3449                 set p [escape_path $p]
3450                 set o normal
3451         }
3452
3453         .vpane.lower.diff.header.status configure -text $s
3454         .vpane.lower.diff.header.file configure -text $f
3455         .vpane.lower.diff.header.path configure -text $p
3456         foreach w $diff_actions {
3457                 uplevel #0 $w $o
3458         }
3459 }
3460 trace add variable current_diff write trace_current_diff
3461
3462 frame .vpane.lower.diff.header -background orange
3463 label .vpane.lower.diff.header.status \
3464         -background orange \
3465         -width $max_status_desc \
3466         -anchor w \
3467         -justify left \
3468         -font font_ui
3469 label .vpane.lower.diff.header.file \
3470         -background orange \
3471         -anchor w \
3472         -justify left \
3473         -font font_ui
3474 label .vpane.lower.diff.header.path \
3475         -background orange \
3476         -anchor w \
3477         -justify left \
3478         -font font_ui
3479 pack .vpane.lower.diff.header.status -side left
3480 pack .vpane.lower.diff.header.file -side left
3481 pack .vpane.lower.diff.header.path -fill x
3482 set ctxm .vpane.lower.diff.header.ctxm
3483 menu $ctxm -tearoff 0
3484 $ctxm add command \
3485         -label {Copy} \
3486         -font font_ui \
3487         -command {
3488                 clipboard clear
3489                 clipboard append \
3490                         -format STRING \
3491                         -type STRING \
3492                         -- $current_diff
3493         }
3494 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3495 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3496
3497 # -- Diff Body
3498 #
3499 frame .vpane.lower.diff.body
3500 set ui_diff .vpane.lower.diff.body.t
3501 text $ui_diff -background white -borderwidth 0 \
3502         -width 80 -height 15 -wrap none \
3503         -font font_diff \
3504         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3505         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3506         -state disabled
3507 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3508         -command [list $ui_diff xview]
3509 scrollbar .vpane.lower.diff.body.sby -orient vertical \
3510         -command [list $ui_diff yview]
3511 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3512 pack .vpane.lower.diff.body.sby -side right -fill y
3513 pack $ui_diff -side left -fill both -expand 1
3514 pack .vpane.lower.diff.header -side top -fill x
3515 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3516
3517 $ui_diff tag conf d_@ -font font_diffbold
3518 $ui_diff tag conf d_+  -foreground blue
3519 $ui_diff tag conf d_-  -foreground red
3520 $ui_diff tag conf d_++ -foreground {#00a000}
3521 $ui_diff tag conf d_-- -foreground {#a000a0}
3522 $ui_diff tag conf d_+- \
3523         -foreground red \
3524         -background {light goldenrod yellow}
3525 $ui_diff tag conf d_-+ \
3526         -foreground blue \
3527         -background azure2
3528
3529 # -- Diff Body Context Menu
3530 #
3531 set ctxm .vpane.lower.diff.body.ctxm
3532 menu $ctxm -tearoff 0
3533 $ctxm add command \
3534         -label {Copy} \
3535         -font font_ui \
3536         -command {tk_textCopy $ui_diff}
3537 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3538 $ctxm add command \
3539         -label {Select All} \
3540         -font font_ui \
3541         -command {$ui_diff tag add sel 0.0 end}
3542 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3543 $ctxm add command \
3544         -label {Copy All} \
3545         -font font_ui \
3546         -command {
3547                 $ui_diff tag add sel 0.0 end
3548                 tk_textCopy $ui_diff
3549                 $ui_diff tag remove sel 0.0 end
3550         }
3551 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3552 $ctxm add separator
3553 $ctxm add command \
3554         -label {Decrease Font Size} \
3555         -font font_ui \
3556         -command {incr_font_size font_diff -1}
3557 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3558 $ctxm add command \
3559         -label {Increase Font Size} \
3560         -font font_ui \
3561         -command {incr_font_size font_diff 1}
3562 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3563 $ctxm add separator
3564 $ctxm add command \
3565         -label {Show Less Context} \
3566         -font font_ui \
3567         -command {if {$repo_config(gui.diffcontext) >= 2} {
3568                 incr repo_config(gui.diffcontext) -1
3569                 reshow_diff
3570         }}
3571 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3572 $ctxm add command \
3573         -label {Show More Context} \
3574         -font font_ui \
3575         -command {
3576                 incr repo_config(gui.diffcontext)
3577                 reshow_diff
3578         }
3579 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3580 $ctxm add separator
3581 $ctxm add command -label {Options...} \
3582         -font font_ui \
3583         -command do_options
3584 bind_button3 $ui_diff "tk_popup $ctxm %X %Y"
3585
3586 # -- Status Bar
3587 #
3588 set ui_status_value {Initializing...}
3589 label .status -textvariable ui_status_value \
3590         -anchor w \
3591         -justify left \
3592         -borderwidth 1 \
3593         -relief sunken \
3594         -font font_ui
3595 pack .status -anchor w -side bottom -fill x
3596
3597 # -- Load geometry
3598 #
3599 catch {
3600 set gm $repo_config(gui.geometry)
3601 wm geometry . [lindex $gm 0]
3602 .vpane sash place 0 \
3603         [lindex [.vpane sash coord 0] 0] \
3604         [lindex $gm 1]
3605 .vpane.files sash place 0 \
3606         [lindex $gm 2] \
3607         [lindex [.vpane.files sash coord 0] 1]
3608 unset gm
3609 }
3610
3611 # -- Key Bindings
3612 #
3613 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3614 bind $ui_comm <$M1B-Key-i> {do_include_all;break}
3615 bind $ui_comm <$M1B-Key-I> {do_include_all;break}
3616 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3617 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3618 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3619 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3620 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3621 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3622 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3623 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3624
3625 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3626 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3627 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3628 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3629 bind $ui_diff <$M1B-Key-v> {break}
3630 bind $ui_diff <$M1B-Key-V> {break}
3631 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3632 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3633 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3634 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3635 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3636 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3637
3638 bind .   <Destroy> do_quit
3639 bind all <Key-F5> do_rescan
3640 bind all <$M1B-Key-r> do_rescan
3641 bind all <$M1B-Key-R> do_rescan
3642 bind .   <$M1B-Key-s> do_signoff
3643 bind .   <$M1B-Key-S> do_signoff
3644 bind .   <$M1B-Key-i> do_include_all
3645 bind .   <$M1B-Key-I> do_include_all
3646 bind .   <$M1B-Key-Return> do_commit
3647 bind all <$M1B-Key-q> do_quit
3648 bind all <$M1B-Key-Q> do_quit
3649 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
3650 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
3651 foreach i [list $ui_index $ui_other] {
3652         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3653         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3654         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3655 }
3656 unset i
3657
3658 set file_lists($ui_index) [list]
3659 set file_lists($ui_other) [list]
3660
3661 set HEAD {}
3662 set PARENT {}
3663 set MERGE_HEAD [list]
3664 set commit_type {}
3665 set empty_tree {}
3666 set current_branch {}
3667 set current_diff {}
3668 set selected_commit_type new
3669
3670 wm title . "$appname ([file normalize [file dirname $gitdir]])"
3671 focus -force $ui_comm
3672
3673 # -- Warn the user about environmental problems.  Cygwin's Tcl
3674 #    does *not* pass its env array onto any processes it spawns.
3675 #    This means that git processes get none of our environment.
3676 #
3677 if {[is_Windows]} {
3678         set ignored_env 0
3679         set suggest_user {}
3680         set msg "Possible environment issues exist.
3681
3682 The following environment variables are probably
3683 going to be ignored by any Git subprocess run
3684 by $appname:
3685
3686 "
3687         foreach name [array names env] {
3688                 switch -regexp -- $name {
3689                 {^GIT_INDEX_FILE$} -
3690                 {^GIT_OBJECT_DIRECTORY$} -
3691                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3692                 {^GIT_DIFF_OPTS$} -
3693                 {^GIT_EXTERNAL_DIFF$} -
3694                 {^GIT_PAGER$} -
3695                 {^GIT_TRACE$} -
3696                 {^GIT_CONFIG$} -
3697                 {^GIT_CONFIG_LOCAL$} -
3698                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3699                         append msg " - $name\n"
3700                         incr ignored_env
3701                 }
3702                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3703                         append msg " - $name\n"
3704                         incr ignored_env
3705                         set suggest_user $name
3706                 }
3707                 }
3708         }
3709         if {$ignored_env > 0} {
3710                 append msg "
3711 This is due to a known issue with the
3712 Tcl binary distributed by Cygwin."
3713
3714                 if {$suggest_user ne {}} {
3715                         append msg "
3716
3717 A good replacement for $suggest_user
3718 is placing values for the user.name and
3719 user.email settings into your personal
3720 ~/.gitconfig file.
3721 "
3722                 }
3723                 warn_popup $msg
3724         }
3725         unset ignored_env msg suggest_user name
3726 }
3727
3728 # -- Only initialize complex UI if we are going to stay running.
3729 #
3730 if {!$single_commit} {
3731         load_all_remotes
3732         load_all_heads
3733
3734         populate_branch_menu .mbar.branch
3735         populate_fetch_menu .mbar.fetch
3736         populate_pull_menu .mbar.pull
3737         populate_push_menu .mbar.push
3738 }
3739
3740 lock_index begin-read
3741 after 1 do_rescan