git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [encoding convertfrom utf-8 {
  14 Copyright © 2006, 2007 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title [mc "git-gui: fatal error"] \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 set oguilib {@@GITGUI_LIBDIR@@}
  53 set oguirel {@@GITGUI_RELATIVE@@}
  54 if {$oguirel eq {1}} {
  55         set oguilib [file dirname [file normalize $argv0]]
  56         if {[file tail $oguilib] eq {git-core}} {
  57                 set oguilib [file dirname $oguilib]
  58         }
  59         set oguilib [file dirname $oguilib]
  60         set oguilib [file join $oguilib share git-gui lib]
  61         set oguimsg [file join $oguilib msgs]
  62 } elseif {[string match @@* $oguirel]} {
  63         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  64         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  65 } else {
  66         set oguimsg [file join $oguilib msgs]
  67 }
  68 unset oguirel
  69
  70 ######################################################################
  71 ##
  72 ## enable verbose loading?
  73
  74 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  75         unset _verbose
  76         rename auto_load real__auto_load
  77         proc auto_load {name args} {
  78                 puts stderr "auto_load $name"
  79                 return [uplevel 1 real__auto_load $name $args]
  80         }
  81         rename source real__source
  82         proc source {name} {
  83                 puts stderr "source    $name"
  84                 uplevel 1 real__source $name
  85         }
  86 }
  87
  88 ######################################################################
  89 ##
  90 ## Internationalization (i18n) through msgcat and gettext. See
  91 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  92
  93 package require msgcat
  94
  95 proc _mc_trim {fmt} {
  96         set cmk [string first @@ $fmt]
  97         if {$cmk > 0} {
  98                 return [string range $fmt 0 [expr {$cmk - 1}]]
  99         }
 100         return $fmt
 101 }
 102
 103 proc mc {en_fmt args} {
 104         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 105         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 106                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 107         }
 108         return $msg
 109 }
 110
 111 proc strcat {args} {
 112         return [join $args {}]
 113 }
 114
 115 ::msgcat::mcload $oguimsg
 116 unset oguimsg
 117
 118 ######################################################################
 119 ##
 120 ## read only globals
 121
 122 set _appname {Git Gui}
 123 set _gitdir {}
 124 set _gitexec {}
 125 set _reponame {}
 126 set _iscygwin {}
 127 set _search_path {}
 128
 129 set _trace [lsearch -exact $argv --trace]
 130 if {$_trace >= 0} {
 131         set argv [lreplace $argv $_trace $_trace]
 132         set _trace 1
 133 } else {
 134         set _trace 0
 135 }
 136
 137 proc appname {} {
 138         global _appname
 139         return $_appname
 140 }
 141
 142 proc gitdir {args} {
 143         global _gitdir
 144         if {$args eq {}} {
 145                 return $_gitdir
 146         }
 147         return [eval [list file join $_gitdir] $args]
 148 }
 149
 150 proc gitexec {args} {
 151         global _gitexec
 152         if {$_gitexec eq {}} {
 153                 if {[catch {set _gitexec [git --exec-path]} err]} {
 154                         error "Git not installed?\n\n$err"
 155                 }
 156                 if {[is_Cygwin]} {
 157                         set _gitexec [exec cygpath \
 158                                 --windows \
 159                                 --absolute \
 160                                 $_gitexec]
 161                 } else {
 162                         set _gitexec [file normalize $_gitexec]
 163                 }
 164         }
 165         if {$args eq {}} {
 166                 return $_gitexec
 167         }
 168         return [eval [list file join $_gitexec] $args]
 169 }
 170
 171 proc reponame {} {
 172         return $::_reponame
 173 }
 174
 175 proc is_MacOSX {} {
 176         if {[tk windowingsystem] eq {aqua}} {
 177                 return 1
 178         }
 179         return 0
 180 }
 181
 182 proc is_Windows {} {
 183         if {$::tcl_platform(platform) eq {windows}} {
 184                 return 1
 185         }
 186         return 0
 187 }
 188
 189 proc is_Cygwin {} {
 190         global _iscygwin
 191         if {$_iscygwin eq {}} {
 192                 if {$::tcl_platform(platform) eq {windows}} {
 193                         if {[catch {set p [exec cygpath --windir]} err]} {
 194                                 set _iscygwin 0
 195                         } else {
 196                                 set _iscygwin 1
 197                         }
 198                 } else {
 199                         set _iscygwin 0
 200                 }
 201         }
 202         return $_iscygwin
 203 }
 204
 205 proc is_enabled {option} {
 206         global enabled_options
 207         if {[catch {set on $enabled_options($option)}]} {return 0}
 208         return $on
 209 }
 210
 211 proc enable_option {option} {
 212         global enabled_options
 213         set enabled_options($option) 1
 214 }
 215
 216 proc disable_option {option} {
 217         global enabled_options
 218         set enabled_options($option) 0
 219 }
 220
 221 ######################################################################
 222 ##
 223 ## config
 224
 225 proc is_many_config {name} {
 226         switch -glob -- $name {
 227         gui.recentrepo -
 228         remote.*.fetch -
 229         remote.*.push
 230                 {return 1}
 231         *
 232                 {return 0}
 233         }
 234 }
 235
 236 proc is_config_true {name} {
 237         global repo_config
 238         if {[catch {set v $repo_config($name)}]} {
 239                 return 0
 240         } elseif {$v eq {true} || $v eq {1} || $v eq {yes}} {
 241                 return 1
 242         } else {
 243                 return 0
 244         }
 245 }
 246
 247 proc get_config {name} {
 248         global repo_config
 249         if {[catch {set v $repo_config($name)}]} {
 250                 return {}
 251         } else {
 252                 return $v
 253         }
 254 }
 255
 256 ######################################################################
 257 ##
 258 ## handy utils
 259
 260 proc _trace_exec {cmd} {
 261         if {!$::_trace} return
 262         set d {}
 263         foreach v $cmd {
 264                 if {$d ne {}} {
 265                         append d { }
 266                 }
 267                 if {[regexp {[ \t\r\n'"$?*]} $v]} {
 268                         set v [sq $v]
 269                 }
 270                 append d $v
 271         }
 272         puts stderr $d
 273 }
 274
 275 proc _git_cmd {name} {
 276         global _git_cmd_path
 277
 278         if {[catch {set v $_git_cmd_path($name)}]} {
 279                 switch -- $name {
 280                   version   -
 281                 --version   -
 282                 --exec-path { return [list $::_git $name] }
 283                 }
 284
 285                 set p [gitexec git-$name$::_search_exe]
 286                 if {[file exists $p]} {
 287                         set v [list $p]
 288                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 289                         # Try to determine what sort of magic will make
 290                         # git-$name go and do its thing, because native
 291                         # Tcl on Windows doesn't know it.
 292                         #
 293                         set p [gitexec git-$name]
 294                         set f [open $p r]
 295                         set s [gets $f]
 296                         close $f
 297
 298                         switch -glob -- [lindex $s 0] {
 299                         #!*sh     { set i sh     }
 300                         #!*perl   { set i perl   }
 301                         #!*python { set i python }
 302                         default   { error "git-$name is not supported: $s" }
 303                         }
 304
 305                         upvar #0 _$i interp
 306                         if {![info exists interp]} {
 307                                 set interp [_which $i]
 308                         }
 309                         if {$interp eq {}} {
 310                                 error "git-$name requires $i (not in PATH)"
 311                         }
 312                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 313                 } else {
 314                         # Assume it is builtin to git somehow and we
 315                         # aren't actually able to see a file for it.
 316                         #
 317                         set v [list $::_git $name]
 318                 }
 319                 set _git_cmd_path($name) $v
 320         }
 321         return $v
 322 }
 323
 324 proc _which {what args} {
 325         global env _search_exe _search_path
 326
 327         if {$_search_path eq {}} {
 328                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 329                         set _search_path [split [exec cygpath \
 330                                 --windows \
 331                                 --path \
 332                                 --absolute \
 333                                 $env(PATH)] {;}]
 334                         set _search_exe .exe
 335                 } elseif {[is_Windows]} {
 336                         set gitguidir [file dirname [info script]]
 337                         regsub -all ";" $gitguidir "\\;" gitguidir
 338                         set env(PATH) "$gitguidir;$env(PATH)"
 339                         set _search_path [split $env(PATH) {;}]
 340                         set _search_exe .exe
 341                 } else {
 342                         set _search_path [split $env(PATH) :]
 343                         set _search_exe {}
 344                 }
 345         }
 346
 347         if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 348                 set suffix {}
 349         } else {
 350                 set suffix $_search_exe
 351         }
 352
 353         foreach p $_search_path {
 354                 set p [file join $p $what$suffix]
 355                 if {[file exists $p]} {
 356                         return [file normalize $p]
 357                 }
 358         }
 359         return {}
 360 }
 361
 362 proc _lappend_nice {cmd_var} {
 363         global _nice
 364         upvar $cmd_var cmd
 365
 366         if {![info exists _nice]} {
 367                 set _nice [_which nice]
 368         }
 369         if {$_nice ne {}} {
 370                 lappend cmd $_nice
 371         }
 372 }
 373
 374 proc git {args} {
 375         set opt [list]
 376
 377         while {1} {
 378                 switch -- [lindex $args 0] {
 379                 --nice {
 380                         _lappend_nice opt
 381                 }
 382
 383                 default {
 384                         break
 385                 }
 386
 387                 }
 388
 389                 set args [lrange $args 1 end]
 390         }
 391
 392         set cmdp [_git_cmd [lindex $args 0]]
 393         set args [lrange $args 1 end]
 394
 395         _trace_exec [concat $opt $cmdp $args]
 396         set result [eval exec $opt $cmdp $args]
 397         if {$::_trace} {
 398                 puts stderr "< $result"
 399         }
 400         return $result
 401 }
 402
 403 proc _open_stdout_stderr {cmd} {
 404         _trace_exec $cmd
 405         if {[catch {
 406                         set fd [open [concat [list | ] $cmd] r]
 407                 } err]} {
 408                 if {   [lindex $cmd end] eq {2>@1}
 409                     && $err eq {can not find channel named "1"}
 410                         } {
 411                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 412                         # redirect operator.  Fallback to |& cat for those.
 413                         # The command was not actually started, so its safe
 414                         # to try to start it a second time.
 415                         #
 416                         set fd [open [concat \
 417                                 [list | ] \
 418                                 [lrange $cmd 0 end-1] \
 419                                 [list |& cat] \
 420                                 ] r]
 421                 } else {
 422                         error $err
 423                 }
 424         }
 425         fconfigure $fd -eofchar {}
 426         return $fd
 427 }
 428
 429 proc git_read {args} {
 430         set opt [list]
 431
 432         while {1} {
 433                 switch -- [lindex $args 0] {
 434                 --nice {
 435                         _lappend_nice opt
 436                 }
 437
 438                 --stderr {
 439                         lappend args 2>@1
 440                 }
 441
 442                 default {
 443                         break
 444                 }
 445
 446                 }
 447
 448                 set args [lrange $args 1 end]
 449         }
 450
 451         set cmdp [_git_cmd [lindex $args 0]]
 452         set args [lrange $args 1 end]
 453
 454         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 455 }
 456
 457 proc git_write {args} {
 458         set opt [list]
 459
 460         while {1} {
 461                 switch -- [lindex $args 0] {
 462                 --nice {
 463                         _lappend_nice opt
 464                 }
 465
 466                 default {
 467                         break
 468                 }
 469
 470                 }
 471
 472                 set args [lrange $args 1 end]
 473         }
 474
 475         set cmdp [_git_cmd [lindex $args 0]]
 476         set args [lrange $args 1 end]
 477
 478         _trace_exec [concat $opt $cmdp $args]
 479         return [open [concat [list | ] $opt $cmdp $args] w]
 480 }
 481
 482 proc githook_read {hook_name args} {
 483         set pchook [gitdir hooks $hook_name]
 484         lappend args 2>@1
 485
 486         # On Windows [file executable] might lie so we need to ask
 487         # the shell if the hook is executable.  Yes that's annoying.
 488         #
 489         if {[is_Windows]} {
 490                 upvar #0 _sh interp
 491                 if {![info exists interp]} {
 492                         set interp [_which sh]
 493                 }
 494                 if {$interp eq {}} {
 495                         error "hook execution requires sh (not in PATH)"
 496                 }
 497
 498                 set scr {if test -x "$1";then exec "$@";fi}
 499                 set sh_c [list $interp -c $scr $interp $pchook]
 500                 return [_open_stdout_stderr [concat $sh_c $args]]
 501         }
 502
 503         if {[file executable $pchook]} {
 504                 return [_open_stdout_stderr [concat [list $pchook] $args]]
 505         }
 506
 507         return {}
 508 }
 509
 510 proc kill_file_process {fd} {
 511         set process [pid $fd]
 512
 513         catch {
 514                 if {[is_Windows]} {
 515                         # Use a Cygwin-specific flag to allow killing
 516                         # native Windows processes
 517                         exec kill -f $process
 518                 } else {
 519                         exec kill $process
 520                 }
 521         }
 522 }
 523
 524 proc gitattr {path attr default} {
 525         if {[catch {set r [git check-attr $attr -- $path]}]} {
 526                 set r unspecified
 527         } else {
 528                 set r [join [lrange [split $r :] 2 end] :]
 529                 regsub {^ } $r {} r
 530         }
 531         if {$r eq {unspecified}} {
 532                 return $default
 533         }
 534         return $r
 535 }
 536
 537 proc sq {value} {
 538         regsub -all ' $value "'\\''" value
 539         return "'$value'"
 540 }
 541
 542 proc load_current_branch {} {
 543         global current_branch is_detached
 544
 545         set fd [open [gitdir HEAD] r]
 546         if {[gets $fd ref] < 1} {
 547                 set ref {}
 548         }
 549         close $fd
 550
 551         set pfx {ref: refs/heads/}
 552         set len [string length $pfx]
 553         if {[string equal -length $len $pfx $ref]} {
 554                 # We're on a branch.  It might not exist.  But
 555                 # HEAD looks good enough to be a branch.
 556                 #
 557                 set current_branch [string range $ref $len end]
 558                 set is_detached 0
 559         } else {
 560                 # Assume this is a detached head.
 561                 #
 562                 set current_branch HEAD
 563                 set is_detached 1
 564         }
 565 }
 566
 567 auto_load tk_optionMenu
 568 rename tk_optionMenu real__tkOptionMenu
 569 proc tk_optionMenu {w varName args} {
 570         set m [eval real__tkOptionMenu $w $varName $args]
 571         $m configure -font font_ui
 572         $w configure -font font_ui
 573         return $m
 574 }
 575
 576 proc rmsel_tag {text} {
 577         $text tag conf sel \
 578                 -background [$text cget -background] \
 579                 -foreground [$text cget -foreground] \
 580                 -borderwidth 0
 581         $text tag conf in_sel -background lightgray
 582         bind $text <Motion> break
 583         return $text
 584 }
 585
 586 set root_exists 0
 587 bind . <Visibility> {
 588         bind . <Visibility> {}
 589         set root_exists 1
 590 }
 591
 592 if {[is_Windows]} {
 593         wm iconbitmap . -default $oguilib/git-gui.ico
 594 }
 595
 596 ######################################################################
 597 ##
 598 ## config defaults
 599
 600 set cursor_ptr arrow
 601 font create font_diff -family Courier -size 10
 602 font create font_ui
 603 catch {
 604         label .dummy
 605         eval font configure font_ui [font actual [.dummy cget -font]]
 606         destroy .dummy
 607 }
 608
 609 font create font_uiitalic
 610 font create font_uibold
 611 font create font_diffbold
 612 font create font_diffitalic
 613
 614 foreach class {Button Checkbutton Entry Label
 615                 Labelframe Listbox Menu Message
 616                 Radiobutton Spinbox Text} {
 617         option add *$class.font font_ui
 618 }
 619 unset class
 620
 621 if {[is_Windows] || [is_MacOSX]} {
 622         option add *Menu.tearOff 0
 623 }
 624
 625 if {[is_MacOSX]} {
 626         set M1B M1
 627         set M1T Cmd
 628 } else {
 629         set M1B Control
 630         set M1T Ctrl
 631 }
 632
 633 proc bind_button3 {w cmd} {
 634         bind $w <Any-Button-3> $cmd
 635         if {[is_MacOSX]} {
 636                 # Mac OS X sends Button-2 on right click through three-button mouse,
 637                 # or through trackpad right-clicking (two-finger touch + click).
 638                 bind $w <Any-Button-2> $cmd
 639                 bind $w <Control-Button-1> $cmd
 640         }
 641 }
 642
 643 proc apply_config {} {
 644         global repo_config font_descs
 645
 646         foreach option $font_descs {
 647                 set name [lindex $option 0]
 648                 set font [lindex $option 1]
 649                 if {[catch {
 650                         set need_weight 1
 651                         foreach {cn cv} $repo_config(gui.$name) {
 652                                 if {$cn eq {-weight}} {
 653                                         set need_weight 0
 654                                 }
 655                                 font configure $font $cn $cv
 656                         }
 657                         if {$need_weight} {
 658                                 font configure $font -weight normal
 659                         }
 660                         } err]} {
 661                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 662                 }
 663                 foreach {cn cv} [font configure $font] {
 664                         font configure ${font}bold $cn $cv
 665                         font configure ${font}italic $cn $cv
 666                 }
 667                 font configure ${font}bold -weight bold
 668                 font configure ${font}italic -slant italic
 669         }
 670 }
 671
 672 set default_config(branch.autosetupmerge) true
 673 set default_config(merge.tool) {}
 674 set default_config(merge.keepbackup) true
 675 set default_config(merge.diffstat) true
 676 set default_config(merge.summary) false
 677 set default_config(merge.verbosity) 2
 678 set default_config(user.name) {}
 679 set default_config(user.email) {}
 680
 681 set default_config(gui.encoding) [encoding system]
 682 set default_config(gui.matchtrackingbranch) false
 683 set default_config(gui.pruneduringfetch) false
 684 set default_config(gui.trustmtime) false
 685 set default_config(gui.fastcopyblame) false
 686 set default_config(gui.copyblamethreshold) 40
 687 set default_config(gui.blamehistoryctx) 7
 688 set default_config(gui.diffcontext) 5
 689 set default_config(gui.commitmsgwidth) 75
 690 set default_config(gui.newbranchtemplate) {}
 691 set default_config(gui.spellingdictionary) {}
 692 set default_config(gui.fontui) [font configure font_ui]
 693 set default_config(gui.fontdiff) [font configure font_diff]
 694 set font_descs {
 695         {fontui   font_ui   {mc "Main Font"}}
 696         {fontdiff font_diff {mc "Diff/Console Font"}}
 697 }
 698
 699 ######################################################################
 700 ##
 701 ## find git
 702
 703 set _git  [_which git]
 704 if {$_git eq {}} {
 705         catch {wm withdraw .}
 706         tk_messageBox \
 707                 -icon error \
 708                 -type ok \
 709                 -title [mc "git-gui: fatal error"] \
 710                 -message [mc "Cannot find git in PATH."]
 711         exit 1
 712 }
 713
 714 ######################################################################
 715 ##
 716 ## version check
 717
 718 if {[catch {set _git_version [git --version]} err]} {
 719         catch {wm withdraw .}
 720         tk_messageBox \
 721                 -icon error \
 722                 -type ok \
 723                 -title [mc "git-gui: fatal error"] \
 724                 -message "Cannot determine Git version:
 725
 726 $err
 727
 728 [appname] requires Git 1.5.0 or later."
 729         exit 1
 730 }
 731 if {![regsub {^git version } $_git_version {} _git_version]} {
 732         catch {wm withdraw .}
 733         tk_messageBox \
 734                 -icon error \
 735                 -type ok \
 736                 -title [mc "git-gui: fatal error"] \
 737                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 738         exit 1
 739 }
 740
 741 set _real_git_version $_git_version
 742 regsub -- {[\-\.]dirty$} $_git_version {} _git_version
 743 regsub {\.[0-9]+\.g[0-9a-f]+$} $_git_version {} _git_version
 744 regsub {\.rc[0-9]+$} $_git_version {} _git_version
 745 regsub {\.GIT$} $_git_version {} _git_version
 746 regsub {\.[a-zA-Z]+\.[0-9]+$} $_git_version {} _git_version
 747
 748 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 749         catch {wm withdraw .}
 750         if {[tk_messageBox \
 751                 -icon warning \
 752                 -type yesno \
 753                 -default no \
 754                 -title "[appname]: warning" \
 755                  -message [mc "Git version cannot be determined.
 756
 757 %s claims it is version '%s'.
 758
 759 %s requires at least Git 1.5.0 or later.
 760
 761 Assume '%s' is version 1.5.0?
 762 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 763                 set _git_version 1.5.0
 764         } else {
 765                 exit 1
 766         }
 767 }
 768 unset _real_git_version
 769
 770 proc git-version {args} {
 771         global _git_version
 772
 773         switch [llength $args] {
 774         0 {
 775                 return $_git_version
 776         }
 777
 778         2 {
 779                 set op [lindex $args 0]
 780                 set vr [lindex $args 1]
 781                 set cm [package vcompare $_git_version $vr]
 782                 return [expr $cm $op 0]
 783         }
 784
 785         4 {
 786                 set type [lindex $args 0]
 787                 set name [lindex $args 1]
 788                 set parm [lindex $args 2]
 789                 set body [lindex $args 3]
 790
 791                 if {($type ne {proc} && $type ne {method})} {
 792                         error "Invalid arguments to git-version"
 793                 }
 794                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
 795                         error "Last arm of $type $name must be default"
 796                 }
 797
 798                 foreach {op vr cb} [lrange $body 0 end-2] {
 799                         if {[git-version $op $vr]} {
 800                                 return [uplevel [list $type $name $parm $cb]]
 801                         }
 802                 }
 803
 804                 return [uplevel [list $type $name $parm [lindex $body end]]]
 805         }
 806
 807         default {
 808                 error "git-version >= x"
 809         }
 810
 811         }
 812 }
 813
 814 if {[git-version < 1.5]} {
 815         catch {wm withdraw .}
 816         tk_messageBox \
 817                 -icon error \
 818                 -type ok \
 819                 -title [mc "git-gui: fatal error"] \
 820                 -message "[appname] requires Git 1.5.0 or later.
 821
 822 You are using [git-version]:
 823
 824 [git --version]"
 825         exit 1
 826 }
 827
 828 ######################################################################
 829 ##
 830 ## configure our library
 831
 832 set idx [file join $oguilib tclIndex]
 833 if {[catch {set fd [open $idx r]} err]} {
 834         catch {wm withdraw .}
 835         tk_messageBox \
 836                 -icon error \
 837                 -type ok \
 838                 -title [mc "git-gui: fatal error"] \
 839                 -message $err
 840         exit 1
 841 }
 842 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
 843         set idx [list]
 844         while {[gets $fd n] >= 0} {
 845                 if {$n ne {} && ![string match #* $n]} {
 846                         lappend idx $n
 847                 }
 848         }
 849 } else {
 850         set idx {}
 851 }
 852 close $fd
 853
 854 if {$idx ne {}} {
 855         set loaded [list]
 856         foreach p $idx {
 857                 if {[lsearch -exact $loaded $p] >= 0} continue
 858                 source [file join $oguilib $p]
 859                 lappend loaded $p
 860         }
 861         unset loaded p
 862 } else {
 863         set auto_path [concat [list $oguilib] $auto_path]
 864 }
 865 unset -nocomplain idx fd
 866
 867 ######################################################################
 868 ##
 869 ## config file parsing
 870
 871 git-version proc _parse_config {arr_name args} {
 872         >= 1.5.3 {
 873                 upvar $arr_name arr
 874                 array unset arr
 875                 set buf {}
 876                 catch {
 877                         set fd_rc [eval \
 878                                 [list git_read config] \
 879                                 $args \
 880                                 [list --null --list]]
 881                         fconfigure $fd_rc -translation binary
 882                         set buf [read $fd_rc]
 883                         close $fd_rc
 884                 }
 885                 foreach line [split $buf "\0"] {
 886                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
 887                                 if {[is_many_config $name]} {
 888                                         lappend arr($name) $value
 889                                 } else {
 890                                         set arr($name) $value
 891                                 }
 892                         }
 893                 }
 894         }
 895         default {
 896                 upvar $arr_name arr
 897                 array unset arr
 898                 catch {
 899                         set fd_rc [eval [list git_read config --list] $args]
 900                         while {[gets $fd_rc line] >= 0} {
 901                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 902                                         if {[is_many_config $name]} {
 903                                                 lappend arr($name) $value
 904                                         } else {
 905                                                 set arr($name) $value
 906                                         }
 907                                 }
 908                         }
 909                         close $fd_rc
 910                 }
 911         }
 912 }
 913
 914 proc load_config {include_global} {
 915         global repo_config global_config default_config
 916
 917         if {$include_global} {
 918                 _parse_config global_config --global
 919         }
 920         _parse_config repo_config
 921
 922         foreach name [array names default_config] {
 923                 if {[catch {set v $global_config($name)}]} {
 924                         set global_config($name) $default_config($name)
 925                 }
 926                 if {[catch {set v $repo_config($name)}]} {
 927                         set repo_config($name) $default_config($name)
 928                 }
 929         }
 930 }
 931
 932 ######################################################################
 933 ##
 934 ## feature option selection
 935
 936 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
 937         unset _junk
 938 } else {
 939         set subcommand gui
 940 }
 941 if {$subcommand eq {gui.sh}} {
 942         set subcommand gui
 943 }
 944 if {$subcommand eq {gui} && [llength $argv] > 0} {
 945         set subcommand [lindex $argv 0]
 946         set argv [lrange $argv 1 end]
 947 }
 948
 949 enable_option multicommit
 950 enable_option branch
 951 enable_option transport
 952 disable_option bare
 953
 954 switch -- $subcommand {
 955 browser -
 956 blame {
 957         enable_option bare
 958
 959         disable_option multicommit
 960         disable_option branch
 961         disable_option transport
 962 }
 963 citool {
 964         enable_option singlecommit
 965         enable_option retcode
 966
 967         disable_option multicommit
 968         disable_option branch
 969         disable_option transport
 970
 971         while {[llength $argv] > 0} {
 972                 set a [lindex $argv 0]
 973                 switch -- $a {
 974                 --amend {
 975                         enable_option initialamend
 976                 }
 977                 --nocommit {
 978                         enable_option nocommit
 979                         enable_option nocommitmsg
 980                 }
 981                 --commitmsg {
 982                         disable_option nocommitmsg
 983                 }
 984                 default {
 985                         break
 986                 }
 987                 }
 988
 989                 set argv [lrange $argv 1 end]
 990         }
 991 }
 992 }
 993
 994 ######################################################################
 995 ##
 996 ## repository setup
 997
 998 if {[catch {
 999                 set _gitdir $env(GIT_DIR)
1000                 set _prefix {}
1001                 }]
1002         && [catch {
1003                 set _gitdir [git rev-parse --git-dir]
1004                 set _prefix [git rev-parse --show-prefix]
1005         } err]} {
1006         load_config 1
1007         apply_config
1008         choose_repository::pick
1009 }
1010 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
1011         catch {set _gitdir [exec cygpath --windows $_gitdir]}
1012 }
1013 if {![file isdirectory $_gitdir]} {
1014         catch {wm withdraw .}
1015         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
1016         exit 1
1017 }
1018 if {$_prefix ne {}} {
1019         regsub -all {[^/]+/} $_prefix ../ cdup
1020         if {[catch {cd $cdup} err]} {
1021                 catch {wm withdraw .}
1022                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
1023                 exit 1
1024         }
1025         unset cdup
1026 } elseif {![is_enabled bare]} {
1027         if {[lindex [file split $_gitdir] end] ne {.git}} {
1028                 catch {wm withdraw .}
1029                 error_popup [strcat [mc "Cannot use funny .git directory:"] "\n\n$_gitdir"]
1030                 exit 1
1031         }
1032         if {[catch {cd [file dirname $_gitdir]} err]} {
1033                 catch {wm withdraw .}
1034                 error_popup [strcat [mc "No working directory"] " [file dirname $_gitdir]:\n\n$err"]
1035                 exit 1
1036         }
1037 }
1038 set _reponame [file split [file normalize $_gitdir]]
1039 if {[lindex $_reponame end] eq {.git}} {
1040         set _reponame [lindex $_reponame end-1]
1041 } else {
1042         set _reponame [lindex $_reponame end]
1043 }
1044
1045 ######################################################################
1046 ##
1047 ## global init
1048
1049 set current_diff_path {}
1050 set current_diff_side {}
1051 set diff_actions [list]
1052
1053 set HEAD {}
1054 set PARENT {}
1055 set MERGE_HEAD [list]
1056 set commit_type {}
1057 set empty_tree {}
1058 set current_branch {}
1059 set is_detached 0
1060 set current_diff_path {}
1061 set is_3way_diff 0
1062 set is_conflict_diff 0
1063 set selected_commit_type new
1064
1065 set nullid "0000000000000000000000000000000000000000"
1066 set nullid2 "0000000000000000000000000000000000000001"
1067
1068 ######################################################################
1069 ##
1070 ## task management
1071
1072 set rescan_active 0
1073 set diff_active 0
1074 set last_clicked {}
1075
1076 set disable_on_lock [list]
1077 set index_lock_type none
1078
1079 proc lock_index {type} {
1080         global index_lock_type disable_on_lock
1081
1082         if {$index_lock_type eq {none}} {
1083                 set index_lock_type $type
1084                 foreach w $disable_on_lock {
1085                         uplevel #0 $w disabled
1086                 }
1087                 return 1
1088         } elseif {$index_lock_type eq "begin-$type"} {
1089                 set index_lock_type $type
1090                 return 1
1091         }
1092         return 0
1093 }
1094
1095 proc unlock_index {} {
1096         global index_lock_type disable_on_lock
1097
1098         set index_lock_type none
1099         foreach w $disable_on_lock {
1100                 uplevel #0 $w normal
1101         }
1102 }
1103
1104 ######################################################################
1105 ##
1106 ## status
1107
1108 proc repository_state {ctvar hdvar mhvar} {
1109         global current_branch
1110         upvar $ctvar ct $hdvar hd $mhvar mh
1111
1112         set mh [list]
1113
1114         load_current_branch
1115         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1116                 set hd {}
1117                 set ct initial
1118                 return
1119         }
1120
1121         set merge_head [gitdir MERGE_HEAD]
1122         if {[file exists $merge_head]} {
1123                 set ct merge
1124                 set fd_mh [open $merge_head r]
1125                 while {[gets $fd_mh line] >= 0} {
1126                         lappend mh $line
1127                 }
1128                 close $fd_mh
1129                 return
1130         }
1131
1132         set ct normal
1133 }
1134
1135 proc PARENT {} {
1136         global PARENT empty_tree
1137
1138         set p [lindex $PARENT 0]
1139         if {$p ne {}} {
1140                 return $p
1141         }
1142         if {$empty_tree eq {}} {
1143                 set empty_tree [git mktree << {}]
1144         }
1145         return $empty_tree
1146 }
1147
1148 proc force_amend {} {
1149         global selected_commit_type
1150         global HEAD PARENT MERGE_HEAD commit_type
1151
1152         repository_state newType newHEAD newMERGE_HEAD
1153         set HEAD $newHEAD
1154         set PARENT $newHEAD
1155         set MERGE_HEAD $newMERGE_HEAD
1156         set commit_type $newType
1157
1158         set selected_commit_type amend
1159         do_select_commit_type
1160 }
1161
1162 proc rescan {after {honor_trustmtime 1}} {
1163         global HEAD PARENT MERGE_HEAD commit_type
1164         global ui_index ui_workdir ui_comm
1165         global rescan_active file_states
1166         global repo_config
1167
1168         if {$rescan_active > 0 || ![lock_index read]} return
1169
1170         repository_state newType newHEAD newMERGE_HEAD
1171         if {[string match amend* $commit_type]
1172                 && $newType eq {normal}
1173                 && $newHEAD eq $HEAD} {
1174         } else {
1175                 set HEAD $newHEAD
1176                 set PARENT $newHEAD
1177                 set MERGE_HEAD $newMERGE_HEAD
1178                 set commit_type $newType
1179         }
1180
1181         array unset file_states
1182
1183         if {!$::GITGUI_BCK_exists &&
1184                 (![$ui_comm edit modified]
1185                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1186                 if {[string match amend* $commit_type]} {
1187                 } elseif {[load_message GITGUI_MSG]} {
1188                 } elseif {[run_prepare_commit_msg_hook]} {
1189                 } elseif {[load_message MERGE_MSG]} {
1190                 } elseif {[load_message SQUASH_MSG]} {
1191                 }
1192                 $ui_comm edit reset
1193                 $ui_comm edit modified false
1194         }
1195
1196         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1197                 rescan_stage2 {} $after
1198         } else {
1199                 set rescan_active 1
1200                 ui_status [mc "Refreshing file status..."]
1201                 set fd_rf [git_read update-index \
1202                         -q \
1203                         --unmerged \
1204                         --ignore-missing \
1205                         --refresh \
1206                         ]
1207                 fconfigure $fd_rf -blocking 0 -translation binary
1208                 fileevent $fd_rf readable \
1209                         [list rescan_stage2 $fd_rf $after]
1210         }
1211 }
1212
1213 if {[is_Cygwin]} {
1214         set is_git_info_exclude {}
1215         proc have_info_exclude {} {
1216                 global is_git_info_exclude
1217
1218                 if {$is_git_info_exclude eq {}} {
1219                         if {[catch {exec test -f [gitdir info exclude]}]} {
1220                                 set is_git_info_exclude 0
1221                         } else {
1222                                 set is_git_info_exclude 1
1223                         }
1224                 }
1225                 return $is_git_info_exclude
1226         }
1227 } else {
1228         proc have_info_exclude {} {
1229                 return [file readable [gitdir info exclude]]
1230         }
1231 }
1232
1233 proc rescan_stage2 {fd after} {
1234         global rescan_active buf_rdi buf_rdf buf_rlo
1235
1236         if {$fd ne {}} {
1237                 read $fd
1238                 if {![eof $fd]} return
1239                 close $fd
1240         }
1241
1242         set ls_others [list --exclude-per-directory=.gitignore]
1243         if {[have_info_exclude]} {
1244                 lappend ls_others "--exclude-from=[gitdir info exclude]"
1245         }
1246         set user_exclude [get_config core.excludesfile]
1247         if {$user_exclude ne {} && [file readable $user_exclude]} {
1248                 lappend ls_others "--exclude-from=$user_exclude"
1249         }
1250
1251         set buf_rdi {}
1252         set buf_rdf {}
1253         set buf_rlo {}
1254
1255         set rescan_active 3
1256         ui_status [mc "Scanning for modified files ..."]
1257         set fd_di [git_read diff-index --cached -z [PARENT]]
1258         set fd_df [git_read diff-files -z]
1259         set fd_lo [eval git_read ls-files --others -z $ls_others]
1260
1261         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1262         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1263         fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1264         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1265         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1266         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1267 }
1268
1269 proc load_message {file} {
1270         global ui_comm
1271
1272         set f [gitdir $file]
1273         if {[file isfile $f]} {
1274                 if {[catch {set fd [open $f r]}]} {
1275                         return 0
1276                 }
1277                 fconfigure $fd -eofchar {}
1278                 set content [string trim [read $fd]]
1279                 close $fd
1280                 regsub -all -line {[ \r\t]+$} $content {} content
1281                 $ui_comm delete 0.0 end
1282                 $ui_comm insert end $content
1283                 return 1
1284         }
1285         return 0
1286 }
1287
1288 proc run_prepare_commit_msg_hook {} {
1289         global pch_error
1290
1291         # prepare-commit-msg requires PREPARE_COMMIT_MSG exist.  From git-gui
1292         # it will be .git/MERGE_MSG (merge), .git/SQUASH_MSG (squash), or an
1293         # empty file but existant file.
1294
1295         set fd_pcm [open [gitdir PREPARE_COMMIT_MSG] a]
1296
1297         if {[file isfile [gitdir MERGE_MSG]]} {
1298                 set pcm_source "merge"
1299                 set fd_mm [open [gitdir MERGE_MSG] r]
1300                 puts -nonewline $fd_pcm [read $fd_mm]
1301                 close $fd_mm
1302         } elseif {[file isfile [gitdir SQUASH_MSG]]} {
1303                 set pcm_source "squash"
1304                 set fd_sm [open [gitdir SQUASH_MSG] r]
1305                 puts -nonewline $fd_pcm [read $fd_sm]
1306                 close $fd_sm
1307         } else {
1308                 set pcm_source ""
1309         }
1310
1311         close $fd_pcm
1312
1313         set fd_ph [githook_read prepare-commit-msg \
1314                         [gitdir PREPARE_COMMIT_MSG] $pcm_source]
1315         if {$fd_ph eq {}} {
1316                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1317                 return 0;
1318         }
1319
1320         ui_status [mc "Calling prepare-commit-msg hook..."]
1321         set pch_error {}
1322
1323         fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
1324         fileevent $fd_ph readable \
1325                 [list prepare_commit_msg_hook_wait $fd_ph]
1326
1327         return 1;
1328 }
1329
1330 proc prepare_commit_msg_hook_wait {fd_ph} {
1331         global pch_error
1332
1333         append pch_error [read $fd_ph]
1334         fconfigure $fd_ph -blocking 1
1335         if {[eof $fd_ph]} {
1336                 if {[catch {close $fd_ph}]} {
1337                         ui_status [mc "Commit declined by prepare-commit-msg hook."]
1338                         hook_failed_popup prepare-commit-msg $pch_error
1339                         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1340                         exit 1
1341                 } else {
1342                         load_message PREPARE_COMMIT_MSG
1343                 }
1344                 set pch_error {}
1345                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1346                 return
1347         }
1348         fconfigure $fd_ph -blocking 0
1349         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1350 }
1351
1352 proc read_diff_index {fd after} {
1353         global buf_rdi
1354
1355         append buf_rdi [read $fd]
1356         set c 0
1357         set n [string length $buf_rdi]
1358         while {$c < $n} {
1359                 set z1 [string first "\0" $buf_rdi $c]
1360                 if {$z1 == -1} break
1361                 incr z1
1362                 set z2 [string first "\0" $buf_rdi $z1]
1363                 if {$z2 == -1} break
1364
1365                 incr c
1366                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1367                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1368                 merge_state \
1369                         [encoding convertfrom $p] \
1370                         [lindex $i 4]? \
1371                         [list [lindex $i 0] [lindex $i 2]] \
1372                         [list]
1373                 set c $z2
1374                 incr c
1375         }
1376         if {$c < $n} {
1377                 set buf_rdi [string range $buf_rdi $c end]
1378         } else {
1379                 set buf_rdi {}
1380         }
1381
1382         rescan_done $fd buf_rdi $after
1383 }
1384
1385 proc read_diff_files {fd after} {
1386         global buf_rdf
1387
1388         append buf_rdf [read $fd]
1389         set c 0
1390         set n [string length $buf_rdf]
1391         while {$c < $n} {
1392                 set z1 [string first "\0" $buf_rdf $c]
1393                 if {$z1 == -1} break
1394                 incr z1
1395                 set z2 [string first "\0" $buf_rdf $z1]
1396                 if {$z2 == -1} break
1397
1398                 incr c
1399                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1400                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1401                 merge_state \
1402                         [encoding convertfrom $p] \
1403                         ?[lindex $i 4] \
1404                         [list] \
1405                         [list [lindex $i 0] [lindex $i 2]]
1406                 set c $z2
1407                 incr c
1408         }
1409         if {$c < $n} {
1410                 set buf_rdf [string range $buf_rdf $c end]
1411         } else {
1412                 set buf_rdf {}
1413         }
1414
1415         rescan_done $fd buf_rdf $after
1416 }
1417
1418 proc read_ls_others {fd after} {
1419         global buf_rlo
1420
1421         append buf_rlo [read $fd]
1422         set pck [split $buf_rlo "\0"]
1423         set buf_rlo [lindex $pck end]
1424         foreach p [lrange $pck 0 end-1] {
1425                 set p [encoding convertfrom $p]
1426                 if {[string index $p end] eq {/}} {
1427                         set p [string range $p 0 end-1]
1428                 }
1429                 merge_state $p ?O
1430         }
1431         rescan_done $fd buf_rlo $after
1432 }
1433
1434 proc rescan_done {fd buf after} {
1435         global rescan_active current_diff_path
1436         global file_states repo_config
1437         upvar $buf to_clear
1438
1439         if {![eof $fd]} return
1440         set to_clear {}
1441         close $fd
1442         if {[incr rescan_active -1] > 0} return
1443
1444         prune_selection
1445         unlock_index
1446         display_all_files
1447         if {$current_diff_path ne {}} reshow_diff
1448         if {$current_diff_path eq {}} select_first_diff
1449
1450         uplevel #0 $after
1451 }
1452
1453 proc prune_selection {} {
1454         global file_states selected_paths
1455
1456         foreach path [array names selected_paths] {
1457                 if {[catch {set still_here $file_states($path)}]} {
1458                         unset selected_paths($path)
1459                 }
1460         }
1461 }
1462
1463 ######################################################################
1464 ##
1465 ## ui helpers
1466
1467 proc mapicon {w state path} {
1468         global all_icons
1469
1470         if {[catch {set r $all_icons($state$w)}]} {
1471                 puts "error: no icon for $w state={$state} $path"
1472                 return file_plain
1473         }
1474         return $r
1475 }
1476
1477 proc mapdesc {state path} {
1478         global all_descs
1479
1480         if {[catch {set r $all_descs($state)}]} {
1481                 puts "error: no desc for state={$state} $path"
1482                 return $state
1483         }
1484         return $r
1485 }
1486
1487 proc ui_status {msg} {
1488         global main_status
1489         if {[info exists main_status]} {
1490                 $main_status show $msg
1491         }
1492 }
1493
1494 proc ui_ready {{test {}}} {
1495         global main_status
1496         if {[info exists main_status]} {
1497                 $main_status show [mc "Ready."] $test
1498         }
1499 }
1500
1501 proc escape_path {path} {
1502         regsub -all {\\} $path "\\\\" path
1503         regsub -all "\n" $path "\\n" path
1504         return $path
1505 }
1506
1507 proc short_path {path} {
1508         return [escape_path [lindex [file split $path] end]]
1509 }
1510
1511 set next_icon_id 0
1512 set null_sha1 [string repeat 0 40]
1513
1514 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1515         global file_states next_icon_id null_sha1
1516
1517         set s0 [string index $new_state 0]
1518         set s1 [string index $new_state 1]
1519
1520         if {[catch {set info $file_states($path)}]} {
1521                 set state __
1522                 set icon n[incr next_icon_id]
1523         } else {
1524                 set state [lindex $info 0]
1525                 set icon [lindex $info 1]
1526                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1527                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1528         }
1529
1530         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1531         elseif {$s0 eq {_}} {set s0 _}
1532
1533         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1534         elseif {$s1 eq {_}} {set s1 _}
1535
1536         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1537                 set head_info [list 0 $null_sha1]
1538         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1539                 && $head_info eq {}} {
1540                 set head_info $index_info
1541         }
1542
1543         set file_states($path) [list $s0$s1 $icon \
1544                 $head_info $index_info \
1545                 ]
1546         return $state
1547 }
1548
1549 proc display_file_helper {w path icon_name old_m new_m} {
1550         global file_lists
1551
1552         if {$new_m eq {_}} {
1553                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1554                 if {$lno >= 0} {
1555                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1556                         incr lno
1557                         $w conf -state normal
1558                         $w delete $lno.0 [expr {$lno + 1}].0
1559                         $w conf -state disabled
1560                 }
1561         } elseif {$old_m eq {_} && $new_m ne {_}} {
1562                 lappend file_lists($w) $path
1563                 set file_lists($w) [lsort -unique $file_lists($w)]
1564                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1565                 incr lno
1566                 $w conf -state normal
1567                 $w image create $lno.0 \
1568                         -align center -padx 5 -pady 1 \
1569                         -name $icon_name \
1570                         -image [mapicon $w $new_m $path]
1571                 $w insert $lno.1 "[escape_path $path]\n"
1572                 $w conf -state disabled
1573         } elseif {$old_m ne $new_m} {
1574                 $w conf -state normal
1575                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1576                 $w conf -state disabled
1577         }
1578 }
1579
1580 proc display_file {path state} {
1581         global file_states selected_paths
1582         global ui_index ui_workdir
1583
1584         set old_m [merge_state $path $state]
1585         set s $file_states($path)
1586         set new_m [lindex $s 0]
1587         set icon_name [lindex $s 1]
1588
1589         set o [string index $old_m 0]
1590         set n [string index $new_m 0]
1591         if {$o eq {U}} {
1592                 set o _
1593         }
1594         if {$n eq {U}} {
1595                 set n _
1596         }
1597         display_file_helper     $ui_index $path $icon_name $o $n
1598
1599         if {[string index $old_m 0] eq {U}} {
1600                 set o U
1601         } else {
1602                 set o [string index $old_m 1]
1603         }
1604         if {[string index $new_m 0] eq {U}} {
1605                 set n U
1606         } else {
1607                 set n [string index $new_m 1]
1608         }
1609         display_file_helper     $ui_workdir $path $icon_name $o $n
1610
1611         if {$new_m eq {__}} {
1612                 unset file_states($path)
1613                 catch {unset selected_paths($path)}
1614         }
1615 }
1616
1617 proc display_all_files_helper {w path icon_name m} {
1618         global file_lists
1619
1620         lappend file_lists($w) $path
1621         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1622         $w image create end \
1623                 -align center -padx 5 -pady 1 \
1624                 -name $icon_name \
1625                 -image [mapicon $w $m $path]
1626         $w insert end "[escape_path $path]\n"
1627 }
1628
1629 proc display_all_files {} {
1630         global ui_index ui_workdir
1631         global file_states file_lists
1632         global last_clicked
1633
1634         $ui_index conf -state normal
1635         $ui_workdir conf -state normal
1636
1637         $ui_index delete 0.0 end
1638         $ui_workdir delete 0.0 end
1639         set last_clicked {}
1640
1641         set file_lists($ui_index) [list]
1642         set file_lists($ui_workdir) [list]
1643
1644         foreach path [lsort [array names file_states]] {
1645                 set s $file_states($path)
1646                 set m [lindex $s 0]
1647                 set icon_name [lindex $s 1]
1648
1649                 set s [string index $m 0]
1650                 if {$s ne {U} && $s ne {_}} {
1651                         display_all_files_helper $ui_index $path \
1652                                 $icon_name $s
1653                 }
1654
1655                 if {[string index $m 0] eq {U}} {
1656                         set s U
1657                 } else {
1658                         set s [string index $m 1]
1659                 }
1660                 if {$s ne {_}} {
1661                         display_all_files_helper $ui_workdir $path \
1662                                 $icon_name $s
1663                 }
1664         }
1665
1666         $ui_index conf -state disabled
1667         $ui_workdir conf -state disabled
1668 }
1669
1670 ######################################################################
1671 ##
1672 ## icons
1673
1674 set filemask {
1675 #define mask_width 14
1676 #define mask_height 15
1677 static unsigned char mask_bits[] = {
1678    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1679    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1680    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1681 }
1682
1683 image create bitmap file_plain -background white -foreground black -data {
1684 #define plain_width 14
1685 #define plain_height 15
1686 static unsigned char plain_bits[] = {
1687    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1688    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1689    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1690 } -maskdata $filemask
1691
1692 image create bitmap file_mod -background white -foreground blue -data {
1693 #define mod_width 14
1694 #define mod_height 15
1695 static unsigned char mod_bits[] = {
1696    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1697    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1698    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1699 } -maskdata $filemask
1700
1701 image create bitmap file_fulltick -background white -foreground "#007000" -data {
1702 #define file_fulltick_width 14
1703 #define file_fulltick_height 15
1704 static unsigned char file_fulltick_bits[] = {
1705    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1706    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1707    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1708 } -maskdata $filemask
1709
1710 image create bitmap file_parttick -background white -foreground "#005050" -data {
1711 #define parttick_width 14
1712 #define parttick_height 15
1713 static unsigned char parttick_bits[] = {
1714    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1715    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
1716    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1717 } -maskdata $filemask
1718
1719 image create bitmap file_question -background white -foreground black -data {
1720 #define file_question_width 14
1721 #define file_question_height 15
1722 static unsigned char file_question_bits[] = {
1723    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1724    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1725    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1726 } -maskdata $filemask
1727
1728 image create bitmap file_removed -background white -foreground red -data {
1729 #define file_removed_width 14
1730 #define file_removed_height 15
1731 static unsigned char file_removed_bits[] = {
1732    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1733    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1734    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1735 } -maskdata $filemask
1736
1737 image create bitmap file_merge -background white -foreground blue -data {
1738 #define file_merge_width 14
1739 #define file_merge_height 15
1740 static unsigned char file_merge_bits[] = {
1741    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1742    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1743    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1744 } -maskdata $filemask
1745
1746 image create bitmap file_statechange -background white -foreground green -data {
1747 #define file_merge_width 14
1748 #define file_merge_height 15
1749 static unsigned char file_statechange_bits[] = {
1750    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
1751    0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
1752    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1753 } -maskdata $filemask
1754
1755 set ui_index .vpane.files.index.list
1756 set ui_workdir .vpane.files.workdir.list
1757
1758 set all_icons(_$ui_index)   file_plain
1759 set all_icons(A$ui_index)   file_fulltick
1760 set all_icons(M$ui_index)   file_fulltick
1761 set all_icons(D$ui_index)   file_removed
1762 set all_icons(U$ui_index)   file_merge
1763 set all_icons(T$ui_index)   file_statechange
1764
1765 set all_icons(_$ui_workdir) file_plain
1766 set all_icons(M$ui_workdir) file_mod
1767 set all_icons(D$ui_workdir) file_question
1768 set all_icons(U$ui_workdir) file_merge
1769 set all_icons(O$ui_workdir) file_plain
1770 set all_icons(T$ui_workdir) file_statechange
1771
1772 set max_status_desc 0
1773 foreach i {
1774                 {__ {mc "Unmodified"}}
1775
1776                 {_M {mc "Modified, not staged"}}
1777                 {M_ {mc "Staged for commit"}}
1778                 {MM {mc "Portions staged for commit"}}
1779                 {MD {mc "Staged for commit, missing"}}
1780
1781                 {_T {mc "File type changed, not staged"}}
1782                 {T_ {mc "File type changed, staged"}}
1783
1784                 {_O {mc "Untracked, not staged"}}
1785                 {A_ {mc "Staged for commit"}}
1786                 {AM {mc "Portions staged for commit"}}
1787                 {AD {mc "Staged for commit, missing"}}
1788
1789                 {_D {mc "Missing"}}
1790                 {D_ {mc "Staged for removal"}}
1791                 {DO {mc "Staged for removal, still present"}}
1792
1793                 {_U {mc "Requires merge resolution"}}
1794                 {U_ {mc "Requires merge resolution"}}
1795                 {UU {mc "Requires merge resolution"}}
1796                 {UM {mc "Requires merge resolution"}}
1797                 {UD {mc "Requires merge resolution"}}
1798                 {UT {mc "Requires merge resolution"}}
1799         } {
1800         set text [eval [lindex $i 1]]
1801         if {$max_status_desc < [string length $text]} {
1802                 set max_status_desc [string length $text]
1803         }
1804         set all_descs([lindex $i 0]) $text
1805 }
1806 unset i
1807
1808 ######################################################################
1809 ##
1810 ## util
1811
1812 proc scrollbar2many {list mode args} {
1813         foreach w $list {eval $w $mode $args}
1814 }
1815
1816 proc many2scrollbar {list mode sb top bottom} {
1817         $sb set $top $bottom
1818         foreach w $list {$w $mode moveto $top}
1819 }
1820
1821 proc incr_font_size {font {amt 1}} {
1822         set sz [font configure $font -size]
1823         incr sz $amt
1824         font configure $font -size $sz
1825         font configure ${font}bold -size $sz
1826         font configure ${font}italic -size $sz
1827 }
1828
1829 ######################################################################
1830 ##
1831 ## ui commands
1832
1833 set starting_gitk_msg [mc "Starting gitk... please wait..."]
1834
1835 proc do_gitk {revs} {
1836         # -- Always start gitk through whatever we were loaded with.  This
1837         #    lets us bypass using shell process on Windows systems.
1838         #
1839         set exe [_which gitk -script]
1840         set cmd [list [info nameofexecutable] $exe]
1841         if {$exe eq {}} {
1842                 error_popup [mc "Couldn't find gitk in PATH"]
1843         } else {
1844                 global env
1845
1846                 if {[info exists env(GIT_DIR)]} {
1847                         set old_GIT_DIR $env(GIT_DIR)
1848                 } else {
1849                         set old_GIT_DIR {}
1850                 }
1851
1852                 set pwd [pwd]
1853                 cd [file dirname [gitdir]]
1854                 set env(GIT_DIR) [file tail [gitdir]]
1855
1856                 eval exec $cmd $revs &
1857
1858                 if {$old_GIT_DIR eq {}} {
1859                         unset env(GIT_DIR)
1860                 } else {
1861                         set env(GIT_DIR) $old_GIT_DIR
1862                 }
1863                 cd $pwd
1864
1865                 ui_status $::starting_gitk_msg
1866                 after 10000 {
1867                         ui_ready $starting_gitk_msg
1868                 }
1869         }
1870 }
1871
1872 proc do_explore {} {
1873         set explorer {}
1874         if {[is_Cygwin] || [is_Windows]} {
1875                 set explorer "explorer.exe"
1876         } elseif {[is_MacOSX]} {
1877                 set explorer "open"
1878         } else {
1879                 # freedesktop.org-conforming system is our best shot
1880                 set explorer "xdg-open"
1881         }
1882         eval exec $explorer [file dirname [gitdir]] &
1883 }
1884
1885 set is_quitting 0
1886 set ret_code    1
1887
1888 proc terminate_me {win} {
1889         global ret_code
1890         if {$win ne {.}} return
1891         exit $ret_code
1892 }
1893
1894 proc do_quit {{rc {1}}} {
1895         global ui_comm is_quitting repo_config commit_type
1896         global GITGUI_BCK_exists GITGUI_BCK_i
1897         global ui_comm_spell
1898         global ret_code
1899
1900         if {$is_quitting} return
1901         set is_quitting 1
1902
1903         if {[winfo exists $ui_comm]} {
1904                 # -- Stash our current commit buffer.
1905                 #
1906                 set save [gitdir GITGUI_MSG]
1907                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
1908                         file rename -force [gitdir GITGUI_BCK] $save
1909                         set GITGUI_BCK_exists 0
1910                 } else {
1911                         set msg [string trim [$ui_comm get 0.0 end]]
1912                         regsub -all -line {[ \r\t]+$} $msg {} msg
1913                         if {(![string match amend* $commit_type]
1914                                 || [$ui_comm edit modified])
1915                                 && $msg ne {}} {
1916                                 catch {
1917                                         set fd [open $save w]
1918                                         puts -nonewline $fd $msg
1919                                         close $fd
1920                                 }
1921                         } else {
1922                                 catch {file delete $save}
1923                         }
1924                 }
1925
1926                 # -- Cancel our spellchecker if its running.
1927                 #
1928                 if {[info exists ui_comm_spell]} {
1929                         $ui_comm_spell stop
1930                 }
1931
1932                 # -- Remove our editor backup, its not needed.
1933                 #
1934                 after cancel $GITGUI_BCK_i
1935                 if {$GITGUI_BCK_exists} {
1936                         catch {file delete [gitdir GITGUI_BCK]}
1937                 }
1938
1939                 # -- Stash our current window geometry into this repository.
1940                 #
1941                 set cfg_geometry [list]
1942                 lappend cfg_geometry [wm geometry .]
1943                 lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
1944                 lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
1945                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
1946                         set rc_geometry {}
1947                 }
1948                 if {$cfg_geometry ne $rc_geometry} {
1949                         catch {git config gui.geometry $cfg_geometry}
1950                 }
1951         }
1952
1953         set ret_code $rc
1954         destroy .
1955 }
1956
1957 proc do_rescan {} {
1958         rescan ui_ready
1959 }
1960
1961 proc ui_do_rescan {} {
1962         rescan {force_first_diff; ui_ready}
1963 }
1964
1965 proc do_commit {} {
1966         commit_tree
1967 }
1968
1969 proc next_diff {} {
1970         global next_diff_p next_diff_w next_diff_i
1971         show_diff $next_diff_p $next_diff_w {}
1972 }
1973
1974 proc find_anchor_pos {lst name} {
1975         set lid [lsearch -sorted -exact $lst $name]
1976
1977         if {$lid == -1} {
1978                 set lid 0
1979                 foreach lname $lst {
1980                         if {$lname >= $name} break
1981                         incr lid
1982                 }
1983         }
1984
1985         return $lid
1986 }
1987
1988 proc find_file_from {flist idx delta path mmask} {
1989         global file_states
1990
1991         set len [llength $flist]
1992         while {$idx >= 0 && $idx < $len} {
1993                 set name [lindex $flist $idx]
1994
1995                 if {$name ne $path && [info exists file_states($name)]} {
1996                         set state [lindex $file_states($name) 0]
1997
1998                         if {$mmask eq {} || [regexp $mmask $state]} {
1999                                 return $idx
2000                         }
2001                 }
2002
2003                 incr idx $delta
2004         }
2005
2006         return {}
2007 }
2008
2009 proc find_next_diff {w path {lno {}} {mmask {}}} {
2010         global next_diff_p next_diff_w next_diff_i
2011         global file_lists ui_index ui_workdir
2012
2013         set flist $file_lists($w)
2014         if {$lno eq {}} {
2015                 set lno [find_anchor_pos $flist $path]
2016         } else {
2017                 incr lno -1
2018         }
2019
2020         if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
2021                 if {$w eq $ui_index} {
2022                         set mmask "^$mmask"
2023                 } else {
2024                         set mmask "$mmask\$"
2025                 }
2026         }
2027
2028         set idx [find_file_from $flist $lno 1 $path $mmask]
2029         if {$idx eq {}} {
2030                 incr lno -1
2031                 set idx [find_file_from $flist $lno -1 $path $mmask]
2032         }
2033
2034         if {$idx ne {}} {
2035                 set next_diff_w $w
2036                 set next_diff_p [lindex $flist $idx]
2037                 set next_diff_i [expr {$idx+1}]
2038                 return 1
2039         } else {
2040                 return 0
2041         }
2042 }
2043
2044 proc next_diff_after_action {w path {lno {}} {mmask {}}} {
2045         global current_diff_path
2046
2047         if {$path ne $current_diff_path} {
2048                 return {}
2049         } elseif {[find_next_diff $w $path $lno $mmask]} {
2050                 return {next_diff;}
2051         } else {
2052                 return {reshow_diff;}
2053         }
2054 }
2055
2056 proc select_first_diff {} {
2057         global ui_workdir
2058
2059         if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
2060             [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
2061                 next_diff
2062         }
2063 }
2064
2065 proc force_first_diff {} {
2066         global current_diff_path
2067
2068         if {[info exists file_states($current_diff_path)]} {
2069                 set state [lindex $file_states($current_diff_path) 0]
2070
2071                 if {[string index $state 1] ne {O}} return
2072         }
2073
2074         select_first_diff
2075 }
2076
2077 proc toggle_or_diff {w x y} {
2078         global file_states file_lists current_diff_path ui_index ui_workdir
2079         global last_clicked selected_paths
2080
2081         set pos [split [$w index @$x,$y] .]
2082         set lno [lindex $pos 0]
2083         set col [lindex $pos 1]
2084         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2085         if {$path eq {}} {
2086                 set last_clicked {}
2087                 return
2088         }
2089
2090         set last_clicked [list $w $lno]
2091         array unset selected_paths
2092         $ui_index tag remove in_sel 0.0 end
2093         $ui_workdir tag remove in_sel 0.0 end
2094
2095         # Determine the state of the file
2096         if {[info exists file_states($path)]} {
2097                 set state [lindex $file_states($path) 0]
2098         } else {
2099                 set state {__}
2100         }
2101
2102         # Restage the file, or simply show the diff
2103         if {$col == 0 && $y > 1} {
2104                 # Conflicts need special handling
2105                 if {[string first {U} $state] >= 0} {
2106                         # $w must always be $ui_workdir, but...
2107                         if {$w ne $ui_workdir} { set lno {} }
2108                         merge_stage_workdir $path $lno
2109                         return
2110                 }
2111
2112                 if {[string index $state 1] eq {O}} {
2113                         set mmask {}
2114                 } else {
2115                         set mmask {[^O]}
2116                 }
2117
2118                 set after [next_diff_after_action $w $path $lno $mmask]
2119
2120                 if {$w eq $ui_index} {
2121                         update_indexinfo \
2122                                 "Unstaging [short_path $path] from commit" \
2123                                 [list $path] \
2124                                 [concat $after [list ui_ready]]
2125                 } elseif {$w eq $ui_workdir} {
2126                         update_index \
2127                                 "Adding [short_path $path]" \
2128                                 [list $path] \
2129                                 [concat $after [list ui_ready]]
2130                 }
2131         } else {
2132                 show_diff $path $w $lno
2133         }
2134 }
2135
2136 proc add_one_to_selection {w x y} {
2137         global file_lists last_clicked selected_paths
2138
2139         set lno [lindex [split [$w index @$x,$y] .] 0]
2140         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2141         if {$path eq {}} {
2142                 set last_clicked {}
2143                 return
2144         }
2145
2146         if {$last_clicked ne {}
2147                 && [lindex $last_clicked 0] ne $w} {
2148                 array unset selected_paths
2149                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
2150         }
2151
2152         set last_clicked [list $w $lno]
2153         if {[catch {set in_sel $selected_paths($path)}]} {
2154                 set in_sel 0
2155         }
2156         if {$in_sel} {
2157                 unset selected_paths($path)
2158                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2159         } else {
2160                 set selected_paths($path) 1
2161                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2162         }
2163 }
2164
2165 proc add_range_to_selection {w x y} {
2166         global file_lists last_clicked selected_paths
2167
2168         if {[lindex $last_clicked 0] ne $w} {
2169                 toggle_or_diff $w $x $y
2170                 return
2171         }
2172
2173         set lno [lindex [split [$w index @$x,$y] .] 0]
2174         set lc [lindex $last_clicked 1]
2175         if {$lc < $lno} {
2176                 set begin $lc
2177                 set end $lno
2178         } else {
2179                 set begin $lno
2180                 set end $lc
2181         }
2182
2183         foreach path [lrange $file_lists($w) \
2184                 [expr {$begin - 1}] \
2185                 [expr {$end - 1}]] {
2186                 set selected_paths($path) 1
2187         }
2188         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2189 }
2190
2191 proc show_more_context {} {
2192         global repo_config
2193         if {$repo_config(gui.diffcontext) < 99} {
2194                 incr repo_config(gui.diffcontext)
2195                 reshow_diff
2196         }
2197 }
2198
2199 proc show_less_context {} {
2200         global repo_config
2201         if {$repo_config(gui.diffcontext) > 1} {
2202                 incr repo_config(gui.diffcontext) -1
2203                 reshow_diff
2204         }
2205 }
2206
2207 ######################################################################
2208 ##
2209 ## ui construction
2210
2211 load_config 0
2212 apply_config
2213 set ui_comm {}
2214
2215 # -- Menu Bar
2216 #
2217 menu .mbar -tearoff 0
2218 .mbar add cascade -label [mc Repository] -menu .mbar.repository
2219 .mbar add cascade -label [mc Edit] -menu .mbar.edit
2220 if {[is_enabled branch]} {
2221         .mbar add cascade -label [mc Branch] -menu .mbar.branch
2222 }
2223 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2224         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2225 }
2226 if {[is_enabled transport]} {
2227         .mbar add cascade -label [mc Merge] -menu .mbar.merge
2228         .mbar add cascade -label [mc Remote] -menu .mbar.remote
2229 }
2230 . configure -menu .mbar
2231
2232 # -- Repository Menu
2233 #
2234 menu .mbar.repository
2235
2236 .mbar.repository add command \
2237         -label [mc "Explore Working Copy"] \
2238         -command {do_explore}
2239 .mbar.repository add separator
2240
2241 .mbar.repository add command \
2242         -label [mc "Browse Current Branch's Files"] \
2243         -command {browser::new $current_branch}
2244 set ui_browse_current [.mbar.repository index last]
2245 .mbar.repository add command \
2246         -label [mc "Browse Branch Files..."] \
2247         -command browser_open::dialog
2248 .mbar.repository add separator
2249
2250 .mbar.repository add command \
2251         -label [mc "Visualize Current Branch's History"] \
2252         -command {do_gitk $current_branch}
2253 set ui_visualize_current [.mbar.repository index last]
2254 .mbar.repository add command \
2255         -label [mc "Visualize All Branch History"] \
2256         -command {do_gitk --all}
2257 .mbar.repository add separator
2258
2259 proc current_branch_write {args} {
2260         global current_branch
2261         .mbar.repository entryconf $::ui_browse_current \
2262                 -label [mc "Browse %s's Files" $current_branch]
2263         .mbar.repository entryconf $::ui_visualize_current \
2264                 -label [mc "Visualize %s's History" $current_branch]
2265 }
2266 trace add variable current_branch write current_branch_write
2267
2268 if {[is_enabled multicommit]} {
2269         .mbar.repository add command -label [mc "Database Statistics"] \
2270                 -command do_stats
2271
2272         .mbar.repository add command -label [mc "Compress Database"] \
2273                 -command do_gc
2274
2275         .mbar.repository add command -label [mc "Verify Database"] \
2276                 -command do_fsck_objects
2277
2278         .mbar.repository add separator
2279
2280         if {[is_Cygwin]} {
2281                 .mbar.repository add command \
2282                         -label [mc "Create Desktop Icon"] \
2283                         -command do_cygwin_shortcut
2284         } elseif {[is_Windows]} {
2285                 .mbar.repository add command \
2286                         -label [mc "Create Desktop Icon"] \
2287                         -command do_windows_shortcut
2288         } elseif {[is_MacOSX]} {
2289                 .mbar.repository add command \
2290                         -label [mc "Create Desktop Icon"] \
2291                         -command do_macosx_app
2292         }
2293 }
2294
2295 if {[is_MacOSX]} {
2296         proc ::tk::mac::Quit {args} { do_quit }
2297 } else {
2298         .mbar.repository add command -label [mc Quit] \
2299                 -command do_quit \
2300                 -accelerator $M1T-Q
2301 }
2302
2303 # -- Edit Menu
2304 #
2305 menu .mbar.edit
2306 .mbar.edit add command -label [mc Undo] \
2307         -command {catch {[focus] edit undo}} \
2308         -accelerator $M1T-Z
2309 .mbar.edit add command -label [mc Redo] \
2310         -command {catch {[focus] edit redo}} \
2311         -accelerator $M1T-Y
2312 .mbar.edit add separator
2313 .mbar.edit add command -label [mc Cut] \
2314         -command {catch {tk_textCut [focus]}} \
2315         -accelerator $M1T-X
2316 .mbar.edit add command -label [mc Copy] \
2317         -command {catch {tk_textCopy [focus]}} \
2318         -accelerator $M1T-C
2319 .mbar.edit add command -label [mc Paste] \
2320         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2321         -accelerator $M1T-V
2322 .mbar.edit add command -label [mc Delete] \
2323         -command {catch {[focus] delete sel.first sel.last}} \
2324         -accelerator Del
2325 .mbar.edit add separator
2326 .mbar.edit add command -label [mc "Select All"] \
2327         -command {catch {[focus] tag add sel 0.0 end}} \
2328         -accelerator $M1T-A
2329
2330 # -- Branch Menu
2331 #
2332 if {[is_enabled branch]} {
2333         menu .mbar.branch
2334
2335         .mbar.branch add command -label [mc "Create..."] \
2336                 -command branch_create::dialog \
2337                 -accelerator $M1T-N
2338         lappend disable_on_lock [list .mbar.branch entryconf \
2339                 [.mbar.branch index last] -state]
2340
2341         .mbar.branch add command -label [mc "Checkout..."] \
2342                 -command branch_checkout::dialog \
2343                 -accelerator $M1T-O
2344         lappend disable_on_lock [list .mbar.branch entryconf \
2345                 [.mbar.branch index last] -state]
2346
2347         .mbar.branch add command -label [mc "Rename..."] \
2348                 -command branch_rename::dialog
2349         lappend disable_on_lock [list .mbar.branch entryconf \
2350                 [.mbar.branch index last] -state]
2351
2352         .mbar.branch add command -label [mc "Delete..."] \
2353                 -command branch_delete::dialog
2354         lappend disable_on_lock [list .mbar.branch entryconf \
2355                 [.mbar.branch index last] -state]
2356
2357         .mbar.branch add command -label [mc "Reset..."] \
2358                 -command merge::reset_hard
2359         lappend disable_on_lock [list .mbar.branch entryconf \
2360                 [.mbar.branch index last] -state]
2361 }
2362
2363 # -- Commit Menu
2364 #
2365 proc commit_btn_caption {} {
2366         if {[is_enabled nocommit]} {
2367                 return [mc "Done"]
2368         } else {
2369                 return [mc Commit@@verb]
2370         }
2371 }
2372
2373 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2374         menu .mbar.commit
2375
2376         if {![is_enabled nocommit]} {
2377                 .mbar.commit add radiobutton \
2378                         -label [mc "New Commit"] \
2379                         -command do_select_commit_type \
2380                         -variable selected_commit_type \
2381                         -value new
2382                 lappend disable_on_lock \
2383                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2384
2385                 .mbar.commit add radiobutton \
2386                         -label [mc "Amend Last Commit"] \
2387                         -command do_select_commit_type \
2388                         -variable selected_commit_type \
2389                         -value amend
2390                 lappend disable_on_lock \
2391                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2392
2393                 .mbar.commit add separator
2394         }
2395
2396         .mbar.commit add command -label [mc Rescan] \
2397                 -command ui_do_rescan \
2398                 -accelerator F5
2399         lappend disable_on_lock \
2400                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2401
2402         .mbar.commit add command -label [mc "Stage To Commit"] \
2403                 -command do_add_selection \
2404                 -accelerator $M1T-T
2405         lappend disable_on_lock \
2406                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2407
2408         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2409                 -command do_add_all \
2410                 -accelerator $M1T-I
2411         lappend disable_on_lock \
2412                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2413
2414         .mbar.commit add command -label [mc "Unstage From Commit"] \
2415                 -command do_unstage_selection
2416         lappend disable_on_lock \
2417                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2418
2419         .mbar.commit add command -label [mc "Revert Changes"] \
2420                 -command do_revert_selection
2421         lappend disable_on_lock \
2422                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2423
2424         .mbar.commit add separator
2425
2426         .mbar.commit add command -label [mc "Show Less Context"] \
2427                 -command show_less_context \
2428                 -accelerator $M1T-\-
2429
2430         .mbar.commit add command -label [mc "Show More Context"] \
2431                 -command show_more_context \
2432                 -accelerator $M1T-=
2433
2434         .mbar.commit add separator
2435
2436         if {![is_enabled nocommitmsg]} {
2437                 .mbar.commit add command -label [mc "Sign Off"] \
2438                         -command do_signoff \
2439                         -accelerator $M1T-S
2440         }
2441
2442         .mbar.commit add command -label [commit_btn_caption] \
2443                 -command do_commit \
2444                 -accelerator $M1T-Return
2445         lappend disable_on_lock \
2446                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2447 }
2448
2449 # -- Merge Menu
2450 #
2451 if {[is_enabled branch]} {
2452         menu .mbar.merge
2453         .mbar.merge add command -label [mc "Local Merge..."] \
2454                 -command merge::dialog \
2455                 -accelerator $M1T-M
2456         lappend disable_on_lock \
2457                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2458         .mbar.merge add command -label [mc "Abort Merge..."] \
2459                 -command merge::reset_hard
2460         lappend disable_on_lock \
2461                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2462 }
2463
2464 # -- Transport Menu
2465 #
2466 if {[is_enabled transport]} {
2467         menu .mbar.remote
2468
2469         .mbar.remote add command \
2470                 -label [mc "Add..."] \
2471                 -command remote_add::dialog \
2472                 -accelerator $M1T-A
2473         .mbar.remote add command \
2474                 -label [mc "Push..."] \
2475                 -command do_push_anywhere \
2476                 -accelerator $M1T-P
2477         .mbar.remote add command \
2478                 -label [mc "Delete Branch..."] \
2479                 -command remote_branch_delete::dialog
2480 }
2481
2482 if {[is_MacOSX]} {
2483         # -- Apple Menu (Mac OS X only)
2484         #
2485         .mbar add cascade -label Apple -menu .mbar.apple
2486         menu .mbar.apple
2487
2488         .mbar.apple add command -label [mc "About %s" [appname]] \
2489                 -command do_about
2490         .mbar.apple add separator
2491         .mbar.apple add command \
2492                 -label [mc "Preferences..."] \
2493                 -command do_options \
2494                 -accelerator $M1T-,
2495         bind . <$M1B-,> do_options
2496 } else {
2497         # -- Edit Menu
2498         #
2499         .mbar.edit add separator
2500         .mbar.edit add command -label [mc "Options..."] \
2501                 -command do_options
2502 }
2503
2504 # -- Help Menu
2505 #
2506 .mbar add cascade -label [mc Help] -menu .mbar.help
2507 menu .mbar.help
2508
2509 if {![is_MacOSX]} {
2510         .mbar.help add command -label [mc "About %s" [appname]] \
2511                 -command do_about
2512 }
2513
2514
2515 set doc_path [file dirname [gitexec]]
2516 set doc_path [file join $doc_path Documentation index.html]
2517
2518 if {[is_Cygwin]} {
2519         set doc_path [exec cygpath --mixed $doc_path]
2520 }
2521
2522 if {[file isfile $doc_path]} {
2523         set doc_url "file:$doc_path"
2524 } else {
2525         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2526 }
2527
2528 proc start_browser {url} {
2529         git "web--browse" $url
2530 }
2531
2532 .mbar.help add command -label [mc "Online Documentation"] \
2533         -command [list start_browser $doc_url]
2534 unset doc_path doc_url
2535
2536 # -- Standard bindings
2537 #
2538 wm protocol . WM_DELETE_WINDOW do_quit
2539 bind all <$M1B-Key-q> do_quit
2540 bind all <$M1B-Key-Q> do_quit
2541 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
2542 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
2543
2544 set subcommand_args {}
2545 proc usage {} {
2546         puts stderr "usage: $::argv0 $::subcommand $::subcommand_args"
2547         exit 1
2548 }
2549
2550 # -- Not a normal commit type invocation?  Do that instead!
2551 #
2552 switch -- $subcommand {
2553 browser -
2554 blame {
2555         if {$subcommand eq "blame"} {
2556                 set subcommand_args {[--line=<num>] rev? path}
2557         } else {
2558                 set subcommand_args {rev? path}
2559         }
2560         if {$argv eq {}} usage
2561         set head {}
2562         set path {}
2563         set jump_spec {}
2564         set is_path 0
2565         foreach a $argv {
2566                 if {$is_path || [file exists $_prefix$a]} {
2567                         if {$path ne {}} usage
2568                         set path $_prefix$a
2569                         break
2570                 } elseif {$a eq {--}} {
2571                         if {$path ne {}} {
2572                                 if {$head ne {}} usage
2573                                 set head $path
2574                                 set path {}
2575                         }
2576                         set is_path 1
2577                 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
2578                         if {$jump_spec ne {} || $head ne {}} usage
2579                         set jump_spec [list $lnum]
2580                 } elseif {$head eq {}} {
2581                         if {$head ne {}} usage
2582                         set head $a
2583                         set is_path 1
2584                 } else {
2585                         usage
2586                 }
2587         }
2588         unset is_path
2589
2590         if {$head ne {} && $path eq {}} {
2591                 set path $_prefix$head
2592                 set head {}
2593         }
2594
2595         if {$head eq {}} {
2596                 load_current_branch
2597         } else {
2598                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
2599                         if {[catch {
2600                                         set head [git rev-parse --verify $head]
2601                                 } err]} {
2602                                 puts stderr $err
2603                                 exit 1
2604                         }
2605                 }
2606                 set current_branch $head
2607         }
2608
2609         switch -- $subcommand {
2610         browser {
2611                 if {$jump_spec ne {}} usage
2612                 if {$head eq {}} {
2613                         if {$path ne {} && [file isdirectory $path]} {
2614                                 set head $current_branch
2615                         } else {
2616                                 set head $path
2617                                 set path {}
2618                         }
2619                 }
2620                 browser::new $head $path
2621         }
2622         blame   {
2623                 if {$head eq {} && ![file exists $path]} {
2624                         puts stderr [mc "fatal: cannot stat path %s: No such file or directory" $path]
2625                         exit 1
2626                 }
2627                 blame::new $head $path $jump_spec
2628         }
2629         }
2630         return
2631 }
2632 citool -
2633 gui {
2634         if {[llength $argv] != 0} {
2635                 puts -nonewline stderr "usage: $argv0"
2636                 if {$subcommand ne {gui}
2637                         && [file tail $argv0] ne "git-$subcommand"} {
2638                         puts -nonewline stderr " $subcommand"
2639                 }
2640                 puts stderr {}
2641                 exit 1
2642         }
2643         # fall through to setup UI for commits
2644 }
2645 default {
2646         puts stderr "usage: $argv0 \[{blame|browser|citool}\]"
2647         exit 1
2648 }
2649 }
2650
2651 # -- Branch Control
2652 #
2653 frame .branch \
2654         -borderwidth 1 \
2655         -relief sunken
2656 label .branch.l1 \
2657         -text [mc "Current Branch:"] \
2658         -anchor w \
2659         -justify left
2660 label .branch.cb \
2661         -textvariable current_branch \
2662         -anchor w \
2663         -justify left
2664 pack .branch.l1 -side left
2665 pack .branch.cb -side left -fill x
2666 pack .branch -side top -fill x
2667
2668 # -- Main Window Layout
2669 #
2670 panedwindow .vpane -orient horizontal
2671 panedwindow .vpane.files -orient vertical
2672 .vpane add .vpane.files -sticky nsew -height 100 -width 200
2673 pack .vpane -anchor n -side top -fill both -expand 1
2674
2675 # -- Index File List
2676 #
2677 frame .vpane.files.index -height 100 -width 200
2678 label .vpane.files.index.title -text [mc "Staged Changes (Will Commit)"] \
2679         -background lightgreen -foreground black
2680 text $ui_index -background white -foreground black \
2681         -borderwidth 0 \
2682         -width 20 -height 10 \
2683         -wrap none \
2684         -cursor $cursor_ptr \
2685         -xscrollcommand {.vpane.files.index.sx set} \
2686         -yscrollcommand {.vpane.files.index.sy set} \
2687         -state disabled
2688 scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
2689 scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
2690 pack .vpane.files.index.title -side top -fill x
2691 pack .vpane.files.index.sx -side bottom -fill x
2692 pack .vpane.files.index.sy -side right -fill y
2693 pack $ui_index -side left -fill both -expand 1
2694
2695 # -- Working Directory File List
2696 #
2697 frame .vpane.files.workdir -height 100 -width 200
2698 label .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
2699         -background lightsalmon -foreground black
2700 text $ui_workdir -background white -foreground black \
2701         -borderwidth 0 \
2702         -width 20 -height 10 \
2703         -wrap none \
2704         -cursor $cursor_ptr \
2705         -xscrollcommand {.vpane.files.workdir.sx set} \
2706         -yscrollcommand {.vpane.files.workdir.sy set} \
2707         -state disabled
2708 scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
2709 scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
2710 pack .vpane.files.workdir.title -side top -fill x
2711 pack .vpane.files.workdir.sx -side bottom -fill x
2712 pack .vpane.files.workdir.sy -side right -fill y
2713 pack $ui_workdir -side left -fill both -expand 1
2714
2715 .vpane.files add .vpane.files.workdir -sticky nsew
2716 .vpane.files add .vpane.files.index -sticky nsew
2717
2718 foreach i [list $ui_index $ui_workdir] {
2719         rmsel_tag $i
2720         $i tag conf in_diff -background [$i tag cget in_sel -background]
2721 }
2722 unset i
2723
2724 # -- Diff and Commit Area
2725 #
2726 frame .vpane.lower -height 300 -width 400
2727 frame .vpane.lower.commarea
2728 frame .vpane.lower.diff -relief sunken -borderwidth 1
2729 pack .vpane.lower.diff -fill both -expand 1
2730 pack .vpane.lower.commarea -side bottom -fill x
2731 .vpane add .vpane.lower -sticky nsew
2732
2733 # -- Commit Area Buttons
2734 #
2735 frame .vpane.lower.commarea.buttons
2736 label .vpane.lower.commarea.buttons.l -text {} \
2737         -anchor w \
2738         -justify left
2739 pack .vpane.lower.commarea.buttons.l -side top -fill x
2740 pack .vpane.lower.commarea.buttons -side left -fill y
2741
2742 button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
2743         -command ui_do_rescan
2744 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
2745 lappend disable_on_lock \
2746         {.vpane.lower.commarea.buttons.rescan conf -state}
2747
2748 button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
2749         -command do_add_all
2750 pack .vpane.lower.commarea.buttons.incall -side top -fill x
2751 lappend disable_on_lock \
2752         {.vpane.lower.commarea.buttons.incall conf -state}
2753
2754 if {![is_enabled nocommitmsg]} {
2755         button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
2756                 -command do_signoff
2757         pack .vpane.lower.commarea.buttons.signoff -side top -fill x
2758 }
2759
2760 button .vpane.lower.commarea.buttons.commit -text [commit_btn_caption] \
2761         -command do_commit
2762 pack .vpane.lower.commarea.buttons.commit -side top -fill x
2763 lappend disable_on_lock \
2764         {.vpane.lower.commarea.buttons.commit conf -state}
2765
2766 if {![is_enabled nocommit]} {
2767         button .vpane.lower.commarea.buttons.push -text [mc Push] \
2768                 -command do_push_anywhere
2769         pack .vpane.lower.commarea.buttons.push -side top -fill x
2770 }
2771
2772 # -- Commit Message Buffer
2773 #
2774 frame .vpane.lower.commarea.buffer
2775 frame .vpane.lower.commarea.buffer.header
2776 set ui_comm .vpane.lower.commarea.buffer.t
2777 set ui_coml .vpane.lower.commarea.buffer.header.l
2778
2779 if {![is_enabled nocommit]} {
2780         radiobutton .vpane.lower.commarea.buffer.header.new \
2781                 -text [mc "New Commit"] \
2782                 -command do_select_commit_type \
2783                 -variable selected_commit_type \
2784                 -value new
2785         lappend disable_on_lock \
2786                 [list .vpane.lower.commarea.buffer.header.new conf -state]
2787         radiobutton .vpane.lower.commarea.buffer.header.amend \
2788                 -text [mc "Amend Last Commit"] \
2789                 -command do_select_commit_type \
2790                 -variable selected_commit_type \
2791                 -value amend
2792         lappend disable_on_lock \
2793                 [list .vpane.lower.commarea.buffer.header.amend conf -state]
2794 }
2795
2796 label $ui_coml \
2797         -anchor w \
2798         -justify left
2799 proc trace_commit_type {varname args} {
2800         global ui_coml commit_type
2801         switch -glob -- $commit_type {
2802         initial       {set txt [mc "Initial Commit Message:"]}
2803         amend         {set txt [mc "Amended Commit Message:"]}
2804         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
2805         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
2806         merge         {set txt [mc "Merge Commit Message:"]}
2807         *             {set txt [mc "Commit Message:"]}
2808         }
2809         $ui_coml conf -text $txt
2810 }
2811 trace add variable commit_type write trace_commit_type
2812 pack $ui_coml -side left -fill x
2813
2814 if {![is_enabled nocommit]} {
2815         pack .vpane.lower.commarea.buffer.header.amend -side right
2816         pack .vpane.lower.commarea.buffer.header.new -side right
2817 }
2818
2819 text $ui_comm -background white -foreground black \
2820         -borderwidth 1 \
2821         -undo true \
2822         -maxundo 20 \
2823         -autoseparators true \
2824         -relief sunken \
2825         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
2826         -font font_diff \
2827         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
2828 scrollbar .vpane.lower.commarea.buffer.sby \
2829         -command [list $ui_comm yview]
2830 pack .vpane.lower.commarea.buffer.header -side top -fill x
2831 pack .vpane.lower.commarea.buffer.sby -side right -fill y
2832 pack $ui_comm -side left -fill y
2833 pack .vpane.lower.commarea.buffer -side left -fill y
2834
2835 # -- Commit Message Buffer Context Menu
2836 #
2837 set ctxm .vpane.lower.commarea.buffer.ctxm
2838 menu $ctxm -tearoff 0
2839 $ctxm add command \
2840         -label [mc Cut] \
2841         -command {tk_textCut $ui_comm}
2842 $ctxm add command \
2843         -label [mc Copy] \
2844         -command {tk_textCopy $ui_comm}
2845 $ctxm add command \
2846         -label [mc Paste] \
2847         -command {tk_textPaste $ui_comm}
2848 $ctxm add command \
2849         -label [mc Delete] \
2850         -command {$ui_comm delete sel.first sel.last}
2851 $ctxm add separator
2852 $ctxm add command \
2853         -label [mc "Select All"] \
2854         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
2855 $ctxm add command \
2856         -label [mc "Copy All"] \
2857         -command {
2858                 $ui_comm tag add sel 0.0 end
2859                 tk_textCopy $ui_comm
2860                 $ui_comm tag remove sel 0.0 end
2861         }
2862 $ctxm add separator
2863 $ctxm add command \
2864         -label [mc "Sign Off"] \
2865         -command do_signoff
2866 set ui_comm_ctxm $ctxm
2867
2868 # -- Diff Header
2869 #
2870 proc trace_current_diff_path {varname args} {
2871         global current_diff_path diff_actions file_states
2872         if {$current_diff_path eq {}} {
2873                 set s {}
2874                 set f {}
2875                 set p {}
2876                 set o disabled
2877         } else {
2878                 set p $current_diff_path
2879                 set s [mapdesc [lindex $file_states($p) 0] $p]
2880                 set f [mc "File:"]
2881                 set p [escape_path $p]
2882                 set o normal
2883         }
2884
2885         .vpane.lower.diff.header.status configure -text $s
2886         .vpane.lower.diff.header.file configure -text $f
2887         .vpane.lower.diff.header.path configure -text $p
2888         foreach w $diff_actions {
2889                 uplevel #0 $w $o
2890         }
2891 }
2892 trace add variable current_diff_path write trace_current_diff_path
2893
2894 frame .vpane.lower.diff.header -background gold
2895 label .vpane.lower.diff.header.status \
2896         -background gold \
2897         -foreground black \
2898         -width $max_status_desc \
2899         -anchor w \
2900         -justify left
2901 label .vpane.lower.diff.header.file \
2902         -background gold \
2903         -foreground black \
2904         -anchor w \
2905         -justify left
2906 label .vpane.lower.diff.header.path \
2907         -background gold \
2908         -foreground black \
2909         -anchor w \
2910         -justify left
2911 pack .vpane.lower.diff.header.status -side left
2912 pack .vpane.lower.diff.header.file -side left
2913 pack .vpane.lower.diff.header.path -fill x
2914 set ctxm .vpane.lower.diff.header.ctxm
2915 menu $ctxm -tearoff 0
2916 $ctxm add command \
2917         -label [mc Copy] \
2918         -command {
2919                 clipboard clear
2920                 clipboard append \
2921                         -format STRING \
2922                         -type STRING \
2923                         -- $current_diff_path
2924         }
2925 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2926 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
2927
2928 # -- Diff Body
2929 #
2930 frame .vpane.lower.diff.body
2931 set ui_diff .vpane.lower.diff.body.t
2932 text $ui_diff -background white -foreground black \
2933         -borderwidth 0 \
2934         -width 80 -height 15 -wrap none \
2935         -font font_diff \
2936         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
2937         -yscrollcommand {.vpane.lower.diff.body.sby set} \
2938         -state disabled
2939 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
2940         -command [list $ui_diff xview]
2941 scrollbar .vpane.lower.diff.body.sby -orient vertical \
2942         -command [list $ui_diff yview]
2943 pack .vpane.lower.diff.body.sbx -side bottom -fill x
2944 pack .vpane.lower.diff.body.sby -side right -fill y
2945 pack $ui_diff -side left -fill both -expand 1
2946 pack .vpane.lower.diff.header -side top -fill x
2947 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
2948
2949 $ui_diff tag conf d_cr -elide true
2950 $ui_diff tag conf d_@ -foreground blue -font font_diffbold
2951 $ui_diff tag conf d_+ -foreground {#00a000}
2952 $ui_diff tag conf d_- -foreground red
2953
2954 $ui_diff tag conf d_++ -foreground {#00a000}
2955 $ui_diff tag conf d_-- -foreground red
2956 $ui_diff tag conf d_+s \
2957         -foreground {#00a000} \
2958         -background {#e2effa}
2959 $ui_diff tag conf d_-s \
2960         -foreground red \
2961         -background {#e2effa}
2962 $ui_diff tag conf d_s+ \
2963         -foreground {#00a000} \
2964         -background ivory1
2965 $ui_diff tag conf d_s- \
2966         -foreground red \
2967         -background ivory1
2968
2969 $ui_diff tag conf d<<<<<<< \
2970         -foreground orange \
2971         -font font_diffbold
2972 $ui_diff tag conf d======= \
2973         -foreground orange \
2974         -font font_diffbold
2975 $ui_diff tag conf d>>>>>>> \
2976         -foreground orange \
2977         -font font_diffbold
2978
2979 $ui_diff tag raise sel
2980
2981 # -- Diff Body Context Menu
2982 #
2983
2984 proc create_common_diff_popup {ctxm} {
2985         $ctxm add command \
2986                 -label [mc "Show Less Context"] \
2987                 -command show_less_context
2988         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2989         $ctxm add command \
2990                 -label [mc "Show More Context"] \
2991                 -command show_more_context
2992         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2993         $ctxm add separator
2994         $ctxm add command \
2995                 -label [mc Refresh] \
2996                 -command reshow_diff
2997         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2998         $ctxm add command \
2999                 -label [mc Copy] \
3000                 -command {tk_textCopy $ui_diff}
3001         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3002         $ctxm add command \
3003                 -label [mc "Select All"] \
3004                 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
3005         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3006         $ctxm add command \
3007                 -label [mc "Copy All"] \
3008                 -command {
3009                         $ui_diff tag add sel 0.0 end
3010                         tk_textCopy $ui_diff
3011                         $ui_diff tag remove sel 0.0 end
3012                 }
3013         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3014         $ctxm add separator
3015         $ctxm add command \
3016                 -label [mc "Decrease Font Size"] \
3017                 -command {incr_font_size font_diff -1}
3018         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3019         $ctxm add command \
3020                 -label [mc "Increase Font Size"] \
3021                 -command {incr_font_size font_diff 1}
3022         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3023         $ctxm add separator
3024         set emenu $ctxm.enc
3025         menu $emenu
3026         build_encoding_menu $emenu [list force_diff_encoding]
3027         $ctxm add cascade \
3028                 -label [mc "Encoding"] \
3029                 -menu $emenu
3030         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3031         $ctxm add separator
3032         $ctxm add command -label [mc "Options..."] \
3033                 -command do_options
3034 }
3035
3036 set ctxm .vpane.lower.diff.body.ctxm
3037 menu $ctxm -tearoff 0
3038 $ctxm add command \
3039         -label [mc "Apply/Reverse Hunk"] \
3040         -command {apply_hunk $cursorX $cursorY}
3041 set ui_diff_applyhunk [$ctxm index last]
3042 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
3043 $ctxm add command \
3044         -label [mc "Apply/Reverse Line"] \
3045         -command {apply_line $cursorX $cursorY; do_rescan}
3046 set ui_diff_applyline [$ctxm index last]
3047 lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
3048 $ctxm add separator
3049 create_common_diff_popup $ctxm
3050
3051 set ctxmmg .vpane.lower.diff.body.ctxmmg
3052 menu $ctxmmg -tearoff 0
3053 $ctxmmg add command \
3054         -label [mc "Run Merge Tool"] \
3055         -command {merge_resolve_tool}
3056 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3057 $ctxmmg add separator
3058 $ctxmmg add command \
3059         -label [mc "Use Remote Version"] \
3060         -command {merge_resolve_one 3}
3061 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3062 $ctxmmg add command \
3063         -label [mc "Use Local Version"] \
3064         -command {merge_resolve_one 2}
3065 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3066 $ctxmmg add command \
3067         -label [mc "Revert To Base"] \
3068         -command {merge_resolve_one 1}
3069 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3070 $ctxmmg add separator
3071 create_common_diff_popup $ctxmmg
3072
3073 proc popup_diff_menu {ctxm ctxmmg x y X Y} {
3074         global current_diff_path file_states
3075         set ::cursorX $x
3076         set ::cursorY $y
3077         if {[info exists file_states($current_diff_path)]} {
3078                 set state [lindex $file_states($current_diff_path) 0]
3079         } else {
3080                 set state {__}
3081         }
3082         if {[string first {U} $state] >= 0} {
3083                 tk_popup $ctxmmg $X $Y
3084         } else {
3085                 if {$::ui_index eq $::current_diff_side} {
3086                         set l [mc "Unstage Hunk From Commit"]
3087                         set t [mc "Unstage Line From Commit"]
3088                 } else {
3089                         set l [mc "Stage Hunk For Commit"]
3090                         set t [mc "Stage Line For Commit"]
3091                 }
3092                 if {$::is_3way_diff
3093                         || $current_diff_path eq {}
3094                         || {__} eq $state
3095                         || {_O} eq $state
3096                         || {_T} eq $state
3097                         || {T_} eq $state} {
3098                         set s disabled
3099                 } else {
3100                         set s normal
3101                 }
3102                 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
3103                 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
3104                 tk_popup $ctxm $X $Y
3105         }
3106 }
3107 bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg %x %y %X %Y]
3108
3109 # -- Status Bar
3110 #
3111 set main_status [::status_bar::new .status]
3112 pack .status -anchor w -side bottom -fill x
3113 $main_status show [mc "Initializing..."]
3114
3115 # -- Load geometry
3116 #
3117 catch {
3118 set gm $repo_config(gui.geometry)
3119 wm geometry . [lindex $gm 0]
3120 .vpane sash place 0 \
3121         [lindex $gm 1] \
3122         [lindex [.vpane sash coord 0] 1]
3123 .vpane.files sash place 0 \
3124         [lindex [.vpane.files sash coord 0] 0] \
3125         [lindex $gm 2]
3126 unset gm
3127 }
3128
3129 # -- Key Bindings
3130 #
3131 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3132 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
3133 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
3134 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3135 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3136 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3137 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3138 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3139 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3140 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3141 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3142 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3143 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3144 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
3145 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
3146 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
3147 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
3148 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
3149
3150 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3151 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3152 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3153 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3154 bind $ui_diff <$M1B-Key-v> {break}
3155 bind $ui_diff <$M1B-Key-V> {break}
3156 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3157 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3158 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3159 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3160 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3161 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3162 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
3163 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
3164 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
3165 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
3166 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
3167 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
3168 bind $ui_diff <Button-1>   {focus %W}
3169
3170 if {[is_enabled branch]} {
3171         bind . <$M1B-Key-n> branch_create::dialog
3172         bind . <$M1B-Key-N> branch_create::dialog
3173         bind . <$M1B-Key-o> branch_checkout::dialog
3174         bind . <$M1B-Key-O> branch_checkout::dialog
3175         bind . <$M1B-Key-m> merge::dialog
3176         bind . <$M1B-Key-M> merge::dialog
3177 }
3178 if {[is_enabled transport]} {
3179         bind . <$M1B-Key-p> do_push_anywhere
3180         bind . <$M1B-Key-P> do_push_anywhere
3181 }
3182
3183 bind .   <Key-F5>     ui_do_rescan
3184 bind .   <$M1B-Key-r> ui_do_rescan
3185 bind .   <$M1B-Key-R> ui_do_rescan
3186 bind .   <$M1B-Key-s> do_signoff
3187 bind .   <$M1B-Key-S> do_signoff
3188 bind .   <$M1B-Key-t> do_add_selection
3189 bind .   <$M1B-Key-T> do_add_selection
3190 bind .   <$M1B-Key-i> do_add_all
3191 bind .   <$M1B-Key-I> do_add_all
3192 bind .   <$M1B-Key-minus> {show_less_context;break}
3193 bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
3194 bind .   <$M1B-Key-equal> {show_more_context;break}
3195 bind .   <$M1B-Key-plus> {show_more_context;break}
3196 bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3197 bind .   <$M1B-Key-Return> do_commit
3198 foreach i [list $ui_index $ui_workdir] {
3199         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3200         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3201         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3202 }
3203 unset i
3204
3205 set file_lists($ui_index) [list]
3206 set file_lists($ui_workdir) [list]
3207
3208 wm title . "[appname] ([reponame]) [file normalize [file dirname [gitdir]]]"
3209 focus -force $ui_comm
3210
3211 # -- Warn the user about environmental problems.  Cygwin's Tcl
3212 #    does *not* pass its env array onto any processes it spawns.
3213 #    This means that git processes get none of our environment.
3214 #
3215 if {[is_Cygwin]} {
3216         set ignored_env 0
3217         set suggest_user {}
3218         set msg [mc "Possible environment issues exist.
3219
3220 The following environment variables are probably
3221 going to be ignored by any Git subprocess run
3222 by %s:
3223
3224 " [appname]]
3225         foreach name [array names env] {
3226                 switch -regexp -- $name {
3227                 {^GIT_INDEX_FILE$} -
3228                 {^GIT_OBJECT_DIRECTORY$} -
3229                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3230                 {^GIT_DIFF_OPTS$} -
3231                 {^GIT_EXTERNAL_DIFF$} -
3232                 {^GIT_PAGER$} -
3233                 {^GIT_TRACE$} -
3234                 {^GIT_CONFIG$} -
3235                 {^GIT_CONFIG_LOCAL$} -
3236                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3237                         append msg " - $name\n"
3238                         incr ignored_env
3239                 }
3240                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3241                         append msg " - $name\n"
3242                         incr ignored_env
3243                         set suggest_user $name
3244                 }
3245                 }
3246         }
3247         if {$ignored_env > 0} {
3248                 append msg [mc "
3249 This is due to a known issue with the
3250 Tcl binary distributed by Cygwin."]
3251
3252                 if {$suggest_user ne {}} {
3253                         append msg [mc "
3254
3255 A good replacement for %s
3256 is placing values for the user.name and
3257 user.email settings into your personal
3258 ~/.gitconfig file.
3259 " $suggest_user]
3260                 }
3261                 warn_popup $msg
3262         }
3263         unset ignored_env msg suggest_user name
3264 }
3265
3266 # -- Only initialize complex UI if we are going to stay running.
3267 #
3268 if {[is_enabled transport]} {
3269         load_all_remotes
3270
3271         set n [.mbar.remote index end]
3272         populate_remotes_menu
3273         set n [expr {[.mbar.remote index end] - $n}]
3274         if {$n > 0} {
3275                 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3276                 .mbar.remote insert $n separator
3277         }
3278         unset n
3279 }
3280
3281 if {[winfo exists $ui_comm]} {
3282         set GITGUI_BCK_exists [load_message GITGUI_BCK]
3283
3284         # -- If both our backup and message files exist use the
3285         #    newer of the two files to initialize the buffer.
3286         #
3287         if {$GITGUI_BCK_exists} {
3288                 set m [gitdir GITGUI_MSG]
3289                 if {[file isfile $m]} {
3290                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3291                                 catch {file delete [gitdir GITGUI_MSG]}
3292                         } else {
3293                                 $ui_comm delete 0.0 end
3294                                 $ui_comm edit reset
3295                                 $ui_comm edit modified false
3296                                 catch {file delete [gitdir GITGUI_BCK]}
3297                                 set GITGUI_BCK_exists 0
3298                         }
3299                 }
3300                 unset m
3301         }
3302
3303         proc backup_commit_buffer {} {
3304                 global ui_comm GITGUI_BCK_exists
3305
3306                 set m [$ui_comm edit modified]
3307                 if {$m || $GITGUI_BCK_exists} {
3308                         set msg [string trim [$ui_comm get 0.0 end]]
3309                         regsub -all -line {[ \r\t]+$} $msg {} msg
3310
3311                         if {$msg eq {}} {
3312                                 if {$GITGUI_BCK_exists} {
3313                                         catch {file delete [gitdir GITGUI_BCK]}
3314                                         set GITGUI_BCK_exists 0
3315                                 }
3316                         } elseif {$m} {
3317                                 catch {
3318                                         set fd [open [gitdir GITGUI_BCK] w]
3319                                         puts -nonewline $fd $msg
3320                                         close $fd
3321                                         set GITGUI_BCK_exists 1
3322                                 }
3323                         }
3324
3325                         $ui_comm edit modified false
3326                 }
3327
3328                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3329         }
3330
3331         backup_commit_buffer
3332
3333         # -- If the user has aspell available we can drive it
3334         #    in pipe mode to spellcheck the commit message.
3335         #
3336         set spell_cmd [list |]
3337         set spell_dict [get_config gui.spellingdictionary]
3338         lappend spell_cmd aspell
3339         if {$spell_dict ne {}} {
3340                 lappend spell_cmd --master=$spell_dict
3341         }
3342         lappend spell_cmd --mode=none
3343         lappend spell_cmd --encoding=utf-8
3344         lappend spell_cmd pipe
3345         if {$spell_dict eq {none}
3346          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3347                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3348         } else {
3349                 set ui_comm_spell [spellcheck::init \
3350                         $spell_fd \
3351                         $ui_comm \
3352                         $ui_comm_ctxm \
3353                 ]
3354         }
3355         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
3356 }
3357
3358 lock_index begin-read
3359 if {![winfo ismapped .]} {
3360         wm deiconify .
3361 }
3362 after 1 {
3363         if {[is_enabled initialamend]} {
3364                 force_amend
3365         } else {
3366                 do_rescan
3367         }
3368
3369         if {[is_enabled nocommitmsg]} {
3370                 $ui_comm configure -state disabled -background gray
3371         }
3372 }
3373 if {[is_enabled multicommit]} {
3374         after 1000 hint_gc
3375 }
3376 if {[is_enabled retcode]} {
3377         bind . <Destroy> {+terminate_me %W}
3378 }