git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [encoding convertfrom utf-8 {
  14 Copyright © 2006, 2007 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title [mc "git-gui: fatal error"] \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 set oguilib {@@GITGUI_LIBDIR@@}
  53 set oguirel {@@GITGUI_RELATIVE@@}
  54 if {$oguirel eq {1}} {
  55         set oguilib [file dirname [file normalize $argv0]]
  56         if {[file tail $oguilib] eq {git-core}} {
  57                 set oguilib [file dirname $oguilib]
  58         }
  59         set oguilib [file dirname $oguilib]
  60         set oguilib [file join $oguilib share git-gui lib]
  61         set oguimsg [file join $oguilib msgs]
  62 } elseif {[string match @@* $oguirel]} {
  63         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  64         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  65 } else {
  66         set oguimsg [file join $oguilib msgs]
  67 }
  68 unset oguirel
  69
  70 ######################################################################
  71 ##
  72 ## enable verbose loading?
  73
  74 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  75         unset _verbose
  76         rename auto_load real__auto_load
  77         proc auto_load {name args} {
  78                 puts stderr "auto_load $name"
  79                 return [uplevel 1 real__auto_load $name $args]
  80         }
  81         rename source real__source
  82         proc source {name} {
  83                 puts stderr "source    $name"
  84                 uplevel 1 real__source $name
  85         }
  86 }
  87
  88 ######################################################################
  89 ##
  90 ## Internationalization (i18n) through msgcat and gettext. See
  91 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  92
  93 package require msgcat
  94
  95 proc _mc_trim {fmt} {
  96         set cmk [string first @@ $fmt]
  97         if {$cmk > 0} {
  98                 return [string range $fmt 0 [expr {$cmk - 1}]]
  99         }
 100         return $fmt
 101 }
 102
 103 proc mc {en_fmt args} {
 104         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 105         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 106                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 107         }
 108         return $msg
 109 }
 110
 111 proc strcat {args} {
 112         return [join $args {}]
 113 }
 114
 115 ::msgcat::mcload $oguimsg
 116 unset oguimsg
 117
 118 ######################################################################
 119 ##
 120 ## read only globals
 121
 122 set _appname {Git Gui}
 123 set _gitdir {}
 124 set _gitexec {}
 125 set _reponame {}
 126 set _iscygwin {}
 127 set _search_path {}
 128
 129 set _trace [lsearch -exact $argv --trace]
 130 if {$_trace >= 0} {
 131         set argv [lreplace $argv $_trace $_trace]
 132         set _trace 1
 133 } else {
 134         set _trace 0
 135 }
 136
 137 proc appname {} {
 138         global _appname
 139         return $_appname
 140 }
 141
 142 proc gitdir {args} {
 143         global _gitdir
 144         if {$args eq {}} {
 145                 return $_gitdir
 146         }
 147         return [eval [list file join $_gitdir] $args]
 148 }
 149
 150 proc gitexec {args} {
 151         global _gitexec
 152         if {$_gitexec eq {}} {
 153                 if {[catch {set _gitexec [git --exec-path]} err]} {
 154                         error "Git not installed?\n\n$err"
 155                 }
 156                 if {[is_Cygwin]} {
 157                         set _gitexec [exec cygpath \
 158                                 --windows \
 159                                 --absolute \
 160                                 $_gitexec]
 161                 } else {
 162                         set _gitexec [file normalize $_gitexec]
 163                 }
 164         }
 165         if {$args eq {}} {
 166                 return $_gitexec
 167         }
 168         return [eval [list file join $_gitexec] $args]
 169 }
 170
 171 proc reponame {} {
 172         return $::_reponame
 173 }
 174
 175 proc is_MacOSX {} {
 176         if {[tk windowingsystem] eq {aqua}} {
 177                 return 1
 178         }
 179         return 0
 180 }
 181
 182 proc is_Windows {} {
 183         if {$::tcl_platform(platform) eq {windows}} {
 184                 return 1
 185         }
 186         return 0
 187 }
 188
 189 proc is_Cygwin {} {
 190         global _iscygwin
 191         if {$_iscygwin eq {}} {
 192                 if {$::tcl_platform(platform) eq {windows}} {
 193                         if {[catch {set p [exec cygpath --windir]} err]} {
 194                                 set _iscygwin 0
 195                         } else {
 196                                 set _iscygwin 1
 197                         }
 198                 } else {
 199                         set _iscygwin 0
 200                 }
 201         }
 202         return $_iscygwin
 203 }
 204
 205 proc is_enabled {option} {
 206         global enabled_options
 207         if {[catch {set on $enabled_options($option)}]} {return 0}
 208         return $on
 209 }
 210
 211 proc enable_option {option} {
 212         global enabled_options
 213         set enabled_options($option) 1
 214 }
 215
 216 proc disable_option {option} {
 217         global enabled_options
 218         set enabled_options($option) 0
 219 }
 220
 221 ######################################################################
 222 ##
 223 ## config
 224
 225 proc is_many_config {name} {
 226         switch -glob -- $name {
 227         gui.recentrepo -
 228         remote.*.fetch -
 229         remote.*.push
 230                 {return 1}
 231         *
 232                 {return 0}
 233         }
 234 }
 235
 236 proc is_config_true {name} {
 237         global repo_config
 238         if {[catch {set v $repo_config($name)}]} {
 239                 return 0
 240         } elseif {$v eq {true} || $v eq {1} || $v eq {yes}} {
 241                 return 1
 242         } else {
 243                 return 0
 244         }
 245 }
 246
 247 proc get_config {name} {
 248         global repo_config
 249         if {[catch {set v $repo_config($name)}]} {
 250                 return {}
 251         } else {
 252                 return $v
 253         }
 254 }
 255
 256 ######################################################################
 257 ##
 258 ## handy utils
 259
 260 proc _trace_exec {cmd} {
 261         if {!$::_trace} return
 262         set d {}
 263         foreach v $cmd {
 264                 if {$d ne {}} {
 265                         append d { }
 266                 }
 267                 if {[regexp {[ \t\r\n'"$?*]} $v]} {
 268                         set v [sq $v]
 269                 }
 270                 append d $v
 271         }
 272         puts stderr $d
 273 }
 274
 275 proc _git_cmd {name} {
 276         global _git_cmd_path
 277
 278         if {[catch {set v $_git_cmd_path($name)}]} {
 279                 switch -- $name {
 280                   version   -
 281                 --version   -
 282                 --exec-path { return [list $::_git $name] }
 283                 }
 284
 285                 set p [gitexec git-$name$::_search_exe]
 286                 if {[file exists $p]} {
 287                         set v [list $p]
 288                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 289                         # Try to determine what sort of magic will make
 290                         # git-$name go and do its thing, because native
 291                         # Tcl on Windows doesn't know it.
 292                         #
 293                         set p [gitexec git-$name]
 294                         set f [open $p r]
 295                         set s [gets $f]
 296                         close $f
 297
 298                         switch -glob -- [lindex $s 0] {
 299                         #!*sh     { set i sh     }
 300                         #!*perl   { set i perl   }
 301                         #!*python { set i python }
 302                         default   { error "git-$name is not supported: $s" }
 303                         }
 304
 305                         upvar #0 _$i interp
 306                         if {![info exists interp]} {
 307                                 set interp [_which $i]
 308                         }
 309                         if {$interp eq {}} {
 310                                 error "git-$name requires $i (not in PATH)"
 311                         }
 312                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 313                 } else {
 314                         # Assume it is builtin to git somehow and we
 315                         # aren't actually able to see a file for it.
 316                         #
 317                         set v [list $::_git $name]
 318                 }
 319                 set _git_cmd_path($name) $v
 320         }
 321         return $v
 322 }
 323
 324 proc _which {what args} {
 325         global env _search_exe _search_path
 326
 327         if {$_search_path eq {}} {
 328                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 329                         set _search_path [split [exec cygpath \
 330                                 --windows \
 331                                 --path \
 332                                 --absolute \
 333                                 $env(PATH)] {;}]
 334                         set _search_exe .exe
 335                 } elseif {[is_Windows]} {
 336                         set gitguidir [file dirname [info script]]
 337                         regsub -all ";" $gitguidir "\\;" gitguidir
 338                         set env(PATH) "$gitguidir;$env(PATH)"
 339                         set _search_path [split $env(PATH) {;}]
 340                         set _search_exe .exe
 341                 } else {
 342                         set _search_path [split $env(PATH) :]
 343                         set _search_exe {}
 344                 }
 345         }
 346
 347         if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 348                 set suffix {}
 349         } else {
 350                 set suffix $_search_exe
 351         }
 352
 353         foreach p $_search_path {
 354                 set p [file join $p $what$suffix]
 355                 if {[file exists $p]} {
 356                         return [file normalize $p]
 357                 }
 358         }
 359         return {}
 360 }
 361
 362 proc _lappend_nice {cmd_var} {
 363         global _nice
 364         upvar $cmd_var cmd
 365
 366         if {![info exists _nice]} {
 367                 set _nice [_which nice]
 368         }
 369         if {$_nice ne {}} {
 370                 lappend cmd $_nice
 371         }
 372 }
 373
 374 proc git {args} {
 375         set opt [list]
 376
 377         while {1} {
 378                 switch -- [lindex $args 0] {
 379                 --nice {
 380                         _lappend_nice opt
 381                 }
 382
 383                 default {
 384                         break
 385                 }
 386
 387                 }
 388
 389                 set args [lrange $args 1 end]
 390         }
 391
 392         set cmdp [_git_cmd [lindex $args 0]]
 393         set args [lrange $args 1 end]
 394
 395         _trace_exec [concat $opt $cmdp $args]
 396         set result [eval exec $opt $cmdp $args]
 397         if {$::_trace} {
 398                 puts stderr "< $result"
 399         }
 400         return $result
 401 }
 402
 403 proc _open_stdout_stderr {cmd} {
 404         _trace_exec $cmd
 405         if {[catch {
 406                         set fd [open [concat [list | ] $cmd] r]
 407                 } err]} {
 408                 if {   [lindex $cmd end] eq {2>@1}
 409                     && $err eq {can not find channel named "1"}
 410                         } {
 411                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 412                         # redirect operator.  Fallback to |& cat for those.
 413                         # The command was not actually started, so its safe
 414                         # to try to start it a second time.
 415                         #
 416                         set fd [open [concat \
 417                                 [list | ] \
 418                                 [lrange $cmd 0 end-1] \
 419                                 [list |& cat] \
 420                                 ] r]
 421                 } else {
 422                         error $err
 423                 }
 424         }
 425         fconfigure $fd -eofchar {}
 426         return $fd
 427 }
 428
 429 proc git_read {args} {
 430         set opt [list]
 431
 432         while {1} {
 433                 switch -- [lindex $args 0] {
 434                 --nice {
 435                         _lappend_nice opt
 436                 }
 437
 438                 --stderr {
 439                         lappend args 2>@1
 440                 }
 441
 442                 default {
 443                         break
 444                 }
 445
 446                 }
 447
 448                 set args [lrange $args 1 end]
 449         }
 450
 451         set cmdp [_git_cmd [lindex $args 0]]
 452         set args [lrange $args 1 end]
 453
 454         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 455 }
 456
 457 proc git_write {args} {
 458         set opt [list]
 459
 460         while {1} {
 461                 switch -- [lindex $args 0] {
 462                 --nice {
 463                         _lappend_nice opt
 464                 }
 465
 466                 default {
 467                         break
 468                 }
 469
 470                 }
 471
 472                 set args [lrange $args 1 end]
 473         }
 474
 475         set cmdp [_git_cmd [lindex $args 0]]
 476         set args [lrange $args 1 end]
 477
 478         _trace_exec [concat $opt $cmdp $args]
 479         return [open [concat [list | ] $opt $cmdp $args] w]
 480 }
 481
 482 proc githook_read {hook_name args} {
 483         set pchook [gitdir hooks $hook_name]
 484         lappend args 2>@1
 485
 486         # On Windows [file executable] might lie so we need to ask
 487         # the shell if the hook is executable.  Yes that's annoying.
 488         #
 489         if {[is_Windows]} {
 490                 upvar #0 _sh interp
 491                 if {![info exists interp]} {
 492                         set interp [_which sh]
 493                 }
 494                 if {$interp eq {}} {
 495                         error "hook execution requires sh (not in PATH)"
 496                 }
 497
 498                 set scr {if test -x "$1";then exec "$@";fi}
 499                 set sh_c [list $interp -c $scr $interp $pchook]
 500                 return [_open_stdout_stderr [concat $sh_c $args]]
 501         }
 502
 503         if {[file executable $pchook]} {
 504                 return [_open_stdout_stderr [concat [list $pchook] $args]]
 505         }
 506
 507         return {}
 508 }
 509
 510 proc kill_file_process {fd} {
 511         set process [pid $fd]
 512
 513         catch {
 514                 if {[is_Windows]} {
 515                         # Use a Cygwin-specific flag to allow killing
 516                         # native Windows processes
 517                         exec kill -f $process
 518                 } else {
 519                         exec kill $process
 520                 }
 521         }
 522 }
 523
 524 proc sq {value} {
 525         regsub -all ' $value "'\\''" value
 526         return "'$value'"
 527 }
 528
 529 proc load_current_branch {} {
 530         global current_branch is_detached
 531
 532         set fd [open [gitdir HEAD] r]
 533         if {[gets $fd ref] < 1} {
 534                 set ref {}
 535         }
 536         close $fd
 537
 538         set pfx {ref: refs/heads/}
 539         set len [string length $pfx]
 540         if {[string equal -length $len $pfx $ref]} {
 541                 # We're on a branch.  It might not exist.  But
 542                 # HEAD looks good enough to be a branch.
 543                 #
 544                 set current_branch [string range $ref $len end]
 545                 set is_detached 0
 546         } else {
 547                 # Assume this is a detached head.
 548                 #
 549                 set current_branch HEAD
 550                 set is_detached 1
 551         }
 552 }
 553
 554 auto_load tk_optionMenu
 555 rename tk_optionMenu real__tkOptionMenu
 556 proc tk_optionMenu {w varName args} {
 557         set m [eval real__tkOptionMenu $w $varName $args]
 558         $m configure -font font_ui
 559         $w configure -font font_ui
 560         return $m
 561 }
 562
 563 proc rmsel_tag {text} {
 564         $text tag conf sel \
 565                 -background [$text cget -background] \
 566                 -foreground [$text cget -foreground] \
 567                 -borderwidth 0
 568         $text tag conf in_sel -background lightgray
 569         bind $text <Motion> break
 570         return $text
 571 }
 572
 573 set root_exists 0
 574 bind . <Visibility> {
 575         bind . <Visibility> {}
 576         set root_exists 1
 577 }
 578
 579 if {[is_Windows]} {
 580         wm iconbitmap . -default $oguilib/git-gui.ico
 581 }
 582
 583 ######################################################################
 584 ##
 585 ## config defaults
 586
 587 set cursor_ptr arrow
 588 font create font_diff -family Courier -size 10
 589 font create font_ui
 590 catch {
 591         label .dummy
 592         eval font configure font_ui [font actual [.dummy cget -font]]
 593         destroy .dummy
 594 }
 595
 596 font create font_uiitalic
 597 font create font_uibold
 598 font create font_diffbold
 599 font create font_diffitalic
 600
 601 foreach class {Button Checkbutton Entry Label
 602                 Labelframe Listbox Menu Message
 603                 Radiobutton Spinbox Text} {
 604         option add *$class.font font_ui
 605 }
 606 unset class
 607
 608 if {[is_Windows] || [is_MacOSX]} {
 609         option add *Menu.tearOff 0
 610 }
 611
 612 if {[is_MacOSX]} {
 613         set M1B M1
 614         set M1T Cmd
 615 } else {
 616         set M1B Control
 617         set M1T Ctrl
 618 }
 619
 620 proc bind_button3 {w cmd} {
 621         bind $w <Any-Button-3> $cmd
 622         if {[is_MacOSX]} {
 623                 # Mac OS X sends Button-2 on right click through three-button mouse,
 624                 # or through trackpad right-clicking (two-finger touch + click).
 625                 bind $w <Any-Button-2> $cmd
 626                 bind $w <Control-Button-1> $cmd
 627         }
 628 }
 629
 630 proc apply_config {} {
 631         global repo_config font_descs
 632
 633         foreach option $font_descs {
 634                 set name [lindex $option 0]
 635                 set font [lindex $option 1]
 636                 if {[catch {
 637                         set need_weight 1
 638                         foreach {cn cv} $repo_config(gui.$name) {
 639                                 if {$cn eq {-weight}} {
 640                                         set need_weight 0
 641                                 }
 642                                 font configure $font $cn $cv
 643                         }
 644                         if {$need_weight} {
 645                                 font configure $font -weight normal
 646                         }
 647                         } err]} {
 648                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 649                 }
 650                 foreach {cn cv} [font configure $font] {
 651                         font configure ${font}bold $cn $cv
 652                         font configure ${font}italic $cn $cv
 653                 }
 654                 font configure ${font}bold -weight bold
 655                 font configure ${font}italic -slant italic
 656         }
 657 }
 658
 659 set default_config(branch.autosetupmerge) true
 660 set default_config(merge.tool) {}
 661 set default_config(merge.keepbackup) true
 662 set default_config(merge.diffstat) true
 663 set default_config(merge.summary) false
 664 set default_config(merge.verbosity) 2
 665 set default_config(user.name) {}
 666 set default_config(user.email) {}
 667
 668 set default_config(gui.matchtrackingbranch) false
 669 set default_config(gui.pruneduringfetch) false
 670 set default_config(gui.trustmtime) false
 671 set default_config(gui.fastcopyblame) false
 672 set default_config(gui.copyblamethreshold) 40
 673 set default_config(gui.blamehistoryctx) 7
 674 set default_config(gui.diffcontext) 5
 675 set default_config(gui.commitmsgwidth) 75
 676 set default_config(gui.newbranchtemplate) {}
 677 set default_config(gui.spellingdictionary) {}
 678 set default_config(gui.fontui) [font configure font_ui]
 679 set default_config(gui.fontdiff) [font configure font_diff]
 680 set font_descs {
 681         {fontui   font_ui   {mc "Main Font"}}
 682         {fontdiff font_diff {mc "Diff/Console Font"}}
 683 }
 684
 685 ######################################################################
 686 ##
 687 ## find git
 688
 689 set _git  [_which git]
 690 if {$_git eq {}} {
 691         catch {wm withdraw .}
 692         tk_messageBox \
 693                 -icon error \
 694                 -type ok \
 695                 -title [mc "git-gui: fatal error"] \
 696                 -message [mc "Cannot find git in PATH."]
 697         exit 1
 698 }
 699
 700 ######################################################################
 701 ##
 702 ## version check
 703
 704 if {[catch {set _git_version [git --version]} err]} {
 705         catch {wm withdraw .}
 706         tk_messageBox \
 707                 -icon error \
 708                 -type ok \
 709                 -title [mc "git-gui: fatal error"] \
 710                 -message "Cannot determine Git version:
 711
 712 $err
 713
 714 [appname] requires Git 1.5.0 or later."
 715         exit 1
 716 }
 717 if {![regsub {^git version } $_git_version {} _git_version]} {
 718         catch {wm withdraw .}
 719         tk_messageBox \
 720                 -icon error \
 721                 -type ok \
 722                 -title [mc "git-gui: fatal error"] \
 723                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 724         exit 1
 725 }
 726
 727 set _real_git_version $_git_version
 728 regsub -- {[\-\.]dirty$} $_git_version {} _git_version
 729 regsub {\.[0-9]+\.g[0-9a-f]+$} $_git_version {} _git_version
 730 regsub {\.rc[0-9]+$} $_git_version {} _git_version
 731 regsub {\.GIT$} $_git_version {} _git_version
 732 regsub {\.[a-zA-Z]+\.[0-9]+$} $_git_version {} _git_version
 733
 734 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 735         catch {wm withdraw .}
 736         if {[tk_messageBox \
 737                 -icon warning \
 738                 -type yesno \
 739                 -default no \
 740                 -title "[appname]: warning" \
 741                  -message [mc "Git version cannot be determined.
 742
 743 %s claims it is version '%s'.
 744
 745 %s requires at least Git 1.5.0 or later.
 746
 747 Assume '%s' is version 1.5.0?
 748 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 749                 set _git_version 1.5.0
 750         } else {
 751                 exit 1
 752         }
 753 }
 754 unset _real_git_version
 755
 756 proc git-version {args} {
 757         global _git_version
 758
 759         switch [llength $args] {
 760         0 {
 761                 return $_git_version
 762         }
 763
 764         2 {
 765                 set op [lindex $args 0]
 766                 set vr [lindex $args 1]
 767                 set cm [package vcompare $_git_version $vr]
 768                 return [expr $cm $op 0]
 769         }
 770
 771         4 {
 772                 set type [lindex $args 0]
 773                 set name [lindex $args 1]
 774                 set parm [lindex $args 2]
 775                 set body [lindex $args 3]
 776
 777                 if {($type ne {proc} && $type ne {method})} {
 778                         error "Invalid arguments to git-version"
 779                 }
 780                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
 781                         error "Last arm of $type $name must be default"
 782                 }
 783
 784                 foreach {op vr cb} [lrange $body 0 end-2] {
 785                         if {[git-version $op $vr]} {
 786                                 return [uplevel [list $type $name $parm $cb]]
 787                         }
 788                 }
 789
 790                 return [uplevel [list $type $name $parm [lindex $body end]]]
 791         }
 792
 793         default {
 794                 error "git-version >= x"
 795         }
 796
 797         }
 798 }
 799
 800 if {[git-version < 1.5]} {
 801         catch {wm withdraw .}
 802         tk_messageBox \
 803                 -icon error \
 804                 -type ok \
 805                 -title [mc "git-gui: fatal error"] \
 806                 -message "[appname] requires Git 1.5.0 or later.
 807
 808 You are using [git-version]:
 809
 810 [git --version]"
 811         exit 1
 812 }
 813
 814 ######################################################################
 815 ##
 816 ## configure our library
 817
 818 set idx [file join $oguilib tclIndex]
 819 if {[catch {set fd [open $idx r]} err]} {
 820         catch {wm withdraw .}
 821         tk_messageBox \
 822                 -icon error \
 823                 -type ok \
 824                 -title [mc "git-gui: fatal error"] \
 825                 -message $err
 826         exit 1
 827 }
 828 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
 829         set idx [list]
 830         while {[gets $fd n] >= 0} {
 831                 if {$n ne {} && ![string match #* $n]} {
 832                         lappend idx $n
 833                 }
 834         }
 835 } else {
 836         set idx {}
 837 }
 838 close $fd
 839
 840 if {$idx ne {}} {
 841         set loaded [list]
 842         foreach p $idx {
 843                 if {[lsearch -exact $loaded $p] >= 0} continue
 844                 source [file join $oguilib $p]
 845                 lappend loaded $p
 846         }
 847         unset loaded p
 848 } else {
 849         set auto_path [concat [list $oguilib] $auto_path]
 850 }
 851 unset -nocomplain idx fd
 852
 853 ######################################################################
 854 ##
 855 ## config file parsing
 856
 857 git-version proc _parse_config {arr_name args} {
 858         >= 1.5.3 {
 859                 upvar $arr_name arr
 860                 array unset arr
 861                 set buf {}
 862                 catch {
 863                         set fd_rc [eval \
 864                                 [list git_read config] \
 865                                 $args \
 866                                 [list --null --list]]
 867                         fconfigure $fd_rc -translation binary
 868                         set buf [read $fd_rc]
 869                         close $fd_rc
 870                 }
 871                 foreach line [split $buf "\0"] {
 872                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
 873                                 if {[is_many_config $name]} {
 874                                         lappend arr($name) $value
 875                                 } else {
 876                                         set arr($name) $value
 877                                 }
 878                         }
 879                 }
 880         }
 881         default {
 882                 upvar $arr_name arr
 883                 array unset arr
 884                 catch {
 885                         set fd_rc [eval [list git_read config --list] $args]
 886                         while {[gets $fd_rc line] >= 0} {
 887                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 888                                         if {[is_many_config $name]} {
 889                                                 lappend arr($name) $value
 890                                         } else {
 891                                                 set arr($name) $value
 892                                         }
 893                                 }
 894                         }
 895                         close $fd_rc
 896                 }
 897         }
 898 }
 899
 900 proc load_config {include_global} {
 901         global repo_config global_config default_config
 902
 903         if {$include_global} {
 904                 _parse_config global_config --global
 905         }
 906         _parse_config repo_config
 907
 908         foreach name [array names default_config] {
 909                 if {[catch {set v $global_config($name)}]} {
 910                         set global_config($name) $default_config($name)
 911                 }
 912                 if {[catch {set v $repo_config($name)}]} {
 913                         set repo_config($name) $default_config($name)
 914                 }
 915         }
 916 }
 917
 918 ######################################################################
 919 ##
 920 ## feature option selection
 921
 922 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
 923         unset _junk
 924 } else {
 925         set subcommand gui
 926 }
 927 if {$subcommand eq {gui.sh}} {
 928         set subcommand gui
 929 }
 930 if {$subcommand eq {gui} && [llength $argv] > 0} {
 931         set subcommand [lindex $argv 0]
 932         set argv [lrange $argv 1 end]
 933 }
 934
 935 enable_option multicommit
 936 enable_option branch
 937 enable_option transport
 938 disable_option bare
 939
 940 switch -- $subcommand {
 941 browser -
 942 blame {
 943         enable_option bare
 944
 945         disable_option multicommit
 946         disable_option branch
 947         disable_option transport
 948 }
 949 citool {
 950         enable_option singlecommit
 951
 952         disable_option multicommit
 953         disable_option branch
 954         disable_option transport
 955 }
 956 }
 957
 958 ######################################################################
 959 ##
 960 ## repository setup
 961
 962 if {[catch {
 963                 set _gitdir $env(GIT_DIR)
 964                 set _prefix {}
 965                 }]
 966         && [catch {
 967                 set _gitdir [git rev-parse --git-dir]
 968                 set _prefix [git rev-parse --show-prefix]
 969         } err]} {
 970         load_config 1
 971         apply_config
 972         choose_repository::pick
 973 }
 974 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
 975         catch {set _gitdir [exec cygpath --windows $_gitdir]}
 976 }
 977 if {![file isdirectory $_gitdir]} {
 978         catch {wm withdraw .}
 979         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
 980         exit 1
 981 }
 982 if {$_prefix ne {}} {
 983         regsub -all {[^/]+/} $_prefix ../ cdup
 984         if {[catch {cd $cdup} err]} {
 985                 catch {wm withdraw .}
 986                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
 987                 exit 1
 988         }
 989         unset cdup
 990 } elseif {![is_enabled bare]} {
 991         if {[lindex [file split $_gitdir] end] ne {.git}} {
 992                 catch {wm withdraw .}
 993                 error_popup [strcat [mc "Cannot use funny .git directory:"] "\n\n$_gitdir"]
 994                 exit 1
 995         }
 996         if {[catch {cd [file dirname $_gitdir]} err]} {
 997                 catch {wm withdraw .}
 998                 error_popup [strcat [mc "No working directory"] " [file dirname $_gitdir]:\n\n$err"]
 999                 exit 1
1000         }
1001 }
1002 set _reponame [file split [file normalize $_gitdir]]
1003 if {[lindex $_reponame end] eq {.git}} {
1004         set _reponame [lindex $_reponame end-1]
1005 } else {
1006         set _reponame [lindex $_reponame end]
1007 }
1008
1009 ######################################################################
1010 ##
1011 ## global init
1012
1013 set current_diff_path {}
1014 set current_diff_side {}
1015 set diff_actions [list]
1016
1017 set HEAD {}
1018 set PARENT {}
1019 set MERGE_HEAD [list]
1020 set commit_type {}
1021 set empty_tree {}
1022 set current_branch {}
1023 set is_detached 0
1024 set current_diff_path {}
1025 set is_3way_diff 0
1026 set selected_commit_type new
1027
1028 ######################################################################
1029 ##
1030 ## task management
1031
1032 set rescan_active 0
1033 set diff_active 0
1034 set last_clicked {}
1035
1036 set disable_on_lock [list]
1037 set index_lock_type none
1038
1039 proc lock_index {type} {
1040         global index_lock_type disable_on_lock
1041
1042         if {$index_lock_type eq {none}} {
1043                 set index_lock_type $type
1044                 foreach w $disable_on_lock {
1045                         uplevel #0 $w disabled
1046                 }
1047                 return 1
1048         } elseif {$index_lock_type eq "begin-$type"} {
1049                 set index_lock_type $type
1050                 return 1
1051         }
1052         return 0
1053 }
1054
1055 proc unlock_index {} {
1056         global index_lock_type disable_on_lock
1057
1058         set index_lock_type none
1059         foreach w $disable_on_lock {
1060                 uplevel #0 $w normal
1061         }
1062 }
1063
1064 ######################################################################
1065 ##
1066 ## status
1067
1068 proc repository_state {ctvar hdvar mhvar} {
1069         global current_branch
1070         upvar $ctvar ct $hdvar hd $mhvar mh
1071
1072         set mh [list]
1073
1074         load_current_branch
1075         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1076                 set hd {}
1077                 set ct initial
1078                 return
1079         }
1080
1081         set merge_head [gitdir MERGE_HEAD]
1082         if {[file exists $merge_head]} {
1083                 set ct merge
1084                 set fd_mh [open $merge_head r]
1085                 while {[gets $fd_mh line] >= 0} {
1086                         lappend mh $line
1087                 }
1088                 close $fd_mh
1089                 return
1090         }
1091
1092         set ct normal
1093 }
1094
1095 proc PARENT {} {
1096         global PARENT empty_tree
1097
1098         set p [lindex $PARENT 0]
1099         if {$p ne {}} {
1100                 return $p
1101         }
1102         if {$empty_tree eq {}} {
1103                 set empty_tree [git mktree << {}]
1104         }
1105         return $empty_tree
1106 }
1107
1108 proc rescan {after {honor_trustmtime 1}} {
1109         global HEAD PARENT MERGE_HEAD commit_type
1110         global ui_index ui_workdir ui_comm
1111         global rescan_active file_states
1112         global repo_config
1113
1114         if {$rescan_active > 0 || ![lock_index read]} return
1115
1116         repository_state newType newHEAD newMERGE_HEAD
1117         if {[string match amend* $commit_type]
1118                 && $newType eq {normal}
1119                 && $newHEAD eq $HEAD} {
1120         } else {
1121                 set HEAD $newHEAD
1122                 set PARENT $newHEAD
1123                 set MERGE_HEAD $newMERGE_HEAD
1124                 set commit_type $newType
1125         }
1126
1127         array unset file_states
1128
1129         if {!$::GITGUI_BCK_exists &&
1130                 (![$ui_comm edit modified]
1131                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1132                 if {[string match amend* $commit_type]} {
1133                 } elseif {[load_message GITGUI_MSG]} {
1134                 } elseif {[load_message MERGE_MSG]} {
1135                 } elseif {[load_message SQUASH_MSG]} {
1136                 }
1137                 $ui_comm edit reset
1138                 $ui_comm edit modified false
1139         }
1140
1141         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1142                 rescan_stage2 {} $after
1143         } else {
1144                 set rescan_active 1
1145                 ui_status [mc "Refreshing file status..."]
1146                 set fd_rf [git_read update-index \
1147                         -q \
1148                         --unmerged \
1149                         --ignore-missing \
1150                         --refresh \
1151                         ]
1152                 fconfigure $fd_rf -blocking 0 -translation binary
1153                 fileevent $fd_rf readable \
1154                         [list rescan_stage2 $fd_rf $after]
1155         }
1156 }
1157
1158 if {[is_Cygwin]} {
1159         set is_git_info_exclude {}
1160         proc have_info_exclude {} {
1161                 global is_git_info_exclude
1162
1163                 if {$is_git_info_exclude eq {}} {
1164                         if {[catch {exec test -f [gitdir info exclude]}]} {
1165                                 set is_git_info_exclude 0
1166                         } else {
1167                                 set is_git_info_exclude 1
1168                         }
1169                 }
1170                 return $is_git_info_exclude
1171         }
1172 } else {
1173         proc have_info_exclude {} {
1174                 return [file readable [gitdir info exclude]]
1175         }
1176 }
1177
1178 proc rescan_stage2 {fd after} {
1179         global rescan_active buf_rdi buf_rdf buf_rlo
1180
1181         if {$fd ne {}} {
1182                 read $fd
1183                 if {![eof $fd]} return
1184                 close $fd
1185         }
1186
1187         set ls_others [list --exclude-per-directory=.gitignore]
1188         if {[have_info_exclude]} {
1189                 lappend ls_others "--exclude-from=[gitdir info exclude]"
1190         }
1191         set user_exclude [get_config core.excludesfile]
1192         if {$user_exclude ne {} && [file readable $user_exclude]} {
1193                 lappend ls_others "--exclude-from=$user_exclude"
1194         }
1195
1196         set buf_rdi {}
1197         set buf_rdf {}
1198         set buf_rlo {}
1199
1200         set rescan_active 3
1201         ui_status [mc "Scanning for modified files ..."]
1202         set fd_di [git_read diff-index --cached -z [PARENT]]
1203         set fd_df [git_read diff-files -z]
1204         set fd_lo [eval git_read ls-files --others -z $ls_others]
1205
1206         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1207         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1208         fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1209         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1210         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1211         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1212 }
1213
1214 proc load_message {file} {
1215         global ui_comm
1216
1217         set f [gitdir $file]
1218         if {[file isfile $f]} {
1219                 if {[catch {set fd [open $f r]}]} {
1220                         return 0
1221                 }
1222                 fconfigure $fd -eofchar {}
1223                 set content [string trim [read $fd]]
1224                 close $fd
1225                 regsub -all -line {[ \r\t]+$} $content {} content
1226                 $ui_comm delete 0.0 end
1227                 $ui_comm insert end $content
1228                 return 1
1229         }
1230         return 0
1231 }
1232
1233 proc read_diff_index {fd after} {
1234         global buf_rdi
1235
1236         append buf_rdi [read $fd]
1237         set c 0
1238         set n [string length $buf_rdi]
1239         while {$c < $n} {
1240                 set z1 [string first "\0" $buf_rdi $c]
1241                 if {$z1 == -1} break
1242                 incr z1
1243                 set z2 [string first "\0" $buf_rdi $z1]
1244                 if {$z2 == -1} break
1245
1246                 incr c
1247                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1248                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1249                 merge_state \
1250                         [encoding convertfrom $p] \
1251                         [lindex $i 4]? \
1252                         [list [lindex $i 0] [lindex $i 2]] \
1253                         [list]
1254                 set c $z2
1255                 incr c
1256         }
1257         if {$c < $n} {
1258                 set buf_rdi [string range $buf_rdi $c end]
1259         } else {
1260                 set buf_rdi {}
1261         }
1262
1263         rescan_done $fd buf_rdi $after
1264 }
1265
1266 proc read_diff_files {fd after} {
1267         global buf_rdf
1268
1269         append buf_rdf [read $fd]
1270         set c 0
1271         set n [string length $buf_rdf]
1272         while {$c < $n} {
1273                 set z1 [string first "\0" $buf_rdf $c]
1274                 if {$z1 == -1} break
1275                 incr z1
1276                 set z2 [string first "\0" $buf_rdf $z1]
1277                 if {$z2 == -1} break
1278
1279                 incr c
1280                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1281                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1282                 merge_state \
1283                         [encoding convertfrom $p] \
1284                         ?[lindex $i 4] \
1285                         [list] \
1286                         [list [lindex $i 0] [lindex $i 2]]
1287                 set c $z2
1288                 incr c
1289         }
1290         if {$c < $n} {
1291                 set buf_rdf [string range $buf_rdf $c end]
1292         } else {
1293                 set buf_rdf {}
1294         }
1295
1296         rescan_done $fd buf_rdf $after
1297 }
1298
1299 proc read_ls_others {fd after} {
1300         global buf_rlo
1301
1302         append buf_rlo [read $fd]
1303         set pck [split $buf_rlo "\0"]
1304         set buf_rlo [lindex $pck end]
1305         foreach p [lrange $pck 0 end-1] {
1306                 set p [encoding convertfrom $p]
1307                 if {[string index $p end] eq {/}} {
1308                         set p [string range $p 0 end-1]
1309                 }
1310                 merge_state $p ?O
1311         }
1312         rescan_done $fd buf_rlo $after
1313 }
1314
1315 proc rescan_done {fd buf after} {
1316         global rescan_active current_diff_path
1317         global file_states repo_config
1318         upvar $buf to_clear
1319
1320         if {![eof $fd]} return
1321         set to_clear {}
1322         close $fd
1323         if {[incr rescan_active -1] > 0} return
1324
1325         prune_selection
1326         unlock_index
1327         display_all_files
1328         if {$current_diff_path ne {}} reshow_diff
1329         if {$current_diff_path eq {}} select_first_diff
1330
1331         uplevel #0 $after
1332 }
1333
1334 proc prune_selection {} {
1335         global file_states selected_paths
1336
1337         foreach path [array names selected_paths] {
1338                 if {[catch {set still_here $file_states($path)}]} {
1339                         unset selected_paths($path)
1340                 }
1341         }
1342 }
1343
1344 ######################################################################
1345 ##
1346 ## ui helpers
1347
1348 proc mapicon {w state path} {
1349         global all_icons
1350
1351         if {[catch {set r $all_icons($state$w)}]} {
1352                 puts "error: no icon for $w state={$state} $path"
1353                 return file_plain
1354         }
1355         return $r
1356 }
1357
1358 proc mapdesc {state path} {
1359         global all_descs
1360
1361         if {[catch {set r $all_descs($state)}]} {
1362                 puts "error: no desc for state={$state} $path"
1363                 return $state
1364         }
1365         return $r
1366 }
1367
1368 proc ui_status {msg} {
1369         global main_status
1370         if {[info exists main_status]} {
1371                 $main_status show $msg
1372         }
1373 }
1374
1375 proc ui_ready {{test {}}} {
1376         global main_status
1377         if {[info exists main_status]} {
1378                 $main_status show [mc "Ready."] $test
1379         }
1380 }
1381
1382 proc escape_path {path} {
1383         regsub -all {\\} $path "\\\\" path
1384         regsub -all "\n" $path "\\n" path
1385         return $path
1386 }
1387
1388 proc short_path {path} {
1389         return [escape_path [lindex [file split $path] end]]
1390 }
1391
1392 set next_icon_id 0
1393 set null_sha1 [string repeat 0 40]
1394
1395 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1396         global file_states next_icon_id null_sha1
1397
1398         set s0 [string index $new_state 0]
1399         set s1 [string index $new_state 1]
1400
1401         if {[catch {set info $file_states($path)}]} {
1402                 set state __
1403                 set icon n[incr next_icon_id]
1404         } else {
1405                 set state [lindex $info 0]
1406                 set icon [lindex $info 1]
1407                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1408                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1409         }
1410
1411         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1412         elseif {$s0 eq {_}} {set s0 _}
1413
1414         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1415         elseif {$s1 eq {_}} {set s1 _}
1416
1417         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1418                 set head_info [list 0 $null_sha1]
1419         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1420                 && $head_info eq {}} {
1421                 set head_info $index_info
1422         }
1423
1424         set file_states($path) [list $s0$s1 $icon \
1425                 $head_info $index_info \
1426                 ]
1427         return $state
1428 }
1429
1430 proc display_file_helper {w path icon_name old_m new_m} {
1431         global file_lists
1432
1433         if {$new_m eq {_}} {
1434                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1435                 if {$lno >= 0} {
1436                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1437                         incr lno
1438                         $w conf -state normal
1439                         $w delete $lno.0 [expr {$lno + 1}].0
1440                         $w conf -state disabled
1441                 }
1442         } elseif {$old_m eq {_} && $new_m ne {_}} {
1443                 lappend file_lists($w) $path
1444                 set file_lists($w) [lsort -unique $file_lists($w)]
1445                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1446                 incr lno
1447                 $w conf -state normal
1448                 $w image create $lno.0 \
1449                         -align center -padx 5 -pady 1 \
1450                         -name $icon_name \
1451                         -image [mapicon $w $new_m $path]
1452                 $w insert $lno.1 "[escape_path $path]\n"
1453                 $w conf -state disabled
1454         } elseif {$old_m ne $new_m} {
1455                 $w conf -state normal
1456                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1457                 $w conf -state disabled
1458         }
1459 }
1460
1461 proc display_file {path state} {
1462         global file_states selected_paths
1463         global ui_index ui_workdir
1464
1465         set old_m [merge_state $path $state]
1466         set s $file_states($path)
1467         set new_m [lindex $s 0]
1468         set icon_name [lindex $s 1]
1469
1470         set o [string index $old_m 0]
1471         set n [string index $new_m 0]
1472         if {$o eq {U}} {
1473                 set o _
1474         }
1475         if {$n eq {U}} {
1476                 set n _
1477         }
1478         display_file_helper     $ui_index $path $icon_name $o $n
1479
1480         if {[string index $old_m 0] eq {U}} {
1481                 set o U
1482         } else {
1483                 set o [string index $old_m 1]
1484         }
1485         if {[string index $new_m 0] eq {U}} {
1486                 set n U
1487         } else {
1488                 set n [string index $new_m 1]
1489         }
1490         display_file_helper     $ui_workdir $path $icon_name $o $n
1491
1492         if {$new_m eq {__}} {
1493                 unset file_states($path)
1494                 catch {unset selected_paths($path)}
1495         }
1496 }
1497
1498 proc display_all_files_helper {w path icon_name m} {
1499         global file_lists
1500
1501         lappend file_lists($w) $path
1502         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1503         $w image create end \
1504                 -align center -padx 5 -pady 1 \
1505                 -name $icon_name \
1506                 -image [mapicon $w $m $path]
1507         $w insert end "[escape_path $path]\n"
1508 }
1509
1510 proc display_all_files {} {
1511         global ui_index ui_workdir
1512         global file_states file_lists
1513         global last_clicked
1514
1515         $ui_index conf -state normal
1516         $ui_workdir conf -state normal
1517
1518         $ui_index delete 0.0 end
1519         $ui_workdir delete 0.0 end
1520         set last_clicked {}
1521
1522         set file_lists($ui_index) [list]
1523         set file_lists($ui_workdir) [list]
1524
1525         foreach path [lsort [array names file_states]] {
1526                 set s $file_states($path)
1527                 set m [lindex $s 0]
1528                 set icon_name [lindex $s 1]
1529
1530                 set s [string index $m 0]
1531                 if {$s ne {U} && $s ne {_}} {
1532                         display_all_files_helper $ui_index $path \
1533                                 $icon_name $s
1534                 }
1535
1536                 if {[string index $m 0] eq {U}} {
1537                         set s U
1538                 } else {
1539                         set s [string index $m 1]
1540                 }
1541                 if {$s ne {_}} {
1542                         display_all_files_helper $ui_workdir $path \
1543                                 $icon_name $s
1544                 }
1545         }
1546
1547         $ui_index conf -state disabled
1548         $ui_workdir conf -state disabled
1549 }
1550
1551 ######################################################################
1552 ##
1553 ## icons
1554
1555 set filemask {
1556 #define mask_width 14
1557 #define mask_height 15
1558 static unsigned char mask_bits[] = {
1559    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1560    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1561    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1562 }
1563
1564 image create bitmap file_plain -background white -foreground black -data {
1565 #define plain_width 14
1566 #define plain_height 15
1567 static unsigned char plain_bits[] = {
1568    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1569    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1570    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1571 } -maskdata $filemask
1572
1573 image create bitmap file_mod -background white -foreground blue -data {
1574 #define mod_width 14
1575 #define mod_height 15
1576 static unsigned char mod_bits[] = {
1577    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1578    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1579    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1580 } -maskdata $filemask
1581
1582 image create bitmap file_fulltick -background white -foreground "#007000" -data {
1583 #define file_fulltick_width 14
1584 #define file_fulltick_height 15
1585 static unsigned char file_fulltick_bits[] = {
1586    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1587    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1588    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1589 } -maskdata $filemask
1590
1591 image create bitmap file_parttick -background white -foreground "#005050" -data {
1592 #define parttick_width 14
1593 #define parttick_height 15
1594 static unsigned char parttick_bits[] = {
1595    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1596    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
1597    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1598 } -maskdata $filemask
1599
1600 image create bitmap file_question -background white -foreground black -data {
1601 #define file_question_width 14
1602 #define file_question_height 15
1603 static unsigned char file_question_bits[] = {
1604    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1605    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1606    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1607 } -maskdata $filemask
1608
1609 image create bitmap file_removed -background white -foreground red -data {
1610 #define file_removed_width 14
1611 #define file_removed_height 15
1612 static unsigned char file_removed_bits[] = {
1613    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1614    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1615    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1616 } -maskdata $filemask
1617
1618 image create bitmap file_merge -background white -foreground blue -data {
1619 #define file_merge_width 14
1620 #define file_merge_height 15
1621 static unsigned char file_merge_bits[] = {
1622    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1623    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1624    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1625 } -maskdata $filemask
1626
1627 image create bitmap file_statechange -background white -foreground green -data {
1628 #define file_merge_width 14
1629 #define file_merge_height 15
1630 static unsigned char file_statechange_bits[] = {
1631    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
1632    0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
1633    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1634 } -maskdata $filemask
1635
1636 set ui_index .vpane.files.index.list
1637 set ui_workdir .vpane.files.workdir.list
1638
1639 set all_icons(_$ui_index)   file_plain
1640 set all_icons(A$ui_index)   file_fulltick
1641 set all_icons(M$ui_index)   file_fulltick
1642 set all_icons(D$ui_index)   file_removed
1643 set all_icons(U$ui_index)   file_merge
1644 set all_icons(T$ui_index)   file_statechange
1645
1646 set all_icons(_$ui_workdir) file_plain
1647 set all_icons(M$ui_workdir) file_mod
1648 set all_icons(D$ui_workdir) file_question
1649 set all_icons(U$ui_workdir) file_merge
1650 set all_icons(O$ui_workdir) file_plain
1651 set all_icons(T$ui_workdir) file_statechange
1652
1653 set max_status_desc 0
1654 foreach i {
1655                 {__ {mc "Unmodified"}}
1656
1657                 {_M {mc "Modified, not staged"}}
1658                 {M_ {mc "Staged for commit"}}
1659                 {MM {mc "Portions staged for commit"}}
1660                 {MD {mc "Staged for commit, missing"}}
1661
1662                 {_T {mc "File type changed, not staged"}}
1663                 {T_ {mc "File type changed, staged"}}
1664
1665                 {_O {mc "Untracked, not staged"}}
1666                 {A_ {mc "Staged for commit"}}
1667                 {AM {mc "Portions staged for commit"}}
1668                 {AD {mc "Staged for commit, missing"}}
1669
1670                 {_D {mc "Missing"}}
1671                 {D_ {mc "Staged for removal"}}
1672                 {DO {mc "Staged for removal, still present"}}
1673
1674                 {_U {mc "Requires merge resolution"}}
1675                 {U_ {mc "Requires merge resolution"}}
1676                 {UU {mc "Requires merge resolution"}}
1677                 {UM {mc "Requires merge resolution"}}
1678                 {UD {mc "Requires merge resolution"}}
1679                 {UT {mc "Requires merge resolution"}}
1680         } {
1681         set text [eval [lindex $i 1]]
1682         if {$max_status_desc < [string length $text]} {
1683                 set max_status_desc [string length $text]
1684         }
1685         set all_descs([lindex $i 0]) $text
1686 }
1687 unset i
1688
1689 ######################################################################
1690 ##
1691 ## util
1692
1693 proc scrollbar2many {list mode args} {
1694         foreach w $list {eval $w $mode $args}
1695 }
1696
1697 proc many2scrollbar {list mode sb top bottom} {
1698         $sb set $top $bottom
1699         foreach w $list {$w $mode moveto $top}
1700 }
1701
1702 proc incr_font_size {font {amt 1}} {
1703         set sz [font configure $font -size]
1704         incr sz $amt
1705         font configure $font -size $sz
1706         font configure ${font}bold -size $sz
1707         font configure ${font}italic -size $sz
1708 }
1709
1710 ######################################################################
1711 ##
1712 ## ui commands
1713
1714 set starting_gitk_msg [mc "Starting gitk... please wait..."]
1715
1716 proc do_gitk {revs} {
1717         # -- Always start gitk through whatever we were loaded with.  This
1718         #    lets us bypass using shell process on Windows systems.
1719         #
1720         set exe [_which gitk -script]
1721         set cmd [list [info nameofexecutable] $exe]
1722         if {$exe eq {}} {
1723                 error_popup [mc "Couldn't find gitk in PATH"]
1724         } else {
1725                 global env
1726
1727                 if {[info exists env(GIT_DIR)]} {
1728                         set old_GIT_DIR $env(GIT_DIR)
1729                 } else {
1730                         set old_GIT_DIR {}
1731                 }
1732
1733                 set pwd [pwd]
1734                 cd [file dirname [gitdir]]
1735                 set env(GIT_DIR) [file tail [gitdir]]
1736
1737                 eval exec $cmd $revs &
1738
1739                 if {$old_GIT_DIR eq {}} {
1740                         unset env(GIT_DIR)
1741                 } else {
1742                         set env(GIT_DIR) $old_GIT_DIR
1743                 }
1744                 cd $pwd
1745
1746                 ui_status $::starting_gitk_msg
1747                 after 10000 {
1748                         ui_ready $starting_gitk_msg
1749                 }
1750         }
1751 }
1752
1753 set is_quitting 0
1754
1755 proc do_quit {} {
1756         global ui_comm is_quitting repo_config commit_type
1757         global GITGUI_BCK_exists GITGUI_BCK_i
1758         global ui_comm_spell
1759
1760         if {$is_quitting} return
1761         set is_quitting 1
1762
1763         if {[winfo exists $ui_comm]} {
1764                 # -- Stash our current commit buffer.
1765                 #
1766                 set save [gitdir GITGUI_MSG]
1767                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
1768                         file rename -force [gitdir GITGUI_BCK] $save
1769                         set GITGUI_BCK_exists 0
1770                 } else {
1771                         set msg [string trim [$ui_comm get 0.0 end]]
1772                         regsub -all -line {[ \r\t]+$} $msg {} msg
1773                         if {(![string match amend* $commit_type]
1774                                 || [$ui_comm edit modified])
1775                                 && $msg ne {}} {
1776                                 catch {
1777                                         set fd [open $save w]
1778                                         puts -nonewline $fd $msg
1779                                         close $fd
1780                                 }
1781                         } else {
1782                                 catch {file delete $save}
1783                         }
1784                 }
1785
1786                 # -- Cancel our spellchecker if its running.
1787                 #
1788                 if {[info exists ui_comm_spell]} {
1789                         $ui_comm_spell stop
1790                 }
1791
1792                 # -- Remove our editor backup, its not needed.
1793                 #
1794                 after cancel $GITGUI_BCK_i
1795                 if {$GITGUI_BCK_exists} {
1796                         catch {file delete [gitdir GITGUI_BCK]}
1797                 }
1798
1799                 # -- Stash our current window geometry into this repository.
1800                 #
1801                 set cfg_geometry [list]
1802                 lappend cfg_geometry [wm geometry .]
1803                 lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
1804                 lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
1805                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
1806                         set rc_geometry {}
1807                 }
1808                 if {$cfg_geometry ne $rc_geometry} {
1809                         catch {git config gui.geometry $cfg_geometry}
1810                 }
1811         }
1812
1813         destroy .
1814 }
1815
1816 proc do_rescan {} {
1817         rescan ui_ready
1818 }
1819
1820 proc do_commit {} {
1821         commit_tree
1822 }
1823
1824 proc next_diff {} {
1825         global next_diff_p next_diff_w next_diff_i
1826         show_diff $next_diff_p $next_diff_w {}
1827 }
1828
1829 proc find_anchor_pos {lst name} {
1830         set lid [lsearch -sorted -exact $lst $name]
1831
1832         if {$lid == -1} {
1833                 set lid 0
1834                 foreach lname $lst {
1835                         if {$lname >= $name} break
1836                         incr lid
1837                 }
1838         }
1839
1840         return $lid
1841 }
1842
1843 proc find_file_from {flist idx delta path mmask} {
1844         global file_states
1845
1846         set len [llength $flist]
1847         while {$idx >= 0 && $idx < $len} {
1848                 set name [lindex $flist $idx]
1849
1850                 if {$name ne $path && [info exists file_states($name)]} {
1851                         set state [lindex $file_states($name) 0]
1852
1853                         if {$mmask eq {} || [regexp $mmask $state]} {
1854                                 return $idx
1855                         }
1856                 }
1857
1858                 incr idx $delta
1859         }
1860
1861         return {}
1862 }
1863
1864 proc find_next_diff {w path {lno {}} {mmask {}}} {
1865         global next_diff_p next_diff_w next_diff_i
1866         global file_lists ui_index ui_workdir
1867
1868         set flist $file_lists($w)
1869         if {$lno eq {}} {
1870                 set lno [find_anchor_pos $flist $path]
1871         } else {
1872                 incr lno -1
1873         }
1874
1875         if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
1876                 if {$w eq $ui_index} {
1877                         set mmask "^$mmask"
1878                 } else {
1879                         set mmask "$mmask\$"
1880                 }
1881         }
1882
1883         set idx [find_file_from $flist $lno 1 $path $mmask]
1884         if {$idx eq {}} {
1885                 incr lno -1
1886                 set idx [find_file_from $flist $lno -1 $path $mmask]
1887         }
1888
1889         if {$idx ne {}} {
1890                 set next_diff_w $w
1891                 set next_diff_p [lindex $flist $idx]
1892                 set next_diff_i [expr {$idx+1}]
1893                 return 1
1894         } else {
1895                 return 0
1896         }
1897 }
1898
1899 proc next_diff_after_action {w path {lno {}} {mmask {}}} {
1900         global current_diff_path
1901
1902         if {$path ne $current_diff_path} {
1903                 return {}
1904         } elseif {[find_next_diff $w $path $lno $mmask]} {
1905                 return {next_diff;}
1906         } else {
1907                 return {reshow_diff;}
1908         }
1909 }
1910
1911 proc select_first_diff {} {
1912         global ui_workdir
1913
1914         if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
1915             [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
1916                 next_diff
1917         }
1918 }
1919
1920 proc toggle_or_diff {w x y} {
1921         global file_states file_lists current_diff_path ui_index ui_workdir
1922         global last_clicked selected_paths
1923
1924         set pos [split [$w index @$x,$y] .]
1925         set lno [lindex $pos 0]
1926         set col [lindex $pos 1]
1927         set path [lindex $file_lists($w) [expr {$lno - 1}]]
1928         if {$path eq {}} {
1929                 set last_clicked {}
1930                 return
1931         }
1932
1933         set last_clicked [list $w $lno]
1934         array unset selected_paths
1935         $ui_index tag remove in_sel 0.0 end
1936         $ui_workdir tag remove in_sel 0.0 end
1937
1938         # Do not stage files with conflicts
1939         if {[info exists file_states($path)]} {
1940                 set state [lindex $file_states($path) 0]
1941                 if {[string first {U} $state] >= 0} {
1942                         set col 1
1943                 }
1944         }
1945
1946         if {$col == 0 && $y > 1} {
1947                 set after [next_diff_after_action $w $path $lno]
1948
1949                 if {$w eq $ui_index} {
1950                         update_indexinfo \
1951                                 "Unstaging [short_path $path] from commit" \
1952                                 [list $path] \
1953                                 [concat $after [list ui_ready]]
1954                 } elseif {$w eq $ui_workdir} {
1955                         update_index \
1956                                 "Adding [short_path $path]" \
1957                                 [list $path] \
1958                                 [concat $after [list ui_ready]]
1959                 }
1960         } else {
1961                 show_diff $path $w $lno
1962         }
1963 }
1964
1965 proc add_one_to_selection {w x y} {
1966         global file_lists last_clicked selected_paths
1967
1968         set lno [lindex [split [$w index @$x,$y] .] 0]
1969         set path [lindex $file_lists($w) [expr {$lno - 1}]]
1970         if {$path eq {}} {
1971                 set last_clicked {}
1972                 return
1973         }
1974
1975         if {$last_clicked ne {}
1976                 && [lindex $last_clicked 0] ne $w} {
1977                 array unset selected_paths
1978                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
1979         }
1980
1981         set last_clicked [list $w $lno]
1982         if {[catch {set in_sel $selected_paths($path)}]} {
1983                 set in_sel 0
1984         }
1985         if {$in_sel} {
1986                 unset selected_paths($path)
1987                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
1988         } else {
1989                 set selected_paths($path) 1
1990                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
1991         }
1992 }
1993
1994 proc add_range_to_selection {w x y} {
1995         global file_lists last_clicked selected_paths
1996
1997         if {[lindex $last_clicked 0] ne $w} {
1998                 toggle_or_diff $w $x $y
1999                 return
2000         }
2001
2002         set lno [lindex [split [$w index @$x,$y] .] 0]
2003         set lc [lindex $last_clicked 1]
2004         if {$lc < $lno} {
2005                 set begin $lc
2006                 set end $lno
2007         } else {
2008                 set begin $lno
2009                 set end $lc
2010         }
2011
2012         foreach path [lrange $file_lists($w) \
2013                 [expr {$begin - 1}] \
2014                 [expr {$end - 1}]] {
2015                 set selected_paths($path) 1
2016         }
2017         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2018 }
2019
2020 proc show_more_context {} {
2021         global repo_config
2022         if {$repo_config(gui.diffcontext) < 99} {
2023                 incr repo_config(gui.diffcontext)
2024                 reshow_diff
2025         }
2026 }
2027
2028 proc show_less_context {} {
2029         global repo_config
2030         if {$repo_config(gui.diffcontext) > 1} {
2031                 incr repo_config(gui.diffcontext) -1
2032                 reshow_diff
2033         }
2034 }
2035
2036 ######################################################################
2037 ##
2038 ## ui construction
2039
2040 load_config 0
2041 apply_config
2042 set ui_comm {}
2043
2044 # -- Menu Bar
2045 #
2046 menu .mbar -tearoff 0
2047 .mbar add cascade -label [mc Repository] -menu .mbar.repository
2048 .mbar add cascade -label [mc Edit] -menu .mbar.edit
2049 if {[is_enabled branch]} {
2050         .mbar add cascade -label [mc Branch] -menu .mbar.branch
2051 }
2052 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2053         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2054 }
2055 if {[is_enabled transport]} {
2056         .mbar add cascade -label [mc Merge] -menu .mbar.merge
2057         .mbar add cascade -label [mc Remote] -menu .mbar.remote
2058 }
2059 . configure -menu .mbar
2060
2061 # -- Repository Menu
2062 #
2063 menu .mbar.repository
2064
2065 .mbar.repository add command \
2066         -label [mc "Browse Current Branch's Files"] \
2067         -command {browser::new $current_branch}
2068 set ui_browse_current [.mbar.repository index last]
2069 .mbar.repository add command \
2070         -label [mc "Browse Branch Files..."] \
2071         -command browser_open::dialog
2072 .mbar.repository add separator
2073
2074 .mbar.repository add command \
2075         -label [mc "Visualize Current Branch's History"] \
2076         -command {do_gitk $current_branch}
2077 set ui_visualize_current [.mbar.repository index last]
2078 .mbar.repository add command \
2079         -label [mc "Visualize All Branch History"] \
2080         -command {do_gitk --all}
2081 .mbar.repository add separator
2082
2083 proc current_branch_write {args} {
2084         global current_branch
2085         .mbar.repository entryconf $::ui_browse_current \
2086                 -label [mc "Browse %s's Files" $current_branch]
2087         .mbar.repository entryconf $::ui_visualize_current \
2088                 -label [mc "Visualize %s's History" $current_branch]
2089 }
2090 trace add variable current_branch write current_branch_write
2091
2092 if {[is_enabled multicommit]} {
2093         .mbar.repository add command -label [mc "Database Statistics"] \
2094                 -command do_stats
2095
2096         .mbar.repository add command -label [mc "Compress Database"] \
2097                 -command do_gc
2098
2099         .mbar.repository add command -label [mc "Verify Database"] \
2100                 -command do_fsck_objects
2101
2102         .mbar.repository add separator
2103
2104         if {[is_Cygwin]} {
2105                 .mbar.repository add command \
2106                         -label [mc "Create Desktop Icon"] \
2107                         -command do_cygwin_shortcut
2108         } elseif {[is_Windows]} {
2109                 .mbar.repository add command \
2110                         -label [mc "Create Desktop Icon"] \
2111                         -command do_windows_shortcut
2112         } elseif {[is_MacOSX]} {
2113                 .mbar.repository add command \
2114                         -label [mc "Create Desktop Icon"] \
2115                         -command do_macosx_app
2116         }
2117 }
2118
2119 if {[is_MacOSX]} {
2120         proc ::tk::mac::Quit {args} { do_quit }
2121 } else {
2122         .mbar.repository add command -label [mc Quit] \
2123                 -command do_quit \
2124                 -accelerator $M1T-Q
2125 }
2126
2127 # -- Edit Menu
2128 #
2129 menu .mbar.edit
2130 .mbar.edit add command -label [mc Undo] \
2131         -command {catch {[focus] edit undo}} \
2132         -accelerator $M1T-Z
2133 .mbar.edit add command -label [mc Redo] \
2134         -command {catch {[focus] edit redo}} \
2135         -accelerator $M1T-Y
2136 .mbar.edit add separator
2137 .mbar.edit add command -label [mc Cut] \
2138         -command {catch {tk_textCut [focus]}} \
2139         -accelerator $M1T-X
2140 .mbar.edit add command -label [mc Copy] \
2141         -command {catch {tk_textCopy [focus]}} \
2142         -accelerator $M1T-C
2143 .mbar.edit add command -label [mc Paste] \
2144         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2145         -accelerator $M1T-V
2146 .mbar.edit add command -label [mc Delete] \
2147         -command {catch {[focus] delete sel.first sel.last}} \
2148         -accelerator Del
2149 .mbar.edit add separator
2150 .mbar.edit add command -label [mc "Select All"] \
2151         -command {catch {[focus] tag add sel 0.0 end}} \
2152         -accelerator $M1T-A
2153
2154 # -- Branch Menu
2155 #
2156 if {[is_enabled branch]} {
2157         menu .mbar.branch
2158
2159         .mbar.branch add command -label [mc "Create..."] \
2160                 -command branch_create::dialog \
2161                 -accelerator $M1T-N
2162         lappend disable_on_lock [list .mbar.branch entryconf \
2163                 [.mbar.branch index last] -state]
2164
2165         .mbar.branch add command -label [mc "Checkout..."] \
2166                 -command branch_checkout::dialog \
2167                 -accelerator $M1T-O
2168         lappend disable_on_lock [list .mbar.branch entryconf \
2169                 [.mbar.branch index last] -state]
2170
2171         .mbar.branch add command -label [mc "Rename..."] \
2172                 -command branch_rename::dialog
2173         lappend disable_on_lock [list .mbar.branch entryconf \
2174                 [.mbar.branch index last] -state]
2175
2176         .mbar.branch add command -label [mc "Delete..."] \
2177                 -command branch_delete::dialog
2178         lappend disable_on_lock [list .mbar.branch entryconf \
2179                 [.mbar.branch index last] -state]
2180
2181         .mbar.branch add command -label [mc "Reset..."] \
2182                 -command merge::reset_hard
2183         lappend disable_on_lock [list .mbar.branch entryconf \
2184                 [.mbar.branch index last] -state]
2185 }
2186
2187 # -- Commit Menu
2188 #
2189 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2190         menu .mbar.commit
2191
2192         .mbar.commit add radiobutton \
2193                 -label [mc "New Commit"] \
2194                 -command do_select_commit_type \
2195                 -variable selected_commit_type \
2196                 -value new
2197         lappend disable_on_lock \
2198                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2199
2200         .mbar.commit add radiobutton \
2201                 -label [mc "Amend Last Commit"] \
2202                 -command do_select_commit_type \
2203                 -variable selected_commit_type \
2204                 -value amend
2205         lappend disable_on_lock \
2206                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2207
2208         .mbar.commit add separator
2209
2210         .mbar.commit add command -label [mc Rescan] \
2211                 -command do_rescan \
2212                 -accelerator F5
2213         lappend disable_on_lock \
2214                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2215
2216         .mbar.commit add command -label [mc "Stage To Commit"] \
2217                 -command do_add_selection \
2218                 -accelerator $M1T-T
2219         lappend disable_on_lock \
2220                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2221
2222         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2223                 -command do_add_all \
2224                 -accelerator $M1T-I
2225         lappend disable_on_lock \
2226                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2227
2228         .mbar.commit add command -label [mc "Unstage From Commit"] \
2229                 -command do_unstage_selection
2230         lappend disable_on_lock \
2231                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2232
2233         .mbar.commit add command -label [mc "Revert Changes"] \
2234                 -command do_revert_selection
2235         lappend disable_on_lock \
2236                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2237
2238         .mbar.commit add separator
2239
2240         .mbar.commit add command -label [mc "Show Less Context"] \
2241                 -command show_less_context \
2242                 -accelerator $M1T-\-
2243
2244         .mbar.commit add command -label [mc "Show More Context"] \
2245                 -command show_more_context \
2246                 -accelerator $M1T-=
2247
2248         .mbar.commit add separator
2249
2250         .mbar.commit add command -label [mc "Sign Off"] \
2251                 -command do_signoff \
2252                 -accelerator $M1T-S
2253
2254         .mbar.commit add command -label [mc Commit@@verb] \
2255                 -command do_commit \
2256                 -accelerator $M1T-Return
2257         lappend disable_on_lock \
2258                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2259 }
2260
2261 # -- Merge Menu
2262 #
2263 if {[is_enabled branch]} {
2264         menu .mbar.merge
2265         .mbar.merge add command -label [mc "Local Merge..."] \
2266                 -command merge::dialog \
2267                 -accelerator $M1T-M
2268         lappend disable_on_lock \
2269                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2270         .mbar.merge add command -label [mc "Abort Merge..."] \
2271                 -command merge::reset_hard
2272         lappend disable_on_lock \
2273                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2274 }
2275
2276 # -- Transport Menu
2277 #
2278 if {[is_enabled transport]} {
2279         menu .mbar.remote
2280
2281         .mbar.remote add command \
2282                 -label [mc "Push..."] \
2283                 -command do_push_anywhere \
2284                 -accelerator $M1T-P
2285         .mbar.remote add command \
2286                 -label [mc "Delete..."] \
2287                 -command remote_branch_delete::dialog
2288 }
2289
2290 if {[is_MacOSX]} {
2291         # -- Apple Menu (Mac OS X only)
2292         #
2293         .mbar add cascade -label Apple -menu .mbar.apple
2294         menu .mbar.apple
2295
2296         .mbar.apple add command -label [mc "About %s" [appname]] \
2297                 -command do_about
2298         .mbar.apple add separator
2299         .mbar.apple add command \
2300                 -label [mc "Preferences..."] \
2301                 -command do_options \
2302                 -accelerator $M1T-,
2303         bind . <$M1B-,> do_options
2304 } else {
2305         # -- Edit Menu
2306         #
2307         .mbar.edit add separator
2308         .mbar.edit add command -label [mc "Options..."] \
2309                 -command do_options
2310 }
2311
2312 # -- Help Menu
2313 #
2314 .mbar add cascade -label [mc Help] -menu .mbar.help
2315 menu .mbar.help
2316
2317 if {![is_MacOSX]} {
2318         .mbar.help add command -label [mc "About %s" [appname]] \
2319                 -command do_about
2320 }
2321
2322 set browser {}
2323 catch {set browser $repo_config(instaweb.browser)}
2324 set doc_path [file dirname [gitexec]]
2325 set doc_path [file join $doc_path Documentation index.html]
2326
2327 if {[is_Cygwin]} {
2328         set doc_path [exec cygpath --mixed $doc_path]
2329 }
2330
2331 if {$browser eq {}} {
2332         if {[is_MacOSX]} {
2333                 set browser open
2334         } elseif {[is_Cygwin]} {
2335                 set program_files [file dirname [exec cygpath --windir]]
2336                 set program_files [file join $program_files {Program Files}]
2337                 set firefox [file join $program_files {Mozilla Firefox} firefox.exe]
2338                 set ie [file join $program_files {Internet Explorer} IEXPLORE.EXE]
2339                 if {[file exists $firefox]} {
2340                         set browser $firefox
2341                 } elseif {[file exists $ie]} {
2342                         set browser $ie
2343                 }
2344                 unset program_files firefox ie
2345         }
2346 }
2347
2348 if {[file isfile $doc_path]} {
2349         set doc_url "file:$doc_path"
2350 } else {
2351         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2352 }
2353
2354 if {$browser ne {}} {
2355         .mbar.help add command -label [mc "Online Documentation"] \
2356                 -command [list exec $browser $doc_url &]
2357 }
2358 unset browser doc_path doc_url
2359
2360 # -- Standard bindings
2361 #
2362 wm protocol . WM_DELETE_WINDOW do_quit
2363 bind all <$M1B-Key-q> do_quit
2364 bind all <$M1B-Key-Q> do_quit
2365 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
2366 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
2367
2368 set subcommand_args {}
2369 proc usage {} {
2370         puts stderr "usage: $::argv0 $::subcommand $::subcommand_args"
2371         exit 1
2372 }
2373
2374 # -- Not a normal commit type invocation?  Do that instead!
2375 #
2376 switch -- $subcommand {
2377 browser -
2378 blame {
2379         if {$subcommand eq "blame"} {
2380                 set subcommand_args {[--line=<num>] rev? path}
2381         } else {
2382                 set subcommand_args {rev? path}
2383         }
2384         if {$argv eq {}} usage
2385         set head {}
2386         set path {}
2387         set jump_spec {}
2388         set is_path 0
2389         foreach a $argv {
2390                 if {$is_path || [file exists $_prefix$a]} {
2391                         if {$path ne {}} usage
2392                         set path $_prefix$a
2393                         break
2394                 } elseif {$a eq {--}} {
2395                         if {$path ne {}} {
2396                                 if {$head ne {}} usage
2397                                 set head $path
2398                                 set path {}
2399                         }
2400                         set is_path 1
2401                 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
2402                         if {$jump_spec ne {} || $head ne {}} usage
2403                         set jump_spec [list $lnum]
2404                 } elseif {$head eq {}} {
2405                         if {$head ne {}} usage
2406                         set head $a
2407                         set is_path 1
2408                 } else {
2409                         usage
2410                 }
2411         }
2412         unset is_path
2413
2414         if {$head ne {} && $path eq {}} {
2415                 set path $_prefix$head
2416                 set head {}
2417         }
2418
2419         if {$head eq {}} {
2420                 load_current_branch
2421         } else {
2422                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
2423                         if {[catch {
2424                                         set head [git rev-parse --verify $head]
2425                                 } err]} {
2426                                 puts stderr $err
2427                                 exit 1
2428                         }
2429                 }
2430                 set current_branch $head
2431         }
2432
2433         switch -- $subcommand {
2434         browser {
2435                 if {$jump_spec ne {}} usage
2436                 if {$head eq {}} {
2437                         if {$path ne {} && [file isdirectory $path]} {
2438                                 set head $current_branch
2439                         } else {
2440                                 set head $path
2441                                 set path {}
2442                         }
2443                 }
2444                 browser::new $head $path
2445         }
2446         blame   {
2447                 if {$head eq {} && ![file exists $path]} {
2448                         puts stderr [mc "fatal: cannot stat path %s: No such file or directory" $path]
2449                         exit 1
2450                 }
2451                 blame::new $head $path $jump_spec
2452         }
2453         }
2454         return
2455 }
2456 citool -
2457 gui {
2458         if {[llength $argv] != 0} {
2459                 puts -nonewline stderr "usage: $argv0"
2460                 if {$subcommand ne {gui}
2461                         && [file tail $argv0] ne "git-$subcommand"} {
2462                         puts -nonewline stderr " $subcommand"
2463                 }
2464                 puts stderr {}
2465                 exit 1
2466         }
2467         # fall through to setup UI for commits
2468 }
2469 default {
2470         puts stderr "usage: $argv0 \[{blame|browser|citool}\]"
2471         exit 1
2472 }
2473 }
2474
2475 # -- Branch Control
2476 #
2477 frame .branch \
2478         -borderwidth 1 \
2479         -relief sunken
2480 label .branch.l1 \
2481         -text [mc "Current Branch:"] \
2482         -anchor w \
2483         -justify left
2484 label .branch.cb \
2485         -textvariable current_branch \
2486         -anchor w \
2487         -justify left
2488 pack .branch.l1 -side left
2489 pack .branch.cb -side left -fill x
2490 pack .branch -side top -fill x
2491
2492 # -- Main Window Layout
2493 #
2494 panedwindow .vpane -orient horizontal
2495 panedwindow .vpane.files -orient vertical
2496 .vpane add .vpane.files -sticky nsew -height 100 -width 200
2497 pack .vpane -anchor n -side top -fill both -expand 1
2498
2499 # -- Index File List
2500 #
2501 frame .vpane.files.index -height 100 -width 200
2502 label .vpane.files.index.title -text [mc "Staged Changes (Will Commit)"] \
2503         -background lightgreen -foreground black
2504 text $ui_index -background white -foreground black \
2505         -borderwidth 0 \
2506         -width 20 -height 10 \
2507         -wrap none \
2508         -cursor $cursor_ptr \
2509         -xscrollcommand {.vpane.files.index.sx set} \
2510         -yscrollcommand {.vpane.files.index.sy set} \
2511         -state disabled
2512 scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
2513 scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
2514 pack .vpane.files.index.title -side top -fill x
2515 pack .vpane.files.index.sx -side bottom -fill x
2516 pack .vpane.files.index.sy -side right -fill y
2517 pack $ui_index -side left -fill both -expand 1
2518
2519 # -- Working Directory File List
2520 #
2521 frame .vpane.files.workdir -height 100 -width 200
2522 label .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
2523         -background lightsalmon -foreground black
2524 text $ui_workdir -background white -foreground black \
2525         -borderwidth 0 \
2526         -width 20 -height 10 \
2527         -wrap none \
2528         -cursor $cursor_ptr \
2529         -xscrollcommand {.vpane.files.workdir.sx set} \
2530         -yscrollcommand {.vpane.files.workdir.sy set} \
2531         -state disabled
2532 scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
2533 scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
2534 pack .vpane.files.workdir.title -side top -fill x
2535 pack .vpane.files.workdir.sx -side bottom -fill x
2536 pack .vpane.files.workdir.sy -side right -fill y
2537 pack $ui_workdir -side left -fill both -expand 1
2538
2539 .vpane.files add .vpane.files.workdir -sticky nsew
2540 .vpane.files add .vpane.files.index -sticky nsew
2541
2542 foreach i [list $ui_index $ui_workdir] {
2543         rmsel_tag $i
2544         $i tag conf in_diff -background [$i tag cget in_sel -background]
2545 }
2546 unset i
2547
2548 # -- Diff and Commit Area
2549 #
2550 frame .vpane.lower -height 300 -width 400
2551 frame .vpane.lower.commarea
2552 frame .vpane.lower.diff -relief sunken -borderwidth 1
2553 pack .vpane.lower.diff -fill both -expand 1
2554 pack .vpane.lower.commarea -side bottom -fill x
2555 .vpane add .vpane.lower -sticky nsew
2556
2557 # -- Commit Area Buttons
2558 #
2559 frame .vpane.lower.commarea.buttons
2560 label .vpane.lower.commarea.buttons.l -text {} \
2561         -anchor w \
2562         -justify left
2563 pack .vpane.lower.commarea.buttons.l -side top -fill x
2564 pack .vpane.lower.commarea.buttons -side left -fill y
2565
2566 button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
2567         -command do_rescan
2568 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
2569 lappend disable_on_lock \
2570         {.vpane.lower.commarea.buttons.rescan conf -state}
2571
2572 button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
2573         -command do_add_all
2574 pack .vpane.lower.commarea.buttons.incall -side top -fill x
2575 lappend disable_on_lock \
2576         {.vpane.lower.commarea.buttons.incall conf -state}
2577
2578 button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
2579         -command do_signoff
2580 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
2581
2582 button .vpane.lower.commarea.buttons.commit -text [mc Commit@@verb] \
2583         -command do_commit
2584 pack .vpane.lower.commarea.buttons.commit -side top -fill x
2585 lappend disable_on_lock \
2586         {.vpane.lower.commarea.buttons.commit conf -state}
2587
2588 button .vpane.lower.commarea.buttons.push -text [mc Push] \
2589         -command do_push_anywhere
2590 pack .vpane.lower.commarea.buttons.push -side top -fill x
2591
2592 # -- Commit Message Buffer
2593 #
2594 frame .vpane.lower.commarea.buffer
2595 frame .vpane.lower.commarea.buffer.header
2596 set ui_comm .vpane.lower.commarea.buffer.t
2597 set ui_coml .vpane.lower.commarea.buffer.header.l
2598 radiobutton .vpane.lower.commarea.buffer.header.new \
2599         -text [mc "New Commit"] \
2600         -command do_select_commit_type \
2601         -variable selected_commit_type \
2602         -value new
2603 lappend disable_on_lock \
2604         [list .vpane.lower.commarea.buffer.header.new conf -state]
2605 radiobutton .vpane.lower.commarea.buffer.header.amend \
2606         -text [mc "Amend Last Commit"] \
2607         -command do_select_commit_type \
2608         -variable selected_commit_type \
2609         -value amend
2610 lappend disable_on_lock \
2611         [list .vpane.lower.commarea.buffer.header.amend conf -state]
2612 label $ui_coml \
2613         -anchor w \
2614         -justify left
2615 proc trace_commit_type {varname args} {
2616         global ui_coml commit_type
2617         switch -glob -- $commit_type {
2618         initial       {set txt [mc "Initial Commit Message:"]}
2619         amend         {set txt [mc "Amended Commit Message:"]}
2620         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
2621         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
2622         merge         {set txt [mc "Merge Commit Message:"]}
2623         *             {set txt [mc "Commit Message:"]}
2624         }
2625         $ui_coml conf -text $txt
2626 }
2627 trace add variable commit_type write trace_commit_type
2628 pack $ui_coml -side left -fill x
2629 pack .vpane.lower.commarea.buffer.header.amend -side right
2630 pack .vpane.lower.commarea.buffer.header.new -side right
2631
2632 text $ui_comm -background white -foreground black \
2633         -borderwidth 1 \
2634         -undo true \
2635         -maxundo 20 \
2636         -autoseparators true \
2637         -relief sunken \
2638         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
2639         -font font_diff \
2640         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
2641 scrollbar .vpane.lower.commarea.buffer.sby \
2642         -command [list $ui_comm yview]
2643 pack .vpane.lower.commarea.buffer.header -side top -fill x
2644 pack .vpane.lower.commarea.buffer.sby -side right -fill y
2645 pack $ui_comm -side left -fill y
2646 pack .vpane.lower.commarea.buffer -side left -fill y
2647
2648 # -- Commit Message Buffer Context Menu
2649 #
2650 set ctxm .vpane.lower.commarea.buffer.ctxm
2651 menu $ctxm -tearoff 0
2652 $ctxm add command \
2653         -label [mc Cut] \
2654         -command {tk_textCut $ui_comm}
2655 $ctxm add command \
2656         -label [mc Copy] \
2657         -command {tk_textCopy $ui_comm}
2658 $ctxm add command \
2659         -label [mc Paste] \
2660         -command {tk_textPaste $ui_comm}
2661 $ctxm add command \
2662         -label [mc Delete] \
2663         -command {$ui_comm delete sel.first sel.last}
2664 $ctxm add separator
2665 $ctxm add command \
2666         -label [mc "Select All"] \
2667         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
2668 $ctxm add command \
2669         -label [mc "Copy All"] \
2670         -command {
2671                 $ui_comm tag add sel 0.0 end
2672                 tk_textCopy $ui_comm
2673                 $ui_comm tag remove sel 0.0 end
2674         }
2675 $ctxm add separator
2676 $ctxm add command \
2677         -label [mc "Sign Off"] \
2678         -command do_signoff
2679 set ui_comm_ctxm $ctxm
2680
2681 # -- Diff Header
2682 #
2683 proc trace_current_diff_path {varname args} {
2684         global current_diff_path diff_actions file_states
2685         if {$current_diff_path eq {}} {
2686                 set s {}
2687                 set f {}
2688                 set p {}
2689                 set o disabled
2690         } else {
2691                 set p $current_diff_path
2692                 set s [mapdesc [lindex $file_states($p) 0] $p]
2693                 set f [mc "File:"]
2694                 set p [escape_path $p]
2695                 set o normal
2696         }
2697
2698         .vpane.lower.diff.header.status configure -text $s
2699         .vpane.lower.diff.header.file configure -text $f
2700         .vpane.lower.diff.header.path configure -text $p
2701         foreach w $diff_actions {
2702                 uplevel #0 $w $o
2703         }
2704 }
2705 trace add variable current_diff_path write trace_current_diff_path
2706
2707 frame .vpane.lower.diff.header -background gold
2708 label .vpane.lower.diff.header.status \
2709         -background gold \
2710         -foreground black \
2711         -width $max_status_desc \
2712         -anchor w \
2713         -justify left
2714 label .vpane.lower.diff.header.file \
2715         -background gold \
2716         -foreground black \
2717         -anchor w \
2718         -justify left
2719 label .vpane.lower.diff.header.path \
2720         -background gold \
2721         -foreground black \
2722         -anchor w \
2723         -justify left
2724 pack .vpane.lower.diff.header.status -side left
2725 pack .vpane.lower.diff.header.file -side left
2726 pack .vpane.lower.diff.header.path -fill x
2727 set ctxm .vpane.lower.diff.header.ctxm
2728 menu $ctxm -tearoff 0
2729 $ctxm add command \
2730         -label [mc Copy] \
2731         -command {
2732                 clipboard clear
2733                 clipboard append \
2734                         -format STRING \
2735                         -type STRING \
2736                         -- $current_diff_path
2737         }
2738 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2739 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
2740
2741 # -- Diff Body
2742 #
2743 frame .vpane.lower.diff.body
2744 set ui_diff .vpane.lower.diff.body.t
2745 text $ui_diff -background white -foreground black \
2746         -borderwidth 0 \
2747         -width 80 -height 15 -wrap none \
2748         -font font_diff \
2749         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
2750         -yscrollcommand {.vpane.lower.diff.body.sby set} \
2751         -state disabled
2752 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
2753         -command [list $ui_diff xview]
2754 scrollbar .vpane.lower.diff.body.sby -orient vertical \
2755         -command [list $ui_diff yview]
2756 pack .vpane.lower.diff.body.sbx -side bottom -fill x
2757 pack .vpane.lower.diff.body.sby -side right -fill y
2758 pack $ui_diff -side left -fill both -expand 1
2759 pack .vpane.lower.diff.header -side top -fill x
2760 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
2761
2762 $ui_diff tag conf d_cr -elide true
2763 $ui_diff tag conf d_@ -foreground blue -font font_diffbold
2764 $ui_diff tag conf d_+ -foreground {#00a000}
2765 $ui_diff tag conf d_- -foreground red
2766
2767 $ui_diff tag conf d_++ -foreground {#00a000}
2768 $ui_diff tag conf d_-- -foreground red
2769 $ui_diff tag conf d_+s \
2770         -foreground {#00a000} \
2771         -background {#e2effa}
2772 $ui_diff tag conf d_-s \
2773         -foreground red \
2774         -background {#e2effa}
2775 $ui_diff tag conf d_s+ \
2776         -foreground {#00a000} \
2777         -background ivory1
2778 $ui_diff tag conf d_s- \
2779         -foreground red \
2780         -background ivory1
2781
2782 $ui_diff tag conf d<<<<<<< \
2783         -foreground orange \
2784         -font font_diffbold
2785 $ui_diff tag conf d======= \
2786         -foreground orange \
2787         -font font_diffbold
2788 $ui_diff tag conf d>>>>>>> \
2789         -foreground orange \
2790         -font font_diffbold
2791
2792 $ui_diff tag raise sel
2793
2794 # -- Diff Body Context Menu
2795 #
2796
2797 proc create_common_diff_popup {ctxm} {
2798         $ctxm add command \
2799                 -label [mc "Show Less Context"] \
2800                 -command show_less_context
2801         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2802         $ctxm add command \
2803                 -label [mc "Show More Context"] \
2804                 -command show_more_context
2805         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2806         $ctxm add separator
2807         $ctxm add command \
2808                 -label [mc Refresh] \
2809                 -command reshow_diff
2810         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2811         $ctxm add command \
2812                 -label [mc Copy] \
2813                 -command {tk_textCopy $ui_diff}
2814         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2815         $ctxm add command \
2816                 -label [mc "Select All"] \
2817                 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
2818         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2819         $ctxm add command \
2820                 -label [mc "Copy All"] \
2821                 -command {
2822                         $ui_diff tag add sel 0.0 end
2823                         tk_textCopy $ui_diff
2824                         $ui_diff tag remove sel 0.0 end
2825                 }
2826         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2827         $ctxm add separator
2828         $ctxm add command \
2829                 -label [mc "Decrease Font Size"] \
2830                 -command {incr_font_size font_diff -1}
2831         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2832         $ctxm add command \
2833                 -label [mc "Increase Font Size"] \
2834                 -command {incr_font_size font_diff 1}
2835         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2836         $ctxm add separator
2837         $ctxm add command -label [mc "Options..."] \
2838                 -command do_options
2839 }
2840
2841 set ctxm .vpane.lower.diff.body.ctxm
2842 menu $ctxm -tearoff 0
2843 $ctxm add command \
2844         -label [mc "Apply/Reverse Hunk"] \
2845         -command {apply_hunk $cursorX $cursorY}
2846 set ui_diff_applyhunk [$ctxm index last]
2847 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
2848 $ctxm add command \
2849         -label [mc "Apply/Reverse Line"] \
2850         -command {apply_line $cursorX $cursorY; do_rescan}
2851 set ui_diff_applyline [$ctxm index last]
2852 lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
2853 $ctxm add separator
2854 create_common_diff_popup $ctxm
2855
2856 set ctxmmg .vpane.lower.diff.body.ctxmmg
2857 menu $ctxmmg -tearoff 0
2858 $ctxmmg add command \
2859         -label [mc "Run Merge Tool"] \
2860         -command {merge_resolve_tool}
2861 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2862 $ctxmmg add separator
2863 $ctxmmg add command \
2864         -label [mc "Use Remote Version"] \
2865         -command {merge_resolve_one 3}
2866 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2867 $ctxmmg add command \
2868         -label [mc "Use Local Version"] \
2869         -command {merge_resolve_one 2}
2870 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2871 $ctxmmg add command \
2872         -label [mc "Revert To Base"] \
2873         -command {merge_resolve_one 1}
2874 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2875 $ctxmmg add separator
2876 create_common_diff_popup $ctxmmg
2877
2878 proc popup_diff_menu {ctxm ctxmmg x y X Y} {
2879         global current_diff_path file_states
2880         set ::cursorX $x
2881         set ::cursorY $y
2882         if {[info exists file_states($current_diff_path)]} {
2883                 set state [lindex $file_states($current_diff_path) 0]
2884         } else {
2885                 set state {__}
2886         }
2887         if {[string first {U} $state] >= 0} {
2888                 tk_popup $ctxmmg $X $Y
2889         } else {
2890                 if {$::ui_index eq $::current_diff_side} {
2891                         set l [mc "Unstage Hunk From Commit"]
2892                         set t [mc "Unstage Line From Commit"]
2893                 } else {
2894                         set l [mc "Stage Hunk For Commit"]
2895                         set t [mc "Stage Line For Commit"]
2896                 }
2897                 if {$::is_3way_diff
2898                         || $current_diff_path eq {}
2899                         || {__} eq $state
2900                         || {_O} eq $state
2901                         || {_T} eq $state
2902                         || {T_} eq $state} {
2903                         set s disabled
2904                 } else {
2905                         set s normal
2906                 }
2907                 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
2908                 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
2909                 tk_popup $ctxm $X $Y
2910         }
2911 }
2912 bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg %x %y %X %Y]
2913
2914 # -- Status Bar
2915 #
2916 set main_status [::status_bar::new .status]
2917 pack .status -anchor w -side bottom -fill x
2918 $main_status show [mc "Initializing..."]
2919
2920 # -- Load geometry
2921 #
2922 catch {
2923 set gm $repo_config(gui.geometry)
2924 wm geometry . [lindex $gm 0]
2925 .vpane sash place 0 \
2926         [lindex $gm 1] \
2927         [lindex [.vpane sash coord 0] 1]
2928 .vpane.files sash place 0 \
2929         [lindex [.vpane.files sash coord 0] 0] \
2930         [lindex $gm 2]
2931 unset gm
2932 }
2933
2934 # -- Key Bindings
2935 #
2936 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
2937 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
2938 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
2939 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
2940 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
2941 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
2942 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
2943 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
2944 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
2945 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
2946 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
2947 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
2948 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
2949 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
2950 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
2951 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
2952 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
2953 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
2954
2955 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
2956 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
2957 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
2958 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
2959 bind $ui_diff <$M1B-Key-v> {break}
2960 bind $ui_diff <$M1B-Key-V> {break}
2961 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
2962 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
2963 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
2964 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
2965 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
2966 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
2967 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
2968 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
2969 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
2970 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
2971 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
2972 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
2973 bind $ui_diff <Button-1>   {focus %W}
2974
2975 if {[is_enabled branch]} {
2976         bind . <$M1B-Key-n> branch_create::dialog
2977         bind . <$M1B-Key-N> branch_create::dialog
2978         bind . <$M1B-Key-o> branch_checkout::dialog
2979         bind . <$M1B-Key-O> branch_checkout::dialog
2980         bind . <$M1B-Key-m> merge::dialog
2981         bind . <$M1B-Key-M> merge::dialog
2982 }
2983 if {[is_enabled transport]} {
2984         bind . <$M1B-Key-p> do_push_anywhere
2985         bind . <$M1B-Key-P> do_push_anywhere
2986 }
2987
2988 bind .   <Key-F5>     do_rescan
2989 bind .   <$M1B-Key-r> do_rescan
2990 bind .   <$M1B-Key-R> do_rescan
2991 bind .   <$M1B-Key-s> do_signoff
2992 bind .   <$M1B-Key-S> do_signoff
2993 bind .   <$M1B-Key-t> do_add_selection
2994 bind .   <$M1B-Key-T> do_add_selection
2995 bind .   <$M1B-Key-i> do_add_all
2996 bind .   <$M1B-Key-I> do_add_all
2997 bind .   <$M1B-Key-minus> {show_less_context;break}
2998 bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
2999 bind .   <$M1B-Key-equal> {show_more_context;break}
3000 bind .   <$M1B-Key-plus> {show_more_context;break}
3001 bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3002 bind .   <$M1B-Key-Return> do_commit
3003 foreach i [list $ui_index $ui_workdir] {
3004         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3005         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3006         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3007 }
3008 unset i
3009
3010 set file_lists($ui_index) [list]
3011 set file_lists($ui_workdir) [list]
3012
3013 wm title . "[appname] ([reponame]) [file normalize [file dirname [gitdir]]]"
3014 focus -force $ui_comm
3015
3016 # -- Warn the user about environmental problems.  Cygwin's Tcl
3017 #    does *not* pass its env array onto any processes it spawns.
3018 #    This means that git processes get none of our environment.
3019 #
3020 if {[is_Cygwin]} {
3021         set ignored_env 0
3022         set suggest_user {}
3023         set msg [mc "Possible environment issues exist.
3024
3025 The following environment variables are probably
3026 going to be ignored by any Git subprocess run
3027 by %s:
3028
3029 " [appname]]
3030         foreach name [array names env] {
3031                 switch -regexp -- $name {
3032                 {^GIT_INDEX_FILE$} -
3033                 {^GIT_OBJECT_DIRECTORY$} -
3034                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3035                 {^GIT_DIFF_OPTS$} -
3036                 {^GIT_EXTERNAL_DIFF$} -
3037                 {^GIT_PAGER$} -
3038                 {^GIT_TRACE$} -
3039                 {^GIT_CONFIG$} -
3040                 {^GIT_CONFIG_LOCAL$} -
3041                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3042                         append msg " - $name\n"
3043                         incr ignored_env
3044                 }
3045                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3046                         append msg " - $name\n"
3047                         incr ignored_env
3048                         set suggest_user $name
3049                 }
3050                 }
3051         }
3052         if {$ignored_env > 0} {
3053                 append msg [mc "
3054 This is due to a known issue with the
3055 Tcl binary distributed by Cygwin."]
3056
3057                 if {$suggest_user ne {}} {
3058                         append msg [mc "
3059
3060 A good replacement for %s
3061 is placing values for the user.name and
3062 user.email settings into your personal
3063 ~/.gitconfig file.
3064 " $suggest_user]
3065                 }
3066                 warn_popup $msg
3067         }
3068         unset ignored_env msg suggest_user name
3069 }
3070
3071 # -- Only initialize complex UI if we are going to stay running.
3072 #
3073 if {[is_enabled transport]} {
3074         load_all_remotes
3075
3076         set n [.mbar.remote index end]
3077         populate_push_menu
3078         populate_fetch_menu
3079         set n [expr {[.mbar.remote index end] - $n}]
3080         if {$n > 0} {
3081                 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3082                 .mbar.remote insert $n separator
3083         }
3084         unset n
3085 }
3086
3087 if {[winfo exists $ui_comm]} {
3088         set GITGUI_BCK_exists [load_message GITGUI_BCK]
3089
3090         # -- If both our backup and message files exist use the
3091         #    newer of the two files to initialize the buffer.
3092         #
3093         if {$GITGUI_BCK_exists} {
3094                 set m [gitdir GITGUI_MSG]
3095                 if {[file isfile $m]} {
3096                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3097                                 catch {file delete [gitdir GITGUI_MSG]}
3098                         } else {
3099                                 $ui_comm delete 0.0 end
3100                                 $ui_comm edit reset
3101                                 $ui_comm edit modified false
3102                                 catch {file delete [gitdir GITGUI_BCK]}
3103                                 set GITGUI_BCK_exists 0
3104                         }
3105                 }
3106                 unset m
3107         }
3108
3109         proc backup_commit_buffer {} {
3110                 global ui_comm GITGUI_BCK_exists
3111
3112                 set m [$ui_comm edit modified]
3113                 if {$m || $GITGUI_BCK_exists} {
3114                         set msg [string trim [$ui_comm get 0.0 end]]
3115                         regsub -all -line {[ \r\t]+$} $msg {} msg
3116
3117                         if {$msg eq {}} {
3118                                 if {$GITGUI_BCK_exists} {
3119                                         catch {file delete [gitdir GITGUI_BCK]}
3120                                         set GITGUI_BCK_exists 0
3121                                 }
3122                         } elseif {$m} {
3123                                 catch {
3124                                         set fd [open [gitdir GITGUI_BCK] w]
3125                                         puts -nonewline $fd $msg
3126                                         close $fd
3127                                         set GITGUI_BCK_exists 1
3128                                 }
3129                         }
3130
3131                         $ui_comm edit modified false
3132                 }
3133
3134                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3135         }
3136
3137         backup_commit_buffer
3138
3139         # -- If the user has aspell available we can drive it
3140         #    in pipe mode to spellcheck the commit message.
3141         #
3142         set spell_cmd [list |]
3143         set spell_dict [get_config gui.spellingdictionary]
3144         lappend spell_cmd aspell
3145         if {$spell_dict ne {}} {
3146                 lappend spell_cmd --master=$spell_dict
3147         }
3148         lappend spell_cmd --mode=none
3149         lappend spell_cmd --encoding=utf-8
3150         lappend spell_cmd pipe
3151         if {$spell_dict eq {none}
3152          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3153                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3154         } else {
3155                 set ui_comm_spell [spellcheck::init \
3156                         $spell_fd \
3157                         $ui_comm \
3158                         $ui_comm_ctxm \
3159                 ]
3160         }
3161         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
3162 }
3163
3164 lock_index begin-read
3165 if {![winfo ismapped .]} {
3166         wm deiconify .
3167 }
3168 after 1 do_rescan
3169 if {[is_enabled multicommit]} {
3170         after 1000 hint_gc
3171 }