git-gui

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3 exec wish "$0" -- "$@"
   4
   5 set copyright {
   6 Copyright © 2006 Shawn Pearce, Paul Mackerras.
   7
   8 All rights reserved.
   9
  10 This program is free software; it may be used, copied, modified
  11 and distributed under the terms of the GNU General Public Licence,
  12 either version 2, or (at your option) any later version.}
  13
  14 set appname [lindex [file split $argv0] end]
  15 set gitdir {}
  16
  17 ######################################################################
  18 ##
  19 ## config
  20
  21 proc is_many_config {name} {
  22         switch -glob -- $name {
  23         remote.*.fetch -
  24         remote.*.push
  25                 {return 1}
  26         *
  27                 {return 0}
  28         }
  29 }
  30
  31 proc load_config {include_global} {
  32         global repo_config global_config default_config
  33
  34         array unset global_config
  35         if {$include_global} {
  36                 catch {
  37                         set fd_rc [open "| git repo-config --global --list" r]
  38                         while {[gets $fd_rc line] >= 0} {
  39                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  40                                         if {[is_many_config $name]} {
  41                                                 lappend global_config($name) $value
  42                                         } else {
  43                                                 set global_config($name) $value
  44                                         }
  45                                 }
  46                         }
  47                         close $fd_rc
  48                 }
  49         }
  50
  51         array unset repo_config
  52         catch {
  53                 set fd_rc [open "| git repo-config --list" r]
  54                 while {[gets $fd_rc line] >= 0} {
  55                         if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  56                                 if {[is_many_config $name]} {
  57                                         lappend repo_config($name) $value
  58                                 } else {
  59                                         set repo_config($name) $value
  60                                 }
  61                         }
  62                 }
  63                 close $fd_rc
  64         }
  65
  66         foreach name [array names default_config] {
  67                 if {[catch {set v $global_config($name)}]} {
  68                         set global_config($name) $default_config($name)
  69                 }
  70                 if {[catch {set v $repo_config($name)}]} {
  71                         set repo_config($name) $default_config($name)
  72                 }
  73         }
  74 }
  75
  76 proc save_config {} {
  77         global default_config font_descs
  78         global repo_config global_config
  79         global repo_config_new global_config_new
  80
  81         foreach option $font_descs {
  82                 set name [lindex $option 0]
  83                 set font [lindex $option 1]
  84                 font configure $font \
  85                         -family $global_config_new(gui.$font^^family) \
  86                         -size $global_config_new(gui.$font^^size)
  87                 font configure ${font}bold \
  88                         -family $global_config_new(gui.$font^^family) \
  89                         -size $global_config_new(gui.$font^^size)
  90                 set global_config_new(gui.$name) [font configure $font]
  91                 unset global_config_new(gui.$font^^family)
  92                 unset global_config_new(gui.$font^^size)
  93         }
  94
  95         foreach name [array names default_config] {
  96                 set value $global_config_new($name)
  97                 if {$value ne $global_config($name)} {
  98                         if {$value eq $default_config($name)} {
  99                                 catch {exec git repo-config --global --unset $name}
 100                         } else {
 101                                 regsub -all "\[{}\]" $value {"} value
 102                                 exec git repo-config --global $name $value
 103                         }
 104                         set global_config($name) $value
 105                         if {$value eq $repo_config($name)} {
 106                                 catch {exec git repo-config --unset $name}
 107                                 set repo_config($name) $value
 108                         }
 109                 }
 110         }
 111
 112         foreach name [array names default_config] {
 113                 set value $repo_config_new($name)
 114                 if {$value ne $repo_config($name)} {
 115                         if {$value eq $global_config($name)} {
 116                                 catch {exec git repo-config --unset $name}
 117                         } else {
 118                                 regsub -all "\[{}\]" $value {"} value
 119                                 exec git repo-config $name $value
 120                         }
 121                         set repo_config($name) $value
 122                 }
 123         }
 124 }
 125
 126 proc error_popup {msg} {
 127         global gitdir appname
 128
 129         set title $appname
 130         if {$gitdir ne {}} {
 131                 append title { (}
 132                 append title [lindex \
 133                         [file split [file normalize [file dirname $gitdir]]] \
 134                         end]
 135                 append title {)}
 136         }
 137         set cmd [list tk_messageBox \
 138                 -icon error \
 139                 -type ok \
 140                 -title "$title: error" \
 141                 -message $msg]
 142         if {[winfo ismapped .]} {
 143                 lappend cmd -parent .
 144         }
 145         eval $cmd
 146 }
 147
 148 proc warn_popup {msg} {
 149         global gitdir appname
 150
 151         set title $appname
 152         if {$gitdir ne {}} {
 153                 append title { (}
 154                 append title [lindex \
 155                         [file split [file normalize [file dirname $gitdir]]] \
 156                         end]
 157                 append title {)}
 158         }
 159         set cmd [list tk_messageBox \
 160                 -icon warning \
 161                 -type ok \
 162                 -title "$title: warning" \
 163                 -message $msg]
 164         if {[winfo ismapped .]} {
 165                 lappend cmd -parent .
 166         }
 167         eval $cmd
 168 }
 169
 170 proc info_popup {msg} {
 171         global gitdir appname
 172
 173         set title $appname
 174         if {$gitdir ne {}} {
 175                 append title { (}
 176                 append title [lindex \
 177                         [file split [file normalize [file dirname $gitdir]]] \
 178                         end]
 179                 append title {)}
 180         }
 181         tk_messageBox \
 182                 -parent . \
 183                 -icon info \
 184                 -type ok \
 185                 -title $title \
 186                 -message $msg
 187 }
 188
 189 ######################################################################
 190 ##
 191 ## repository setup
 192
 193 if {   [catch {set gitdir $env(GIT_DIR)}]
 194         && [catch {set gitdir [exec git rev-parse --git-dir]} err]} {
 195         catch {wm withdraw .}
 196         error_popup "Cannot find the git directory:\n\n$err"
 197         exit 1
 198 }
 199 if {![file isdirectory $gitdir]} {
 200         catch {wm withdraw .}
 201         error_popup "Git directory not found:\n\n$gitdir"
 202         exit 1
 203 }
 204 if {[lindex [file split $gitdir] end] ne {.git}} {
 205         catch {wm withdraw .}
 206         error_popup "Cannot use funny .git directory:\n\n$gitdir"
 207         exit 1
 208 }
 209 if {[catch {cd [file dirname $gitdir]} err]} {
 210         catch {wm withdraw .}
 211         error_popup "No working directory [file dirname $gitdir]:\n\n$err"
 212         exit 1
 213 }
 214
 215 set single_commit 0
 216 if {$appname eq {git-citool}} {
 217         set single_commit 1
 218 }
 219
 220 ######################################################################
 221 ##
 222 ## task management
 223
 224 set rescan_active 0
 225 set diff_active 0
 226 set last_clicked {}
 227
 228 set disable_on_lock [list]
 229 set index_lock_type none
 230
 231 proc lock_index {type} {
 232         global index_lock_type disable_on_lock
 233
 234         if {$index_lock_type eq {none}} {
 235                 set index_lock_type $type
 236                 foreach w $disable_on_lock {
 237                         uplevel #0 $w disabled
 238                 }
 239                 return 1
 240         } elseif {$index_lock_type eq "begin-$type"} {
 241                 set index_lock_type $type
 242                 return 1
 243         }
 244         return 0
 245 }
 246
 247 proc unlock_index {} {
 248         global index_lock_type disable_on_lock
 249
 250         set index_lock_type none
 251         foreach w $disable_on_lock {
 252                 uplevel #0 $w normal
 253         }
 254 }
 255
 256 ######################################################################
 257 ##
 258 ## status
 259
 260 proc repository_state {ctvar hdvar mhvar} {
 261         global gitdir current_branch
 262         upvar $ctvar ct $hdvar hd $mhvar mh
 263
 264         set mh [list]
 265
 266         if {[catch {set current_branch [exec git symbolic-ref HEAD]}]} {
 267                 set current_branch {}
 268         } else {
 269                 regsub ^refs/((heads|tags|remotes)/)? \
 270                         $current_branch \
 271                         {} \
 272                         current_branch
 273         }
 274
 275         if {[catch {set hd [exec git rev-parse --verify HEAD]}]} {
 276                 set hd {}
 277                 set ct initial
 278                 return
 279         }
 280
 281         set merge_head [file join $gitdir MERGE_HEAD]
 282         if {[file exists $merge_head]} {
 283                 set ct merge
 284                 set fd_mh [open $merge_head r]
 285                 while {[gets $fd_mh line] >= 0} {
 286                         lappend mh $line
 287                 }
 288                 close $fd_mh
 289                 return
 290         }
 291
 292         set ct normal
 293 }
 294
 295 proc PARENT {} {
 296         global PARENT empty_tree
 297
 298         set p [lindex $PARENT 0]
 299         if {$p ne {}} {
 300                 return $p
 301         }
 302         if {$empty_tree eq {}} {
 303                 set empty_tree [exec git mktree << {}]
 304         }
 305         return $empty_tree
 306 }
 307
 308 proc rescan {after} {
 309         global HEAD PARENT MERGE_HEAD commit_type
 310         global ui_index ui_other ui_status_value ui_comm
 311         global rescan_active file_states
 312         global repo_config
 313
 314         if {$rescan_active > 0 || ![lock_index read]} return
 315
 316         repository_state newType newHEAD newMERGE_HEAD
 317         if {[string match amend* $commit_type]
 318                 && $newType eq {normal}
 319                 && $newHEAD eq $HEAD} {
 320         } else {
 321                 set HEAD $newHEAD
 322                 set PARENT $newHEAD
 323                 set MERGE_HEAD $newMERGE_HEAD
 324                 set commit_type $newType
 325         }
 326
 327         array unset file_states
 328
 329         if {![$ui_comm edit modified]
 330                 || [string trim [$ui_comm get 0.0 end]] eq {}} {
 331                 if {[load_message GITGUI_MSG]} {
 332                 } elseif {[load_message MERGE_MSG]} {
 333                 } elseif {[load_message SQUASH_MSG]} {
 334                 }
 335                 $ui_comm edit reset
 336                 $ui_comm edit modified false
 337         }
 338
 339         if {$repo_config(gui.trustmtime) eq {true}} {
 340                 rescan_stage2 {} $after
 341         } else {
 342                 set rescan_active 1
 343                 set ui_status_value {Refreshing file status...}
 344                 set cmd [list git update-index]
 345                 lappend cmd -q
 346                 lappend cmd --unmerged
 347                 lappend cmd --ignore-missing
 348                 lappend cmd --refresh
 349                 set fd_rf [open "| $cmd" r]
 350                 fconfigure $fd_rf -blocking 0 -translation binary
 351                 fileevent $fd_rf readable \
 352                         [list rescan_stage2 $fd_rf $after]
 353         }
 354 }
 355
 356 proc rescan_stage2 {fd after} {
 357         global gitdir ui_status_value
 358         global rescan_active buf_rdi buf_rdf buf_rlo
 359
 360         if {$fd ne {}} {
 361                 read $fd
 362                 if {![eof $fd]} return
 363                 close $fd
 364         }
 365
 366         set ls_others [list | git ls-files --others -z \
 367                 --exclude-per-directory=.gitignore]
 368         set info_exclude [file join $gitdir info exclude]
 369         if {[file readable $info_exclude]} {
 370                 lappend ls_others "--exclude-from=$info_exclude"
 371         }
 372
 373         set buf_rdi {}
 374         set buf_rdf {}
 375         set buf_rlo {}
 376
 377         set rescan_active 3
 378         set ui_status_value {Scanning for modified files ...}
 379         set fd_di [open "| git diff-index --cached -z [PARENT]" r]
 380         set fd_df [open "| git diff-files -z" r]
 381         set fd_lo [open $ls_others r]
 382
 383         fconfigure $fd_di -blocking 0 -translation binary
 384         fconfigure $fd_df -blocking 0 -translation binary
 385         fconfigure $fd_lo -blocking 0 -translation binary
 386         fileevent $fd_di readable [list read_diff_index $fd_di $after]
 387         fileevent $fd_df readable [list read_diff_files $fd_df $after]
 388         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
 389 }
 390
 391 proc load_message {file} {
 392         global gitdir ui_comm
 393
 394         set f [file join $gitdir $file]
 395         if {[file isfile $f]} {
 396                 if {[catch {set fd [open $f r]}]} {
 397                         return 0
 398                 }
 399                 set content [string trim [read $fd]]
 400                 close $fd
 401                 $ui_comm delete 0.0 end
 402                 $ui_comm insert end $content
 403                 return 1
 404         }
 405         return 0
 406 }
 407
 408 proc read_diff_index {fd after} {
 409         global buf_rdi
 410
 411         append buf_rdi [read $fd]
 412         set c 0
 413         set n [string length $buf_rdi]
 414         while {$c < $n} {
 415                 set z1 [string first "\0" $buf_rdi $c]
 416                 if {$z1 == -1} break
 417                 incr z1
 418                 set z2 [string first "\0" $buf_rdi $z1]
 419                 if {$z2 == -1} break
 420
 421                 incr c
 422                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
 423                 merge_state \
 424                         [string range $buf_rdi $z1 [expr {$z2 - 1}]] \
 425                         [lindex $i 4]? \
 426                         [list [lindex $i 0] [lindex $i 2]] \
 427                         [list]
 428                 set c $z2
 429                 incr c
 430         }
 431         if {$c < $n} {
 432                 set buf_rdi [string range $buf_rdi $c end]
 433         } else {
 434                 set buf_rdi {}
 435         }
 436
 437         rescan_done $fd buf_rdi $after
 438 }
 439
 440 proc read_diff_files {fd after} {
 441         global buf_rdf
 442
 443         append buf_rdf [read $fd]
 444         set c 0
 445         set n [string length $buf_rdf]
 446         while {$c < $n} {
 447                 set z1 [string first "\0" $buf_rdf $c]
 448                 if {$z1 == -1} break
 449                 incr z1
 450                 set z2 [string first "\0" $buf_rdf $z1]
 451                 if {$z2 == -1} break
 452
 453                 incr c
 454                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
 455                 merge_state \
 456                         [string range $buf_rdf $z1 [expr {$z2 - 1}]] \
 457                         ?[lindex $i 4] \
 458                         [list] \
 459                         [list [lindex $i 0] [lindex $i 2]]
 460                 set c $z2
 461                 incr c
 462         }
 463         if {$c < $n} {
 464                 set buf_rdf [string range $buf_rdf $c end]
 465         } else {
 466                 set buf_rdf {}
 467         }
 468
 469         rescan_done $fd buf_rdf $after
 470 }
 471
 472 proc read_ls_others {fd after} {
 473         global buf_rlo
 474
 475         append buf_rlo [read $fd]
 476         set pck [split $buf_rlo "\0"]
 477         set buf_rlo [lindex $pck end]
 478         foreach p [lrange $pck 0 end-1] {
 479                 merge_state $p ?O
 480         }
 481         rescan_done $fd buf_rlo $after
 482 }
 483
 484 proc rescan_done {fd buf after} {
 485         global rescan_active
 486         global file_states repo_config
 487         upvar $buf to_clear
 488
 489         if {![eof $fd]} return
 490         set to_clear {}
 491         close $fd
 492         if {[incr rescan_active -1] > 0} return
 493
 494         prune_selection
 495         unlock_index
 496         display_all_files
 497
 498         if {$repo_config(gui.partialinclude) ne {true}} {
 499                 set pathList [list]
 500                 foreach path [array names file_states] {
 501                         switch -- [lindex $file_states($path) 0] {
 502                         AM -
 503                         MM {lappend pathList $path}
 504                         }
 505                 }
 506                 if {$pathList ne {}} {
 507                         update_index \
 508                                 "Updating included files" \
 509                                 $pathList \
 510                                 [concat {reshow_diff;} $after]
 511                         return
 512                 }
 513         }
 514
 515         reshow_diff
 516         uplevel #0 $after
 517 }
 518
 519 proc prune_selection {} {
 520         global file_states selected_paths
 521
 522         foreach path [array names selected_paths] {
 523                 if {[catch {set still_here $file_states($path)}]} {
 524                         unset selected_paths($path)
 525                 }
 526         }
 527 }
 528
 529 ######################################################################
 530 ##
 531 ## diff
 532
 533 proc clear_diff {} {
 534         global ui_diff current_diff ui_index ui_other
 535
 536         $ui_diff conf -state normal
 537         $ui_diff delete 0.0 end
 538         $ui_diff conf -state disabled
 539
 540         set current_diff {}
 541
 542         $ui_index tag remove in_diff 0.0 end
 543         $ui_other tag remove in_diff 0.0 end
 544 }
 545
 546 proc reshow_diff {} {
 547         global current_diff ui_status_value file_states
 548
 549         if {$current_diff eq {}
 550                 || [catch {set s $file_states($current_diff)}]} {
 551                 clear_diff
 552         } else {
 553                 show_diff $current_diff
 554         }
 555 }
 556
 557 proc handle_empty_diff {} {
 558         global current_diff file_states file_lists
 559
 560         set path $current_diff
 561         set s $file_states($path)
 562         if {[lindex $s 0] ne {_M}} return
 563
 564         info_popup "No differences detected.
 565
 566 [short_path $path] has no changes.
 567
 568 The modification date of this file was updated
 569 by another application and you currently have
 570 the Trust File Modification Timestamps option
 571 enabled, so Git did not automatically detect
 572 that there are no content differences in this
 573 file.
 574
 575 This file will now be removed from the modified
 576 files list, to prevent possible confusion.
 577 "
 578         if {[catch {exec git update-index -- $path} err]} {
 579                 error_popup "Failed to refresh index:\n\n$err"
 580         }
 581
 582         clear_diff
 583         set old_w [mapcol [lindex $file_states($path) 0] $path]
 584         set lno [lsearch -sorted $file_lists($old_w) $path]
 585         if {$lno >= 0} {
 586                 set file_lists($old_w) \
 587                         [lreplace $file_lists($old_w) $lno $lno]
 588                 incr lno
 589                 $old_w conf -state normal
 590                 $old_w delete $lno.0 [expr {$lno + 1}].0
 591                 $old_w conf -state disabled
 592         }
 593 }
 594
 595 proc show_diff {path {w {}} {lno {}}} {
 596         global file_states file_lists
 597         global is_3way_diff diff_active repo_config
 598         global ui_diff current_diff ui_status_value
 599
 600         if {$diff_active || ![lock_index read]} return
 601
 602         clear_diff
 603         if {$w eq {} || $lno == {}} {
 604                 foreach w [array names file_lists] {
 605                         set lno [lsearch -sorted $file_lists($w) $path]
 606                         if {$lno >= 0} {
 607                                 incr lno
 608                                 break
 609                         }
 610                 }
 611         }
 612         if {$w ne {} && $lno >= 1} {
 613                 $w tag add in_diff $lno.0 [expr {$lno + 1}].0
 614         }
 615
 616         set s $file_states($path)
 617         set m [lindex $s 0]
 618         set is_3way_diff 0
 619         set diff_active 1
 620         set current_diff $path
 621         set ui_status_value "Loading diff of [escape_path $path]..."
 622
 623         set cmd [list | git diff-index]
 624         lappend cmd --no-color
 625         if {$repo_config(gui.diffcontext) > 0} {
 626                 lappend cmd "-U$repo_config(gui.diffcontext)"
 627         }
 628         lappend cmd -p
 629
 630         switch $m {
 631         MM {
 632                 lappend cmd -c
 633         }
 634         _O {
 635                 if {[catch {
 636                                 set fd [open $path r]
 637                                 set content [read $fd]
 638                                 close $fd
 639                         } err ]} {
 640                         set diff_active 0
 641                         unlock_index
 642                         set ui_status_value "Unable to display [escape_path $path]"
 643                         error_popup "Error loading file:\n\n$err"
 644                         return
 645                 }
 646                 $ui_diff conf -state normal
 647                 $ui_diff insert end $content
 648                 $ui_diff conf -state disabled
 649                 set diff_active 0
 650                 unlock_index
 651                 set ui_status_value {Ready.}
 652                 return
 653         }
 654         }
 655
 656         lappend cmd [PARENT]
 657         lappend cmd --
 658         lappend cmd $path
 659
 660         if {[catch {set fd [open $cmd r]} err]} {
 661                 set diff_active 0
 662                 unlock_index
 663                 set ui_status_value "Unable to display [escape_path $path]"
 664                 error_popup "Error loading diff:\n\n$err"
 665                 return
 666         }
 667
 668         fconfigure $fd -blocking 0 -translation auto
 669         fileevent $fd readable [list read_diff $fd]
 670 }
 671
 672 proc read_diff {fd} {
 673         global ui_diff ui_status_value is_3way_diff diff_active
 674         global repo_config
 675
 676         $ui_diff conf -state normal
 677         while {[gets $fd line] >= 0} {
 678                 # -- Cleanup uninteresting diff header lines.
 679                 #
 680                 if {[string match {diff --git *}      $line]} continue
 681                 if {[string match {diff --combined *} $line]} continue
 682                 if {[string match {--- *}             $line]} continue
 683                 if {[string match {+++ *}             $line]} continue
 684                 if {$line eq {deleted file mode 120000}} {
 685                         set line "deleted symlink"
 686                 }
 687
 688                 # -- Automatically detect if this is a 3 way diff.
 689                 #
 690                 if {[string match {@@@ *} $line]} {set is_3way_diff 1}
 691
 692                 # -- Reformat a 3 way diff, 'cause its too weird.
 693                 #
 694                 if {$is_3way_diff} {
 695                         set op [string range $line 0 1]
 696                         switch -- $op {
 697                         {@@} {set tags d_@}
 698                         {++} {set tags d_+ ; set op { +}}
 699                         {--} {set tags d_- ; set op { -}}
 700                         { +} {set tags d_++; set op {++}}
 701                         { -} {set tags d_--; set op {--}}
 702                         {+ } {set tags d_-+; set op {-+}}
 703                         {- } {set tags d_+-; set op {+-}}
 704                         default {set tags {}}
 705                         }
 706                         set line [string replace $line 0 1 $op]
 707                 } else {
 708                         switch -- [string index $line 0] {
 709                         @ {set tags d_@}
 710                         + {set tags d_+}
 711                         - {set tags d_-}
 712                         default {set tags {}}
 713                         }
 714                 }
 715                 $ui_diff insert end $line $tags
 716                 $ui_diff insert end "\n" $tags
 717         }
 718         $ui_diff conf -state disabled
 719
 720         if {[eof $fd]} {
 721                 close $fd
 722                 set diff_active 0
 723                 unlock_index
 724                 set ui_status_value {Ready.}
 725
 726                 if {$repo_config(gui.trustmtime) eq {true}
 727                         && [$ui_diff index end] eq {2.0}} {
 728                         handle_empty_diff
 729                 }
 730         }
 731 }
 732
 733 ######################################################################
 734 ##
 735 ## commit
 736
 737 proc load_last_commit {} {
 738         global HEAD PARENT MERGE_HEAD commit_type ui_comm
 739
 740         if {[llength $PARENT] == 0} {
 741                 error_popup {There is nothing to amend.
 742
 743 You are about to create the initial commit.
 744 There is no commit before this to amend.
 745 }
 746                 return
 747         }
 748
 749         repository_state curType curHEAD curMERGE_HEAD
 750         if {$curType eq {merge}} {
 751                 error_popup {Cannot amend while merging.
 752
 753 You are currently in the middle of a merge that
 754 has not been fully completed.  You cannot amend
 755 the prior commit unless you first abort the
 756 current merge activity.
 757 }
 758                 return
 759         }
 760
 761         set msg {}
 762         set parents [list]
 763         if {[catch {
 764                         set fd [open "| git cat-file commit $curHEAD" r]
 765                         while {[gets $fd line] > 0} {
 766                                 if {[string match {parent *} $line]} {
 767                                         lappend parents [string range $line 7 end]
 768                                 }
 769                         }
 770                         set msg [string trim [read $fd]]
 771                         close $fd
 772                 } err]} {
 773                 error_popup "Error loading commit data for amend:\n\n$err"
 774                 return
 775         }
 776
 777         set HEAD $curHEAD
 778         set PARENT $parents
 779         set MERGE_HEAD [list]
 780         switch -- [llength $parents] {
 781         0       {set commit_type amend-initial}
 782         1       {set commit_type amend}
 783         default {set commit_type amend-merge}
 784         }
 785
 786         $ui_comm delete 0.0 end
 787         $ui_comm insert end $msg
 788         $ui_comm edit reset
 789         $ui_comm edit modified false
 790         rescan {set ui_status_value {Ready.}}
 791 }
 792
 793 proc create_new_commit {} {
 794         global commit_type ui_comm
 795
 796         set commit_type normal
 797         $ui_comm delete 0.0 end
 798         $ui_comm edit reset
 799         $ui_comm edit modified false
 800         rescan {set ui_status_value {Ready.}}
 801 }
 802
 803 set GIT_COMMITTER_IDENT {}
 804
 805 proc committer_ident {} {
 806         global GIT_COMMITTER_IDENT
 807
 808         if {$GIT_COMMITTER_IDENT eq {}} {
 809                 if {[catch {set me [exec git var GIT_COMMITTER_IDENT]} err]} {
 810                         error_popup "Unable to obtain your identity:\n\n$err"
 811                         return {}
 812                 }
 813                 if {![regexp {^(.*) [0-9]+ [-+0-9]+$} \
 814                         $me me GIT_COMMITTER_IDENT]} {
 815                         error_popup "Invalid GIT_COMMITTER_IDENT:\n\n$me"
 816                         return {}
 817                 }
 818         }
 819
 820         return $GIT_COMMITTER_IDENT
 821 }
 822
 823 proc commit_tree {} {
 824         global HEAD commit_type file_states ui_comm repo_config
 825
 826         if {![lock_index update]} return
 827         if {[committer_ident] eq {}} return
 828
 829         # -- Our in memory state should match the repository.
 830         #
 831         repository_state curType curHEAD curMERGE_HEAD
 832         if {[string match amend* $commit_type]
 833                 && $curType eq {normal}
 834                 && $curHEAD eq $HEAD} {
 835         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
 836                 info_popup {Last scanned state does not match repository state.
 837
 838 Another Git program has modified this repository
 839 since the last scan.  A rescan must be performed
 840 before another commit can be created.
 841
 842 The rescan will be automatically started now.
 843 }
 844                 unlock_index
 845                 rescan {set ui_status_value {Ready.}}
 846                 return
 847         }
 848
 849         # -- At least one file should differ in the index.
 850         #
 851         set files_ready 0
 852         foreach path [array names file_states] {
 853                 switch -glob -- [lindex $file_states($path) 0] {
 854                 _? {continue}
 855                 A? -
 856                 D? -
 857                 M? {set files_ready 1; break}
 858                 U? {
 859                         error_popup "Unmerged files cannot be committed.
 860
 861 File [short_path $path] has merge conflicts.
 862 You must resolve them and include the file before committing.
 863 "
 864                         unlock_index
 865                         return
 866                 }
 867                 default {
 868                         error_popup "Unknown file state [lindex $s 0] detected.
 869
 870 File [short_path $path] cannot be committed by this program.
 871 "
 872                 }
 873                 }
 874         }
 875         if {!$files_ready} {
 876                 error_popup {No included files to commit.
 877
 878 You must include at least 1 file before you can commit.
 879 }
 880                 unlock_index
 881                 return
 882         }
 883
 884         # -- A message is required.
 885         #
 886         set msg [string trim [$ui_comm get 1.0 end]]
 887         if {$msg eq {}} {
 888                 error_popup {Please supply a commit message.
 889
 890 A good commit message has the following format:
 891
 892 - First line: Describe in one sentance what you did.
 893 - Second line: Blank
 894 - Remaining lines: Describe why this change is good.
 895 }
 896                 unlock_index
 897                 return
 898         }
 899
 900         # -- Update included files if partialincludes are off.
 901         #
 902         if {$repo_config(gui.partialinclude) ne {true}} {
 903                 set pathList [list]
 904                 foreach path [array names file_states] {
 905                         switch -glob -- [lindex $file_states($path) 0] {
 906                         A? -
 907                         M? {lappend pathList $path}
 908                         }
 909                 }
 910                 if {$pathList ne {}} {
 911                         unlock_index
 912                         update_index \
 913                                 "Updating included files" \
 914                                 $pathList \
 915                                 [concat {lock_index update;} \
 916                                         [list commit_prehook $curHEAD $msg]]
 917                         return
 918                 }
 919         }
 920
 921         commit_prehook $curHEAD $msg
 922 }
 923
 924 proc commit_prehook {curHEAD msg} {
 925         global gitdir ui_status_value pch_error
 926
 927         set pchook [file join $gitdir hooks pre-commit]
 928
 929         # On Cygwin [file executable] might lie so we need to ask
 930         # the shell if the hook is executable.  Yes that's annoying.
 931         #
 932         if {[is_Windows] && [file isfile $pchook]} {
 933                 set pchook [list sh -c [concat \
 934                         "if test -x \"$pchook\";" \
 935                         "then exec \"$pchook\" 2>&1;" \
 936                         "fi"]]
 937         } elseif {[file executable $pchook]} {
 938                 set pchook [list $pchook |& cat]
 939         } else {
 940                 commit_writetree $curHEAD $msg
 941                 return
 942         }
 943
 944         set ui_status_value {Calling pre-commit hook...}
 945         set pch_error {}
 946         set fd_ph [open "| $pchook" r]
 947         fconfigure $fd_ph -blocking 0 -translation binary
 948         fileevent $fd_ph readable \
 949                 [list commit_prehook_wait $fd_ph $curHEAD $msg]
 950 }
 951
 952 proc commit_prehook_wait {fd_ph curHEAD msg} {
 953         global pch_error ui_status_value
 954
 955         append pch_error [read $fd_ph]
 956         fconfigure $fd_ph -blocking 1
 957         if {[eof $fd_ph]} {
 958                 if {[catch {close $fd_ph}]} {
 959                         set ui_status_value {Commit declined by pre-commit hook.}
 960                         hook_failed_popup pre-commit $pch_error
 961                         unlock_index
 962                 } else {
 963                         commit_writetree $curHEAD $msg
 964                 }
 965                 set pch_error {}
 966                 return
 967         }
 968         fconfigure $fd_ph -blocking 0
 969 }
 970
 971 proc commit_writetree {curHEAD msg} {
 972         global ui_status_value
 973
 974         set ui_status_value {Committing changes...}
 975         set fd_wt [open "| git write-tree" r]
 976         fileevent $fd_wt readable \
 977                 [list commit_committree $fd_wt $curHEAD $msg]
 978 }
 979
 980 proc commit_committree {fd_wt curHEAD msg} {
 981         global HEAD PARENT MERGE_HEAD commit_type
 982         global single_commit gitdir
 983         global ui_status_value ui_comm selected_commit_type
 984         global file_states selected_paths rescan_active
 985
 986         gets $fd_wt tree_id
 987         if {$tree_id eq {} || [catch {close $fd_wt} err]} {
 988                 error_popup "write-tree failed:\n\n$err"
 989                 set ui_status_value {Commit failed.}
 990                 unlock_index
 991                 return
 992         }
 993
 994         # -- Create the commit.
 995         #
 996         set cmd [list git commit-tree $tree_id]
 997         set parents [concat $PARENT $MERGE_HEAD]
 998         if {[llength $parents] > 0} {
 999                 foreach p $parents {
1000                         lappend cmd -p $p
1001                 }
1002         } else {
1003                 # git commit-tree writes to stderr during initial commit.
1004                 lappend cmd 2>/dev/null
1005         }
1006         lappend cmd << $msg
1007         if {[catch {set cmt_id [eval exec $cmd]} err]} {
1008                 error_popup "commit-tree failed:\n\n$err"
1009                 set ui_status_value {Commit failed.}
1010                 unlock_index
1011                 return
1012         }
1013
1014         # -- Update the HEAD ref.
1015         #
1016         set reflogm commit
1017         if {$commit_type ne {normal}} {
1018                 append reflogm " ($commit_type)"
1019         }
1020         set i [string first "\n" $msg]
1021         if {$i >= 0} {
1022                 append reflogm {: } [string range $msg 0 [expr {$i - 1}]]
1023         } else {
1024                 append reflogm {: } $msg
1025         }
1026         set cmd [list git update-ref -m $reflogm HEAD $cmt_id $curHEAD]
1027         if {[catch {eval exec $cmd} err]} {
1028                 error_popup "update-ref failed:\n\n$err"
1029                 set ui_status_value {Commit failed.}
1030                 unlock_index
1031                 return
1032         }
1033
1034         # -- Cleanup after ourselves.
1035         #
1036         catch {file delete [file join $gitdir MERGE_HEAD]}
1037         catch {file delete [file join $gitdir MERGE_MSG]}
1038         catch {file delete [file join $gitdir SQUASH_MSG]}
1039         catch {file delete [file join $gitdir GITGUI_MSG]}
1040
1041         # -- Let rerere do its thing.
1042         #
1043         if {[file isdirectory [file join $gitdir rr-cache]]} {
1044                 catch {exec git rerere}
1045         }
1046
1047         # -- Run the post-commit hook.
1048         #
1049         set pchook [file join $gitdir hooks post-commit]
1050         if {[is_Windows] && [file isfile $pchook]} {
1051                 set pchook [list sh -c [concat \
1052                         "if test -x \"$pchook\";" \
1053                         "then exec \"$pchook\";" \
1054                         "fi"]]
1055         } elseif {![file executable $pchook]} {
1056                 set pchook {}
1057         }
1058         if {$pchook ne {}} {
1059                 catch {exec $pchook &}
1060         }
1061
1062         $ui_comm delete 0.0 end
1063         $ui_comm edit reset
1064         $ui_comm edit modified false
1065
1066         if {$single_commit} do_quit
1067
1068         # -- Update in memory status
1069         #
1070         set selected_commit_type new
1071         set commit_type normal
1072         set HEAD $cmt_id
1073         set PARENT $cmt_id
1074         set MERGE_HEAD [list]
1075
1076         foreach path [array names file_states] {
1077                 set s $file_states($path)
1078                 set m [lindex $s 0]
1079                 switch -glob -- $m {
1080                 _O -
1081                 _M -
1082                 _D {continue}
1083                 __ -
1084                 A_ -
1085                 M_ -
1086                 DD {
1087                         unset file_states($path)
1088                         catch {unset selected_paths($path)}
1089                 }
1090                 DO {
1091                         set file_states($path) [list _O [lindex $s 1] {} {}]
1092                 }
1093                 AM -
1094                 AD -
1095                 MM -
1096                 MD -
1097                 DM {
1098                         set file_states($path) [list \
1099                                 _[string index $m 1] \
1100                                 [lindex $s 1] \
1101                                 [lindex $s 3] \
1102                                 {}]
1103                 }
1104                 }
1105         }
1106
1107         display_all_files
1108         unlock_index
1109         reshow_diff
1110         set ui_status_value \
1111                 "Changes committed as [string range $cmt_id 0 7]."
1112 }
1113
1114 ######################################################################
1115 ##
1116 ## fetch pull push
1117
1118 proc fetch_from {remote} {
1119         set w [new_console "fetch $remote" \
1120                 "Fetching new changes from $remote"]
1121         set cmd [list git fetch]
1122         lappend cmd $remote
1123         console_exec $w $cmd
1124 }
1125
1126 proc pull_remote {remote branch} {
1127         global HEAD commit_type file_states repo_config
1128
1129         if {![lock_index update]} return
1130
1131         # -- Our in memory state should match the repository.
1132         #
1133         repository_state curType curHEAD curMERGE_HEAD
1134         if {$commit_type ne $curType || $HEAD ne $curHEAD} {
1135                 info_popup {Last scanned state does not match repository state.
1136
1137 Another Git program has modified this repository
1138 since the last scan.  A rescan must be performed
1139 before a pull operation can be started.
1140
1141 The rescan will be automatically started now.
1142 }
1143                 unlock_index
1144                 rescan {set ui_status_value {Ready.}}
1145                 return
1146         }
1147
1148         # -- No differences should exist before a pull.
1149         #
1150         if {[array size file_states] != 0} {
1151                 error_popup {Uncommitted but modified files are present.
1152
1153 You should not perform a pull with unmodified
1154 files in your working directory as Git will be
1155 unable to recover from an incorrect merge.
1156
1157 You should commit or revert all changes before
1158 starting a pull operation.
1159 }
1160                 unlock_index
1161                 return
1162         }
1163
1164         set w [new_console "pull $remote $branch" \
1165                 "Pulling new changes from branch $branch in $remote"]
1166         set cmd [list git pull]
1167         if {$repo_config(gui.pullsummary) eq {false}} {
1168                 lappend cmd --no-summary
1169         }
1170         lappend cmd $remote
1171         lappend cmd $branch
1172         console_exec $w $cmd [list post_pull_remote $remote $branch]
1173 }
1174
1175 proc post_pull_remote {remote branch success} {
1176         global HEAD PARENT MERGE_HEAD commit_type selected_commit_type
1177         global ui_status_value
1178
1179         unlock_index
1180         if {$success} {
1181                 repository_state commit_type HEAD MERGE_HEAD
1182                 set PARENT $HEAD
1183                 set selected_commit_type new
1184                 set ui_status_value "Pulling $branch from $remote complete."
1185         } else {
1186                 rescan [list set ui_status_value \
1187                         "Conflicts detected while pulling $branch from $remote."]
1188         }
1189 }
1190
1191 proc push_to {remote} {
1192         set w [new_console "push $remote" \
1193                 "Pushing changes to $remote"]
1194         set cmd [list git push]
1195         lappend cmd $remote
1196         console_exec $w $cmd
1197 }
1198
1199 ######################################################################
1200 ##
1201 ## ui helpers
1202
1203 proc mapcol {state path} {
1204         global all_cols ui_other
1205
1206         if {[catch {set r $all_cols($state)}]} {
1207                 puts "error: no column for state={$state} $path"
1208                 return $ui_other
1209         }
1210         return $r
1211 }
1212
1213 proc mapicon {state path} {
1214         global all_icons
1215
1216         if {[catch {set r $all_icons($state)}]} {
1217                 puts "error: no icon for state={$state} $path"
1218                 return file_plain
1219         }
1220         return $r
1221 }
1222
1223 proc mapdesc {state path} {
1224         global all_descs
1225
1226         if {[catch {set r $all_descs($state)}]} {
1227                 puts "error: no desc for state={$state} $path"
1228                 return $state
1229         }
1230         return $r
1231 }
1232
1233 proc escape_path {path} {
1234         regsub -all "\n" $path "\\n" path
1235         return $path
1236 }
1237
1238 proc short_path {path} {
1239         return [escape_path [lindex [file split $path] end]]
1240 }
1241
1242 set next_icon_id 0
1243 set null_sha1 [string repeat 0 40]
1244
1245 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1246         global file_states next_icon_id null_sha1
1247
1248         set s0 [string index $new_state 0]
1249         set s1 [string index $new_state 1]
1250
1251         if {[catch {set info $file_states($path)}]} {
1252                 set state __
1253                 set icon n[incr next_icon_id]
1254         } else {
1255                 set state [lindex $info 0]
1256                 set icon [lindex $info 1]
1257                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1258                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1259         }
1260
1261         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1262         elseif {$s0 eq {_}} {set s0 _}
1263
1264         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1265         elseif {$s1 eq {_}} {set s1 _}
1266
1267         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1268                 set head_info [list 0 $null_sha1]
1269         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1270                 && $head_info eq {}} {
1271                 set head_info $index_info
1272         }
1273
1274         set file_states($path) [list $s0$s1 $icon \
1275                 $head_info $index_info \
1276                 ]
1277         return $state
1278 }
1279
1280 proc display_file {path state} {
1281         global file_states file_lists selected_paths
1282
1283         set old_m [merge_state $path $state]
1284         set s $file_states($path)
1285         set new_m [lindex $s 0]
1286         set new_w [mapcol $new_m $path]
1287         set old_w [mapcol $old_m $path]
1288         set new_icon [mapicon $new_m $path]
1289
1290         if {$new_m eq {__}} {
1291                 set lno [lsearch -sorted $file_lists($old_w) $path]
1292                 if {$lno >= 0} {
1293                         set file_lists($old_w) \
1294                                 [lreplace $file_lists($old_w) $lno $lno]
1295                         incr lno
1296                         $old_w conf -state normal
1297                         $old_w delete $lno.0 [expr {$lno + 1}].0
1298                         $old_w conf -state disabled
1299                 }
1300                 unset file_states($path)
1301                 catch {unset selected_paths($path)}
1302                 return
1303         }
1304
1305         if {$new_w ne $old_w} {
1306                 set lno [lsearch -sorted $file_lists($old_w) $path]
1307                 if {$lno >= 0} {
1308                         set file_lists($old_w) \
1309                                 [lreplace $file_lists($old_w) $lno $lno]
1310                         incr lno
1311                         $old_w conf -state normal
1312                         $old_w delete $lno.0 [expr {$lno + 1}].0
1313                         $old_w conf -state disabled
1314                 }
1315
1316                 lappend file_lists($new_w) $path
1317                 set file_lists($new_w) [lsort $file_lists($new_w)]
1318                 set lno [lsearch -sorted $file_lists($new_w) $path]
1319                 incr lno
1320                 $new_w conf -state normal
1321                 $new_w image create $lno.0 \
1322                         -align center -padx 5 -pady 1 \
1323                         -name [lindex $s 1] \
1324                         -image $new_icon
1325                 $new_w insert $lno.1 "[escape_path $path]\n"
1326                 if {[catch {set in_sel $selected_paths($path)}]} {
1327                         set in_sel 0
1328                 }
1329                 if {$in_sel} {
1330                         $new_w tag add in_sel $lno.0 [expr {$lno + 1}].0
1331                 }
1332                 $new_w conf -state disabled
1333         } elseif {$new_icon ne [mapicon $old_m $path]} {
1334                 $new_w conf -state normal
1335                 $new_w image conf [lindex $s 1] -image $new_icon
1336                 $new_w conf -state disabled
1337         }
1338 }
1339
1340 proc display_all_files {} {
1341         global ui_index ui_other
1342         global file_states file_lists
1343         global last_clicked selected_paths
1344
1345         $ui_index conf -state normal
1346         $ui_other conf -state normal
1347
1348         $ui_index delete 0.0 end
1349         $ui_other delete 0.0 end
1350         set last_clicked {}
1351
1352         set file_lists($ui_index) [list]
1353         set file_lists($ui_other) [list]
1354
1355         foreach path [lsort [array names file_states]] {
1356                 set s $file_states($path)
1357                 set m [lindex $s 0]
1358                 set w [mapcol $m $path]
1359                 lappend file_lists($w) $path
1360                 set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1361                 $w image create end \
1362                         -align center -padx 5 -pady 1 \
1363                         -name [lindex $s 1] \
1364                         -image [mapicon $m $path]
1365                 $w insert end "[escape_path $path]\n"
1366                 if {[catch {set in_sel $selected_paths($path)}]} {
1367                         set in_sel 0
1368                 }
1369                 if {$in_sel} {
1370                         $w tag add in_sel $lno.0 [expr {$lno + 1}].0
1371                 }
1372         }
1373
1374         $ui_index conf -state disabled
1375         $ui_other conf -state disabled
1376 }
1377
1378 proc update_indexinfo {msg pathList after} {
1379         global update_index_cp ui_status_value
1380
1381         if {![lock_index update]} return
1382
1383         set update_index_cp 0
1384         set pathList [lsort $pathList]
1385         set totalCnt [llength $pathList]
1386         set batch [expr {int($totalCnt * .01) + 1}]
1387         if {$batch > 25} {set batch 25}
1388
1389         set ui_status_value [format \
1390                 "$msg... %i/%i files (%.2f%%)" \
1391                 $update_index_cp \
1392                 $totalCnt \
1393                 0.0]
1394         set fd [open "| git update-index -z --index-info" w]
1395         fconfigure $fd \
1396                 -blocking 0 \
1397                 -buffering full \
1398                 -buffersize 512 \
1399                 -translation binary
1400         fileevent $fd writable [list \
1401                 write_update_indexinfo \
1402                 $fd \
1403                 $pathList \
1404                 $totalCnt \
1405                 $batch \
1406                 $msg \
1407                 $after \
1408                 ]
1409 }
1410
1411 proc write_update_indexinfo {fd pathList totalCnt batch msg after} {
1412         global update_index_cp ui_status_value
1413         global file_states current_diff
1414
1415         if {$update_index_cp >= $totalCnt} {
1416                 close $fd
1417                 unlock_index
1418                 uplevel #0 $after
1419                 return
1420         }
1421
1422         for {set i $batch} \
1423                 {$update_index_cp < $totalCnt && $i > 0} \
1424                 {incr i -1} {
1425                 set path [lindex $pathList $update_index_cp]
1426                 incr update_index_cp
1427
1428                 set s $file_states($path)
1429                 switch -glob -- [lindex $s 0] {
1430                 A? {set new _O}
1431                 M? {set new _M}
1432                 D? {set new _?}
1433                 ?? {continue}
1434                 }
1435                 set info [lindex $s 2]
1436                 if {$info eq {}} continue
1437
1438                 puts -nonewline $fd $info
1439                 puts -nonewline $fd "\t"
1440                 puts -nonewline $fd $path
1441                 puts -nonewline $fd "\0"
1442                 display_file $path $new
1443         }
1444
1445         set ui_status_value [format \
1446                 "$msg... %i/%i files (%.2f%%)" \
1447                 $update_index_cp \
1448                 $totalCnt \
1449                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1450 }
1451
1452 proc update_index {msg pathList after} {
1453         global update_index_cp ui_status_value
1454
1455         if {![lock_index update]} return
1456
1457         set update_index_cp 0
1458         set pathList [lsort $pathList]
1459         set totalCnt [llength $pathList]
1460         set batch [expr {int($totalCnt * .01) + 1}]
1461         if {$batch > 25} {set batch 25}
1462
1463         set ui_status_value [format \
1464                 "$msg... %i/%i files (%.2f%%)" \
1465                 $update_index_cp \
1466                 $totalCnt \
1467                 0.0]
1468         set fd [open "| git update-index --add --remove -z --stdin" w]
1469         fconfigure $fd \
1470                 -blocking 0 \
1471                 -buffering full \
1472                 -buffersize 512 \
1473                 -translation binary
1474         fileevent $fd writable [list \
1475                 write_update_index \
1476                 $fd \
1477                 $pathList \
1478                 $totalCnt \
1479                 $batch \
1480                 $msg \
1481                 $after \
1482                 ]
1483 }
1484
1485 proc write_update_index {fd pathList totalCnt batch msg after} {
1486         global update_index_cp ui_status_value
1487         global file_states current_diff
1488
1489         if {$update_index_cp >= $totalCnt} {
1490                 close $fd
1491                 unlock_index
1492                 uplevel #0 $after
1493                 return
1494         }
1495
1496         for {set i $batch} \
1497                 {$update_index_cp < $totalCnt && $i > 0} \
1498                 {incr i -1} {
1499                 set path [lindex $pathList $update_index_cp]
1500                 incr update_index_cp
1501
1502                 switch -glob -- [lindex $file_states($path) 0] {
1503                 AD -
1504                 MD -
1505                 _D {set new DD}
1506
1507                 _M -
1508                 MM -
1509                 M_ {set new M_}
1510
1511                 _O -
1512                 AM -
1513                 A_ {set new A_}
1514
1515                 ?? {continue}
1516                 }
1517
1518                 puts -nonewline $fd $path
1519                 puts -nonewline $fd "\0"
1520                 display_file $path $new
1521         }
1522
1523         set ui_status_value [format \
1524                 "$msg... %i/%i files (%.2f%%)" \
1525                 $update_index_cp \
1526                 $totalCnt \
1527                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1528 }
1529
1530 proc checkout_index {msg pathList after} {
1531         global update_index_cp ui_status_value
1532
1533         if {![lock_index update]} return
1534
1535         set update_index_cp 0
1536         set pathList [lsort $pathList]
1537         set totalCnt [llength $pathList]
1538         set batch [expr {int($totalCnt * .01) + 1}]
1539         if {$batch > 25} {set batch 25}
1540
1541         set ui_status_value [format \
1542                 "$msg... %i/%i files (%.2f%%)" \
1543                 $update_index_cp \
1544                 $totalCnt \
1545                 0.0]
1546         set cmd [list git checkout-index]
1547         lappend cmd --index
1548         lappend cmd --quiet
1549         lappend cmd --force
1550         lappend cmd -z
1551         lappend cmd --stdin
1552         set fd [open "| $cmd " w]
1553         fconfigure $fd \
1554                 -blocking 0 \
1555                 -buffering full \
1556                 -buffersize 512 \
1557                 -translation binary
1558         fileevent $fd writable [list \
1559                 write_checkout_index \
1560                 $fd \
1561                 $pathList \
1562                 $totalCnt \
1563                 $batch \
1564                 $msg \
1565                 $after \
1566                 ]
1567 }
1568
1569 proc write_checkout_index {fd pathList totalCnt batch msg after} {
1570         global update_index_cp ui_status_value
1571         global file_states current_diff
1572
1573         if {$update_index_cp >= $totalCnt} {
1574                 close $fd
1575                 unlock_index
1576                 uplevel #0 $after
1577                 return
1578         }
1579
1580         for {set i $batch} \
1581                 {$update_index_cp < $totalCnt && $i > 0} \
1582                 {incr i -1} {
1583                 set path [lindex $pathList $update_index_cp]
1584                 incr update_index_cp
1585
1586                 switch -glob -- [lindex $file_states($path) 0] {
1587                 AM -
1588                 AD {set new A_}
1589                 MM -
1590                 MD {set new M_}
1591                 _M -
1592                 _D {set new __}
1593                 ?? {continue}
1594                 }
1595
1596                 puts -nonewline $fd $path
1597                 puts -nonewline $fd "\0"
1598                 display_file $path $new
1599         }
1600
1601         set ui_status_value [format \
1602                 "$msg... %i/%i files (%.2f%%)" \
1603                 $update_index_cp \
1604                 $totalCnt \
1605                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1606 }
1607
1608 ######################################################################
1609 ##
1610 ## branch management
1611
1612 proc load_all_branches {} {
1613         global all_branches
1614
1615         set all_branches [list]
1616         set cmd [list git for-each-ref]
1617         lappend cmd --format=%(refname)
1618         lappend cmd refs/heads
1619         set fd [open "| $cmd" r]
1620         while {[gets $fd line] > 0} {
1621                 if {[regsub ^refs/heads/ $line {} line]} {
1622                         lappend all_branches $line
1623                 }
1624         }
1625         close $fd
1626
1627         set all_branches [lsort $all_branches]
1628 }
1629
1630 proc populate_branch_menu {m} {
1631         global all_branches disable_on_lock
1632
1633         $m add separator
1634         foreach b $all_branches {
1635                 $m add radiobutton \
1636                         -label $b \
1637                         -command [list do_switch_branch $b] \
1638                         -variable current_branch \
1639                         -value $b \
1640                         -font font_ui
1641                 lappend disable_on_lock \
1642                         [list $m entryconf [$m index last] -state]
1643         }
1644 }
1645
1646 ######################################################################
1647 ##
1648 ## remote management
1649
1650 proc load_all_remotes {} {
1651         global gitdir all_remotes repo_config
1652
1653         set all_remotes [list]
1654         set rm_dir [file join $gitdir remotes]
1655         if {[file isdirectory $rm_dir]} {
1656                 set all_remotes [concat $all_remotes [glob \
1657                         -types f \
1658                         -tails \
1659                         -nocomplain \
1660                         -directory $rm_dir *]]
1661         }
1662
1663         foreach line [array names repo_config remote.*.url] {
1664                 if {[regexp ^remote\.(.*)\.url\$ $line line name]} {
1665                         lappend all_remotes $name
1666                 }
1667         }
1668
1669         set all_remotes [lsort -unique $all_remotes]
1670 }
1671
1672 proc populate_fetch_menu {m} {
1673         global gitdir all_remotes repo_config
1674
1675         foreach r $all_remotes {
1676                 set enable 0
1677                 if {![catch {set a $repo_config(remote.$r.url)}]} {
1678                         if {![catch {set a $repo_config(remote.$r.fetch)}]} {
1679                                 set enable 1
1680                         }
1681                 } else {
1682                         catch {
1683                                 set fd [open [file join $gitdir remotes $r] r]
1684                                 while {[gets $fd n] >= 0} {
1685                                         if {[regexp {^Pull:[ \t]*([^:]+):} $n]} {
1686                                                 set enable 1
1687                                                 break
1688                                         }
1689                                 }
1690                                 close $fd
1691                         }
1692                 }
1693
1694                 if {$enable} {
1695                         $m add command \
1696                                 -label "Fetch from $r..." \
1697                                 -command [list fetch_from $r] \
1698                                 -font font_ui
1699                 }
1700         }
1701 }
1702
1703 proc populate_push_menu {m} {
1704         global gitdir all_remotes repo_config
1705
1706         foreach r $all_remotes {
1707                 set enable 0
1708                 if {![catch {set a $repo_config(remote.$r.url)}]} {
1709                         if {![catch {set a $repo_config(remote.$r.push)}]} {
1710                                 set enable 1
1711                         }
1712                 } else {
1713                         catch {
1714                                 set fd [open [file join $gitdir remotes $r] r]
1715                                 while {[gets $fd n] >= 0} {
1716                                         if {[regexp {^Push:[ \t]*([^:]+):} $n]} {
1717                                                 set enable 1
1718                                                 break
1719                                         }
1720                                 }
1721                                 close $fd
1722                         }
1723                 }
1724
1725                 if {$enable} {
1726                         $m add command \
1727                                 -label "Push to $r..." \
1728                                 -command [list push_to $r] \
1729                                 -font font_ui
1730                 }
1731         }
1732 }
1733
1734 proc populate_pull_menu {m} {
1735         global gitdir repo_config all_remotes disable_on_lock
1736
1737         foreach remote $all_remotes {
1738                 set rb {}
1739                 if {[array get repo_config remote.$remote.url] ne {}} {
1740                         if {[array get repo_config remote.$remote.fetch] ne {}} {
1741                                 regexp {^([^:]+):} \
1742                                         [lindex $repo_config(remote.$remote.fetch) 0] \
1743                                         line rb
1744                         }
1745                 } else {
1746                         catch {
1747                                 set fd [open [file join $gitdir remotes $remote] r]
1748                                 while {[gets $fd line] >= 0} {
1749                                         if {[regexp {^Pull:[ \t]*([^:]+):} $line line rb]} {
1750                                                 break
1751                                         }
1752                                 }
1753                                 close $fd
1754                         }
1755                 }
1756
1757                 set rb_short $rb
1758                 regsub ^refs/heads/ $rb {} rb_short
1759                 if {$rb_short ne {}} {
1760                         $m add command \
1761                                 -label "Branch $rb_short from $remote..." \
1762                                 -command [list pull_remote $remote $rb] \
1763                                 -font font_ui
1764                         lappend disable_on_lock \
1765                                 [list $m entryconf [$m index last] -state]
1766                 }
1767         }
1768 }
1769
1770 ######################################################################
1771 ##
1772 ## icons
1773
1774 set filemask {
1775 #define mask_width 14
1776 #define mask_height 15
1777 static unsigned char mask_bits[] = {
1778    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1779    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1780    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1781 }
1782
1783 image create bitmap file_plain -background white -foreground black -data {
1784 #define plain_width 14
1785 #define plain_height 15
1786 static unsigned char plain_bits[] = {
1787    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1788    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1789    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1790 } -maskdata $filemask
1791
1792 image create bitmap file_mod -background white -foreground blue -data {
1793 #define mod_width 14
1794 #define mod_height 15
1795 static unsigned char mod_bits[] = {
1796    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1797    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1798    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1799 } -maskdata $filemask
1800
1801 image create bitmap file_fulltick -background white -foreground "#007000" -data {
1802 #define file_fulltick_width 14
1803 #define file_fulltick_height 15
1804 static unsigned char file_fulltick_bits[] = {
1805    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1806    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1807    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1808 } -maskdata $filemask
1809
1810 image create bitmap file_parttick -background white -foreground "#005050" -data {
1811 #define parttick_width 14
1812 #define parttick_height 15
1813 static unsigned char parttick_bits[] = {
1814    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1815    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
1816    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1817 } -maskdata $filemask
1818
1819 image create bitmap file_question -background white -foreground black -data {
1820 #define file_question_width 14
1821 #define file_question_height 15
1822 static unsigned char file_question_bits[] = {
1823    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1824    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1825    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1826 } -maskdata $filemask
1827
1828 image create bitmap file_removed -background white -foreground red -data {
1829 #define file_removed_width 14
1830 #define file_removed_height 15
1831 static unsigned char file_removed_bits[] = {
1832    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1833    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1834    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1835 } -maskdata $filemask
1836
1837 image create bitmap file_merge -background white -foreground blue -data {
1838 #define file_merge_width 14
1839 #define file_merge_height 15
1840 static unsigned char file_merge_bits[] = {
1841    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1842    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1843    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1844 } -maskdata $filemask
1845
1846 set ui_index .vpane.files.index.list
1847 set ui_other .vpane.files.other.list
1848 set max_status_desc 0
1849 foreach i {
1850                 {__ i plain    "Unmodified"}
1851                 {_M i mod      "Modified"}
1852                 {M_ i fulltick "Included in commit"}
1853                 {MM i parttick "Partially included"}
1854                 {MD i question "Included (but gone)"}
1855
1856                 {_O o plain    "Untracked"}
1857                 {A_ o fulltick "Added by commit"}
1858                 {AM o parttick "Partially added"}
1859                 {AD o question "Added (but gone)"}
1860
1861                 {_D i question "Missing"}
1862                 {DD i removed  "Removed by commit"}
1863                 {DO i removed  "Removed (still exists)"}
1864                 {DM i removed  "Removed (but modified)"}
1865
1866                 {UD i merge    "Merge conflicts"}
1867                 {UM i merge    "Merge conflicts"}
1868                 {U_ i merge    "Merge conflicts"}
1869         } {
1870         if {$max_status_desc < [string length [lindex $i 3]]} {
1871                 set max_status_desc [string length [lindex $i 3]]
1872         }
1873         if {[lindex $i 1] eq {i}} {
1874                 set all_cols([lindex $i 0]) $ui_index
1875         } else {
1876                 set all_cols([lindex $i 0]) $ui_other
1877         }
1878         set all_icons([lindex $i 0]) file_[lindex $i 2]
1879         set all_descs([lindex $i 0]) [lindex $i 3]
1880 }
1881 unset filemask i
1882
1883 ######################################################################
1884 ##
1885 ## util
1886
1887 proc is_MacOSX {} {
1888         global tcl_platform tk_library
1889         if {[tk windowingsystem] eq {aqua}} {
1890                 return 1
1891         }
1892         return 0
1893 }
1894
1895 proc is_Windows {} {
1896         global tcl_platform
1897         if {$tcl_platform(platform) eq {windows}} {
1898                 return 1
1899         }
1900         return 0
1901 }
1902
1903 proc bind_button3 {w cmd} {
1904         bind $w <Any-Button-3> $cmd
1905         if {[is_MacOSX]} {
1906                 bind $w <Control-Button-1> $cmd
1907         }
1908 }
1909
1910 proc incr_font_size {font {amt 1}} {
1911         set sz [font configure $font -size]
1912         incr sz $amt
1913         font configure $font -size $sz
1914         font configure ${font}bold -size $sz
1915 }
1916
1917 proc hook_failed_popup {hook msg} {
1918         global gitdir appname
1919
1920         set w .hookfail
1921         toplevel $w
1922
1923         frame $w.m
1924         label $w.m.l1 -text "$hook hook failed:" \
1925                 -anchor w \
1926                 -justify left \
1927                 -font font_uibold
1928         text $w.m.t \
1929                 -background white -borderwidth 1 \
1930                 -relief sunken \
1931                 -width 80 -height 10 \
1932                 -font font_diff \
1933                 -yscrollcommand [list $w.m.sby set]
1934         label $w.m.l2 \
1935                 -text {You must correct the above errors before committing.} \
1936                 -anchor w \
1937                 -justify left \
1938                 -font font_uibold
1939         scrollbar $w.m.sby -command [list $w.m.t yview]
1940         pack $w.m.l1 -side top -fill x
1941         pack $w.m.l2 -side bottom -fill x
1942         pack $w.m.sby -side right -fill y
1943         pack $w.m.t -side left -fill both -expand 1
1944         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
1945
1946         $w.m.t insert 1.0 $msg
1947         $w.m.t conf -state disabled
1948
1949         button $w.ok -text OK \
1950                 -width 15 \
1951                 -font font_ui \
1952                 -command "destroy $w"
1953         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
1954
1955         bind $w <Visibility> "grab $w; focus $w"
1956         bind $w <Key-Return> "destroy $w"
1957         wm title $w "$appname ([lindex [file split \
1958                 [file normalize [file dirname $gitdir]]] \
1959                 end]): error"
1960         tkwait window $w
1961 }
1962
1963 set next_console_id 0
1964
1965 proc new_console {short_title long_title} {
1966         global next_console_id console_data
1967         set w .console[incr next_console_id]
1968         set console_data($w) [list $short_title $long_title]
1969         return [console_init $w]
1970 }
1971
1972 proc console_init {w} {
1973         global console_cr console_data
1974         global gitdir appname M1B
1975
1976         set console_cr($w) 1.0
1977         toplevel $w
1978         frame $w.m
1979         label $w.m.l1 -text "[lindex $console_data($w) 1]:" \
1980                 -anchor w \
1981                 -justify left \
1982                 -font font_uibold
1983         text $w.m.t \
1984                 -background white -borderwidth 1 \
1985                 -relief sunken \
1986                 -width 80 -height 10 \
1987                 -font font_diff \
1988                 -state disabled \
1989                 -yscrollcommand [list $w.m.sby set]
1990         label $w.m.s -text {Working... please wait...} \
1991                 -anchor w \
1992                 -justify left \
1993                 -font font_uibold
1994         scrollbar $w.m.sby -command [list $w.m.t yview]
1995         pack $w.m.l1 -side top -fill x
1996         pack $w.m.s -side bottom -fill x
1997         pack $w.m.sby -side right -fill y
1998         pack $w.m.t -side left -fill both -expand 1
1999         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2000
2001         menu $w.ctxm -tearoff 0
2002         $w.ctxm add command -label "Copy" \
2003                 -font font_ui \
2004                 -command "tk_textCopy $w.m.t"
2005         $w.ctxm add command -label "Select All" \
2006                 -font font_ui \
2007                 -command "$w.m.t tag add sel 0.0 end"
2008         $w.ctxm add command -label "Copy All" \
2009                 -font font_ui \
2010                 -command "
2011                         $w.m.t tag add sel 0.0 end
2012                         tk_textCopy $w.m.t
2013                         $w.m.t tag remove sel 0.0 end
2014                 "
2015
2016         button $w.ok -text {Close} \
2017                 -font font_ui \
2018                 -state disabled \
2019                 -command "destroy $w"
2020         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2021
2022         bind_button3 $w.m.t "tk_popup $w.ctxm %X %Y"
2023         bind $w.m.t <$M1B-Key-a> "$w.m.t tag add sel 0.0 end;break"
2024         bind $w.m.t <$M1B-Key-A> "$w.m.t tag add sel 0.0 end;break"
2025         bind $w <Visibility> "focus $w"
2026         wm title $w "$appname ([lindex [file split \
2027                 [file normalize [file dirname $gitdir]]] \
2028                 end]): [lindex $console_data($w) 0]"
2029         return $w
2030 }
2031
2032 proc console_exec {w cmd {after {}}} {
2033         # -- Windows tosses the enviroment when we exec our child.
2034         #    But most users need that so we have to relogin. :-(
2035         #
2036         if {[is_Windows]} {
2037                 set cmd [list sh --login -c "cd \"[pwd]\" && [join $cmd { }]"]
2038         }
2039
2040         # -- Tcl won't let us redirect both stdout and stderr to
2041         #    the same pipe.  So pass it through cat...
2042         #
2043         set cmd [concat | $cmd |& cat]
2044
2045         set fd_f [open $cmd r]
2046         fconfigure $fd_f -blocking 0 -translation binary
2047         fileevent $fd_f readable [list console_read $w $fd_f $after]
2048 }
2049
2050 proc console_read {w fd after} {
2051         global console_cr console_data
2052
2053         set buf [read $fd]
2054         if {$buf ne {}} {
2055                 if {![winfo exists $w]} {console_init $w}
2056                 $w.m.t conf -state normal
2057                 set c 0
2058                 set n [string length $buf]
2059                 while {$c < $n} {
2060                         set cr [string first "\r" $buf $c]
2061                         set lf [string first "\n" $buf $c]
2062                         if {$cr < 0} {set cr [expr {$n + 1}]}
2063                         if {$lf < 0} {set lf [expr {$n + 1}]}
2064
2065                         if {$lf < $cr} {
2066                                 $w.m.t insert end [string range $buf $c $lf]
2067                                 set console_cr($w) [$w.m.t index {end -1c}]
2068                                 set c $lf
2069                                 incr c
2070                         } else {
2071                                 $w.m.t delete $console_cr($w) end
2072                                 $w.m.t insert end "\n"
2073                                 $w.m.t insert end [string range $buf $c $cr]
2074                                 set c $cr
2075                                 incr c
2076                         }
2077                 }
2078                 $w.m.t conf -state disabled
2079                 $w.m.t see end
2080         }
2081
2082         fconfigure $fd -blocking 1
2083         if {[eof $fd]} {
2084                 if {[catch {close $fd}]} {
2085                         if {![winfo exists $w]} {console_init $w}
2086                         $w.m.s conf -background red -text {Error: Command Failed}
2087                         $w.ok conf -state normal
2088                         set ok 0
2089                 } elseif {[winfo exists $w]} {
2090                         $w.m.s conf -background green -text {Success}
2091                         $w.ok conf -state normal
2092                         set ok 1
2093                 }
2094                 array unset console_cr $w
2095                 array unset console_data $w
2096                 if {$after ne {}} {
2097                         uplevel #0 $after $ok
2098                 }
2099                 return
2100         }
2101         fconfigure $fd -blocking 0
2102 }
2103
2104 ######################################################################
2105 ##
2106 ## ui commands
2107
2108 set starting_gitk_msg {Please wait... Starting gitk...}
2109
2110 proc do_gitk {revs} {
2111         global ui_status_value starting_gitk_msg
2112
2113         set cmd gitk
2114         if {$revs ne {}} {
2115                 append cmd { }
2116                 append cmd $revs
2117         }
2118         if {[is_Windows]} {
2119                 set cmd "sh -c \"exec $cmd\""
2120         }
2121         append cmd { &}
2122
2123         if {[catch {eval exec $cmd} err]} {
2124                 error_popup "Failed to start gitk:\n\n$err"
2125         } else {
2126                 set ui_status_value $starting_gitk_msg
2127                 after 10000 {
2128                         if {$ui_status_value eq $starting_gitk_msg} {
2129                                 set ui_status_value {Ready.}
2130                         }
2131                 }
2132         }
2133 }
2134
2135 proc do_repack {} {
2136         set w [new_console {repack} \
2137                 {Repacking the object database}]
2138         set cmd [list git repack]
2139         lappend cmd -a
2140         lappend cmd -d
2141         console_exec $w $cmd
2142 }
2143
2144 proc do_fsck_objects {} {
2145         set w [new_console {fsck-objects} \
2146                 {Verifying the object database with fsck-objects}]
2147         set cmd [list git fsck-objects]
2148         lappend cmd --full
2149         lappend cmd --cache
2150         lappend cmd --strict
2151         console_exec $w $cmd
2152 }
2153
2154 set is_quitting 0
2155
2156 proc do_quit {} {
2157         global gitdir ui_comm is_quitting repo_config commit_type
2158
2159         if {$is_quitting} return
2160         set is_quitting 1
2161
2162         # -- Stash our current commit buffer.
2163         #
2164         set save [file join $gitdir GITGUI_MSG]
2165         set msg [string trim [$ui_comm get 0.0 end]]
2166         if {![string match amend* $commit_type]
2167                 && [$ui_comm edit modified]
2168                 && $msg ne {}} {
2169                 catch {
2170                         set fd [open $save w]
2171                         puts $fd [string trim [$ui_comm get 0.0 end]]
2172                         close $fd
2173                 }
2174         } else {
2175                 catch {file delete $save}
2176         }
2177
2178         # -- Stash our current window geometry into this repository.
2179         #
2180         set cfg_geometry [list]
2181         lappend cfg_geometry [wm geometry .]
2182         lappend cfg_geometry [lindex [.vpane sash coord 0] 1]
2183         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 0]
2184         if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2185                 set rc_geometry {}
2186         }
2187         if {$cfg_geometry ne $rc_geometry} {
2188                 catch {exec git repo-config gui.geometry $cfg_geometry}
2189         }
2190
2191         destroy .
2192 }
2193
2194 proc do_rescan {} {
2195         rescan {set ui_status_value {Ready.}}
2196 }
2197
2198 proc remove_helper {txt paths} {
2199         global file_states current_diff
2200
2201         if {![lock_index begin-update]} return
2202
2203         set pathList [list]
2204         set after {}
2205         foreach path $paths {
2206                 switch -glob -- [lindex $file_states($path) 0] {
2207                 A? -
2208                 M? -
2209                 D? {
2210                         lappend pathList $path
2211                         if {$path eq $current_diff} {
2212                                 set after {reshow_diff;}
2213                         }
2214                 }
2215                 }
2216         }
2217         if {$pathList eq {}} {
2218                 unlock_index
2219         } else {
2220                 update_indexinfo \
2221                         $txt \
2222                         $pathList \
2223                         [concat $after {set ui_status_value {Ready.}}]
2224         }
2225 }
2226
2227 proc do_remove_selection {} {
2228         global current_diff selected_paths
2229
2230         if {[array size selected_paths] > 0} {
2231                 remove_helper \
2232                         {Removing selected files from commit} \
2233                         [array names selected_paths]
2234         } elseif {$current_diff ne {}} {
2235                 remove_helper \
2236                         "Removing [short_path $current_diff] from commit" \
2237                         [list $current_diff]
2238         }
2239 }
2240
2241 proc include_helper {txt paths} {
2242         global file_states current_diff
2243
2244         if {![lock_index begin-update]} return
2245
2246         set pathList [list]
2247         set after {}
2248         foreach path $paths {
2249                 switch -glob -- [lindex $file_states($path) 0] {
2250                 AM -
2251                 AD -
2252                 MM -
2253                 MD -
2254                 U? -
2255                 _M -
2256                 _D -
2257                 _O {
2258                         lappend pathList $path
2259                         if {$path eq $current_diff} {
2260                                 set after {reshow_diff;}
2261                         }
2262                 }
2263                 }
2264         }
2265         if {$pathList eq {}} {
2266                 unlock_index
2267         } else {
2268                 update_index \
2269                         $txt \
2270                         $pathList \
2271                         [concat $after {set ui_status_value {Ready to commit.}}]
2272         }
2273 }
2274
2275 proc do_include_selection {} {
2276         global current_diff selected_paths
2277
2278         if {[array size selected_paths] > 0} {
2279                 include_helper \
2280                         {Including selected files} \
2281                         [array names selected_paths]
2282         } elseif {$current_diff ne {}} {
2283                 include_helper \
2284                         "Including [short_path $current_diff]" \
2285                         [list $current_diff]
2286         }
2287 }
2288
2289 proc do_include_all {} {
2290         global file_states
2291
2292         set paths [list]
2293         foreach path [array names file_states] {
2294                 switch -- [lindex $file_states($path) 0] {
2295                 AM -
2296                 AD -
2297                 MM -
2298                 MD -
2299                 _M -
2300                 _D {lappend paths $path}
2301                 }
2302         }
2303         include_helper \
2304                 {Including all modified files} \
2305                 $paths
2306 }
2307
2308 proc revert_helper {txt paths} {
2309         global file_states current_diff
2310
2311         if {![lock_index begin-update]} return
2312
2313         set pathList [list]
2314         set after {}
2315         foreach path $paths {
2316                 switch -glob -- [lindex $file_states($path) 0] {
2317                 AM -
2318                 AD -
2319                 MM -
2320                 MD -
2321                 _M -
2322                 _D {
2323                         lappend pathList $path
2324                         if {$path eq $current_diff} {
2325                                 set after {reshow_diff;}
2326                         }
2327                 }
2328                 }
2329         }
2330
2331         set n [llength $pathList]
2332         if {$n == 0} {
2333                 unlock_index
2334                 return
2335         } elseif {$n == 1} {
2336                 set s "[short_path [lindex $pathList]]"
2337         } else {
2338                 set s "these $n files"
2339         }
2340
2341         set reply [tk_dialog \
2342                 .confirm_revert \
2343                 "title" \
2344                 "Revert unincluded changes in $s?
2345
2346 Any unincluded changes will be permanently lost by the revert." \
2347                 questhead \
2348                 1 \
2349                 {Do Nothing} \
2350                 {Revert Changes} \
2351                 ]
2352         if {$reply == 1} {
2353                 checkout_index \
2354                         $txt \
2355                         $pathList \
2356                         [concat $after {set ui_status_value {Ready.}}]
2357         } else {
2358                 unlock_index
2359         }
2360 }
2361
2362 proc do_revert_selection {} {
2363         global current_diff selected_paths
2364
2365         if {[array size selected_paths] > 0} {
2366                 revert_helper \
2367                         {Reverting selected files} \
2368                         [array names selected_paths]
2369         } elseif {$current_diff ne {}} {
2370                 revert_helper \
2371                         "Reverting [short_path $current_diff]" \
2372                         [list $current_diff]
2373         }
2374 }
2375
2376 proc do_signoff {} {
2377         global ui_comm
2378
2379         set me [committer_ident]
2380         if {$me eq {}} return
2381
2382         set sob "Signed-off-by: $me"
2383         set last [$ui_comm get {end -1c linestart} {end -1c}]
2384         if {$last ne $sob} {
2385                 $ui_comm edit separator
2386                 if {$last ne {}
2387                         && ![regexp {^[A-Z][A-Za-z]*-[A-Za-z-]+: *} $last]} {
2388                         $ui_comm insert end "\n"
2389                 }
2390                 $ui_comm insert end "\n$sob"
2391                 $ui_comm edit separator
2392                 $ui_comm see end
2393         }
2394 }
2395
2396 proc do_select_commit_type {} {
2397         global commit_type selected_commit_type
2398
2399         if {$selected_commit_type eq {new}
2400                 && [string match amend* $commit_type]} {
2401                 create_new_commit
2402         } elseif {$selected_commit_type eq {amend}
2403                 && ![string match amend* $commit_type]} {
2404                 load_last_commit
2405
2406                 # The amend request was rejected...
2407                 #
2408                 if {![string match amend* $commit_type]} {
2409                         set selected_commit_type new
2410                 }
2411         }
2412 }
2413
2414 proc do_commit {} {
2415         commit_tree
2416 }
2417
2418 proc do_about {} {
2419         global appname copyright
2420         global tcl_patchLevel tk_patchLevel
2421
2422         set w .about_dialog
2423         toplevel $w
2424         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2425
2426         label $w.header -text "About $appname" \
2427                 -font font_uibold
2428         pack $w.header -side top -fill x
2429
2430         frame $w.buttons
2431         button $w.buttons.close -text {Close} \
2432                 -font font_ui \
2433                 -command [list destroy $w]
2434         pack $w.buttons.close -side right
2435         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2436
2437         label $w.desc \
2438                 -text "$appname - a commit creation tool for Git.
2439 $copyright" \
2440                 -padx 5 -pady 5 \
2441                 -justify left \
2442                 -anchor w \
2443                 -borderwidth 1 \
2444                 -relief solid \
2445                 -font font_ui
2446         pack $w.desc -side top -fill x -padx 5 -pady 5
2447
2448         set v [exec git --version]
2449         append v "\n\n"
2450         if {$tcl_patchLevel eq $tk_patchLevel} {
2451                 append v "Tcl/Tk version $tcl_patchLevel"
2452         } else {
2453                 append v "Tcl version $tcl_patchLevel"
2454                 append v ", Tk version $tk_patchLevel"
2455         }
2456
2457         label $w.vers \
2458                 -text $v \
2459                 -padx 5 -pady 5 \
2460                 -justify left \
2461                 -anchor w \
2462                 -borderwidth 1 \
2463                 -relief solid \
2464                 -font font_ui
2465         pack $w.vers -side top -fill x -padx 5 -pady 5
2466
2467         bind $w <Visibility> "grab $w; focus $w"
2468         bind $w <Key-Escape> "destroy $w"
2469         wm title $w "About $appname"
2470         tkwait window $w
2471 }
2472
2473 proc do_options {} {
2474         global appname gitdir font_descs
2475         global repo_config global_config
2476         global repo_config_new global_config_new
2477
2478         array unset repo_config_new
2479         array unset global_config_new
2480         foreach name [array names repo_config] {
2481                 set repo_config_new($name) $repo_config($name)
2482         }
2483         load_config 1
2484         foreach name [array names repo_config] {
2485                 switch -- $name {
2486                 gui.diffcontext {continue}
2487                 }
2488                 set repo_config_new($name) $repo_config($name)
2489         }
2490         foreach name [array names global_config] {
2491                 set global_config_new($name) $global_config($name)
2492         }
2493         set reponame [lindex [file split \
2494                 [file normalize [file dirname $gitdir]]] \
2495                 end]
2496
2497         set w .options_editor
2498         toplevel $w
2499         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2500
2501         label $w.header -text "$appname Options" \
2502                 -font font_uibold
2503         pack $w.header -side top -fill x
2504
2505         frame $w.buttons
2506         button $w.buttons.restore -text {Restore Defaults} \
2507                 -font font_ui \
2508                 -command do_restore_defaults
2509         pack $w.buttons.restore -side left
2510         button $w.buttons.save -text Save \
2511                 -font font_ui \
2512                 -command [list do_save_config $w]
2513         pack $w.buttons.save -side right
2514         button $w.buttons.cancel -text {Cancel} \
2515                 -font font_ui \
2516                 -command [list destroy $w]
2517         pack $w.buttons.cancel -side right
2518         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2519
2520         labelframe $w.repo -text "$reponame Repository" \
2521                 -font font_ui \
2522                 -relief raised -borderwidth 2
2523         labelframe $w.global -text {Global (All Repositories)} \
2524                 -font font_ui \
2525                 -relief raised -borderwidth 2
2526         pack $w.repo -side left -fill both -expand 1 -pady 5 -padx 5
2527         pack $w.global -side right -fill both -expand 1 -pady 5 -padx 5
2528
2529         foreach option {
2530                 {b partialinclude {Allow Partially Included Files}}
2531                 {b pullsummary {Show Pull Summary}}
2532                 {b trustmtime  {Trust File Modification Timestamps}}
2533                 {i diffcontext {Number of Diff Context Lines}}
2534                 } {
2535                 set type [lindex $option 0]
2536                 set name [lindex $option 1]
2537                 set text [lindex $option 2]
2538                 foreach f {repo global} {
2539                         switch $type {
2540                         b {
2541                                 checkbutton $w.$f.$name -text $text \
2542                                         -variable ${f}_config_new(gui.$name) \
2543                                         -onvalue true \
2544                                         -offvalue false \
2545                                         -font font_ui
2546                                 pack $w.$f.$name -side top -anchor w
2547                         }
2548                         i {
2549                                 frame $w.$f.$name
2550                                 label $w.$f.$name.l -text "$text:" -font font_ui
2551                                 pack $w.$f.$name.l -side left -anchor w -fill x
2552                                 spinbox $w.$f.$name.v \
2553                                         -textvariable ${f}_config_new(gui.$name) \
2554                                         -from 1 -to 99 -increment 1 \
2555                                         -width 3 \
2556                                         -font font_ui
2557                                 pack $w.$f.$name.v -side right -anchor e
2558                                 pack $w.$f.$name -side top -anchor w -fill x
2559                         }
2560                         }
2561                 }
2562         }
2563
2564         set all_fonts [lsort [font families]]
2565         foreach option $font_descs {
2566                 set name [lindex $option 0]
2567                 set font [lindex $option 1]
2568                 set text [lindex $option 2]
2569
2570                 set global_config_new(gui.$font^^family) \
2571                         [font configure $font -family]
2572                 set global_config_new(gui.$font^^size) \
2573                         [font configure $font -size]
2574
2575                 frame $w.global.$name
2576                 label $w.global.$name.l -text "$text:" -font font_ui
2577                 pack $w.global.$name.l -side left -anchor w -fill x
2578                 eval tk_optionMenu $w.global.$name.family \
2579                         global_config_new(gui.$font^^family) \
2580                         $all_fonts
2581                 spinbox $w.global.$name.size \
2582                         -textvariable global_config_new(gui.$font^^size) \
2583                         -from 2 -to 80 -increment 1 \
2584                         -width 3 \
2585                         -font font_ui
2586                 pack $w.global.$name.size -side right -anchor e
2587                 pack $w.global.$name.family -side right -anchor e
2588                 pack $w.global.$name -side top -anchor w -fill x
2589         }
2590
2591         bind $w <Visibility> "grab $w; focus $w"
2592         bind $w <Key-Escape> "destroy $w"
2593         wm title $w "$appname ($reponame): Options"
2594         tkwait window $w
2595 }
2596
2597 proc do_restore_defaults {} {
2598         global font_descs default_config repo_config
2599         global repo_config_new global_config_new
2600
2601         foreach name [array names default_config] {
2602                 set repo_config_new($name) $default_config($name)
2603                 set global_config_new($name) $default_config($name)
2604         }
2605
2606         foreach option $font_descs {
2607                 set name [lindex $option 0]
2608                 set repo_config(gui.$name) $default_config(gui.$name)
2609         }
2610         apply_config
2611
2612         foreach option $font_descs {
2613                 set name [lindex $option 0]
2614                 set font [lindex $option 1]
2615                 set global_config_new(gui.$font^^family) \
2616                         [font configure $font -family]
2617                 set global_config_new(gui.$font^^size) \
2618                         [font configure $font -size]
2619         }
2620 }
2621
2622 proc do_save_config {w} {
2623         if {[catch {save_config} err]} {
2624                 error_popup "Failed to completely save options:\n\n$err"
2625         }
2626         reshow_diff
2627         destroy $w
2628 }
2629
2630 proc do_windows_shortcut {} {
2631         global gitdir appname argv0
2632
2633         set reponame [lindex [file split \
2634                 [file normalize [file dirname $gitdir]]] \
2635                 end]
2636
2637         if {[catch {
2638                 set desktop [exec cygpath \
2639                         --windows \
2640                         --absolute \
2641                         --long-name \
2642                         --desktop]
2643                 }]} {
2644                         set desktop .
2645         }
2646         set fn [tk_getSaveFile \
2647                 -parent . \
2648                 -title "$appname ($reponame): Create Desktop Icon" \
2649                 -initialdir $desktop \
2650                 -initialfile "Git $reponame.bat"]
2651         if {$fn != {}} {
2652                 if {[catch {
2653                                 set fd [open $fn w]
2654                                 set sh [exec cygpath \
2655                                         --windows \
2656                                         --absolute \
2657                                         --long-name \
2658                                         /bin/sh]
2659                                 set me [exec cygpath \
2660                                         --unix \
2661                                         --absolute \
2662                                         $argv0]
2663                                 set gd [exec cygpath \
2664                                         --unix \
2665                                         --absolute \
2666                                         $gitdir]
2667                                 regsub -all ' $me "'\\''" me
2668                                 regsub -all ' $gd "'\\''" gd
2669                                 puts -nonewline $fd "\"$sh\" --login -c \""
2670                                 puts -nonewline $fd "GIT_DIR='$gd'"
2671                                 puts -nonewline $fd " '$me'"
2672                                 puts $fd "&\""
2673                                 close $fd
2674                         } err]} {
2675                         error_popup "Cannot write script:\n\n$err"
2676                 }
2677         }
2678 }
2679
2680 proc do_macosx_app {} {
2681         global gitdir appname argv0 env
2682
2683         set reponame [lindex [file split \
2684                 [file normalize [file dirname $gitdir]]] \
2685                 end]
2686
2687         set fn [tk_getSaveFile \
2688                 -parent . \
2689                 -title "$appname ($reponame): Create Desktop Icon" \
2690                 -initialdir [file join $env(HOME) Desktop] \
2691                 -initialfile "Git $reponame.app"]
2692         if {$fn != {}} {
2693                 if {[catch {
2694                                 set Contents [file join $fn Contents]
2695                                 set MacOS [file join $Contents MacOS]
2696                                 set exe [file join $MacOS git-gui]
2697
2698                                 file mkdir $MacOS
2699
2700                                 set fd [open [file join $Contents Info.plist] w]
2701                                 puts $fd {<?xml version="1.0" encoding="UTF-8"?>
2702 <!DOCTYPE plist PUBLIC "-//Apple Computer//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
2703 <plist version="1.0">
2704 <dict>
2705         <key>CFBundleDevelopmentRegion</key>
2706         <string>English</string>
2707         <key>CFBundleExecutable</key>
2708         <string>git-gui</string>
2709         <key>CFBundleIdentifier</key>
2710         <string>org.spearce.git-gui</string>
2711         <key>CFBundleInfoDictionaryVersion</key>
2712         <string>6.0</string>
2713         <key>CFBundlePackageType</key>
2714         <string>APPL</string>
2715         <key>CFBundleSignature</key>
2716         <string>????</string>
2717         <key>CFBundleVersion</key>
2718         <string>1.0</string>
2719         <key>NSPrincipalClass</key>
2720         <string>NSApplication</string>
2721 </dict>
2722 </plist>}
2723                                 close $fd
2724
2725                                 set fd [open $exe w]
2726                                 set gd [file normalize $gitdir]
2727                                 set ep [file normalize [exec git --exec-path]]
2728                                 regsub -all ' $gd "'\\''" gd
2729                                 regsub -all ' $ep "'\\''" ep
2730                                 puts $fd "#!/bin/sh"
2731                                 foreach name [array names env] {
2732                                         if {[string match GIT_* $name]} {
2733                                                 regsub -all ' $env($name) "'\\''" v
2734                                                 puts $fd "export $name='$v'"
2735                                         }
2736                                 }
2737                                 puts $fd "export PATH='$ep':\$PATH"
2738                                 puts $fd "export GIT_DIR='$gd'"
2739                                 puts $fd "exec [file normalize $argv0]"
2740                                 close $fd
2741
2742                                 file attributes $exe -permissions u+x,g+x,o+x
2743                         } err]} {
2744                         error_popup "Cannot write icon:\n\n$err"
2745                 }
2746         }
2747 }
2748
2749 proc toggle_or_diff {w x y} {
2750         global file_states file_lists current_diff ui_index ui_other
2751         global last_clicked selected_paths
2752
2753         set pos [split [$w index @$x,$y] .]
2754         set lno [lindex $pos 0]
2755         set col [lindex $pos 1]
2756         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2757         if {$path eq {}} {
2758                 set last_clicked {}
2759                 return
2760         }
2761
2762         set last_clicked [list $w $lno]
2763         array unset selected_paths
2764         $ui_index tag remove in_sel 0.0 end
2765         $ui_other tag remove in_sel 0.0 end
2766
2767         if {$col == 0} {
2768                 if {$current_diff eq $path} {
2769                         set after {reshow_diff;}
2770                 } else {
2771                         set after {}
2772                 }
2773                 switch -glob -- [lindex $file_states($path) 0] {
2774                 A_ -
2775                 M_ -
2776                 DD -
2777                 DO -
2778                 DM {
2779                         update_indexinfo \
2780                                 "Removing [short_path $path] from commit" \
2781                                 [list $path] \
2782                                 [concat $after {set ui_status_value {Ready.}}]
2783                 }
2784                 ?? {
2785                         update_index \
2786                                 "Including [short_path $path]" \
2787                                 [list $path] \
2788                                 [concat $after {set ui_status_value {Ready.}}]
2789                 }
2790                 }
2791         } else {
2792                 show_diff $path $w $lno
2793         }
2794 }
2795
2796 proc add_one_to_selection {w x y} {
2797         global file_lists
2798         global last_clicked selected_paths
2799
2800         set pos [split [$w index @$x,$y] .]
2801         set lno [lindex $pos 0]
2802         set col [lindex $pos 1]
2803         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2804         if {$path eq {}} {
2805                 set last_clicked {}
2806                 return
2807         }
2808
2809         set last_clicked [list $w $lno]
2810         if {[catch {set in_sel $selected_paths($path)}]} {
2811                 set in_sel 0
2812         }
2813         if {$in_sel} {
2814                 unset selected_paths($path)
2815                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2816         } else {
2817                 set selected_paths($path) 1
2818                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2819         }
2820 }
2821
2822 proc add_range_to_selection {w x y} {
2823         global file_lists
2824         global last_clicked selected_paths
2825
2826         if {[lindex $last_clicked 0] ne $w} {
2827                 toggle_or_diff $w $x $y
2828                 return
2829         }
2830
2831         set pos [split [$w index @$x,$y] .]
2832         set lno [lindex $pos 0]
2833         set lc [lindex $last_clicked 1]
2834         if {$lc < $lno} {
2835                 set begin $lc
2836                 set end $lno
2837         } else {
2838                 set begin $lno
2839                 set end $lc
2840         }
2841
2842         foreach path [lrange $file_lists($w) \
2843                 [expr {$begin - 1}] \
2844                 [expr {$end - 1}]] {
2845                 set selected_paths($path) 1
2846         }
2847         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2848 }
2849
2850 ######################################################################
2851 ##
2852 ## config defaults
2853
2854 set cursor_ptr arrow
2855 font create font_diff -family Courier -size 10
2856 font create font_ui
2857 catch {
2858         label .dummy
2859         eval font configure font_ui [font actual [.dummy cget -font]]
2860         destroy .dummy
2861 }
2862
2863 font create font_uibold
2864 font create font_diffbold
2865
2866 if {[is_Windows]} {
2867         set M1B Control
2868         set M1T Ctrl
2869 } elseif {[is_MacOSX]} {
2870         set M1B M1
2871         set M1T Cmd
2872 } else {
2873         set M1B M1
2874         set M1T M1
2875 }
2876
2877 proc apply_config {} {
2878         global repo_config font_descs
2879
2880         foreach option $font_descs {
2881                 set name [lindex $option 0]
2882                 set font [lindex $option 1]
2883                 if {[catch {
2884                         foreach {cn cv} $repo_config(gui.$name) {
2885                                 font configure $font $cn $cv
2886                         }
2887                         } err]} {
2888                         error_popup "Invalid font specified in gui.$name:\n\n$err"
2889                 }
2890                 foreach {cn cv} [font configure $font] {
2891                         font configure ${font}bold $cn $cv
2892                 }
2893                 font configure ${font}bold -weight bold
2894         }
2895 }
2896
2897 set default_config(gui.trustmtime) false
2898 set default_config(gui.pullsummary) true
2899 set default_config(gui.partialinclude) false
2900 set default_config(gui.diffcontext) 5
2901 set default_config(gui.fontui) [font configure font_ui]
2902 set default_config(gui.fontdiff) [font configure font_diff]
2903 set font_descs {
2904         {fontui   font_ui   {Main Font}}
2905         {fontdiff font_diff {Diff/Console Font}}
2906 }
2907 load_config 0
2908 apply_config
2909
2910 ######################################################################
2911 ##
2912 ## ui construction
2913
2914 # -- Menu Bar
2915 #
2916 menu .mbar -tearoff 0
2917 .mbar add cascade -label Repository -menu .mbar.repository
2918 .mbar add cascade -label Edit -menu .mbar.edit
2919 if {!$single_commit} {
2920         .mbar add cascade -label Branch -menu .mbar.branch
2921 }
2922 .mbar add cascade -label Commit -menu .mbar.commit
2923 if {!$single_commit} {
2924         .mbar add cascade -label Fetch -menu .mbar.fetch
2925         .mbar add cascade -label Pull -menu .mbar.pull
2926         .mbar add cascade -label Push -menu .mbar.push
2927 }
2928 . configure -menu .mbar
2929
2930 # -- Repository Menu
2931 #
2932 menu .mbar.repository
2933 .mbar.repository add command \
2934         -label {Visualize Current Branch} \
2935         -command {do_gitk {}} \
2936         -font font_ui
2937 if {![is_MacOSX]} {
2938         .mbar.repository add command \
2939                 -label {Visualize All Branches} \
2940                 -command {do_gitk {--all}} \
2941                 -font font_ui
2942 }
2943 .mbar.repository add separator
2944
2945 if {!$single_commit} {
2946         .mbar.repository add command -label {Repack Database} \
2947                 -command do_repack \
2948                 -font font_ui
2949
2950         .mbar.repository add command -label {Verify Database} \
2951                 -command do_fsck_objects \
2952                 -font font_ui
2953
2954         .mbar.repository add separator
2955
2956         if {[is_Windows]} {
2957                 .mbar.repository add command \
2958                         -label {Create Desktop Icon} \
2959                         -command do_windows_shortcut \
2960                         -font font_ui
2961         } elseif {[is_MacOSX]} {
2962                 .mbar.repository add command \
2963                         -label {Create Desktop Icon} \
2964                         -command do_macosx_app \
2965                         -font font_ui
2966         }
2967 }
2968 .mbar.repository add command -label Quit \
2969         -command do_quit \
2970         -accelerator $M1T-Q \
2971         -font font_ui
2972
2973 # -- Edit Menu
2974 #
2975 menu .mbar.edit
2976 .mbar.edit add command -label Undo \
2977         -command {catch {[focus] edit undo}} \
2978         -accelerator $M1T-Z \
2979         -font font_ui
2980 .mbar.edit add command -label Redo \
2981         -command {catch {[focus] edit redo}} \
2982         -accelerator $M1T-Y \
2983         -font font_ui
2984 .mbar.edit add separator
2985 .mbar.edit add command -label Cut \
2986         -command {catch {tk_textCut [focus]}} \
2987         -accelerator $M1T-X \
2988         -font font_ui
2989 .mbar.edit add command -label Copy \
2990         -command {catch {tk_textCopy [focus]}} \
2991         -accelerator $M1T-C \
2992         -font font_ui
2993 .mbar.edit add command -label Paste \
2994         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2995         -accelerator $M1T-V \
2996         -font font_ui
2997 .mbar.edit add command -label Delete \
2998         -command {catch {[focus] delete sel.first sel.last}} \
2999         -accelerator Del \
3000         -font font_ui
3001 .mbar.edit add separator
3002 .mbar.edit add command -label {Select All} \
3003         -command {catch {[focus] tag add sel 0.0 end}} \
3004         -accelerator $M1T-A \
3005         -font font_ui
3006
3007 if {!$single_commit} {
3008         # -- Branch Menu
3009         #
3010         menu .mbar.branch
3011
3012         .mbar.branch add command -label {Create...} \
3013                 -command do_create_branch \
3014                 -font font_ui
3015         lappend disable_on_lock [list .mbar.branch entryconf \
3016                 [.mbar.branch index last] -state]
3017
3018         .mbar.branch add command -label {Delete...} \
3019                 -command do_delete_branch \
3020                 -font font_ui
3021         lappend disable_on_lock [list .mbar.branch entryconf \
3022                 [.mbar.branch index last] -state]
3023 }
3024
3025 # -- Commit Menu
3026 #
3027 menu .mbar.commit
3028
3029 .mbar.commit add radiobutton \
3030         -label {New Commit} \
3031         -command do_select_commit_type \
3032         -variable selected_commit_type \
3033         -value new \
3034         -font font_ui
3035 lappend disable_on_lock \
3036         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3037
3038 .mbar.commit add radiobutton \
3039         -label {Amend Last Commit} \
3040         -command do_select_commit_type \
3041         -variable selected_commit_type \
3042         -value amend \
3043         -font font_ui
3044 lappend disable_on_lock \
3045         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3046
3047 .mbar.commit add separator
3048
3049 .mbar.commit add command -label Rescan \
3050         -command do_rescan \
3051         -accelerator F5 \
3052         -font font_ui
3053 lappend disable_on_lock \
3054         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3055
3056 .mbar.commit add command -label {Include In Commit} \
3057         -command do_include_selection \
3058         -font font_ui
3059 lappend disable_on_lock \
3060         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3061
3062 .mbar.commit add command -label {Include All In Commit} \
3063         -command do_include_all \
3064         -accelerator $M1T-I \
3065         -font font_ui
3066 lappend disable_on_lock \
3067         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3068
3069 .mbar.commit add command -label {Remove From Commit} \
3070         -command do_remove_selection \
3071         -font font_ui
3072 lappend disable_on_lock \
3073         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3074
3075 .mbar.commit add command -label {Revert Changes} \
3076         -command do_revert_selection \
3077         -font font_ui
3078 lappend disable_on_lock \
3079         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3080
3081 .mbar.commit add separator
3082
3083 .mbar.commit add command -label {Sign Off} \
3084         -command do_signoff \
3085         -accelerator $M1T-S \
3086         -font font_ui
3087
3088 .mbar.commit add command -label Commit \
3089         -command do_commit \
3090         -accelerator $M1T-Return \
3091         -font font_ui
3092 lappend disable_on_lock \
3093         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3094
3095 # -- Transport menus
3096 #
3097 if {!$single_commit} {
3098         menu .mbar.fetch
3099         menu .mbar.pull
3100         menu .mbar.push
3101 }
3102
3103 if {[is_MacOSX]} {
3104         # -- Apple Menu (Mac OS X only)
3105         #
3106         .mbar add cascade -label Apple -menu .mbar.apple
3107         menu .mbar.apple
3108
3109         .mbar.apple add command -label "About $appname" \
3110                 -command do_about \
3111                 -font font_ui
3112         .mbar.apple add command -label "$appname Options..." \
3113                 -command do_options \
3114                 -font font_ui
3115 } else {
3116         # -- Edit Menu
3117         #
3118         .mbar.edit add separator
3119         .mbar.edit add command -label {Options...} \
3120                 -command do_options \
3121                 -font font_ui
3122
3123         # -- Help Menu
3124         #
3125         .mbar add cascade -label Help -menu .mbar.help
3126         menu .mbar.help
3127
3128         .mbar.help add command -label "About $appname" \
3129                 -command do_about \
3130                 -font font_ui
3131 }
3132
3133
3134 # -- Branch Control
3135 #
3136 frame .branch \
3137         -borderwidth 1 \
3138         -relief sunken
3139 label .branch.l1 \
3140         -text {Current Branch:} \
3141         -anchor w \
3142         -justify left \
3143         -font font_ui
3144 label .branch.cb \
3145         -textvariable current_branch \
3146         -anchor w \
3147         -justify left \
3148         -font font_ui
3149 pack .branch.l1 -side left
3150 pack .branch.cb -side left -fill x
3151 pack .branch -side top -fill x
3152
3153 # -- Main Window Layout
3154 #
3155 panedwindow .vpane -orient vertical
3156 panedwindow .vpane.files -orient horizontal
3157 .vpane add .vpane.files -sticky nsew -height 100 -width 400
3158 pack .vpane -anchor n -side top -fill both -expand 1
3159
3160 # -- Index File List
3161 #
3162 frame .vpane.files.index -height 100 -width 400
3163 label .vpane.files.index.title -text {Modified Files} \
3164         -background green \
3165         -font font_ui
3166 text $ui_index -background white -borderwidth 0 \
3167         -width 40 -height 10 \
3168         -font font_ui \
3169         -cursor $cursor_ptr \
3170         -yscrollcommand {.vpane.files.index.sb set} \
3171         -state disabled
3172 scrollbar .vpane.files.index.sb -command [list $ui_index yview]
3173 pack .vpane.files.index.title -side top -fill x
3174 pack .vpane.files.index.sb -side right -fill y
3175 pack $ui_index -side left -fill both -expand 1
3176 .vpane.files add .vpane.files.index -sticky nsew
3177
3178 # -- Other (Add) File List
3179 #
3180 frame .vpane.files.other -height 100 -width 100
3181 label .vpane.files.other.title -text {Untracked Files} \
3182         -background red \
3183         -font font_ui
3184 text $ui_other -background white -borderwidth 0 \
3185         -width 40 -height 10 \
3186         -font font_ui \
3187         -cursor $cursor_ptr \
3188         -yscrollcommand {.vpane.files.other.sb set} \
3189         -state disabled
3190 scrollbar .vpane.files.other.sb -command [list $ui_other yview]
3191 pack .vpane.files.other.title -side top -fill x
3192 pack .vpane.files.other.sb -side right -fill y
3193 pack $ui_other -side left -fill both -expand 1
3194 .vpane.files add .vpane.files.other -sticky nsew
3195
3196 foreach i [list $ui_index $ui_other] {
3197         $i tag conf in_diff -font font_uibold
3198         $i tag conf in_sel \
3199                 -background [$i cget -foreground] \
3200                 -foreground [$i cget -background]
3201 }
3202 unset i
3203
3204 # -- Diff and Commit Area
3205 #
3206 frame .vpane.lower -height 300 -width 400
3207 frame .vpane.lower.commarea
3208 frame .vpane.lower.diff -relief sunken -borderwidth 1
3209 pack .vpane.lower.commarea -side top -fill x
3210 pack .vpane.lower.diff -side bottom -fill both -expand 1
3211 .vpane add .vpane.lower -stick nsew
3212
3213 # -- Commit Area Buttons
3214 #
3215 frame .vpane.lower.commarea.buttons
3216 label .vpane.lower.commarea.buttons.l -text {} \
3217         -anchor w \
3218         -justify left \
3219         -font font_ui
3220 pack .vpane.lower.commarea.buttons.l -side top -fill x
3221 pack .vpane.lower.commarea.buttons -side left -fill y
3222
3223 button .vpane.lower.commarea.buttons.rescan -text {Rescan} \
3224         -command do_rescan \
3225         -font font_ui
3226 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3227 lappend disable_on_lock \
3228         {.vpane.lower.commarea.buttons.rescan conf -state}
3229
3230 button .vpane.lower.commarea.buttons.incall -text {Include All} \
3231         -command do_include_all \
3232         -font font_ui
3233 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3234 lappend disable_on_lock \
3235         {.vpane.lower.commarea.buttons.incall conf -state}
3236
3237 button .vpane.lower.commarea.buttons.signoff -text {Sign Off} \
3238         -command do_signoff \
3239         -font font_ui
3240 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3241
3242 button .vpane.lower.commarea.buttons.commit -text {Commit} \
3243         -command do_commit \
3244         -font font_ui
3245 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3246 lappend disable_on_lock \
3247         {.vpane.lower.commarea.buttons.commit conf -state}
3248
3249 # -- Commit Message Buffer
3250 #
3251 frame .vpane.lower.commarea.buffer
3252 frame .vpane.lower.commarea.buffer.header
3253 set ui_comm .vpane.lower.commarea.buffer.t
3254 set ui_coml .vpane.lower.commarea.buffer.header.l
3255 radiobutton .vpane.lower.commarea.buffer.header.new \
3256         -text {New Commit} \
3257         -command do_select_commit_type \
3258         -variable selected_commit_type \
3259         -value new \
3260         -font font_ui
3261 lappend disable_on_lock \
3262         [list .vpane.lower.commarea.buffer.header.new conf -state]
3263 radiobutton .vpane.lower.commarea.buffer.header.amend \
3264         -text {Amend Last Commit} \
3265         -command do_select_commit_type \
3266         -variable selected_commit_type \
3267         -value amend \
3268         -font font_ui
3269 lappend disable_on_lock \
3270         [list .vpane.lower.commarea.buffer.header.amend conf -state]
3271 label $ui_coml \
3272         -anchor w \
3273         -justify left \
3274         -font font_ui
3275 proc trace_commit_type {varname args} {
3276         global ui_coml commit_type
3277         switch -glob -- $commit_type {
3278         initial       {set txt {Initial Commit Message:}}
3279         amend         {set txt {Amended Commit Message:}}
3280         amend-initial {set txt {Amended Initial Commit Message:}}
3281         amend-merge   {set txt {Amended Merge Commit Message:}}
3282         merge         {set txt {Merge Commit Message:}}
3283         *             {set txt {Commit Message:}}
3284         }
3285         $ui_coml conf -text $txt
3286 }
3287 trace add variable commit_type write trace_commit_type
3288 pack $ui_coml -side left -fill x
3289 pack .vpane.lower.commarea.buffer.header.amend -side right
3290 pack .vpane.lower.commarea.buffer.header.new -side right
3291
3292 text $ui_comm -background white -borderwidth 1 \
3293         -undo true \
3294         -maxundo 20 \
3295         -autoseparators true \
3296         -relief sunken \
3297         -width 75 -height 9 -wrap none \
3298         -font font_diff \
3299         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3300 scrollbar .vpane.lower.commarea.buffer.sby \
3301         -command [list $ui_comm yview]
3302 pack .vpane.lower.commarea.buffer.header -side top -fill x
3303 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3304 pack $ui_comm -side left -fill y
3305 pack .vpane.lower.commarea.buffer -side left -fill y
3306
3307 # -- Commit Message Buffer Context Menu
3308 #
3309 set ctxm .vpane.lower.commarea.buffer.ctxm
3310 menu $ctxm -tearoff 0
3311 $ctxm add command \
3312         -label {Cut} \
3313         -font font_ui \
3314         -command {tk_textCut $ui_comm}
3315 $ctxm add command \
3316         -label {Copy} \
3317         -font font_ui \
3318         -command {tk_textCopy $ui_comm}
3319 $ctxm add command \
3320         -label {Paste} \
3321         -font font_ui \
3322         -command {tk_textPaste $ui_comm}
3323 $ctxm add command \
3324         -label {Delete} \
3325         -font font_ui \
3326         -command {$ui_comm delete sel.first sel.last}
3327 $ctxm add separator
3328 $ctxm add command \
3329         -label {Select All} \
3330         -font font_ui \
3331         -command {$ui_comm tag add sel 0.0 end}
3332 $ctxm add command \
3333         -label {Copy All} \
3334         -font font_ui \
3335         -command {
3336                 $ui_comm tag add sel 0.0 end
3337                 tk_textCopy $ui_comm
3338                 $ui_comm tag remove sel 0.0 end
3339         }
3340 $ctxm add separator
3341 $ctxm add command \
3342         -label {Sign Off} \
3343         -font font_ui \
3344         -command do_signoff
3345 bind_button3 $ui_comm "tk_popup $ctxm %X %Y"
3346
3347 # -- Diff Header
3348 #
3349 set current_diff {}
3350 set diff_actions [list]
3351 proc trace_current_diff {varname args} {
3352         global current_diff diff_actions file_states
3353         if {$current_diff eq {}} {
3354                 set s {}
3355                 set f {}
3356                 set p {}
3357                 set o disabled
3358         } else {
3359                 set p $current_diff
3360                 set s [mapdesc [lindex $file_states($p) 0] $p]
3361                 set f {File:}
3362                 set p [escape_path $p]
3363                 set o normal
3364         }
3365
3366         .vpane.lower.diff.header.status configure -text $s
3367         .vpane.lower.diff.header.file configure -text $f
3368         .vpane.lower.diff.header.path configure -text $p
3369         foreach w $diff_actions {
3370                 uplevel #0 $w $o
3371         }
3372 }
3373 trace add variable current_diff write trace_current_diff
3374
3375 frame .vpane.lower.diff.header -background orange
3376 label .vpane.lower.diff.header.status \
3377         -background orange \
3378         -width $max_status_desc \
3379         -anchor w \
3380         -justify left \
3381         -font font_ui
3382 label .vpane.lower.diff.header.file \
3383         -background orange \
3384         -anchor w \
3385         -justify left \
3386         -font font_ui
3387 label .vpane.lower.diff.header.path \
3388         -background orange \
3389         -anchor w \
3390         -justify left \
3391         -font font_ui
3392 pack .vpane.lower.diff.header.status -side left
3393 pack .vpane.lower.diff.header.file -side left
3394 pack .vpane.lower.diff.header.path -fill x
3395 set ctxm .vpane.lower.diff.header.ctxm
3396 menu $ctxm -tearoff 0
3397 $ctxm add command \
3398         -label {Copy} \
3399         -font font_ui \
3400         -command {
3401                 clipboard clear
3402                 clipboard append \
3403                         -format STRING \
3404                         -type STRING \
3405                         -- $current_diff
3406         }
3407 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3408 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3409
3410 # -- Diff Body
3411 #
3412 frame .vpane.lower.diff.body
3413 set ui_diff .vpane.lower.diff.body.t
3414 text $ui_diff -background white -borderwidth 0 \
3415         -width 80 -height 15 -wrap none \
3416         -font font_diff \
3417         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3418         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3419         -state disabled
3420 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3421         -command [list $ui_diff xview]
3422 scrollbar .vpane.lower.diff.body.sby -orient vertical \
3423         -command [list $ui_diff yview]
3424 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3425 pack .vpane.lower.diff.body.sby -side right -fill y
3426 pack $ui_diff -side left -fill both -expand 1
3427 pack .vpane.lower.diff.header -side top -fill x
3428 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3429
3430 $ui_diff tag conf d_@ -font font_diffbold
3431 $ui_diff tag conf d_+  -foreground blue
3432 $ui_diff tag conf d_-  -foreground red
3433 $ui_diff tag conf d_++ -foreground {#00a000}
3434 $ui_diff tag conf d_-- -foreground {#a000a0}
3435 $ui_diff tag conf d_+- \
3436         -foreground red \
3437         -background {light goldenrod yellow}
3438 $ui_diff tag conf d_-+ \
3439         -foreground blue \
3440         -background azure2
3441
3442 # -- Diff Body Context Menu
3443 #
3444 set ctxm .vpane.lower.diff.body.ctxm
3445 menu $ctxm -tearoff 0
3446 $ctxm add command \
3447         -label {Copy} \
3448         -font font_ui \
3449         -command {tk_textCopy $ui_diff}
3450 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3451 $ctxm add command \
3452         -label {Select All} \
3453         -font font_ui \
3454         -command {$ui_diff tag add sel 0.0 end}
3455 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3456 $ctxm add command \
3457         -label {Copy All} \
3458         -font font_ui \
3459         -command {
3460                 $ui_diff tag add sel 0.0 end
3461                 tk_textCopy $ui_diff
3462                 $ui_diff tag remove sel 0.0 end
3463         }
3464 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3465 $ctxm add separator
3466 $ctxm add command \
3467         -label {Decrease Font Size} \
3468         -font font_ui \
3469         -command {incr_font_size font_diff -1}
3470 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3471 $ctxm add command \
3472         -label {Increase Font Size} \
3473         -font font_ui \
3474         -command {incr_font_size font_diff 1}
3475 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3476 $ctxm add separator
3477 $ctxm add command \
3478         -label {Show Less Context} \
3479         -font font_ui \
3480         -command {if {$repo_config(gui.diffcontext) >= 2} {
3481                 incr repo_config(gui.diffcontext) -1
3482                 reshow_diff
3483         }}
3484 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3485 $ctxm add command \
3486         -label {Show More Context} \
3487         -font font_ui \
3488         -command {
3489                 incr repo_config(gui.diffcontext)
3490                 reshow_diff
3491         }
3492 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3493 $ctxm add separator
3494 $ctxm add command -label {Options...} \
3495         -font font_ui \
3496         -command do_options
3497 bind_button3 $ui_diff "tk_popup $ctxm %X %Y"
3498
3499 # -- Status Bar
3500 #
3501 set ui_status_value {Initializing...}
3502 label .status -textvariable ui_status_value \
3503         -anchor w \
3504         -justify left \
3505         -borderwidth 1 \
3506         -relief sunken \
3507         -font font_ui
3508 pack .status -anchor w -side bottom -fill x
3509
3510 # -- Load geometry
3511 #
3512 catch {
3513 set gm $repo_config(gui.geometry)
3514 wm geometry . [lindex $gm 0]
3515 .vpane sash place 0 \
3516         [lindex [.vpane sash coord 0] 0] \
3517         [lindex $gm 1]
3518 .vpane.files sash place 0 \
3519         [lindex $gm 2] \
3520         [lindex [.vpane.files sash coord 0] 1]
3521 unset gm
3522 }
3523
3524 # -- Key Bindings
3525 #
3526 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3527 bind $ui_comm <$M1B-Key-i> {do_include_all;break}
3528 bind $ui_comm <$M1B-Key-I> {do_include_all;break}
3529 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3530 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3531 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3532 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3533 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3534 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3535 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3536 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3537
3538 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3539 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3540 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3541 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3542 bind $ui_diff <$M1B-Key-v> {break}
3543 bind $ui_diff <$M1B-Key-V> {break}
3544 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3545 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3546 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3547 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3548 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3549 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3550
3551 bind .   <Destroy> do_quit
3552 bind all <Key-F5> do_rescan
3553 bind all <$M1B-Key-r> do_rescan
3554 bind all <$M1B-Key-R> do_rescan
3555 bind .   <$M1B-Key-s> do_signoff
3556 bind .   <$M1B-Key-S> do_signoff
3557 bind .   <$M1B-Key-i> do_include_all
3558 bind .   <$M1B-Key-I> do_include_all
3559 bind .   <$M1B-Key-Return> do_commit
3560 bind all <$M1B-Key-q> do_quit
3561 bind all <$M1B-Key-Q> do_quit
3562 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
3563 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
3564 foreach i [list $ui_index $ui_other] {
3565         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3566         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3567         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3568 }
3569 unset i
3570
3571 set file_lists($ui_index) [list]
3572 set file_lists($ui_other) [list]
3573
3574 set HEAD {}
3575 set PARENT {}
3576 set MERGE_HEAD [list]
3577 set commit_type {}
3578 set empty_tree {}
3579 set current_branch {}
3580 set current_diff {}
3581 set selected_commit_type new
3582
3583 wm title . "$appname ([file normalize [file dirname $gitdir]])"
3584 focus -force $ui_comm
3585
3586 # -- Warn the user about environmental problems.
3587 #    Cygwin's Tcl does *not* pass its env array
3588 #    onto any processes it spawns.  This means
3589 #    that the git processes get none of our
3590 #    environment.  That may not work...
3591 #
3592 if {[is_Windows]} {
3593         set ignored_env 0
3594         set suggest_user {}
3595         set msg "Possible environment issues exist.
3596
3597 The following environment variables are probably
3598 going to be ignored by any Git subprocess run
3599 by $appname:
3600
3601 "
3602         foreach name [array names env] {
3603                 switch -regexp -- $name {
3604                 {^GIT_INDEX_FILE$} -
3605                 {^GIT_OBJECT_DIRECTORY$} -
3606                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3607                 {^GIT_DIFF_OPTS$} -
3608                 {^GIT_EXTERNAL_DIFF$} -
3609                 {^GIT_PAGER$} -
3610                 {^GIT_TRACE$} -
3611                 {^GIT_CONFIG$} -
3612                 {^GIT_CONFIG_LOCAL$} -
3613                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3614                         append msg " - $name\n"
3615                         incr ignored_env
3616                 }
3617                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3618                         append msg " - $name\n"
3619                         incr ignored_env
3620                         set suggest_user $name
3621                 }
3622                 }
3623         }
3624         if {$ignored_env > 0} {
3625                 append msg "
3626 This is due to a known issue with the
3627 Tcl binary distributed by Cygwin."
3628
3629                 if {$suggest_user ne {}} {
3630                         append msg "
3631
3632 A good replacement for $suggest_user
3633 is placing values for the user.name and
3634 user.email settings into your personal
3635 ~/.gitconfig file.
3636 "
3637                 }
3638                 warn_popup $msg
3639         }
3640         unset ignored_env msg suggest_user name
3641 }
3642
3643 if {!$single_commit} {
3644         load_all_remotes
3645         load_all_branches
3646         populate_branch_menu .mbar.branch
3647         populate_fetch_menu .mbar.fetch
3648         populate_pull_menu .mbar.pull
3649         populate_push_menu .mbar.push
3650 }
3651 lock_index begin-read
3652 after 1 do_rescan