git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3 exec wish "$0" -- "$@"
   4
   5 set appvers {@@GIT_VERSION@@}
   6 set copyright {
   7 Copyright © 2006, 2007 Shawn Pearce, Paul Mackerras.
   8
   9 This program is free software; you can redistribute it and/or modify
  10 it under the terms of the GNU General Public License as published by
  11 the Free Software Foundation; either version 2 of the License, or
  12 (at your option) any later version.
  13
  14 This program is distributed in the hope that it will be useful,
  15 but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 GNU General Public License for more details.
  18
  19 You should have received a copy of the GNU General Public License
  20 along with this program; if not, write to the Free Software
  21 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}
  22
  23 ######################################################################
  24 ##
  25 ## read only globals
  26
  27 set _appname [lindex [file split $argv0] end]
  28 set _gitdir {}
  29 set _reponame {}
  30
  31 proc appname {} {
  32         global _appname
  33         return $_appname
  34 }
  35
  36 proc gitdir {args} {
  37         global _gitdir
  38         if {$args eq {}} {
  39                 return $_gitdir
  40         }
  41         return [eval [concat [list file join $_gitdir] $args]]
  42 }
  43
  44 proc reponame {} {
  45         global _reponame
  46         return $_reponame
  47 }
  48
  49 ######################################################################
  50 ##
  51 ## config
  52
  53 proc is_many_config {name} {
  54         switch -glob -- $name {
  55         remote.*.fetch -
  56         remote.*.push
  57                 {return 1}
  58         *
  59                 {return 0}
  60         }
  61 }
  62
  63 proc load_config {include_global} {
  64         global repo_config global_config default_config
  65
  66         array unset global_config
  67         if {$include_global} {
  68                 catch {
  69                         set fd_rc [open "| git repo-config --global --list" r]
  70                         while {[gets $fd_rc line] >= 0} {
  71                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  72                                         if {[is_many_config $name]} {
  73                                                 lappend global_config($name) $value
  74                                         } else {
  75                                                 set global_config($name) $value
  76                                         }
  77                                 }
  78                         }
  79                         close $fd_rc
  80                 }
  81         }
  82
  83         array unset repo_config
  84         catch {
  85                 set fd_rc [open "| git repo-config --list" r]
  86                 while {[gets $fd_rc line] >= 0} {
  87                         if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  88                                 if {[is_many_config $name]} {
  89                                         lappend repo_config($name) $value
  90                                 } else {
  91                                         set repo_config($name) $value
  92                                 }
  93                         }
  94                 }
  95                 close $fd_rc
  96         }
  97
  98         foreach name [array names default_config] {
  99                 if {[catch {set v $global_config($name)}]} {
 100                         set global_config($name) $default_config($name)
 101                 }
 102                 if {[catch {set v $repo_config($name)}]} {
 103                         set repo_config($name) $default_config($name)
 104                 }
 105         }
 106 }
 107
 108 proc save_config {} {
 109         global default_config font_descs
 110         global repo_config global_config
 111         global repo_config_new global_config_new
 112
 113         foreach option $font_descs {
 114                 set name [lindex $option 0]
 115                 set font [lindex $option 1]
 116                 font configure $font \
 117                         -family $global_config_new(gui.$font^^family) \
 118                         -size $global_config_new(gui.$font^^size)
 119                 font configure ${font}bold \
 120                         -family $global_config_new(gui.$font^^family) \
 121                         -size $global_config_new(gui.$font^^size)
 122                 set global_config_new(gui.$name) [font configure $font]
 123                 unset global_config_new(gui.$font^^family)
 124                 unset global_config_new(gui.$font^^size)
 125         }
 126
 127         foreach name [array names default_config] {
 128                 set value $global_config_new($name)
 129                 if {$value ne $global_config($name)} {
 130                         if {$value eq $default_config($name)} {
 131                                 catch {exec git repo-config --global --unset $name}
 132                         } else {
 133                                 regsub -all "\[{}\]" $value {"} value
 134                                 exec git repo-config --global $name $value
 135                         }
 136                         set global_config($name) $value
 137                         if {$value eq $repo_config($name)} {
 138                                 catch {exec git repo-config --unset $name}
 139                                 set repo_config($name) $value
 140                         }
 141                 }
 142         }
 143
 144         foreach name [array names default_config] {
 145                 set value $repo_config_new($name)
 146                 if {$value ne $repo_config($name)} {
 147                         if {$value eq $global_config($name)} {
 148                                 catch {exec git repo-config --unset $name}
 149                         } else {
 150                                 regsub -all "\[{}\]" $value {"} value
 151                                 exec git repo-config $name $value
 152                         }
 153                         set repo_config($name) $value
 154                 }
 155         }
 156 }
 157
 158 proc error_popup {msg} {
 159         set title [appname]
 160         if {[reponame] ne {}} {
 161                 append title " ([reponame])"
 162         }
 163         set cmd [list tk_messageBox \
 164                 -icon error \
 165                 -type ok \
 166                 -title "$title: error" \
 167                 -message $msg]
 168         if {[winfo ismapped .]} {
 169                 lappend cmd -parent .
 170         }
 171         eval $cmd
 172 }
 173
 174 proc warn_popup {msg} {
 175         set title [appname]
 176         if {[reponame] ne {}} {
 177                 append title " ([reponame])"
 178         }
 179         set cmd [list tk_messageBox \
 180                 -icon warning \
 181                 -type ok \
 182                 -title "$title: warning" \
 183                 -message $msg]
 184         if {[winfo ismapped .]} {
 185                 lappend cmd -parent .
 186         }
 187         eval $cmd
 188 }
 189
 190 proc info_popup {msg} {
 191         set title [appname]
 192         if {[reponame] ne {}} {
 193                 append title " ([reponame])"
 194         }
 195         tk_messageBox \
 196                 -parent . \
 197                 -icon info \
 198                 -type ok \
 199                 -title $title \
 200                 -message $msg
 201 }
 202
 203 proc ask_popup {msg} {
 204         set title [appname]
 205         if {[reponame] ne {}} {
 206                 append title " ([reponame])"
 207         }
 208         return [tk_messageBox \
 209                 -parent . \
 210                 -icon question \
 211                 -type yesno \
 212                 -title $title \
 213                 -message $msg]
 214 }
 215
 216 ######################################################################
 217 ##
 218 ## repository setup
 219
 220 if {   [catch {set _gitdir $env(GIT_DIR)}]
 221         && [catch {set _gitdir [exec git rev-parse --git-dir]} err]} {
 222         catch {wm withdraw .}
 223         error_popup "Cannot find the git directory:\n\n$err"
 224         exit 1
 225 }
 226 if {![file isdirectory $_gitdir]} {
 227         catch {wm withdraw .}
 228         error_popup "Git directory not found:\n\n$_gitdir"
 229         exit 1
 230 }
 231 if {[lindex [file split $_gitdir] end] ne {.git}} {
 232         catch {wm withdraw .}
 233         error_popup "Cannot use funny .git directory:\n\n$gitdir"
 234         exit 1
 235 }
 236 if {[catch {cd [file dirname $_gitdir]} err]} {
 237         catch {wm withdraw .}
 238         error_popup "No working directory [file dirname $_gitdir]:\n\n$err"
 239         exit 1
 240 }
 241 set _reponame [lindex [file split \
 242         [file normalize [file dirname $_gitdir]]] \
 243         end]
 244
 245 set single_commit 0
 246 if {[appname] eq {git-citool}} {
 247         set single_commit 1
 248 }
 249
 250 ######################################################################
 251 ##
 252 ## task management
 253
 254 set rescan_active 0
 255 set diff_active 0
 256 set last_clicked {}
 257
 258 set disable_on_lock [list]
 259 set index_lock_type none
 260
 261 proc lock_index {type} {
 262         global index_lock_type disable_on_lock
 263
 264         if {$index_lock_type eq {none}} {
 265                 set index_lock_type $type
 266                 foreach w $disable_on_lock {
 267                         uplevel #0 $w disabled
 268                 }
 269                 return 1
 270         } elseif {$index_lock_type eq "begin-$type"} {
 271                 set index_lock_type $type
 272                 return 1
 273         }
 274         return 0
 275 }
 276
 277 proc unlock_index {} {
 278         global index_lock_type disable_on_lock
 279
 280         set index_lock_type none
 281         foreach w $disable_on_lock {
 282                 uplevel #0 $w normal
 283         }
 284 }
 285
 286 ######################################################################
 287 ##
 288 ## status
 289
 290 proc repository_state {ctvar hdvar mhvar} {
 291         global current_branch
 292         upvar $ctvar ct $hdvar hd $mhvar mh
 293
 294         set mh [list]
 295
 296         if {[catch {set current_branch [exec git symbolic-ref HEAD]}]} {
 297                 set current_branch {}
 298         } else {
 299                 regsub ^refs/((heads|tags|remotes)/)? \
 300                         $current_branch \
 301                         {} \
 302                         current_branch
 303         }
 304
 305         if {[catch {set hd [exec git rev-parse --verify HEAD]}]} {
 306                 set hd {}
 307                 set ct initial
 308                 return
 309         }
 310
 311         set merge_head [gitdir MERGE_HEAD]
 312         if {[file exists $merge_head]} {
 313                 set ct merge
 314                 set fd_mh [open $merge_head r]
 315                 while {[gets $fd_mh line] >= 0} {
 316                         lappend mh $line
 317                 }
 318                 close $fd_mh
 319                 return
 320         }
 321
 322         set ct normal
 323 }
 324
 325 proc PARENT {} {
 326         global PARENT empty_tree
 327
 328         set p [lindex $PARENT 0]
 329         if {$p ne {}} {
 330                 return $p
 331         }
 332         if {$empty_tree eq {}} {
 333                 set empty_tree [exec git mktree << {}]
 334         }
 335         return $empty_tree
 336 }
 337
 338 proc rescan {after} {
 339         global HEAD PARENT MERGE_HEAD commit_type
 340         global ui_index ui_workdir ui_status_value ui_comm
 341         global rescan_active file_states
 342         global repo_config
 343
 344         if {$rescan_active > 0 || ![lock_index read]} return
 345
 346         repository_state newType newHEAD newMERGE_HEAD
 347         if {[string match amend* $commit_type]
 348                 && $newType eq {normal}
 349                 && $newHEAD eq $HEAD} {
 350         } else {
 351                 set HEAD $newHEAD
 352                 set PARENT $newHEAD
 353                 set MERGE_HEAD $newMERGE_HEAD
 354                 set commit_type $newType
 355         }
 356
 357         array unset file_states
 358
 359         if {![$ui_comm edit modified]
 360                 || [string trim [$ui_comm get 0.0 end]] eq {}} {
 361                 if {[load_message GITGUI_MSG]} {
 362                 } elseif {[load_message MERGE_MSG]} {
 363                 } elseif {[load_message SQUASH_MSG]} {
 364                 }
 365                 $ui_comm edit reset
 366                 $ui_comm edit modified false
 367         }
 368
 369         if {$repo_config(gui.trustmtime) eq {true}} {
 370                 rescan_stage2 {} $after
 371         } else {
 372                 set rescan_active 1
 373                 set ui_status_value {Refreshing file status...}
 374                 set cmd [list git update-index]
 375                 lappend cmd -q
 376                 lappend cmd --unmerged
 377                 lappend cmd --ignore-missing
 378                 lappend cmd --refresh
 379                 set fd_rf [open "| $cmd" r]
 380                 fconfigure $fd_rf -blocking 0 -translation binary
 381                 fileevent $fd_rf readable \
 382                         [list rescan_stage2 $fd_rf $after]
 383         }
 384 }
 385
 386 proc rescan_stage2 {fd after} {
 387         global ui_status_value
 388         global rescan_active buf_rdi buf_rdf buf_rlo
 389
 390         if {$fd ne {}} {
 391                 read $fd
 392                 if {![eof $fd]} return
 393                 close $fd
 394         }
 395
 396         set ls_others [list | git ls-files --others -z \
 397                 --exclude-per-directory=.gitignore]
 398         set info_exclude [gitdir info exclude]
 399         if {[file readable $info_exclude]} {
 400                 lappend ls_others "--exclude-from=$info_exclude"
 401         }
 402
 403         set buf_rdi {}
 404         set buf_rdf {}
 405         set buf_rlo {}
 406
 407         set rescan_active 3
 408         set ui_status_value {Scanning for modified files ...}
 409         set fd_di [open "| git diff-index --cached -z [PARENT]" r]
 410         set fd_df [open "| git diff-files -z" r]
 411         set fd_lo [open $ls_others r]
 412
 413         fconfigure $fd_di -blocking 0 -translation binary
 414         fconfigure $fd_df -blocking 0 -translation binary
 415         fconfigure $fd_lo -blocking 0 -translation binary
 416         fileevent $fd_di readable [list read_diff_index $fd_di $after]
 417         fileevent $fd_df readable [list read_diff_files $fd_df $after]
 418         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
 419 }
 420
 421 proc load_message {file} {
 422         global ui_comm
 423
 424         set f [gitdir $file]
 425         if {[file isfile $f]} {
 426                 if {[catch {set fd [open $f r]}]} {
 427                         return 0
 428                 }
 429                 set content [string trim [read $fd]]
 430                 close $fd
 431                 $ui_comm delete 0.0 end
 432                 $ui_comm insert end $content
 433                 return 1
 434         }
 435         return 0
 436 }
 437
 438 proc read_diff_index {fd after} {
 439         global buf_rdi
 440
 441         append buf_rdi [read $fd]
 442         set c 0
 443         set n [string length $buf_rdi]
 444         while {$c < $n} {
 445                 set z1 [string first "\0" $buf_rdi $c]
 446                 if {$z1 == -1} break
 447                 incr z1
 448                 set z2 [string first "\0" $buf_rdi $z1]
 449                 if {$z2 == -1} break
 450
 451                 incr c
 452                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
 453                 merge_state \
 454                         [string range $buf_rdi $z1 [expr {$z2 - 1}]] \
 455                         [lindex $i 4]? \
 456                         [list [lindex $i 0] [lindex $i 2]] \
 457                         [list]
 458                 set c $z2
 459                 incr c
 460         }
 461         if {$c < $n} {
 462                 set buf_rdi [string range $buf_rdi $c end]
 463         } else {
 464                 set buf_rdi {}
 465         }
 466
 467         rescan_done $fd buf_rdi $after
 468 }
 469
 470 proc read_diff_files {fd after} {
 471         global buf_rdf
 472
 473         append buf_rdf [read $fd]
 474         set c 0
 475         set n [string length $buf_rdf]
 476         while {$c < $n} {
 477                 set z1 [string first "\0" $buf_rdf $c]
 478                 if {$z1 == -1} break
 479                 incr z1
 480                 set z2 [string first "\0" $buf_rdf $z1]
 481                 if {$z2 == -1} break
 482
 483                 incr c
 484                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
 485                 merge_state \
 486                         [string range $buf_rdf $z1 [expr {$z2 - 1}]] \
 487                         ?[lindex $i 4] \
 488                         [list] \
 489                         [list [lindex $i 0] [lindex $i 2]]
 490                 set c $z2
 491                 incr c
 492         }
 493         if {$c < $n} {
 494                 set buf_rdf [string range $buf_rdf $c end]
 495         } else {
 496                 set buf_rdf {}
 497         }
 498
 499         rescan_done $fd buf_rdf $after
 500 }
 501
 502 proc read_ls_others {fd after} {
 503         global buf_rlo
 504
 505         append buf_rlo [read $fd]
 506         set pck [split $buf_rlo "\0"]
 507         set buf_rlo [lindex $pck end]
 508         foreach p [lrange $pck 0 end-1] {
 509                 merge_state $p ?O
 510         }
 511         rescan_done $fd buf_rlo $after
 512 }
 513
 514 proc rescan_done {fd buf after} {
 515         global rescan_active
 516         global file_states repo_config
 517         upvar $buf to_clear
 518
 519         if {![eof $fd]} return
 520         set to_clear {}
 521         close $fd
 522         if {[incr rescan_active -1] > 0} return
 523
 524         prune_selection
 525         unlock_index
 526         display_all_files
 527
 528         if {$repo_config(gui.partialinclude) ne {true}} {
 529                 set pathList [list]
 530                 foreach path [array names file_states] {
 531                         switch -- [lindex $file_states($path) 0] {
 532                         A? -
 533                         M? {lappend pathList $path}
 534                         }
 535                 }
 536                 if {$pathList ne {}} {
 537                         update_index \
 538                                 "Updating included files" \
 539                                 $pathList \
 540                                 [concat {reshow_diff;} $after]
 541                         return
 542                 }
 543         }
 544
 545         reshow_diff
 546         uplevel #0 $after
 547 }
 548
 549 proc prune_selection {} {
 550         global file_states selected_paths
 551
 552         foreach path [array names selected_paths] {
 553                 if {[catch {set still_here $file_states($path)}]} {
 554                         unset selected_paths($path)
 555                 }
 556         }
 557 }
 558
 559 ######################################################################
 560 ##
 561 ## diff
 562
 563 proc clear_diff {} {
 564         global ui_diff current_diff ui_index ui_workdir
 565
 566         $ui_diff conf -state normal
 567         $ui_diff delete 0.0 end
 568         $ui_diff conf -state disabled
 569
 570         set current_diff {}
 571
 572         $ui_index tag remove in_diff 0.0 end
 573         $ui_workdir tag remove in_diff 0.0 end
 574 }
 575
 576 proc reshow_diff {} {
 577         global current_diff ui_status_value file_states
 578
 579         if {$current_diff eq {}
 580                 || [catch {set s $file_states($current_diff)}]} {
 581                 clear_diff
 582         } else {
 583                 show_diff $current_diff
 584         }
 585 }
 586
 587 proc handle_empty_diff {} {
 588         global current_diff file_states file_lists
 589
 590         set path $current_diff
 591         set s $file_states($path)
 592         if {[lindex $s 0] ne {_M}} return
 593
 594         info_popup "No differences detected.
 595
 596 [short_path $path] has no changes.
 597
 598 The modification date of this file was updated
 599 by another application and you currently have
 600 the Trust File Modification Timestamps option
 601 enabled, so Git did not automatically detect
 602 that there are no content differences in this
 603 file.
 604
 605 This file will now be removed from the modified
 606 files list, to prevent possible confusion.
 607 "
 608         if {[catch {exec git update-index -- $path} err]} {
 609                 error_popup "Failed to refresh index:\n\n$err"
 610         }
 611
 612         clear_diff
 613         display_file $path __
 614 }
 615
 616 proc show_diff {path {w {}} {lno {}}} {
 617         global file_states file_lists
 618         global is_3way_diff diff_active repo_config
 619         global ui_diff current_diff ui_status_value
 620
 621         if {$diff_active || ![lock_index read]} return
 622
 623         clear_diff
 624         if {$w eq {} || $lno == {}} {
 625                 foreach w [array names file_lists] {
 626                         set lno [lsearch -sorted $file_lists($w) $path]
 627                         if {$lno >= 0} {
 628                                 incr lno
 629                                 break
 630                         }
 631                 }
 632         }
 633         if {$w ne {} && $lno >= 1} {
 634                 $w tag add in_diff $lno.0 [expr {$lno + 1}].0
 635         }
 636
 637         set s $file_states($path)
 638         set m [lindex $s 0]
 639         set is_3way_diff 0
 640         set diff_active 1
 641         set current_diff $path
 642         set ui_status_value "Loading diff of [escape_path $path]..."
 643
 644         set cmd [list | git diff-index]
 645         lappend cmd --no-color
 646         if {$repo_config(gui.diffcontext) > 0} {
 647                 lappend cmd "-U$repo_config(gui.diffcontext)"
 648         }
 649         lappend cmd -p
 650
 651         switch $m {
 652         MM {
 653                 lappend cmd -c
 654         }
 655         _O {
 656                 if {[catch {
 657                                 set fd [open $path r]
 658                                 set content [read $fd]
 659                                 close $fd
 660                         } err ]} {
 661                         set diff_active 0
 662                         unlock_index
 663                         set ui_status_value "Unable to display [escape_path $path]"
 664                         error_popup "Error loading file:\n\n$err"
 665                         return
 666                 }
 667                 $ui_diff conf -state normal
 668                 $ui_diff insert end $content
 669                 $ui_diff conf -state disabled
 670                 set diff_active 0
 671                 unlock_index
 672                 set ui_status_value {Ready.}
 673                 return
 674         }
 675         }
 676
 677         lappend cmd [PARENT]
 678         lappend cmd --
 679         lappend cmd $path
 680
 681         if {[catch {set fd [open $cmd r]} err]} {
 682                 set diff_active 0
 683                 unlock_index
 684                 set ui_status_value "Unable to display [escape_path $path]"
 685                 error_popup "Error loading diff:\n\n$err"
 686                 return
 687         }
 688
 689         fconfigure $fd -blocking 0 -translation auto
 690         fileevent $fd readable [list read_diff $fd]
 691 }
 692
 693 proc read_diff {fd} {
 694         global ui_diff ui_status_value is_3way_diff diff_active
 695         global repo_config
 696
 697         $ui_diff conf -state normal
 698         while {[gets $fd line] >= 0} {
 699                 # -- Cleanup uninteresting diff header lines.
 700                 #
 701                 if {[string match {diff --git *}      $line]} continue
 702                 if {[string match {diff --combined *} $line]} continue
 703                 if {[string match {--- *}             $line]} continue
 704                 if {[string match {+++ *}             $line]} continue
 705                 if {$line eq {deleted file mode 120000}} {
 706                         set line "deleted symlink"
 707                 }
 708
 709                 # -- Automatically detect if this is a 3 way diff.
 710                 #
 711                 if {[string match {@@@ *} $line]} {set is_3way_diff 1}
 712
 713                 # -- Reformat a 3 way diff, 'cause its too weird.
 714                 #
 715                 if {$is_3way_diff} {
 716                         set op [string range $line 0 1]
 717                         switch -- $op {
 718                         {@@} {set tags d_@}
 719                         {++} {set tags d_+ ; set op { +}}
 720                         {--} {set tags d_- ; set op { -}}
 721                         { +} {set tags d_++; set op {++}}
 722                         { -} {set tags d_--; set op {--}}
 723                         {+ } {set tags d_-+; set op {-+}}
 724                         {- } {set tags d_+-; set op {+-}}
 725                         default {set tags {}}
 726                         }
 727                         set line [string replace $line 0 1 $op]
 728                 } else {
 729                         switch -- [string index $line 0] {
 730                         @ {set tags d_@}
 731                         + {set tags d_+}
 732                         - {set tags d_-}
 733                         default {set tags {}}
 734                         }
 735                 }
 736                 $ui_diff insert end $line $tags
 737                 $ui_diff insert end "\n" $tags
 738         }
 739         $ui_diff conf -state disabled
 740
 741         if {[eof $fd]} {
 742                 close $fd
 743                 set diff_active 0
 744                 unlock_index
 745                 set ui_status_value {Ready.}
 746
 747                 if {$repo_config(gui.trustmtime) eq {true}
 748                         && [$ui_diff index end] eq {2.0}} {
 749                         handle_empty_diff
 750                 }
 751         }
 752 }
 753
 754 ######################################################################
 755 ##
 756 ## commit
 757
 758 proc load_last_commit {} {
 759         global HEAD PARENT MERGE_HEAD commit_type ui_comm
 760
 761         if {[llength $PARENT] == 0} {
 762                 error_popup {There is nothing to amend.
 763
 764 You are about to create the initial commit.
 765 There is no commit before this to amend.
 766 }
 767                 return
 768         }
 769
 770         repository_state curType curHEAD curMERGE_HEAD
 771         if {$curType eq {merge}} {
 772                 error_popup {Cannot amend while merging.
 773
 774 You are currently in the middle of a merge that
 775 has not been fully completed.  You cannot amend
 776 the prior commit unless you first abort the
 777 current merge activity.
 778 }
 779                 return
 780         }
 781
 782         set msg {}
 783         set parents [list]
 784         if {[catch {
 785                         set fd [open "| git cat-file commit $curHEAD" r]
 786                         while {[gets $fd line] > 0} {
 787                                 if {[string match {parent *} $line]} {
 788                                         lappend parents [string range $line 7 end]
 789                                 }
 790                         }
 791                         set msg [string trim [read $fd]]
 792                         close $fd
 793                 } err]} {
 794                 error_popup "Error loading commit data for amend:\n\n$err"
 795                 return
 796         }
 797
 798         set HEAD $curHEAD
 799         set PARENT $parents
 800         set MERGE_HEAD [list]
 801         switch -- [llength $parents] {
 802         0       {set commit_type amend-initial}
 803         1       {set commit_type amend}
 804         default {set commit_type amend-merge}
 805         }
 806
 807         $ui_comm delete 0.0 end
 808         $ui_comm insert end $msg
 809         $ui_comm edit reset
 810         $ui_comm edit modified false
 811         rescan {set ui_status_value {Ready.}}
 812 }
 813
 814 proc create_new_commit {} {
 815         global commit_type ui_comm
 816
 817         set commit_type normal
 818         $ui_comm delete 0.0 end
 819         $ui_comm edit reset
 820         $ui_comm edit modified false
 821         rescan {set ui_status_value {Ready.}}
 822 }
 823
 824 set GIT_COMMITTER_IDENT {}
 825
 826 proc committer_ident {} {
 827         global GIT_COMMITTER_IDENT
 828
 829         if {$GIT_COMMITTER_IDENT eq {}} {
 830                 if {[catch {set me [exec git var GIT_COMMITTER_IDENT]} err]} {
 831                         error_popup "Unable to obtain your identity:\n\n$err"
 832                         return {}
 833                 }
 834                 if {![regexp {^(.*) [0-9]+ [-+0-9]+$} \
 835                         $me me GIT_COMMITTER_IDENT]} {
 836                         error_popup "Invalid GIT_COMMITTER_IDENT:\n\n$me"
 837                         return {}
 838                 }
 839         }
 840
 841         return $GIT_COMMITTER_IDENT
 842 }
 843
 844 proc commit_tree {} {
 845         global HEAD commit_type file_states ui_comm repo_config
 846
 847         if {![lock_index update]} return
 848         if {[committer_ident] eq {}} return
 849
 850         # -- Our in memory state should match the repository.
 851         #
 852         repository_state curType curHEAD curMERGE_HEAD
 853         if {[string match amend* $commit_type]
 854                 && $curType eq {normal}
 855                 && $curHEAD eq $HEAD} {
 856         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
 857                 info_popup {Last scanned state does not match repository state.
 858
 859 Another Git program has modified this repository
 860 since the last scan.  A rescan must be performed
 861 before another commit can be created.
 862
 863 The rescan will be automatically started now.
 864 }
 865                 unlock_index
 866                 rescan {set ui_status_value {Ready.}}
 867                 return
 868         }
 869
 870         # -- At least one file should differ in the index.
 871         #
 872         set files_ready 0
 873         foreach path [array names file_states] {
 874                 switch -glob -- [lindex $file_states($path) 0] {
 875                 _? {continue}
 876                 A? -
 877                 D? -
 878                 M? {set files_ready 1; break}
 879                 U? {
 880                         error_popup "Unmerged files cannot be committed.
 881
 882 File [short_path $path] has merge conflicts.
 883 You must resolve them and include the file before committing.
 884 "
 885                         unlock_index
 886                         return
 887                 }
 888                 default {
 889                         error_popup "Unknown file state [lindex $s 0] detected.
 890
 891 File [short_path $path] cannot be committed by this program.
 892 "
 893                 }
 894                 }
 895         }
 896         if {!$files_ready} {
 897                 error_popup {No included files to commit.
 898
 899 You must include at least 1 file before you can commit.
 900 }
 901                 unlock_index
 902                 return
 903         }
 904
 905         # -- A message is required.
 906         #
 907         set msg [string trim [$ui_comm get 1.0 end]]
 908         if {$msg eq {}} {
 909                 error_popup {Please supply a commit message.
 910
 911 A good commit message has the following format:
 912
 913 - First line: Describe in one sentance what you did.
 914 - Second line: Blank
 915 - Remaining lines: Describe why this change is good.
 916 }
 917                 unlock_index
 918                 return
 919         }
 920
 921         # -- Update included files if partialincludes are off.
 922         #
 923         if {$repo_config(gui.partialinclude) ne {true}} {
 924                 set pathList [list]
 925                 foreach path [array names file_states] {
 926                         switch -glob -- [lindex $file_states($path) 0] {
 927                         A? -
 928                         M? {lappend pathList $path}
 929                         }
 930                 }
 931                 if {$pathList ne {}} {
 932                         unlock_index
 933                         update_index \
 934                                 "Updating included files" \
 935                                 $pathList \
 936                                 [concat {lock_index update;} \
 937                                         [list commit_prehook $curHEAD $msg]]
 938                         return
 939                 }
 940         }
 941
 942         commit_prehook $curHEAD $msg
 943 }
 944
 945 proc commit_prehook {curHEAD msg} {
 946         global ui_status_value pch_error
 947
 948         set pchook [gitdir hooks pre-commit]
 949
 950         # On Cygwin [file executable] might lie so we need to ask
 951         # the shell if the hook is executable.  Yes that's annoying.
 952         #
 953         if {[is_Windows] && [file isfile $pchook]} {
 954                 set pchook [list sh -c [concat \
 955                         "if test -x \"$pchook\";" \
 956                         "then exec \"$pchook\" 2>&1;" \
 957                         "fi"]]
 958         } elseif {[file executable $pchook]} {
 959                 set pchook [list $pchook |& cat]
 960         } else {
 961                 commit_writetree $curHEAD $msg
 962                 return
 963         }
 964
 965         set ui_status_value {Calling pre-commit hook...}
 966         set pch_error {}
 967         set fd_ph [open "| $pchook" r]
 968         fconfigure $fd_ph -blocking 0 -translation binary
 969         fileevent $fd_ph readable \
 970                 [list commit_prehook_wait $fd_ph $curHEAD $msg]
 971 }
 972
 973 proc commit_prehook_wait {fd_ph curHEAD msg} {
 974         global pch_error ui_status_value
 975
 976         append pch_error [read $fd_ph]
 977         fconfigure $fd_ph -blocking 1
 978         if {[eof $fd_ph]} {
 979                 if {[catch {close $fd_ph}]} {
 980                         set ui_status_value {Commit declined by pre-commit hook.}
 981                         hook_failed_popup pre-commit $pch_error
 982                         unlock_index
 983                 } else {
 984                         commit_writetree $curHEAD $msg
 985                 }
 986                 set pch_error {}
 987                 return
 988         }
 989         fconfigure $fd_ph -blocking 0
 990 }
 991
 992 proc commit_writetree {curHEAD msg} {
 993         global ui_status_value
 994
 995         set ui_status_value {Committing changes...}
 996         set fd_wt [open "| git write-tree" r]
 997         fileevent $fd_wt readable \
 998                 [list commit_committree $fd_wt $curHEAD $msg]
 999 }
1000
1001 proc commit_committree {fd_wt curHEAD msg} {
1002         global HEAD PARENT MERGE_HEAD commit_type
1003         global single_commit
1004         global ui_status_value ui_comm selected_commit_type
1005         global file_states selected_paths rescan_active
1006
1007         gets $fd_wt tree_id
1008         if {$tree_id eq {} || [catch {close $fd_wt} err]} {
1009                 error_popup "write-tree failed:\n\n$err"
1010                 set ui_status_value {Commit failed.}
1011                 unlock_index
1012                 return
1013         }
1014
1015         # -- Create the commit.
1016         #
1017         set cmd [list git commit-tree $tree_id]
1018         set parents [concat $PARENT $MERGE_HEAD]
1019         if {[llength $parents] > 0} {
1020                 foreach p $parents {
1021                         lappend cmd -p $p
1022                 }
1023         } else {
1024                 # git commit-tree writes to stderr during initial commit.
1025                 lappend cmd 2>/dev/null
1026         }
1027         lappend cmd << $msg
1028         if {[catch {set cmt_id [eval exec $cmd]} err]} {
1029                 error_popup "commit-tree failed:\n\n$err"
1030                 set ui_status_value {Commit failed.}
1031                 unlock_index
1032                 return
1033         }
1034
1035         # -- Update the HEAD ref.
1036         #
1037         set reflogm commit
1038         if {$commit_type ne {normal}} {
1039                 append reflogm " ($commit_type)"
1040         }
1041         set i [string first "\n" $msg]
1042         if {$i >= 0} {
1043                 append reflogm {: } [string range $msg 0 [expr {$i - 1}]]
1044         } else {
1045                 append reflogm {: } $msg
1046         }
1047         set cmd [list git update-ref -m $reflogm HEAD $cmt_id $curHEAD]
1048         if {[catch {eval exec $cmd} err]} {
1049                 error_popup "update-ref failed:\n\n$err"
1050                 set ui_status_value {Commit failed.}
1051                 unlock_index
1052                 return
1053         }
1054
1055         # -- Cleanup after ourselves.
1056         #
1057         catch {file delete [gitdir MERGE_HEAD]}
1058         catch {file delete [gitdir MERGE_MSG]}
1059         catch {file delete [gitdir SQUASH_MSG]}
1060         catch {file delete [gitdir GITGUI_MSG]}
1061
1062         # -- Let rerere do its thing.
1063         #
1064         if {[file isdirectory [gitdir rr-cache]]} {
1065                 catch {exec git rerere}
1066         }
1067
1068         # -- Run the post-commit hook.
1069         #
1070         set pchook [gitdir hooks post-commit]
1071         if {[is_Windows] && [file isfile $pchook]} {
1072                 set pchook [list sh -c [concat \
1073                         "if test -x \"$pchook\";" \
1074                         "then exec \"$pchook\";" \
1075                         "fi"]]
1076         } elseif {![file executable $pchook]} {
1077                 set pchook {}
1078         }
1079         if {$pchook ne {}} {
1080                 catch {exec $pchook &}
1081         }
1082
1083         $ui_comm delete 0.0 end
1084         $ui_comm edit reset
1085         $ui_comm edit modified false
1086
1087         if {$single_commit} do_quit
1088
1089         # -- Update in memory status
1090         #
1091         set selected_commit_type new
1092         set commit_type normal
1093         set HEAD $cmt_id
1094         set PARENT $cmt_id
1095         set MERGE_HEAD [list]
1096
1097         foreach path [array names file_states] {
1098                 set s $file_states($path)
1099                 set m [lindex $s 0]
1100                 switch -glob -- $m {
1101                 _O -
1102                 _M -
1103                 _D {continue}
1104                 __ -
1105                 A_ -
1106                 M_ -
1107                 D_ {
1108                         unset file_states($path)
1109                         catch {unset selected_paths($path)}
1110                 }
1111                 DO {
1112                         set file_states($path) [list _O [lindex $s 1] {} {}]
1113                 }
1114                 AM -
1115                 AD -
1116                 MM -
1117                 MD {
1118                         set file_states($path) [list \
1119                                 _[string index $m 1] \
1120                                 [lindex $s 1] \
1121                                 [lindex $s 3] \
1122                                 {}]
1123                 }
1124                 }
1125         }
1126
1127         display_all_files
1128         unlock_index
1129         reshow_diff
1130         set ui_status_value \
1131                 "Changes committed as [string range $cmt_id 0 7]."
1132 }
1133
1134 ######################################################################
1135 ##
1136 ## fetch pull push
1137
1138 proc fetch_from {remote} {
1139         set w [new_console "fetch $remote" \
1140                 "Fetching new changes from $remote"]
1141         set cmd [list git fetch]
1142         lappend cmd $remote
1143         console_exec $w $cmd
1144 }
1145
1146 proc pull_remote {remote branch} {
1147         global HEAD commit_type file_states repo_config
1148
1149         if {![lock_index update]} return
1150
1151         # -- Our in memory state should match the repository.
1152         #
1153         repository_state curType curHEAD curMERGE_HEAD
1154         if {$commit_type ne $curType || $HEAD ne $curHEAD} {
1155                 info_popup {Last scanned state does not match repository state.
1156
1157 Another Git program has modified this repository
1158 since the last scan.  A rescan must be performed
1159 before a pull operation can be started.
1160
1161 The rescan will be automatically started now.
1162 }
1163                 unlock_index
1164                 rescan {set ui_status_value {Ready.}}
1165                 return
1166         }
1167
1168         # -- No differences should exist before a pull.
1169         #
1170         if {[array size file_states] != 0} {
1171                 error_popup {Uncommitted but modified files are present.
1172
1173 You should not perform a pull with unmodified
1174 files in your working directory as Git will be
1175 unable to recover from an incorrect merge.
1176
1177 You should commit or revert all changes before
1178 starting a pull operation.
1179 }
1180                 unlock_index
1181                 return
1182         }
1183
1184         set w [new_console "pull $remote $branch" \
1185                 "Pulling new changes from branch $branch in $remote"]
1186         set cmd [list git pull]
1187         if {$repo_config(gui.pullsummary) eq {false}} {
1188                 lappend cmd --no-summary
1189         }
1190         lappend cmd $remote
1191         lappend cmd $branch
1192         console_exec $w $cmd [list post_pull_remote $remote $branch]
1193 }
1194
1195 proc post_pull_remote {remote branch success} {
1196         global HEAD PARENT MERGE_HEAD commit_type selected_commit_type
1197         global ui_status_value
1198
1199         unlock_index
1200         if {$success} {
1201                 repository_state commit_type HEAD MERGE_HEAD
1202                 set PARENT $HEAD
1203                 set selected_commit_type new
1204                 set ui_status_value "Pulling $branch from $remote complete."
1205         } else {
1206                 rescan [list set ui_status_value \
1207                         "Conflicts detected while pulling $branch from $remote."]
1208         }
1209 }
1210
1211 proc push_to {remote} {
1212         set w [new_console "push $remote" \
1213                 "Pushing changes to $remote"]
1214         set cmd [list git push]
1215         lappend cmd $remote
1216         console_exec $w $cmd
1217 }
1218
1219 ######################################################################
1220 ##
1221 ## ui helpers
1222
1223 proc mapicon {w state path} {
1224         global all_icons
1225
1226         if {[catch {set r $all_icons($state$w)}]} {
1227                 puts "error: no icon for $w state={$state} $path"
1228                 return file_plain
1229         }
1230         return $r
1231 }
1232
1233 proc mapdesc {state path} {
1234         global all_descs
1235
1236         if {[catch {set r $all_descs($state)}]} {
1237                 puts "error: no desc for state={$state} $path"
1238                 return $state
1239         }
1240         return $r
1241 }
1242
1243 proc escape_path {path} {
1244         regsub -all "\n" $path "\\n" path
1245         return $path
1246 }
1247
1248 proc short_path {path} {
1249         return [escape_path [lindex [file split $path] end]]
1250 }
1251
1252 set next_icon_id 0
1253 set null_sha1 [string repeat 0 40]
1254
1255 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1256         global file_states next_icon_id null_sha1
1257
1258         set s0 [string index $new_state 0]
1259         set s1 [string index $new_state 1]
1260
1261         if {[catch {set info $file_states($path)}]} {
1262                 set state __
1263                 set icon n[incr next_icon_id]
1264         } else {
1265                 set state [lindex $info 0]
1266                 set icon [lindex $info 1]
1267                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1268                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1269         }
1270
1271         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1272         elseif {$s0 eq {_}} {set s0 _}
1273
1274         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1275         elseif {$s1 eq {_}} {set s1 _}
1276
1277         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1278                 set head_info [list 0 $null_sha1]
1279         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1280                 && $head_info eq {}} {
1281                 set head_info $index_info
1282         }
1283
1284         set file_states($path) [list $s0$s1 $icon \
1285                 $head_info $index_info \
1286                 ]
1287         return $state
1288 }
1289
1290 proc display_file_helper {w path icon_name old_m new_m} {
1291         global file_lists
1292
1293         if {$new_m eq {_}} {
1294                 set lno [lsearch -sorted $file_lists($w) $path]
1295                 if {$lno >= 0} {
1296                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1297                         incr lno
1298                         $w conf -state normal
1299                         $w delete $lno.0 [expr {$lno + 1}].0
1300                         $w conf -state disabled
1301                 }
1302         } elseif {$old_m eq {_} && $new_m ne {_}} {
1303                 lappend file_lists($w) $path
1304                 set file_lists($w) [lsort -unique $file_lists($w)]
1305                 set lno [lsearch -sorted $file_lists($w) $path]
1306                 incr lno
1307                 $w conf -state normal
1308                 $w image create $lno.0 \
1309                         -align center -padx 5 -pady 1 \
1310                         -name $icon_name \
1311                         -image [mapicon $w $new_m $path]
1312                 $w insert $lno.1 "[escape_path $path]\n"
1313                 $w conf -state disabled
1314         } elseif {$old_m ne $new_m} {
1315                 $w conf -state normal
1316                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1317                 $w conf -state disabled
1318         }
1319 }
1320
1321 proc display_file {path state} {
1322         global file_states selected_paths
1323         global ui_index ui_workdir
1324
1325         set old_m [merge_state $path $state]
1326         set s $file_states($path)
1327         set new_m [lindex $s 0]
1328         set icon_name [lindex $s 1]
1329
1330         display_file_helper     $ui_index $path $icon_name \
1331                 [string index $old_m 0] \
1332                 [string index $new_m 0]
1333         display_file_helper     $ui_workdir $path $icon_name \
1334                 [string index $old_m 1] \
1335                 [string index $new_m 1]
1336
1337         if {$new_m eq {__}} {
1338                 unset file_states($path)
1339                 catch {unset selected_paths($path)}
1340         }
1341 }
1342
1343 proc display_all_files_helper {w path icon_name m} {
1344         global file_lists
1345
1346         lappend file_lists($w) $path
1347         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1348         $w image create end \
1349                 -align center -padx 5 -pady 1 \
1350                 -name $icon_name \
1351                 -image [mapicon $w $m $path]
1352         $w insert end "[escape_path $path]\n"
1353 }
1354
1355 proc display_all_files {} {
1356         global ui_index ui_workdir
1357         global file_states file_lists
1358         global last_clicked
1359
1360         $ui_index conf -state normal
1361         $ui_workdir conf -state normal
1362
1363         $ui_index delete 0.0 end
1364         $ui_workdir delete 0.0 end
1365         set last_clicked {}
1366
1367         set file_lists($ui_index) [list]
1368         set file_lists($ui_workdir) [list]
1369
1370         foreach path [lsort [array names file_states]] {
1371                 set s $file_states($path)
1372                 set m [lindex $s 0]
1373                 set icon_name [lindex $s 1]
1374
1375                 if {[string index $m 0] ne {_}} {
1376                         display_all_files_helper $ui_index $path \
1377                                 $icon_name [string index $m 0]
1378                 }
1379                 if {[string index $m 1] ne {_}} {
1380                         display_all_files_helper $ui_workdir $path \
1381                                 $icon_name [string index $m 1]
1382                 }
1383         }
1384
1385         $ui_index conf -state disabled
1386         $ui_workdir conf -state disabled
1387 }
1388
1389 proc update_indexinfo {msg pathList after} {
1390         global update_index_cp ui_status_value
1391
1392         if {![lock_index update]} return
1393
1394         set update_index_cp 0
1395         set pathList [lsort $pathList]
1396         set totalCnt [llength $pathList]
1397         set batch [expr {int($totalCnt * .01) + 1}]
1398         if {$batch > 25} {set batch 25}
1399
1400         set ui_status_value [format \
1401                 "$msg... %i/%i files (%.2f%%)" \
1402                 $update_index_cp \
1403                 $totalCnt \
1404                 0.0]
1405         set fd [open "| git update-index -z --index-info" w]
1406         fconfigure $fd \
1407                 -blocking 0 \
1408                 -buffering full \
1409                 -buffersize 512 \
1410                 -translation binary
1411         fileevent $fd writable [list \
1412                 write_update_indexinfo \
1413                 $fd \
1414                 $pathList \
1415                 $totalCnt \
1416                 $batch \
1417                 $msg \
1418                 $after \
1419                 ]
1420 }
1421
1422 proc write_update_indexinfo {fd pathList totalCnt batch msg after} {
1423         global update_index_cp ui_status_value
1424         global file_states current_diff
1425
1426         if {$update_index_cp >= $totalCnt} {
1427                 close $fd
1428                 unlock_index
1429                 uplevel #0 $after
1430                 return
1431         }
1432
1433         for {set i $batch} \
1434                 {$update_index_cp < $totalCnt && $i > 0} \
1435                 {incr i -1} {
1436                 set path [lindex $pathList $update_index_cp]
1437                 incr update_index_cp
1438
1439                 set s $file_states($path)
1440                 switch -glob -- [lindex $s 0] {
1441                 A? {set new _O}
1442                 M? {set new _M}
1443                 D_ {set new _D}
1444                 D? {set new _?}
1445                 ?? {continue}
1446                 }
1447                 set info [lindex $s 2]
1448                 if {$info eq {}} continue
1449
1450                 puts -nonewline $fd "$info\t$path\0"
1451                 display_file $path $new
1452         }
1453
1454         set ui_status_value [format \
1455                 "$msg... %i/%i files (%.2f%%)" \
1456                 $update_index_cp \
1457                 $totalCnt \
1458                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1459 }
1460
1461 proc update_index {msg pathList after} {
1462         global update_index_cp ui_status_value
1463
1464         if {![lock_index update]} return
1465
1466         set update_index_cp 0
1467         set pathList [lsort $pathList]
1468         set totalCnt [llength $pathList]
1469         set batch [expr {int($totalCnt * .01) + 1}]
1470         if {$batch > 25} {set batch 25}
1471
1472         set ui_status_value [format \
1473                 "$msg... %i/%i files (%.2f%%)" \
1474                 $update_index_cp \
1475                 $totalCnt \
1476                 0.0]
1477         set fd [open "| git update-index --add --remove -z --stdin" w]
1478         fconfigure $fd \
1479                 -blocking 0 \
1480                 -buffering full \
1481                 -buffersize 512 \
1482                 -translation binary
1483         fileevent $fd writable [list \
1484                 write_update_index \
1485                 $fd \
1486                 $pathList \
1487                 $totalCnt \
1488                 $batch \
1489                 $msg \
1490                 $after \
1491                 ]
1492 }
1493
1494 proc write_update_index {fd pathList totalCnt batch msg after} {
1495         global update_index_cp ui_status_value
1496         global file_states current_diff
1497
1498         if {$update_index_cp >= $totalCnt} {
1499                 close $fd
1500                 unlock_index
1501                 uplevel #0 $after
1502                 return
1503         }
1504
1505         for {set i $batch} \
1506                 {$update_index_cp < $totalCnt && $i > 0} \
1507                 {incr i -1} {
1508                 set path [lindex $pathList $update_index_cp]
1509                 incr update_index_cp
1510
1511                 switch -glob -- [lindex $file_states($path) 0] {
1512                 AD {set new __}
1513                 ?D {set new D_}
1514                 _O -
1515                 AM {set new A_}
1516                 U_ -
1517                 ?M {set new M_}
1518                 ?? {continue}
1519                 }
1520                 puts -nonewline $fd "$path\0"
1521                 display_file $path $new
1522         }
1523
1524         set ui_status_value [format \
1525                 "$msg... %i/%i files (%.2f%%)" \
1526                 $update_index_cp \
1527                 $totalCnt \
1528                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1529 }
1530
1531 proc checkout_index {msg pathList after} {
1532         global update_index_cp ui_status_value
1533
1534         if {![lock_index update]} return
1535
1536         set update_index_cp 0
1537         set pathList [lsort $pathList]
1538         set totalCnt [llength $pathList]
1539         set batch [expr {int($totalCnt * .01) + 1}]
1540         if {$batch > 25} {set batch 25}
1541
1542         set ui_status_value [format \
1543                 "$msg... %i/%i files (%.2f%%)" \
1544                 $update_index_cp \
1545                 $totalCnt \
1546                 0.0]
1547         set cmd [list git checkout-index]
1548         lappend cmd --index
1549         lappend cmd --quiet
1550         lappend cmd --force
1551         lappend cmd -z
1552         lappend cmd --stdin
1553         set fd [open "| $cmd " w]
1554         fconfigure $fd \
1555                 -blocking 0 \
1556                 -buffering full \
1557                 -buffersize 512 \
1558                 -translation binary
1559         fileevent $fd writable [list \
1560                 write_checkout_index \
1561                 $fd \
1562                 $pathList \
1563                 $totalCnt \
1564                 $batch \
1565                 $msg \
1566                 $after \
1567                 ]
1568 }
1569
1570 proc write_checkout_index {fd pathList totalCnt batch msg after} {
1571         global update_index_cp ui_status_value
1572         global file_states current_diff
1573
1574         if {$update_index_cp >= $totalCnt} {
1575                 close $fd
1576                 unlock_index
1577                 uplevel #0 $after
1578                 return
1579         }
1580
1581         for {set i $batch} \
1582                 {$update_index_cp < $totalCnt && $i > 0} \
1583                 {incr i -1} {
1584                 set path [lindex $pathList $update_index_cp]
1585                 incr update_index_cp
1586                 switch -glob -- [lindex $file_states($path) 0] {
1587                 U? {continue}
1588                 ?M -
1589                 ?D {
1590                         puts -nonewline $fd "$path\0"
1591                         display_file $path ?_
1592                 }
1593                 }
1594         }
1595
1596         set ui_status_value [format \
1597                 "$msg... %i/%i files (%.2f%%)" \
1598                 $update_index_cp \
1599                 $totalCnt \
1600                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1601 }
1602
1603 ######################################################################
1604 ##
1605 ## branch management
1606
1607 proc load_all_heads {} {
1608         global all_heads tracking_branches
1609
1610         set all_heads [list]
1611         set cmd [list git for-each-ref]
1612         lappend cmd --format=%(refname)
1613         lappend cmd refs/heads
1614         set fd [open "| $cmd" r]
1615         while {[gets $fd line] > 0} {
1616                 if {![catch {set info $tracking_branches($line)}]} continue
1617                 if {![regsub ^refs/heads/ $line {} name]} continue
1618                 lappend all_heads $name
1619         }
1620         close $fd
1621
1622         set all_heads [lsort $all_heads]
1623 }
1624
1625 proc populate_branch_menu {} {
1626         global all_heads disable_on_lock
1627
1628         set m .mbar.branch
1629         set last [$m index last]
1630         for {set i 0} {$i <= $last} {incr i} {
1631                 if {[$m type $i] eq {separator}} {
1632                         $m delete $i last
1633                         set new_dol [list]
1634                         foreach a $disable_on_lock {
1635                                 if {[lindex $a 0] ne $m || [lindex $a 2] < $i} {
1636                                         lappend new_dol $a
1637                                 }
1638                         }
1639                         set disable_on_lock $new_dol
1640                         break
1641                 }
1642         }
1643
1644         $m add separator
1645         foreach b $all_heads {
1646                 $m add radiobutton \
1647                         -label $b \
1648                         -command [list switch_branch $b] \
1649                         -variable current_branch \
1650                         -value $b \
1651                         -font font_ui
1652                 lappend disable_on_lock \
1653                         [list $m entryconf [$m index last] -state]
1654         }
1655 }
1656
1657 proc do_create_branch_action {w} {
1658         global all_heads null_sha1
1659         global create_branch_checkout create_branch_revtype create_branch_head
1660
1661         set newbranch [string trim [$w.name.t get 0.0 end]]
1662         if {![catch {exec git show-ref --verify -- "refs/heads/$newbranch"}]} {
1663                 tk_messageBox \
1664                         -icon error \
1665                         -type ok \
1666                         -title [wm title $w] \
1667                         -parent $w \
1668                         -message "Branch '$newbranch' already exists."
1669                 focus $w.name.t
1670                 return
1671         }
1672         if {[catch {exec git check-ref-format "heads/$newbranch"}]} {
1673                 tk_messageBox \
1674                         -icon error \
1675                         -type ok \
1676                         -title [wm title $w] \
1677                         -parent $w \
1678                         -message "We do not like '$newbranch' as a branch name."
1679                 focus $w.name.t
1680                 return
1681         }
1682
1683         set rev {}
1684         switch -- $create_branch_revtype {
1685         head {set rev $create_branch_head}
1686         expression {set rev [string trim [$w.from.exp.t get 0.0 end]]}
1687         }
1688         if {[catch {set cmt [exec git rev-parse --verify "${rev}^0"]}]} {
1689                 tk_messageBox \
1690                         -icon error \
1691                         -type ok \
1692                         -title [wm title $w] \
1693                         -parent $w \
1694                         -message "Invalid starting revision: $rev"
1695                 return
1696         }
1697         set cmd [list git update-ref]
1698         lappend cmd -m
1699         lappend cmd "branch: Created from $rev"
1700         lappend cmd "refs/heads/$newbranch"
1701         lappend cmd $cmt
1702         lappend cmd $null_sha1
1703         if {[catch {eval exec $cmd} err]} {
1704                 tk_messageBox \
1705                         -icon error \
1706                         -type ok \
1707                         -title [wm title $w] \
1708                         -parent $w \
1709                         -message "Failed to create '$newbranch'.\n\n$err"
1710                 return
1711         }
1712
1713         lappend all_heads $newbranch
1714         set all_heads [lsort $all_heads]
1715         populate_branch_menu
1716         destroy $w
1717 }
1718
1719 proc do_create_branch {} {
1720         global all_heads current_branch
1721         global create_branch_checkout create_branch_revtype create_branch_head
1722
1723         set create_branch_checkout true
1724         set create_branch_revtype head
1725         set create_branch_head $current_branch
1726
1727         set w .branch_editor
1728         toplevel $w
1729         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
1730
1731         label $w.header -text {Create New Branch} \
1732                 -font font_uibold
1733         pack $w.header -side top -fill x
1734
1735         frame $w.buttons
1736         button $w.buttons.create -text Create \
1737                 -font font_ui \
1738                 -default active \
1739                 -command [list do_create_branch_action $w]
1740         pack $w.buttons.create -side right
1741         button $w.buttons.cancel -text {Cancel} \
1742                 -font font_ui \
1743                 -command [list destroy $w]
1744         pack $w.buttons.cancel -side right -padx 5
1745         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
1746
1747         labelframe $w.name \
1748                 -text {Branch Description} \
1749                 -font font_ui
1750         label $w.name.l -text {Name:} -font font_ui
1751         text $w.name.t \
1752                 -height 1 \
1753                 -width 40 \
1754                 -font font_ui
1755         bind $w.name.t <Shift-Key-Tab> "focus $w.postActions.checkout;break"
1756         bind $w.name.t <Key-Tab> "focus $w.from.exp.t;break"
1757         bind $w.name.t <Key-Return> "do_create_branch_action $w;break"
1758         bind $w.name.t <Key> {
1759                 if {{%K} ne {BackSpace}
1760                         && {%K} ne {Tab}
1761                         && {%K} ne {Escape}
1762                         && {%K} ne {Return}} {
1763                         if {%k <= 32} break
1764                         if {[string first %A {~^:?*[}] >= 0} break
1765                 }
1766         }
1767         pack $w.name.l -side left -padx 5
1768         pack $w.name.t -side left -fill x -expand 1
1769         pack $w.name -anchor nw -fill x -pady 5 -padx 5
1770
1771         labelframe $w.from \
1772                 -text {Starting Revision} \
1773                 -font font_ui
1774         frame $w.from.head
1775         radiobutton $w.from.head.r \
1776                 -text {Local Branch:} \
1777                 -value head \
1778                 -variable create_branch_revtype \
1779                 -font font_ui
1780         eval tk_optionMenu $w.from.head.m create_branch_head $all_heads
1781         pack $w.from.head.r -side left
1782         pack $w.from.head.m -side left
1783         frame $w.from.exp
1784         radiobutton $w.from.exp.r \
1785                 -text {Revision Expression:} \
1786                 -value expression \
1787                 -variable create_branch_revtype \
1788                 -font font_ui
1789         text $w.from.exp.t \
1790                 -height 1 \
1791                 -width 50 \
1792                 -font font_ui
1793         bind $w.from.exp.t <Shift-Key-Tab> "focus $w.name.t;break"
1794         bind $w.from.exp.t <Key-Tab> "focus $w.postActions.checkout;break"
1795         bind $w.from.exp.t <Key-Return> "do_create_branch_action $w;break"
1796         pack $w.from.exp.r -side left
1797         pack $w.from.exp.t -side left -fill x -expand 1
1798         pack $w.from.head -padx 5 -fill x -expand 1
1799         pack $w.from.exp -padx 5 -fill x -expand 1
1800         pack $w.from -anchor nw -fill x -pady 5 -padx 5
1801
1802         labelframe $w.postActions \
1803                 -text {Post Creation Actions} \
1804                 -font font_ui
1805         checkbutton $w.postActions.checkout \
1806                 -text {Checkout after creation} \
1807                 -offvalue false \
1808                 -onvalue true \
1809                 -variable create_branch_checkout \
1810                 -font font_ui
1811         pack $w.postActions.checkout -anchor nw
1812         pack $w.postActions -anchor nw -fill x -pady 5 -padx 5
1813
1814         bind $w <Visibility> "grab $w; focus $w.name.t"
1815         bind $w <Key-Escape> "destroy $w"
1816         bind $w <Key-Return> "do_create_branch_action $w;break"
1817         wm title $w "[appname] ([reponame]): Create Branch"
1818         tkwait window $w
1819 }
1820
1821 proc do_delete_branch_action {w} {
1822         global all_heads
1823         global delete_branch_checkhead delete_branch_head
1824
1825         set to_delete [list]
1826         set msg {Are you sure you want to delete the following branches?
1827
1828 }
1829         foreach i [$w.list.l curselection] {
1830                 set b [$w.list.l get $i]
1831                 if {[catch {set o [exec git rev-parse --verify $b]}]} continue
1832                 if {$delete_branch_checkhead} {
1833                         if {[catch {set m [exec git merge-base $o $delete_branch_head]}]} continue
1834                         if {$o ne $m} continue
1835                 }
1836                 lappend to_delete [list $b $o]
1837                 append msg " - $b\n"
1838         }
1839         if {$to_delete eq {}} {
1840                 tk_messageBox \
1841                         -icon info \
1842                         -type ok \
1843                         -title [wm title $w] \
1844                         -parent $w \
1845                         -message {No branches are able to be deleted.
1846
1847 This is likely because you did not select any branches,
1848 or all selected branches are not completely merged.
1849 }
1850                 return
1851         }
1852         append msg {
1853 It can be difficult to recover deleted branches.
1854
1855 Delete the above branches?}
1856         if {[tk_messageBox \
1857                 -icon warning \
1858                 -type yesno \
1859                 -title [wm title $w] \
1860                 -parent $w \
1861                 -message $msg] ne yes} {
1862                 return
1863         }
1864
1865         set failed {}
1866         foreach i $to_delete {
1867                 set b [lindex $i 0]
1868                 set o [lindex $i 1]
1869                 if {[catch {exec git update-ref -d "refs/heads/$b" $o} err]} {
1870                         append failed " - $b: $err\n"
1871                 } else {
1872                         set x [lsearch -sorted $all_heads $b]
1873                         if {$x >= 0} {
1874                                 set all_heads [lreplace $all_heads $x $x]
1875                         }
1876                 }
1877         }
1878
1879         if {$failed ne {}} {
1880                 tk_messageBox \
1881                         -icon error \
1882                         -type ok \
1883                         -title [wm title $w] \
1884                         -parent $w \
1885                         -message "Failed to delete branches:\n$failed"
1886         }
1887
1888         set all_heads [lsort $all_heads]
1889         populate_branch_menu
1890         destroy $w
1891 }
1892
1893 proc do_delete_branch {} {
1894         global all_heads current_branch
1895         global delete_branch_checkhead delete_branch_head
1896
1897         set delete_branch_checkhead 1
1898         set delete_branch_head $current_branch
1899
1900         set w .branch_editor
1901         toplevel $w
1902         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
1903
1904         label $w.header -text {Delete Local Branch} \
1905                 -font font_uibold
1906         pack $w.header -side top -fill x
1907
1908         frame $w.buttons
1909         button $w.buttons.create -text Delete \
1910                 -font font_ui \
1911                 -command [list do_delete_branch_action $w]
1912         pack $w.buttons.create -side right
1913         button $w.buttons.cancel -text {Cancel} \
1914                 -font font_ui \
1915                 -command [list destroy $w]
1916         pack $w.buttons.cancel -side right -padx 5
1917         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
1918
1919         labelframe $w.list \
1920                 -text {Local Branches} \
1921                 -font font_ui
1922         listbox $w.list.l \
1923                 -height 10 \
1924                 -width 50 \
1925                 -selectmode extended \
1926                 -font font_ui
1927         foreach h $all_heads {
1928                 if {$h ne $current_branch} {
1929                         $w.list.l insert end $h
1930                 }
1931         }
1932         pack $w.list.l -fill both -pady 5 -padx 5
1933         pack $w.list -fill both -pady 5 -padx 5
1934
1935         labelframe $w.validate \
1936                 -text {Only Delete If} \
1937                 -font font_ui
1938         frame $w.validate.head
1939         checkbutton $w.validate.head.r \
1940                 -text {Already Merged Into Local Branch:} \
1941                 -variable delete_branch_checkhead \
1942                 -font font_ui
1943         eval tk_optionMenu $w.validate.head.m delete_branch_head $all_heads
1944         pack $w.validate.head.r -side left
1945         pack $w.validate.head.m -side left
1946         pack $w.validate.head -padx 5 -fill x -expand 1
1947         pack $w.validate -anchor nw -fill x -pady 5 -padx 5
1948
1949         bind $w <Visibility> "grab $w; focus $w"
1950         bind $w <Key-Escape> "destroy $w"
1951         wm title $w "[appname] ([reponame]): Delete Branch"
1952         tkwait window $w
1953 }
1954
1955 proc switch_branch {b} {
1956         global HEAD commit_type file_states current_branch
1957         global selected_commit_type ui_comm
1958
1959         if {![lock_index switch]} return
1960
1961         # -- Backup the selected branch (repository_state resets it)
1962         #
1963         set new_branch $current_branch
1964
1965         # -- Our in memory state should match the repository.
1966         #
1967         repository_state curType curHEAD curMERGE_HEAD
1968         if {[string match amend* $commit_type]
1969                 && $curType eq {normal}
1970                 && $curHEAD eq $HEAD} {
1971         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
1972                 info_popup {Last scanned state does not match repository state.
1973
1974 Another Git program has modified this repository
1975 since the last scan.  A rescan must be performed
1976 before the current branch can be changed.
1977
1978 The rescan will be automatically started now.
1979 }
1980                 unlock_index
1981                 rescan {set ui_status_value {Ready.}}
1982                 return
1983         }
1984
1985         # -- Toss the message buffer if we are in amend mode.
1986         #
1987         if {[string match amend* $curType]} {
1988                 $ui_comm delete 0.0 end
1989                 $ui_comm edit reset
1990                 $ui_comm edit modified false
1991         }
1992
1993         set selected_commit_type new
1994         set current_branch $new_branch
1995
1996         unlock_index
1997         error "NOT FINISHED"
1998 }
1999
2000 ######################################################################
2001 ##
2002 ## remote management
2003
2004 proc load_all_remotes {} {
2005         global repo_config
2006         global all_remotes tracking_branches
2007
2008         set all_remotes [list]
2009         array unset tracking_branches
2010
2011         set rm_dir [gitdir remotes]
2012         if {[file isdirectory $rm_dir]} {
2013                 set all_remotes [glob \
2014                         -types f \
2015                         -tails \
2016                         -nocomplain \
2017                         -directory $rm_dir *]
2018
2019                 foreach name $all_remotes {
2020                         catch {
2021                                 set fd [open [file join $rm_dir $name] r]
2022                                 while {[gets $fd line] >= 0} {
2023                                         if {![regexp {^Pull:[   ]*([^:]+):(.+)$} \
2024                                                 $line line src dst]} continue
2025                                         if {![regexp ^refs/ $dst]} {
2026                                                 set dst "refs/heads/$dst"
2027                                         }
2028                                         set tracking_branches($dst) [list $name $src]
2029                                 }
2030                                 close $fd
2031                         }
2032                 }
2033         }
2034
2035         foreach line [array names repo_config remote.*.url] {
2036                 if {![regexp ^remote\.(.*)\.url\$ $line line name]} continue
2037                 lappend all_remotes $name
2038
2039                 if {[catch {set fl $repo_config(remote.$name.fetch)}]} {
2040                         set fl {}
2041                 }
2042                 foreach line $fl {
2043                         if {![regexp {^([^:]+):(.+)$} $line line src dst]} continue
2044                         if {![regexp ^refs/ $dst]} {
2045                                 set dst "refs/heads/$dst"
2046                         }
2047                         set tracking_branches($dst) [list $name $src]
2048                 }
2049         }
2050
2051         set all_remotes [lsort -unique $all_remotes]
2052 }
2053
2054 proc populate_fetch_menu {m} {
2055         global all_remotes repo_config
2056
2057         foreach r $all_remotes {
2058                 set enable 0
2059                 if {![catch {set a $repo_config(remote.$r.url)}]} {
2060                         if {![catch {set a $repo_config(remote.$r.fetch)}]} {
2061                                 set enable 1
2062                         }
2063                 } else {
2064                         catch {
2065                                 set fd [open [gitdir remotes $r] r]
2066                                 while {[gets $fd n] >= 0} {
2067                                         if {[regexp {^Pull:[ \t]*([^:]+):} $n]} {
2068                                                 set enable 1
2069                                                 break
2070                                         }
2071                                 }
2072                                 close $fd
2073                         }
2074                 }
2075
2076                 if {$enable} {
2077                         $m add command \
2078                                 -label "Fetch from $r..." \
2079                                 -command [list fetch_from $r] \
2080                                 -font font_ui
2081                 }
2082         }
2083 }
2084
2085 proc populate_push_menu {m} {
2086         global all_remotes repo_config
2087
2088         foreach r $all_remotes {
2089                 set enable 0
2090                 if {![catch {set a $repo_config(remote.$r.url)}]} {
2091                         if {![catch {set a $repo_config(remote.$r.push)}]} {
2092                                 set enable 1
2093                         }
2094                 } else {
2095                         catch {
2096                                 set fd [open [gitdir remotes $r] r]
2097                                 while {[gets $fd n] >= 0} {
2098                                         if {[regexp {^Push:[ \t]*([^:]+):} $n]} {
2099                                                 set enable 1
2100                                                 break
2101                                         }
2102                                 }
2103                                 close $fd
2104                         }
2105                 }
2106
2107                 if {$enable} {
2108                         $m add command \
2109                                 -label "Push to $r..." \
2110                                 -command [list push_to $r] \
2111                                 -font font_ui
2112                 }
2113         }
2114 }
2115
2116 proc populate_pull_menu {m} {
2117         global repo_config all_remotes disable_on_lock
2118
2119         foreach remote $all_remotes {
2120                 set rb_list [list]
2121                 if {[array get repo_config remote.$remote.url] ne {}} {
2122                         if {[array get repo_config remote.$remote.fetch] ne {}} {
2123                                 foreach line $repo_config(remote.$remote.fetch) {
2124                                         if {[regexp {^([^:]+):} $line line rb]} {
2125                                                 lappend rb_list $rb
2126                                         }
2127                                 }
2128                         }
2129                 } else {
2130                         catch {
2131                                 set fd [open [gitdir remotes $remote] r]
2132                                 while {[gets $fd line] >= 0} {
2133                                         if {[regexp {^Pull:[ \t]*([^:]+):} $line line rb]} {
2134                                                 lappend rb_list $rb
2135                                         }
2136                                 }
2137                                 close $fd
2138                         }
2139                 }
2140
2141                 foreach rb $rb_list {
2142                         regsub ^refs/heads/ $rb {} rb_short
2143                         $m add command \
2144                                 -label "Branch $rb_short from $remote..." \
2145                                 -command [list pull_remote $remote $rb] \
2146                                 -font font_ui
2147                         lappend disable_on_lock \
2148                                 [list $m entryconf [$m index last] -state]
2149                 }
2150         }
2151 }
2152
2153 ######################################################################
2154 ##
2155 ## icons
2156
2157 set filemask {
2158 #define mask_width 14
2159 #define mask_height 15
2160 static unsigned char mask_bits[] = {
2161    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2162    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2163    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
2164 }
2165
2166 image create bitmap file_plain -background white -foreground black -data {
2167 #define plain_width 14
2168 #define plain_height 15
2169 static unsigned char plain_bits[] = {
2170    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2171    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
2172    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2173 } -maskdata $filemask
2174
2175 image create bitmap file_mod -background white -foreground blue -data {
2176 #define mod_width 14
2177 #define mod_height 15
2178 static unsigned char mod_bits[] = {
2179    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2180    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2181    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2182 } -maskdata $filemask
2183
2184 image create bitmap file_fulltick -background white -foreground "#007000" -data {
2185 #define file_fulltick_width 14
2186 #define file_fulltick_height 15
2187 static unsigned char file_fulltick_bits[] = {
2188    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
2189    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
2190    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2191 } -maskdata $filemask
2192
2193 image create bitmap file_parttick -background white -foreground "#005050" -data {
2194 #define parttick_width 14
2195 #define parttick_height 15
2196 static unsigned char parttick_bits[] = {
2197    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2198    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
2199    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2200 } -maskdata $filemask
2201
2202 image create bitmap file_question -background white -foreground black -data {
2203 #define file_question_width 14
2204 #define file_question_height 15
2205 static unsigned char file_question_bits[] = {
2206    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
2207    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
2208    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2209 } -maskdata $filemask
2210
2211 image create bitmap file_removed -background white -foreground red -data {
2212 #define file_removed_width 14
2213 #define file_removed_height 15
2214 static unsigned char file_removed_bits[] = {
2215    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2216    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
2217    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
2218 } -maskdata $filemask
2219
2220 image create bitmap file_merge -background white -foreground blue -data {
2221 #define file_merge_width 14
2222 #define file_merge_height 15
2223 static unsigned char file_merge_bits[] = {
2224    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
2225    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2226    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2227 } -maskdata $filemask
2228
2229 set ui_index .vpane.files.index.list
2230 set ui_workdir .vpane.files.workdir.list
2231
2232 set all_icons(_$ui_index)   file_plain
2233 set all_icons(A$ui_index)   file_fulltick
2234 set all_icons(M$ui_index)   file_fulltick
2235 set all_icons(D$ui_index)   file_removed
2236 set all_icons(U$ui_index)   file_merge
2237
2238 set all_icons(_$ui_workdir) file_plain
2239 set all_icons(M$ui_workdir) file_mod
2240 set all_icons(D$ui_workdir) file_question
2241 set all_icons(O$ui_workdir) file_plain
2242
2243 set max_status_desc 0
2244 foreach i {
2245                 {__ "Unmodified"}
2246
2247                 {_M "Modified, not staged"}
2248                 {M_ "Staged for commit"}
2249                 {MM "Portions staged for commit"}
2250                 {MD "Staged for commit, missing"}
2251
2252                 {_O "Untracked, not staged"}
2253                 {A_ "Staged for commit"}
2254                 {AM "Portions staged for commit"}
2255                 {AD "Staged for commit, missing"}
2256
2257                 {_D "Missing"}
2258                 {D_ "Staged for removal"}
2259                 {DO "Staged for removal, still present"}
2260
2261                 {U_ "Requires merge resolution"}
2262                 {UM "Requires merge resolution"}
2263                 {UD "Requires merge resolution"}
2264         } {
2265         if {$max_status_desc < [string length [lindex $i 1]]} {
2266                 set max_status_desc [string length [lindex $i 1]]
2267         }
2268         set all_descs([lindex $i 0]) [lindex $i 1]
2269 }
2270 unset i
2271
2272 ######################################################################
2273 ##
2274 ## util
2275
2276 proc is_MacOSX {} {
2277         global tcl_platform tk_library
2278         if {[tk windowingsystem] eq {aqua}} {
2279                 return 1
2280         }
2281         return 0
2282 }
2283
2284 proc is_Windows {} {
2285         global tcl_platform
2286         if {$tcl_platform(platform) eq {windows}} {
2287                 return 1
2288         }
2289         return 0
2290 }
2291
2292 proc bind_button3 {w cmd} {
2293         bind $w <Any-Button-3> $cmd
2294         if {[is_MacOSX]} {
2295                 bind $w <Control-Button-1> $cmd
2296         }
2297 }
2298
2299 proc incr_font_size {font {amt 1}} {
2300         set sz [font configure $font -size]
2301         incr sz $amt
2302         font configure $font -size $sz
2303         font configure ${font}bold -size $sz
2304 }
2305
2306 proc hook_failed_popup {hook msg} {
2307         set w .hookfail
2308         toplevel $w
2309
2310         frame $w.m
2311         label $w.m.l1 -text "$hook hook failed:" \
2312                 -anchor w \
2313                 -justify left \
2314                 -font font_uibold
2315         text $w.m.t \
2316                 -background white -borderwidth 1 \
2317                 -relief sunken \
2318                 -width 80 -height 10 \
2319                 -font font_diff \
2320                 -yscrollcommand [list $w.m.sby set]
2321         label $w.m.l2 \
2322                 -text {You must correct the above errors before committing.} \
2323                 -anchor w \
2324                 -justify left \
2325                 -font font_uibold
2326         scrollbar $w.m.sby -command [list $w.m.t yview]
2327         pack $w.m.l1 -side top -fill x
2328         pack $w.m.l2 -side bottom -fill x
2329         pack $w.m.sby -side right -fill y
2330         pack $w.m.t -side left -fill both -expand 1
2331         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2332
2333         $w.m.t insert 1.0 $msg
2334         $w.m.t conf -state disabled
2335
2336         button $w.ok -text OK \
2337                 -width 15 \
2338                 -font font_ui \
2339                 -command "destroy $w"
2340         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2341
2342         bind $w <Visibility> "grab $w; focus $w"
2343         bind $w <Key-Return> "destroy $w"
2344         wm title $w "[appname] ([reponame]): error"
2345         tkwait window $w
2346 }
2347
2348 set next_console_id 0
2349
2350 proc new_console {short_title long_title} {
2351         global next_console_id console_data
2352         set w .console[incr next_console_id]
2353         set console_data($w) [list $short_title $long_title]
2354         return [console_init $w]
2355 }
2356
2357 proc console_init {w} {
2358         global console_cr console_data M1B
2359
2360         set console_cr($w) 1.0
2361         toplevel $w
2362         frame $w.m
2363         label $w.m.l1 -text "[lindex $console_data($w) 1]:" \
2364                 -anchor w \
2365                 -justify left \
2366                 -font font_uibold
2367         text $w.m.t \
2368                 -background white -borderwidth 1 \
2369                 -relief sunken \
2370                 -width 80 -height 10 \
2371                 -font font_diff \
2372                 -state disabled \
2373                 -yscrollcommand [list $w.m.sby set]
2374         label $w.m.s -text {Working... please wait...} \
2375                 -anchor w \
2376                 -justify left \
2377                 -font font_uibold
2378         scrollbar $w.m.sby -command [list $w.m.t yview]
2379         pack $w.m.l1 -side top -fill x
2380         pack $w.m.s -side bottom -fill x
2381         pack $w.m.sby -side right -fill y
2382         pack $w.m.t -side left -fill both -expand 1
2383         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2384
2385         menu $w.ctxm -tearoff 0
2386         $w.ctxm add command -label "Copy" \
2387                 -font font_ui \
2388                 -command "tk_textCopy $w.m.t"
2389         $w.ctxm add command -label "Select All" \
2390                 -font font_ui \
2391                 -command "$w.m.t tag add sel 0.0 end"
2392         $w.ctxm add command -label "Copy All" \
2393                 -font font_ui \
2394                 -command "
2395                         $w.m.t tag add sel 0.0 end
2396                         tk_textCopy $w.m.t
2397                         $w.m.t tag remove sel 0.0 end
2398                 "
2399
2400         button $w.ok -text {Close} \
2401                 -font font_ui \
2402                 -state disabled \
2403                 -command "destroy $w"
2404         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2405
2406         bind_button3 $w.m.t "tk_popup $w.ctxm %X %Y"
2407         bind $w.m.t <$M1B-Key-a> "$w.m.t tag add sel 0.0 end;break"
2408         bind $w.m.t <$M1B-Key-A> "$w.m.t tag add sel 0.0 end;break"
2409         bind $w <Visibility> "focus $w"
2410         wm title $w "[appname] ([reponame]): [lindex $console_data($w) 0]"
2411         return $w
2412 }
2413
2414 proc console_exec {w cmd {after {}}} {
2415         # -- Windows tosses the enviroment when we exec our child.
2416         #    But most users need that so we have to relogin. :-(
2417         #
2418         if {[is_Windows]} {
2419                 set cmd [list sh --login -c "cd \"[pwd]\" && [join $cmd { }]"]
2420         }
2421
2422         # -- Tcl won't let us redirect both stdout and stderr to
2423         #    the same pipe.  So pass it through cat...
2424         #
2425         set cmd [concat | $cmd |& cat]
2426
2427         set fd_f [open $cmd r]
2428         fconfigure $fd_f -blocking 0 -translation binary
2429         fileevent $fd_f readable [list console_read $w $fd_f $after]
2430 }
2431
2432 proc console_read {w fd after} {
2433         global console_cr console_data
2434
2435         set buf [read $fd]
2436         if {$buf ne {}} {
2437                 if {![winfo exists $w]} {console_init $w}
2438                 $w.m.t conf -state normal
2439                 set c 0
2440                 set n [string length $buf]
2441                 while {$c < $n} {
2442                         set cr [string first "\r" $buf $c]
2443                         set lf [string first "\n" $buf $c]
2444                         if {$cr < 0} {set cr [expr {$n + 1}]}
2445                         if {$lf < 0} {set lf [expr {$n + 1}]}
2446
2447                         if {$lf < $cr} {
2448                                 $w.m.t insert end [string range $buf $c $lf]
2449                                 set console_cr($w) [$w.m.t index {end -1c}]
2450                                 set c $lf
2451                                 incr c
2452                         } else {
2453                                 $w.m.t delete $console_cr($w) end
2454                                 $w.m.t insert end "\n"
2455                                 $w.m.t insert end [string range $buf $c $cr]
2456                                 set c $cr
2457                                 incr c
2458                         }
2459                 }
2460                 $w.m.t conf -state disabled
2461                 $w.m.t see end
2462         }
2463
2464         fconfigure $fd -blocking 1
2465         if {[eof $fd]} {
2466                 if {[catch {close $fd}]} {
2467                         if {![winfo exists $w]} {console_init $w}
2468                         $w.m.s conf -background red -text {Error: Command Failed}
2469                         $w.ok conf -state normal
2470                         set ok 0
2471                 } elseif {[winfo exists $w]} {
2472                         $w.m.s conf -background green -text {Success}
2473                         $w.ok conf -state normal
2474                         set ok 1
2475                 }
2476                 array unset console_cr $w
2477                 array unset console_data $w
2478                 if {$after ne {}} {
2479                         uplevel #0 $after $ok
2480                 }
2481                 return
2482         }
2483         fconfigure $fd -blocking 0
2484 }
2485
2486 ######################################################################
2487 ##
2488 ## ui commands
2489
2490 set starting_gitk_msg {Starting gitk... please wait...}
2491
2492 proc do_gitk {revs} {
2493         global ui_status_value starting_gitk_msg
2494
2495         set cmd gitk
2496         if {$revs ne {}} {
2497                 append cmd { }
2498                 append cmd $revs
2499         }
2500         if {[is_Windows]} {
2501                 set cmd "sh -c \"exec $cmd\""
2502         }
2503         append cmd { &}
2504
2505         if {[catch {eval exec $cmd} err]} {
2506                 error_popup "Failed to start gitk:\n\n$err"
2507         } else {
2508                 set ui_status_value $starting_gitk_msg
2509                 after 10000 {
2510                         if {$ui_status_value eq $starting_gitk_msg} {
2511                                 set ui_status_value {Ready.}
2512                         }
2513                 }
2514         }
2515 }
2516
2517 proc do_gc {} {
2518         set w [new_console {gc} {Compressing the object database}]
2519         console_exec $w {git gc}
2520 }
2521
2522 proc do_fsck_objects {} {
2523         set w [new_console {fsck-objects} \
2524                 {Verifying the object database with fsck-objects}]
2525         set cmd [list git fsck-objects]
2526         lappend cmd --full
2527         lappend cmd --cache
2528         lappend cmd --strict
2529         console_exec $w $cmd
2530 }
2531
2532 set is_quitting 0
2533
2534 proc do_quit {} {
2535         global ui_comm is_quitting repo_config commit_type
2536
2537         if {$is_quitting} return
2538         set is_quitting 1
2539
2540         # -- Stash our current commit buffer.
2541         #
2542         set save [gitdir GITGUI_MSG]
2543         set msg [string trim [$ui_comm get 0.0 end]]
2544         if {![string match amend* $commit_type]
2545                 && [$ui_comm edit modified]
2546                 && $msg ne {}} {
2547                 catch {
2548                         set fd [open $save w]
2549                         puts $fd [string trim [$ui_comm get 0.0 end]]
2550                         close $fd
2551                 }
2552         } else {
2553                 catch {file delete $save}
2554         }
2555
2556         # -- Stash our current window geometry into this repository.
2557         #
2558         set cfg_geometry [list]
2559         lappend cfg_geometry [wm geometry .]
2560         lappend cfg_geometry [lindex [.vpane sash coord 0] 1]
2561         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 0]
2562         if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2563                 set rc_geometry {}
2564         }
2565         if {$cfg_geometry ne $rc_geometry} {
2566                 catch {exec git repo-config gui.geometry $cfg_geometry}
2567         }
2568
2569         destroy .
2570 }
2571
2572 proc do_rescan {} {
2573         rescan {set ui_status_value {Ready.}}
2574 }
2575
2576 proc unstage_helper {txt paths} {
2577         global file_states current_diff
2578
2579         if {![lock_index begin-update]} return
2580
2581         set pathList [list]
2582         set after {}
2583         foreach path $paths {
2584                 switch -glob -- [lindex $file_states($path) 0] {
2585                 A? -
2586                 M? -
2587                 D? {
2588                         lappend pathList $path
2589                         if {$path eq $current_diff} {
2590                                 set after {reshow_diff;}
2591                         }
2592                 }
2593                 }
2594         }
2595         if {$pathList eq {}} {
2596                 unlock_index
2597         } else {
2598                 update_indexinfo \
2599                         $txt \
2600                         $pathList \
2601                         [concat $after {set ui_status_value {Ready.}}]
2602         }
2603 }
2604
2605 proc do_unstage_selection {} {
2606         global current_diff selected_paths
2607
2608         if {[array size selected_paths] > 0} {
2609                 unstage_helper \
2610                         {Unstaging selected files from commit} \
2611                         [array names selected_paths]
2612         } elseif {$current_diff ne {}} {
2613                 unstage_helper \
2614                         "Unstaging [short_path $current_diff] from commit" \
2615                         [list $current_diff]
2616         }
2617 }
2618
2619 proc add_helper {txt paths} {
2620         global file_states current_diff
2621
2622         if {![lock_index begin-update]} return
2623
2624         set pathList [list]
2625         set after {}
2626         foreach path $paths {
2627                 switch -glob -- [lindex $file_states($path) 0] {
2628                 _O -
2629                 ?M -
2630                 ?D -
2631                 U? {
2632                         lappend pathList $path
2633                         if {$path eq $current_diff} {
2634                                 set after {reshow_diff;}
2635                         }
2636                 }
2637                 }
2638         }
2639         if {$pathList eq {}} {
2640                 unlock_index
2641         } else {
2642                 update_index \
2643                         $txt \
2644                         $pathList \
2645                         [concat $after {set ui_status_value {Ready to commit.}}]
2646         }
2647 }
2648
2649 proc do_add_selection {} {
2650         global current_diff selected_paths
2651
2652         if {[array size selected_paths] > 0} {
2653                 add_helper \
2654                         {Adding selected files} \
2655                         [array names selected_paths]
2656         } elseif {$current_diff ne {}} {
2657                 add_helper \
2658                         "Adding [short_path $current_diff]" \
2659                         [list $current_diff]
2660         }
2661 }
2662
2663 proc do_add_all {} {
2664         global file_states
2665
2666         set paths [list]
2667         foreach path [array names file_states] {
2668                 switch -glob -- [lindex $file_states($path) 0] {
2669                 U? {continue}
2670                 ?M -
2671                 ?D {lappend paths $path}
2672                 }
2673         }
2674         add_helper {Adding all changed files} $paths
2675 }
2676
2677 proc revert_helper {txt paths} {
2678         global file_states current_diff
2679
2680         if {![lock_index begin-update]} return
2681
2682         set pathList [list]
2683         set after {}
2684         foreach path $paths {
2685                 switch -glob -- [lindex $file_states($path) 0] {
2686                 U? {continue}
2687                 ?M -
2688                 ?D {
2689                         lappend pathList $path
2690                         if {$path eq $current_diff} {
2691                                 set after {reshow_diff;}
2692                         }
2693                 }
2694                 }
2695         }
2696
2697         set n [llength $pathList]
2698         if {$n == 0} {
2699                 unlock_index
2700                 return
2701         } elseif {$n == 1} {
2702                 set s "[short_path [lindex $pathList]]"
2703         } else {
2704                 set s "these $n files"
2705         }
2706
2707         set reply [tk_dialog \
2708                 .confirm_revert \
2709                 "[appname] ([reponame])" \
2710                 "Revert changes in $s?
2711
2712 Any unadded changes will be permanently lost by the revert." \
2713                 question \
2714                 1 \
2715                 {Do Nothing} \
2716                 {Revert Changes} \
2717                 ]
2718         if {$reply == 1} {
2719                 checkout_index \
2720                         $txt \
2721                         $pathList \
2722                         [concat $after {set ui_status_value {Ready.}}]
2723         } else {
2724                 unlock_index
2725         }
2726 }
2727
2728 proc do_revert_selection {} {
2729         global current_diff selected_paths
2730
2731         if {[array size selected_paths] > 0} {
2732                 revert_helper \
2733                         {Reverting selected files} \
2734                         [array names selected_paths]
2735         } elseif {$current_diff ne {}} {
2736                 revert_helper \
2737                         "Reverting [short_path $current_diff]" \
2738                         [list $current_diff]
2739         }
2740 }
2741
2742 proc do_signoff {} {
2743         global ui_comm
2744
2745         set me [committer_ident]
2746         if {$me eq {}} return
2747
2748         set sob "Signed-off-by: $me"
2749         set last [$ui_comm get {end -1c linestart} {end -1c}]
2750         if {$last ne $sob} {
2751                 $ui_comm edit separator
2752                 if {$last ne {}
2753                         && ![regexp {^[A-Z][A-Za-z]*-[A-Za-z-]+: *} $last]} {
2754                         $ui_comm insert end "\n"
2755                 }
2756                 $ui_comm insert end "\n$sob"
2757                 $ui_comm edit separator
2758                 $ui_comm see end
2759         }
2760 }
2761
2762 proc do_select_commit_type {} {
2763         global commit_type selected_commit_type
2764
2765         if {$selected_commit_type eq {new}
2766                 && [string match amend* $commit_type]} {
2767                 create_new_commit
2768         } elseif {$selected_commit_type eq {amend}
2769                 && ![string match amend* $commit_type]} {
2770                 load_last_commit
2771
2772                 # The amend request was rejected...
2773                 #
2774                 if {![string match amend* $commit_type]} {
2775                         set selected_commit_type new
2776                 }
2777         }
2778 }
2779
2780 proc do_commit {} {
2781         commit_tree
2782 }
2783
2784 proc do_about {} {
2785         global appvers copyright
2786         global tcl_patchLevel tk_patchLevel
2787
2788         set w .about_dialog
2789         toplevel $w
2790         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2791
2792         label $w.header -text "About [appname]" \
2793                 -font font_uibold
2794         pack $w.header -side top -fill x
2795
2796         frame $w.buttons
2797         button $w.buttons.close -text {Close} \
2798                 -font font_ui \
2799                 -command [list destroy $w]
2800         pack $w.buttons.close -side right
2801         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2802
2803         label $w.desc \
2804                 -text "[appname] - a commit creation tool for Git.
2805 $copyright" \
2806                 -padx 5 -pady 5 \
2807                 -justify left \
2808                 -anchor w \
2809                 -borderwidth 1 \
2810                 -relief solid \
2811                 -font font_ui
2812         pack $w.desc -side top -fill x -padx 5 -pady 5
2813
2814         set v {}
2815         append v "[appname] version $appvers\n"
2816         append v "[exec git version]\n"
2817         append v "\n"
2818         if {$tcl_patchLevel eq $tk_patchLevel} {
2819                 append v "Tcl/Tk version $tcl_patchLevel"
2820         } else {
2821                 append v "Tcl version $tcl_patchLevel"
2822                 append v ", Tk version $tk_patchLevel"
2823         }
2824
2825         label $w.vers \
2826                 -text $v \
2827                 -padx 5 -pady 5 \
2828                 -justify left \
2829                 -anchor w \
2830                 -borderwidth 1 \
2831                 -relief solid \
2832                 -font font_ui
2833         pack $w.vers -side top -fill x -padx 5 -pady 5
2834
2835         menu $w.ctxm -tearoff 0
2836         $w.ctxm add command \
2837                 -label {Copy} \
2838                 -font font_ui \
2839                 -command "
2840                 clipboard clear
2841                 clipboard append -format STRING -type STRING -- \[$w.vers cget -text\]
2842         "
2843
2844         bind $w <Visibility> "grab $w; focus $w"
2845         bind $w <Key-Escape> "destroy $w"
2846         bind_button3 $w.vers "tk_popup $w.ctxm %X %Y; grab $w; focus $w"
2847         wm title $w "About [appname]"
2848         tkwait window $w
2849 }
2850
2851 proc do_options {} {
2852         global repo_config global_config font_descs
2853         global repo_config_new global_config_new
2854
2855         array unset repo_config_new
2856         array unset global_config_new
2857         foreach name [array names repo_config] {
2858                 set repo_config_new($name) $repo_config($name)
2859         }
2860         load_config 1
2861         foreach name [array names repo_config] {
2862                 switch -- $name {
2863                 gui.diffcontext {continue}
2864                 }
2865                 set repo_config_new($name) $repo_config($name)
2866         }
2867         foreach name [array names global_config] {
2868                 set global_config_new($name) $global_config($name)
2869         }
2870
2871         set w .options_editor
2872         toplevel $w
2873         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2874
2875         label $w.header -text "[appname] Options" \
2876                 -font font_uibold
2877         pack $w.header -side top -fill x
2878
2879         frame $w.buttons
2880         button $w.buttons.restore -text {Restore Defaults} \
2881                 -font font_ui \
2882                 -command do_restore_defaults
2883         pack $w.buttons.restore -side left
2884         button $w.buttons.save -text Save \
2885                 -font font_ui \
2886                 -command [list do_save_config $w]
2887         pack $w.buttons.save -side right
2888         button $w.buttons.cancel -text {Cancel} \
2889                 -font font_ui \
2890                 -command [list destroy $w]
2891         pack $w.buttons.cancel -side right -padx 5
2892         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2893
2894         labelframe $w.repo -text "[reponame] Repository" \
2895                 -font font_ui \
2896                 -relief raised -borderwidth 2
2897         labelframe $w.global -text {Global (All Repositories)} \
2898                 -font font_ui \
2899                 -relief raised -borderwidth 2
2900         pack $w.repo -side left -fill both -expand 1 -pady 5 -padx 5
2901         pack $w.global -side right -fill both -expand 1 -pady 5 -padx 5
2902
2903         foreach option {
2904                 {b partialinclude {Allow Partially Added Files}}
2905                 {b pullsummary {Show Pull Summary}}
2906                 {b trustmtime  {Trust File Modification Timestamps}}
2907                 {i diffcontext {Number of Diff Context Lines}}
2908                 } {
2909                 set type [lindex $option 0]
2910                 set name [lindex $option 1]
2911                 set text [lindex $option 2]
2912                 foreach f {repo global} {
2913                         switch $type {
2914                         b {
2915                                 checkbutton $w.$f.$name -text $text \
2916                                         -variable ${f}_config_new(gui.$name) \
2917                                         -onvalue true \
2918                                         -offvalue false \
2919                                         -font font_ui
2920                                 pack $w.$f.$name -side top -anchor w
2921                         }
2922                         i {
2923                                 frame $w.$f.$name
2924                                 label $w.$f.$name.l -text "$text:" -font font_ui
2925                                 pack $w.$f.$name.l -side left -anchor w -fill x
2926                                 spinbox $w.$f.$name.v \
2927                                         -textvariable ${f}_config_new(gui.$name) \
2928                                         -from 1 -to 99 -increment 1 \
2929                                         -width 3 \
2930                                         -font font_ui
2931                                 pack $w.$f.$name.v -side right -anchor e
2932                                 pack $w.$f.$name -side top -anchor w -fill x
2933                         }
2934                         }
2935                 }
2936         }
2937
2938         set all_fonts [lsort [font families]]
2939         foreach option $font_descs {
2940                 set name [lindex $option 0]
2941                 set font [lindex $option 1]
2942                 set text [lindex $option 2]
2943
2944                 set global_config_new(gui.$font^^family) \
2945                         [font configure $font -family]
2946                 set global_config_new(gui.$font^^size) \
2947                         [font configure $font -size]
2948
2949                 frame $w.global.$name
2950                 label $w.global.$name.l -text "$text:" -font font_ui
2951                 pack $w.global.$name.l -side left -anchor w -fill x
2952                 eval tk_optionMenu $w.global.$name.family \
2953                         global_config_new(gui.$font^^family) \
2954                         $all_fonts
2955                 spinbox $w.global.$name.size \
2956                         -textvariable global_config_new(gui.$font^^size) \
2957                         -from 2 -to 80 -increment 1 \
2958                         -width 3 \
2959                         -font font_ui
2960                 pack $w.global.$name.size -side right -anchor e
2961                 pack $w.global.$name.family -side right -anchor e
2962                 pack $w.global.$name -side top -anchor w -fill x
2963         }
2964
2965         bind $w <Visibility> "grab $w; focus $w"
2966         bind $w <Key-Escape> "destroy $w"
2967         wm title $w "[appname] ([reponame]): Options"
2968         tkwait window $w
2969 }
2970
2971 proc do_restore_defaults {} {
2972         global font_descs default_config repo_config
2973         global repo_config_new global_config_new
2974
2975         foreach name [array names default_config] {
2976                 set repo_config_new($name) $default_config($name)
2977                 set global_config_new($name) $default_config($name)
2978         }
2979
2980         foreach option $font_descs {
2981                 set name [lindex $option 0]
2982                 set repo_config(gui.$name) $default_config(gui.$name)
2983         }
2984         apply_config
2985
2986         foreach option $font_descs {
2987                 set name [lindex $option 0]
2988                 set font [lindex $option 1]
2989                 set global_config_new(gui.$font^^family) \
2990                         [font configure $font -family]
2991                 set global_config_new(gui.$font^^size) \
2992                         [font configure $font -size]
2993         }
2994 }
2995
2996 proc do_save_config {w} {
2997         if {[catch {save_config} err]} {
2998                 error_popup "Failed to completely save options:\n\n$err"
2999         }
3000         reshow_diff
3001         destroy $w
3002 }
3003
3004 proc do_windows_shortcut {} {
3005         global argv0
3006
3007         if {[catch {
3008                 set desktop [exec cygpath \
3009                         --windows \
3010                         --absolute \
3011                         --long-name \
3012                         --desktop]
3013                 }]} {
3014                         set desktop .
3015         }
3016         set fn [tk_getSaveFile \
3017                 -parent . \
3018                 -title "[appname] ([reponame]): Create Desktop Icon" \
3019                 -initialdir $desktop \
3020                 -initialfile "Git [reponame].bat"]
3021         if {$fn != {}} {
3022                 if {[catch {
3023                                 set fd [open $fn w]
3024                                 set sh [exec cygpath \
3025                                         --windows \
3026                                         --absolute \
3027                                         /bin/sh]
3028                                 set me [exec cygpath \
3029                                         --unix \
3030                                         --absolute \
3031                                         $argv0]
3032                                 set gd [exec cygpath \
3033                                         --unix \
3034                                         --absolute \
3035                                         [gitdir]]
3036                                 set gw [exec cygpath \
3037                                         --windows \
3038                                         --absolute \
3039                                         [file dirname [gitdir]]]
3040                                 regsub -all ' $me "'\\''" me
3041                                 regsub -all ' $gd "'\\''" gd
3042                                 puts $fd "@ECHO Entering $gw"
3043                                 puts $fd "@ECHO Starting git-gui... please wait..."
3044                                 puts -nonewline $fd "@\"$sh\" --login -c \""
3045                                 puts -nonewline $fd "GIT_DIR='$gd'"
3046                                 puts -nonewline $fd " '$me'"
3047                                 puts $fd "&\""
3048                                 close $fd
3049                         } err]} {
3050                         error_popup "Cannot write script:\n\n$err"
3051                 }
3052         }
3053 }
3054
3055 proc do_macosx_app {} {
3056         global argv0 env
3057
3058         set fn [tk_getSaveFile \
3059                 -parent . \
3060                 -title "[appname] ([reponame]): Create Desktop Icon" \
3061                 -initialdir [file join $env(HOME) Desktop] \
3062                 -initialfile "Git [reponame].app"]
3063         if {$fn != {}} {
3064                 if {[catch {
3065                                 set Contents [file join $fn Contents]
3066                                 set MacOS [file join $Contents MacOS]
3067                                 set exe [file join $MacOS git-gui]
3068
3069                                 file mkdir $MacOS
3070
3071                                 set fd [open [file join $Contents Info.plist] w]
3072                                 puts $fd {<?xml version="1.0" encoding="UTF-8"?>
3073 <!DOCTYPE plist PUBLIC "-//Apple Computer//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
3074 <plist version="1.0">
3075 <dict>
3076         <key>CFBundleDevelopmentRegion</key>
3077         <string>English</string>
3078         <key>CFBundleExecutable</key>
3079         <string>git-gui</string>
3080         <key>CFBundleIdentifier</key>
3081         <string>org.spearce.git-gui</string>
3082         <key>CFBundleInfoDictionaryVersion</key>
3083         <string>6.0</string>
3084         <key>CFBundlePackageType</key>
3085         <string>APPL</string>
3086         <key>CFBundleSignature</key>
3087         <string>????</string>
3088         <key>CFBundleVersion</key>
3089         <string>1.0</string>
3090         <key>NSPrincipalClass</key>
3091         <string>NSApplication</string>
3092 </dict>
3093 </plist>}
3094                                 close $fd
3095
3096                                 set fd [open $exe w]
3097                                 set gd [file normalize [gitdir]]
3098                                 set ep [file normalize [exec git --exec-path]]
3099                                 regsub -all ' $gd "'\\''" gd
3100                                 regsub -all ' $ep "'\\''" ep
3101                                 puts $fd "#!/bin/sh"
3102                                 foreach name [array names env] {
3103                                         if {[string match GIT_* $name]} {
3104                                                 regsub -all ' $env($name) "'\\''" v
3105                                                 puts $fd "export $name='$v'"
3106                                         }
3107                                 }
3108                                 puts $fd "export PATH='$ep':\$PATH"
3109                                 puts $fd "export GIT_DIR='$gd'"
3110                                 puts $fd "exec [file normalize $argv0]"
3111                                 close $fd
3112
3113                                 file attributes $exe -permissions u+x,g+x,o+x
3114                         } err]} {
3115                         error_popup "Cannot write icon:\n\n$err"
3116                 }
3117         }
3118 }
3119
3120 proc toggle_or_diff {w x y} {
3121         global file_states file_lists current_diff ui_index ui_workdir
3122         global last_clicked selected_paths
3123
3124         set pos [split [$w index @$x,$y] .]
3125         set lno [lindex $pos 0]
3126         set col [lindex $pos 1]
3127         set path [lindex $file_lists($w) [expr {$lno - 1}]]
3128         if {$path eq {}} {
3129                 set last_clicked {}
3130                 return
3131         }
3132
3133         set last_clicked [list $w $lno]
3134         array unset selected_paths
3135         $ui_index tag remove in_sel 0.0 end
3136         $ui_workdir tag remove in_sel 0.0 end
3137
3138         if {$col == 0} {
3139                 if {$current_diff eq $path} {
3140                         set after {reshow_diff;}
3141                 } else {
3142                         set after {}
3143                 }
3144                 if {$w eq $ui_index} {
3145                         update_indexinfo \
3146                                 "Unstaging [short_path $path] from commit" \
3147                                 [list $path] \
3148                                 [concat $after {set ui_status_value {Ready.}}]
3149                 } elseif {$w eq $ui_workdir} {
3150                         update_index \
3151                                 "Adding [short_path $path]" \
3152                                 [list $path] \
3153                                 [concat $after {set ui_status_value {Ready.}}]
3154                 }
3155         } else {
3156                 show_diff $path $w $lno
3157         }
3158 }
3159
3160 proc add_one_to_selection {w x y} {
3161         global file_lists last_clicked selected_paths
3162
3163         set lno [lindex [split [$w index @$x,$y] .] 0]
3164         set path [lindex $file_lists($w) [expr {$lno - 1}]]
3165         if {$path eq {}} {
3166                 set last_clicked {}
3167                 return
3168         }
3169
3170         if {$last_clicked ne {}
3171                 && [lindex $last_clicked 0] ne $w} {
3172                 array unset selected_paths
3173                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
3174         }
3175
3176         set last_clicked [list $w $lno]
3177         if {[catch {set in_sel $selected_paths($path)}]} {
3178                 set in_sel 0
3179         }
3180         if {$in_sel} {
3181                 unset selected_paths($path)
3182                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
3183         } else {
3184                 set selected_paths($path) 1
3185                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
3186         }
3187 }
3188
3189 proc add_range_to_selection {w x y} {
3190         global file_lists last_clicked selected_paths
3191
3192         if {[lindex $last_clicked 0] ne $w} {
3193                 toggle_or_diff $w $x $y
3194                 return
3195         }
3196
3197         set lno [lindex [split [$w index @$x,$y] .] 0]
3198         set lc [lindex $last_clicked 1]
3199         if {$lc < $lno} {
3200                 set begin $lc
3201                 set end $lno
3202         } else {
3203                 set begin $lno
3204                 set end $lc
3205         }
3206
3207         foreach path [lrange $file_lists($w) \
3208                 [expr {$begin - 1}] \
3209                 [expr {$end - 1}]] {
3210                 set selected_paths($path) 1
3211         }
3212         $w tag add in_sel $begin.0 [expr {$end + 1}].0
3213 }
3214
3215 ######################################################################
3216 ##
3217 ## config defaults
3218
3219 set cursor_ptr arrow
3220 font create font_diff -family Courier -size 10
3221 font create font_ui
3222 catch {
3223         label .dummy
3224         eval font configure font_ui [font actual [.dummy cget -font]]
3225         destroy .dummy
3226 }
3227
3228 font create font_uibold
3229 font create font_diffbold
3230
3231 if {[is_Windows]} {
3232         set M1B Control
3233         set M1T Ctrl
3234 } elseif {[is_MacOSX]} {
3235         set M1B M1
3236         set M1T Cmd
3237 } else {
3238         set M1B M1
3239         set M1T M1
3240 }
3241
3242 proc apply_config {} {
3243         global repo_config font_descs
3244
3245         foreach option $font_descs {
3246                 set name [lindex $option 0]
3247                 set font [lindex $option 1]
3248                 if {[catch {
3249                         foreach {cn cv} $repo_config(gui.$name) {
3250                                 font configure $font $cn $cv
3251                         }
3252                         } err]} {
3253                         error_popup "Invalid font specified in gui.$name:\n\n$err"
3254                 }
3255                 foreach {cn cv} [font configure $font] {
3256                         font configure ${font}bold $cn $cv
3257                 }
3258                 font configure ${font}bold -weight bold
3259         }
3260 }
3261
3262 set default_config(gui.trustmtime) false
3263 set default_config(gui.pullsummary) true
3264 set default_config(gui.partialinclude) false
3265 set default_config(gui.diffcontext) 5
3266 set default_config(gui.fontui) [font configure font_ui]
3267 set default_config(gui.fontdiff) [font configure font_diff]
3268 set font_descs {
3269         {fontui   font_ui   {Main Font}}
3270         {fontdiff font_diff {Diff/Console Font}}
3271 }
3272 load_config 0
3273 apply_config
3274
3275 ######################################################################
3276 ##
3277 ## ui construction
3278
3279 # -- Menu Bar
3280 #
3281 menu .mbar -tearoff 0
3282 .mbar add cascade -label Repository -menu .mbar.repository
3283 .mbar add cascade -label Edit -menu .mbar.edit
3284 if {!$single_commit} {
3285         .mbar add cascade -label Branch -menu .mbar.branch
3286 }
3287 .mbar add cascade -label Commit -menu .mbar.commit
3288 if {!$single_commit} {
3289         .mbar add cascade -label Fetch -menu .mbar.fetch
3290         .mbar add cascade -label Pull -menu .mbar.pull
3291         .mbar add cascade -label Push -menu .mbar.push
3292 }
3293 . configure -menu .mbar
3294
3295 # -- Repository Menu
3296 #
3297 menu .mbar.repository
3298 .mbar.repository add command \
3299         -label {Visualize Current Branch} \
3300         -command {do_gitk {}} \
3301         -font font_ui
3302 if {![is_MacOSX]} {
3303         .mbar.repository add command \
3304                 -label {Visualize All Branches} \
3305                 -command {do_gitk {--all}} \
3306                 -font font_ui
3307 }
3308 .mbar.repository add separator
3309
3310 if {!$single_commit} {
3311         .mbar.repository add command -label {Compress Database} \
3312                 -command do_gc \
3313                 -font font_ui
3314
3315         .mbar.repository add command -label {Verify Database} \
3316                 -command do_fsck_objects \
3317                 -font font_ui
3318
3319         .mbar.repository add separator
3320
3321         if {[is_Windows]} {
3322                 .mbar.repository add command \
3323                         -label {Create Desktop Icon} \
3324                         -command do_windows_shortcut \
3325                         -font font_ui
3326         } elseif {[is_MacOSX]} {
3327                 .mbar.repository add command \
3328                         -label {Create Desktop Icon} \
3329                         -command do_macosx_app \
3330                         -font font_ui
3331         }
3332 }
3333
3334 .mbar.repository add command -label Quit \
3335         -command do_quit \
3336         -accelerator $M1T-Q \
3337         -font font_ui
3338
3339 # -- Edit Menu
3340 #
3341 menu .mbar.edit
3342 .mbar.edit add command -label Undo \
3343         -command {catch {[focus] edit undo}} \
3344         -accelerator $M1T-Z \
3345         -font font_ui
3346 .mbar.edit add command -label Redo \
3347         -command {catch {[focus] edit redo}} \
3348         -accelerator $M1T-Y \
3349         -font font_ui
3350 .mbar.edit add separator
3351 .mbar.edit add command -label Cut \
3352         -command {catch {tk_textCut [focus]}} \
3353         -accelerator $M1T-X \
3354         -font font_ui
3355 .mbar.edit add command -label Copy \
3356         -command {catch {tk_textCopy [focus]}} \
3357         -accelerator $M1T-C \
3358         -font font_ui
3359 .mbar.edit add command -label Paste \
3360         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
3361         -accelerator $M1T-V \
3362         -font font_ui
3363 .mbar.edit add command -label Delete \
3364         -command {catch {[focus] delete sel.first sel.last}} \
3365         -accelerator Del \
3366         -font font_ui
3367 .mbar.edit add separator
3368 .mbar.edit add command -label {Select All} \
3369         -command {catch {[focus] tag add sel 0.0 end}} \
3370         -accelerator $M1T-A \
3371         -font font_ui
3372
3373 # -- Branch Menu
3374 #
3375 if {!$single_commit} {
3376         menu .mbar.branch
3377
3378         .mbar.branch add command -label {Create...} \
3379                 -command do_create_branch \
3380                 -accelerator $M1T-N \
3381                 -font font_ui
3382         lappend disable_on_lock [list .mbar.branch entryconf \
3383                 [.mbar.branch index last] -state]
3384
3385         .mbar.branch add command -label {Delete...} \
3386                 -command do_delete_branch \
3387                 -font font_ui
3388         lappend disable_on_lock [list .mbar.branch entryconf \
3389                 [.mbar.branch index last] -state]
3390 }
3391
3392 # -- Commit Menu
3393 #
3394 menu .mbar.commit
3395
3396 .mbar.commit add radiobutton \
3397         -label {New Commit} \
3398         -command do_select_commit_type \
3399         -variable selected_commit_type \
3400         -value new \
3401         -font font_ui
3402 lappend disable_on_lock \
3403         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3404
3405 .mbar.commit add radiobutton \
3406         -label {Amend Last Commit} \
3407         -command do_select_commit_type \
3408         -variable selected_commit_type \
3409         -value amend \
3410         -font font_ui
3411 lappend disable_on_lock \
3412         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3413
3414 .mbar.commit add separator
3415
3416 .mbar.commit add command -label Rescan \
3417         -command do_rescan \
3418         -accelerator F5 \
3419         -font font_ui
3420 lappend disable_on_lock \
3421         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3422
3423 .mbar.commit add command -label {Add To Commit} \
3424         -command do_add_selection \
3425         -font font_ui
3426 lappend disable_on_lock \
3427         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3428
3429 .mbar.commit add command -label {Add All To Commit} \
3430         -command do_add_all \
3431         -accelerator $M1T-I \
3432         -font font_ui
3433 lappend disable_on_lock \
3434         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3435
3436 .mbar.commit add command -label {Unstage From Commit} \
3437         -command do_unstage_selection \
3438         -font font_ui
3439 lappend disable_on_lock \
3440         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3441
3442 .mbar.commit add command -label {Revert Changes} \
3443         -command do_revert_selection \
3444         -font font_ui
3445 lappend disable_on_lock \
3446         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3447
3448 .mbar.commit add separator
3449
3450 .mbar.commit add command -label {Sign Off} \
3451         -command do_signoff \
3452         -accelerator $M1T-S \
3453         -font font_ui
3454
3455 .mbar.commit add command -label Commit \
3456         -command do_commit \
3457         -accelerator $M1T-Return \
3458         -font font_ui
3459 lappend disable_on_lock \
3460         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3461
3462 # -- Transport menus
3463 #
3464 if {!$single_commit} {
3465         menu .mbar.fetch
3466         menu .mbar.pull
3467         menu .mbar.push
3468 }
3469
3470 if {[is_MacOSX]} {
3471         # -- Apple Menu (Mac OS X only)
3472         #
3473         .mbar add cascade -label Apple -menu .mbar.apple
3474         menu .mbar.apple
3475
3476         .mbar.apple add command -label "About [appname]" \
3477                 -command do_about \
3478                 -font font_ui
3479         .mbar.apple add command -label "[appname] Options..." \
3480                 -command do_options \
3481                 -font font_ui
3482 } else {
3483         # -- Edit Menu
3484         #
3485         .mbar.edit add separator
3486         .mbar.edit add command -label {Options...} \
3487                 -command do_options \
3488                 -font font_ui
3489
3490         # -- Tools Menu
3491         #
3492         if {[file exists /usr/local/miga/lib/gui-miga]
3493                 && [file exists .pvcsrc]} {
3494         proc do_miga {} {
3495                 global ui_status_value
3496                 if {![lock_index update]} return
3497                 set cmd [list sh --login -c "/usr/local/miga/lib/gui-miga \"[pwd]\""]
3498                 set miga_fd [open "|$cmd" r]
3499                 fconfigure $miga_fd -blocking 0
3500                 fileevent $miga_fd readable [list miga_done $miga_fd]
3501                 set ui_status_value {Running miga...}
3502         }
3503         proc miga_done {fd} {
3504                 read $fd 512
3505                 if {[eof $fd]} {
3506                         close $fd
3507                         unlock_index
3508                         rescan [list set ui_status_value {Ready.}]
3509                 }
3510         }
3511         .mbar add cascade -label Tools -menu .mbar.tools
3512         menu .mbar.tools
3513         .mbar.tools add command -label "Migrate" \
3514                 -command do_miga \
3515                 -font font_ui
3516         lappend disable_on_lock \
3517                 [list .mbar.tools entryconf [.mbar.tools index last] -state]
3518         }
3519
3520         # -- Help Menu
3521         #
3522         .mbar add cascade -label Help -menu .mbar.help
3523         menu .mbar.help
3524
3525         .mbar.help add command -label "About [appname]" \
3526                 -command do_about \
3527                 -font font_ui
3528 }
3529
3530
3531 # -- Branch Control
3532 #
3533 frame .branch \
3534         -borderwidth 1 \
3535         -relief sunken
3536 label .branch.l1 \
3537         -text {Current Branch:} \
3538         -anchor w \
3539         -justify left \
3540         -font font_ui
3541 label .branch.cb \
3542         -textvariable current_branch \
3543         -anchor w \
3544         -justify left \
3545         -font font_ui
3546 pack .branch.l1 -side left
3547 pack .branch.cb -side left -fill x
3548 pack .branch -side top -fill x
3549
3550 # -- Main Window Layout
3551 #
3552 panedwindow .vpane -orient vertical
3553 panedwindow .vpane.files -orient horizontal
3554 .vpane add .vpane.files -sticky nsew -height 100 -width 400
3555 pack .vpane -anchor n -side top -fill both -expand 1
3556
3557 # -- Index File List
3558 #
3559 frame .vpane.files.index -height 100 -width 400
3560 label .vpane.files.index.title -text {Changes To Be Committed} \
3561         -background green \
3562         -font font_ui
3563 text $ui_index -background white -borderwidth 0 \
3564         -width 40 -height 10 \
3565         -font font_ui \
3566         -cursor $cursor_ptr \
3567         -yscrollcommand {.vpane.files.index.sb set} \
3568         -state disabled
3569 scrollbar .vpane.files.index.sb -command [list $ui_index yview]
3570 pack .vpane.files.index.title -side top -fill x
3571 pack .vpane.files.index.sb -side right -fill y
3572 pack $ui_index -side left -fill both -expand 1
3573 .vpane.files add .vpane.files.index -sticky nsew
3574
3575 # -- Working Directory File List
3576 #
3577 frame .vpane.files.workdir -height 100 -width 100
3578 label .vpane.files.workdir.title -text {Changed But Not Updated} \
3579         -background red \
3580         -font font_ui
3581 text $ui_workdir -background white -borderwidth 0 \
3582         -width 40 -height 10 \
3583         -font font_ui \
3584         -cursor $cursor_ptr \
3585         -yscrollcommand {.vpane.files.workdir.sb set} \
3586         -state disabled
3587 scrollbar .vpane.files.workdir.sb -command [list $ui_workdir yview]
3588 pack .vpane.files.workdir.title -side top -fill x
3589 pack .vpane.files.workdir.sb -side right -fill y
3590 pack $ui_workdir -side left -fill both -expand 1
3591 .vpane.files add .vpane.files.workdir -sticky nsew
3592
3593 foreach i [list $ui_index $ui_workdir] {
3594         $i tag conf in_diff -font font_uibold
3595         $i tag conf in_sel \
3596                 -background [$i cget -foreground] \
3597                 -foreground [$i cget -background]
3598 }
3599 unset i
3600
3601 # -- Diff and Commit Area
3602 #
3603 frame .vpane.lower -height 300 -width 400
3604 frame .vpane.lower.commarea
3605 frame .vpane.lower.diff -relief sunken -borderwidth 1
3606 pack .vpane.lower.commarea -side top -fill x
3607 pack .vpane.lower.diff -side bottom -fill both -expand 1
3608 .vpane add .vpane.lower -stick nsew
3609
3610 # -- Commit Area Buttons
3611 #
3612 frame .vpane.lower.commarea.buttons
3613 label .vpane.lower.commarea.buttons.l -text {} \
3614         -anchor w \
3615         -justify left \
3616         -font font_ui
3617 pack .vpane.lower.commarea.buttons.l -side top -fill x
3618 pack .vpane.lower.commarea.buttons -side left -fill y
3619
3620 button .vpane.lower.commarea.buttons.rescan -text {Rescan} \
3621         -command do_rescan \
3622         -font font_ui
3623 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3624 lappend disable_on_lock \
3625         {.vpane.lower.commarea.buttons.rescan conf -state}
3626
3627 button .vpane.lower.commarea.buttons.incall -text {Add All} \
3628         -command do_add_all \
3629         -font font_ui
3630 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3631 lappend disable_on_lock \
3632         {.vpane.lower.commarea.buttons.incall conf -state}
3633
3634 button .vpane.lower.commarea.buttons.signoff -text {Sign Off} \
3635         -command do_signoff \
3636         -font font_ui
3637 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3638
3639 button .vpane.lower.commarea.buttons.commit -text {Commit} \
3640         -command do_commit \
3641         -font font_ui
3642 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3643 lappend disable_on_lock \
3644         {.vpane.lower.commarea.buttons.commit conf -state}
3645
3646 # -- Commit Message Buffer
3647 #
3648 frame .vpane.lower.commarea.buffer
3649 frame .vpane.lower.commarea.buffer.header
3650 set ui_comm .vpane.lower.commarea.buffer.t
3651 set ui_coml .vpane.lower.commarea.buffer.header.l
3652 radiobutton .vpane.lower.commarea.buffer.header.new \
3653         -text {New Commit} \
3654         -command do_select_commit_type \
3655         -variable selected_commit_type \
3656         -value new \
3657         -font font_ui
3658 lappend disable_on_lock \
3659         [list .vpane.lower.commarea.buffer.header.new conf -state]
3660 radiobutton .vpane.lower.commarea.buffer.header.amend \
3661         -text {Amend Last Commit} \
3662         -command do_select_commit_type \
3663         -variable selected_commit_type \
3664         -value amend \
3665         -font font_ui
3666 lappend disable_on_lock \
3667         [list .vpane.lower.commarea.buffer.header.amend conf -state]
3668 label $ui_coml \
3669         -anchor w \
3670         -justify left \
3671         -font font_ui
3672 proc trace_commit_type {varname args} {
3673         global ui_coml commit_type
3674         switch -glob -- $commit_type {
3675         initial       {set txt {Initial Commit Message:}}
3676         amend         {set txt {Amended Commit Message:}}
3677         amend-initial {set txt {Amended Initial Commit Message:}}
3678         amend-merge   {set txt {Amended Merge Commit Message:}}
3679         merge         {set txt {Merge Commit Message:}}
3680         *             {set txt {Commit Message:}}
3681         }
3682         $ui_coml conf -text $txt
3683 }
3684 trace add variable commit_type write trace_commit_type
3685 pack $ui_coml -side left -fill x
3686 pack .vpane.lower.commarea.buffer.header.amend -side right
3687 pack .vpane.lower.commarea.buffer.header.new -side right
3688
3689 text $ui_comm -background white -borderwidth 1 \
3690         -undo true \
3691         -maxundo 20 \
3692         -autoseparators true \
3693         -relief sunken \
3694         -width 75 -height 9 -wrap none \
3695         -font font_diff \
3696         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3697 scrollbar .vpane.lower.commarea.buffer.sby \
3698         -command [list $ui_comm yview]
3699 pack .vpane.lower.commarea.buffer.header -side top -fill x
3700 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3701 pack $ui_comm -side left -fill y
3702 pack .vpane.lower.commarea.buffer -side left -fill y
3703
3704 # -- Commit Message Buffer Context Menu
3705 #
3706 set ctxm .vpane.lower.commarea.buffer.ctxm
3707 menu $ctxm -tearoff 0
3708 $ctxm add command \
3709         -label {Cut} \
3710         -font font_ui \
3711         -command {tk_textCut $ui_comm}
3712 $ctxm add command \
3713         -label {Copy} \
3714         -font font_ui \
3715         -command {tk_textCopy $ui_comm}
3716 $ctxm add command \
3717         -label {Paste} \
3718         -font font_ui \
3719         -command {tk_textPaste $ui_comm}
3720 $ctxm add command \
3721         -label {Delete} \
3722         -font font_ui \
3723         -command {$ui_comm delete sel.first sel.last}
3724 $ctxm add separator
3725 $ctxm add command \
3726         -label {Select All} \
3727         -font font_ui \
3728         -command {$ui_comm tag add sel 0.0 end}
3729 $ctxm add command \
3730         -label {Copy All} \
3731         -font font_ui \
3732         -command {
3733                 $ui_comm tag add sel 0.0 end
3734                 tk_textCopy $ui_comm
3735                 $ui_comm tag remove sel 0.0 end
3736         }
3737 $ctxm add separator
3738 $ctxm add command \
3739         -label {Sign Off} \
3740         -font font_ui \
3741         -command do_signoff
3742 bind_button3 $ui_comm "tk_popup $ctxm %X %Y"
3743
3744 # -- Diff Header
3745 #
3746 set current_diff {}
3747 set diff_actions [list]
3748 proc trace_current_diff {varname args} {
3749         global current_diff diff_actions file_states
3750         if {$current_diff eq {}} {
3751                 set s {}
3752                 set f {}
3753                 set p {}
3754                 set o disabled
3755         } else {
3756                 set p $current_diff
3757                 set s [mapdesc [lindex $file_states($p) 0] $p]
3758                 set f {File:}
3759                 set p [escape_path $p]
3760                 set o normal
3761         }
3762
3763         .vpane.lower.diff.header.status configure -text $s
3764         .vpane.lower.diff.header.file configure -text $f
3765         .vpane.lower.diff.header.path configure -text $p
3766         foreach w $diff_actions {
3767                 uplevel #0 $w $o
3768         }
3769 }
3770 trace add variable current_diff write trace_current_diff
3771
3772 frame .vpane.lower.diff.header -background orange
3773 label .vpane.lower.diff.header.status \
3774         -background orange \
3775         -width $max_status_desc \
3776         -anchor w \
3777         -justify left \
3778         -font font_ui
3779 label .vpane.lower.diff.header.file \
3780         -background orange \
3781         -anchor w \
3782         -justify left \
3783         -font font_ui
3784 label .vpane.lower.diff.header.path \
3785         -background orange \
3786         -anchor w \
3787         -justify left \
3788         -font font_ui
3789 pack .vpane.lower.diff.header.status -side left
3790 pack .vpane.lower.diff.header.file -side left
3791 pack .vpane.lower.diff.header.path -fill x
3792 set ctxm .vpane.lower.diff.header.ctxm
3793 menu $ctxm -tearoff 0
3794 $ctxm add command \
3795         -label {Copy} \
3796         -font font_ui \
3797         -command {
3798                 clipboard clear
3799                 clipboard append \
3800                         -format STRING \
3801                         -type STRING \
3802                         -- $current_diff
3803         }
3804 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3805 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3806
3807 # -- Diff Body
3808 #
3809 frame .vpane.lower.diff.body
3810 set ui_diff .vpane.lower.diff.body.t
3811 text $ui_diff -background white -borderwidth 0 \
3812         -width 80 -height 15 -wrap none \
3813         -font font_diff \
3814         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3815         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3816         -state disabled
3817 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3818         -command [list $ui_diff xview]
3819 scrollbar .vpane.lower.diff.body.sby -orient vertical \
3820         -command [list $ui_diff yview]
3821 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3822 pack .vpane.lower.diff.body.sby -side right -fill y
3823 pack $ui_diff -side left -fill both -expand 1
3824 pack .vpane.lower.diff.header -side top -fill x
3825 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3826
3827 $ui_diff tag conf d_@ -font font_diffbold
3828 $ui_diff tag conf d_+  -foreground blue
3829 $ui_diff tag conf d_-  -foreground red
3830 $ui_diff tag conf d_++ -foreground {#00a000}
3831 $ui_diff tag conf d_-- -foreground {#a000a0}
3832 $ui_diff tag conf d_+- \
3833         -foreground red \
3834         -background {light goldenrod yellow}
3835 $ui_diff tag conf d_-+ \
3836         -foreground blue \
3837         -background azure2
3838
3839 # -- Diff Body Context Menu
3840 #
3841 set ctxm .vpane.lower.diff.body.ctxm
3842 menu $ctxm -tearoff 0
3843 $ctxm add command \
3844         -label {Copy} \
3845         -font font_ui \
3846         -command {tk_textCopy $ui_diff}
3847 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3848 $ctxm add command \
3849         -label {Select All} \
3850         -font font_ui \
3851         -command {$ui_diff tag add sel 0.0 end}
3852 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3853 $ctxm add command \
3854         -label {Copy All} \
3855         -font font_ui \
3856         -command {
3857                 $ui_diff tag add sel 0.0 end
3858                 tk_textCopy $ui_diff
3859                 $ui_diff tag remove sel 0.0 end
3860         }
3861 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3862 $ctxm add separator
3863 $ctxm add command \
3864         -label {Decrease Font Size} \
3865         -font font_ui \
3866         -command {incr_font_size font_diff -1}
3867 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3868 $ctxm add command \
3869         -label {Increase Font Size} \
3870         -font font_ui \
3871         -command {incr_font_size font_diff 1}
3872 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3873 $ctxm add separator
3874 $ctxm add command \
3875         -label {Show Less Context} \
3876         -font font_ui \
3877         -command {if {$repo_config(gui.diffcontext) >= 2} {
3878                 incr repo_config(gui.diffcontext) -1
3879                 reshow_diff
3880         }}
3881 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3882 $ctxm add command \
3883         -label {Show More Context} \
3884         -font font_ui \
3885         -command {
3886                 incr repo_config(gui.diffcontext)
3887                 reshow_diff
3888         }
3889 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3890 $ctxm add separator
3891 $ctxm add command -label {Options...} \
3892         -font font_ui \
3893         -command do_options
3894 bind_button3 $ui_diff "tk_popup $ctxm %X %Y"
3895
3896 # -- Status Bar
3897 #
3898 set ui_status_value {Initializing...}
3899 label .status -textvariable ui_status_value \
3900         -anchor w \
3901         -justify left \
3902         -borderwidth 1 \
3903         -relief sunken \
3904         -font font_ui
3905 pack .status -anchor w -side bottom -fill x
3906
3907 # -- Load geometry
3908 #
3909 catch {
3910 set gm $repo_config(gui.geometry)
3911 wm geometry . [lindex $gm 0]
3912 .vpane sash place 0 \
3913         [lindex [.vpane sash coord 0] 0] \
3914         [lindex $gm 1]
3915 .vpane.files sash place 0 \
3916         [lindex $gm 2] \
3917         [lindex [.vpane.files sash coord 0] 1]
3918 unset gm
3919 }
3920
3921 # -- Key Bindings
3922 #
3923 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3924 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3925 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3926 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3927 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3928 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3929 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3930 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3931 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3932 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3933 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3934
3935 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3936 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3937 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3938 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3939 bind $ui_diff <$M1B-Key-v> {break}
3940 bind $ui_diff <$M1B-Key-V> {break}
3941 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3942 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3943 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3944 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3945 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3946 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3947
3948 if {!$single_commit} {
3949         bind . <$M1B-Key-n> do_create_branch
3950         bind . <$M1B-Key-N> do_create_branch
3951 }
3952
3953 bind .   <Destroy> do_quit
3954 bind all <Key-F5> do_rescan
3955 bind all <$M1B-Key-r> do_rescan
3956 bind all <$M1B-Key-R> do_rescan
3957 bind .   <$M1B-Key-s> do_signoff
3958 bind .   <$M1B-Key-S> do_signoff
3959 bind .   <$M1B-Key-i> do_add_all
3960 bind .   <$M1B-Key-I> do_add_all
3961 bind .   <$M1B-Key-Return> do_commit
3962 bind all <$M1B-Key-q> do_quit
3963 bind all <$M1B-Key-Q> do_quit
3964 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
3965 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
3966 foreach i [list $ui_index $ui_workdir] {
3967         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3968         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3969         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3970 }
3971 unset i
3972
3973 set file_lists($ui_index) [list]
3974 set file_lists($ui_workdir) [list]
3975
3976 set HEAD {}
3977 set PARENT {}
3978 set MERGE_HEAD [list]
3979 set commit_type {}
3980 set empty_tree {}
3981 set current_branch {}
3982 set current_diff {}
3983 set selected_commit_type new
3984
3985 wm title . "[appname] ([file normalize [file dirname [gitdir]]])"
3986 focus -force $ui_comm
3987
3988 # -- Warn the user about environmental problems.  Cygwin's Tcl
3989 #    does *not* pass its env array onto any processes it spawns.
3990 #    This means that git processes get none of our environment.
3991 #
3992 if {[is_Windows]} {
3993         set ignored_env 0
3994         set suggest_user {}
3995         set msg "Possible environment issues exist.
3996
3997 The following environment variables are probably
3998 going to be ignored by any Git subprocess run
3999 by [appname]:
4000
4001 "
4002         foreach name [array names env] {
4003                 switch -regexp -- $name {
4004                 {^GIT_INDEX_FILE$} -
4005                 {^GIT_OBJECT_DIRECTORY$} -
4006                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
4007                 {^GIT_DIFF_OPTS$} -
4008                 {^GIT_EXTERNAL_DIFF$} -
4009                 {^GIT_PAGER$} -
4010                 {^GIT_TRACE$} -
4011                 {^GIT_CONFIG$} -
4012                 {^GIT_CONFIG_LOCAL$} -
4013                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
4014                         append msg " - $name\n"
4015                         incr ignored_env
4016                 }
4017                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
4018                         append msg " - $name\n"
4019                         incr ignored_env
4020                         set suggest_user $name
4021                 }
4022                 }
4023         }
4024         if {$ignored_env > 0} {
4025                 append msg "
4026 This is due to a known issue with the
4027 Tcl binary distributed by Cygwin."
4028
4029                 if {$suggest_user ne {}} {
4030                         append msg "
4031
4032 A good replacement for $suggest_user
4033 is placing values for the user.name and
4034 user.email settings into your personal
4035 ~/.gitconfig file.
4036 "
4037                 }
4038                 warn_popup $msg
4039         }
4040         unset ignored_env msg suggest_user name
4041 }
4042
4043 # -- Only initialize complex UI if we are going to stay running.
4044 #
4045 if {!$single_commit} {
4046         load_all_remotes
4047         load_all_heads
4048
4049         populate_branch_menu
4050         populate_fetch_menu .mbar.fetch
4051         populate_pull_menu .mbar.pull
4052         populate_push_menu .mbar.push
4053 }
4054
4055 # -- Only suggest a gc run if we are going to stay running.
4056 #
4057 if {!$single_commit} {
4058         set object_limit 2000
4059         if {[is_Windows]} {set object_limit 200}
4060         regexp {^([0-9]+) objects,} [exec git count-objects] _junk objects_current
4061         if {$objects_current >= $object_limit} {
4062                 if {[ask_popup \
4063                         "This repository currently has $objects_current loose objects.
4064
4065 To maintain optimal performance it is strongly
4066 recommended that you compress the database
4067 when more than $object_limit loose objects exist.
4068
4069 Compress the database now?"] eq yes} {
4070                         do_gc
4071                 }
4072         }
4073         unset object_limit _junk objects_current
4074 }
4075
4076 lock_index begin-read
4077 after 1 do_rescan