git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  exec wish "$0" -- "$@"
  10
  11 set appvers {@@GITGUI_VERSION@@}
  12 set copyright {
  13 Copyright © 2006, 2007 Shawn Pearce, et. al.
  14
  15 This program is free software; you can redistribute it and/or modify
  16 it under the terms of the GNU General Public License as published by
  17 the Free Software Foundation; either version 2 of the License, or
  18 (at your option) any later version.
  19
  20 This program is distributed in the hope that it will be useful,
  21 but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 GNU General Public License for more details.
  24
  25 You should have received a copy of the GNU General Public License
  26 along with this program; if not, write to the Free Software
  27 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}
  28
  29 ######################################################################
  30 ##
  31 ## Tcl/Tk sanity check
  32
  33 if {[catch {package require Tcl 8.4} err]
  34  || [catch {package require Tk  8.4} err]
  35 } {
  36         catch {wm withdraw .}
  37         tk_messageBox \
  38                 -icon error \
  39                 -type ok \
  40                 -title "git-gui: fatal error" \
  41                 -message $err
  42         exit 1
  43 }
  44
  45 ######################################################################
  46 ##
  47 ## enable verbose loading?
  48
  49 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  50         unset _verbose
  51         rename auto_load real__auto_load
  52         proc auto_load {name args} {
  53                 puts stderr "auto_load $name"
  54                 return [uplevel 1 real__auto_load $name $args]
  55         }
  56         rename source real__source
  57         proc source {name} {
  58                 puts stderr "source    $name"
  59                 uplevel 1 real__source $name
  60         }
  61 }
  62
  63 ######################################################################
  64 ##
  65 ## configure our library
  66
  67 set oguilib {@@GITGUI_LIBDIR@@}
  68 set oguirel {@@GITGUI_RELATIVE@@}
  69 if {$oguirel eq {1}} {
  70         set oguilib [file dirname [file dirname [file normalize $argv0]]]
  71         set oguilib [file join $oguilib share git-gui lib]
  72 } elseif {[string match @@* $oguirel]} {
  73         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  74 }
  75
  76 set idx [file join $oguilib tclIndex]
  77 if {[catch {set fd [open $idx r]} err]} {
  78         catch {wm withdraw .}
  79         tk_messageBox \
  80                 -icon error \
  81                 -type ok \
  82                 -title "git-gui: fatal error" \
  83                 -message $err
  84         exit 1
  85 }
  86 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
  87         set idx [list]
  88         while {[gets $fd n] >= 0} {
  89                 if {$n ne {} && ![string match #* $n]} {
  90                         lappend idx $n
  91                 }
  92         }
  93 } else {
  94         set idx {}
  95 }
  96 close $fd
  97
  98 if {$idx ne {}} {
  99         set loaded [list]
 100         foreach p $idx {
 101                 if {[lsearch -exact $loaded $p] >= 0} continue
 102                 source [file join $oguilib $p]
 103                 lappend loaded $p
 104         }
 105         unset loaded p
 106 } else {
 107         set auto_path [concat [list $oguilib] $auto_path]
 108 }
 109 unset -nocomplain oguirel idx fd
 110
 111 ######################################################################
 112 ##
 113 ## read only globals
 114
 115 set _appname [lindex [file split $argv0] end]
 116 set _gitdir {}
 117 set _gitexec {}
 118 set _reponame {}
 119 set _iscygwin {}
 120
 121 proc appname {} {
 122         global _appname
 123         return $_appname
 124 }
 125
 126 proc gitdir {args} {
 127         global _gitdir
 128         if {$args eq {}} {
 129                 return $_gitdir
 130         }
 131         return [eval [concat [list file join $_gitdir] $args]]
 132 }
 133
 134 proc gitexec {args} {
 135         global _gitexec
 136         if {$_gitexec eq {}} {
 137                 if {[catch {set _gitexec [git --exec-path]} err]} {
 138                         error "Git not installed?\n\n$err"
 139                 }
 140         }
 141         if {$args eq {}} {
 142                 return $_gitexec
 143         }
 144         return [eval [concat [list file join $_gitexec] $args]]
 145 }
 146
 147 proc reponame {} {
 148         global _reponame
 149         return $_reponame
 150 }
 151
 152 proc is_MacOSX {} {
 153         global tcl_platform tk_library
 154         if {[tk windowingsystem] eq {aqua}} {
 155                 return 1
 156         }
 157         return 0
 158 }
 159
 160 proc is_Windows {} {
 161         global tcl_platform
 162         if {$tcl_platform(platform) eq {windows}} {
 163                 return 1
 164         }
 165         return 0
 166 }
 167
 168 proc is_Cygwin {} {
 169         global tcl_platform _iscygwin
 170         if {$_iscygwin eq {}} {
 171                 if {$tcl_platform(platform) eq {windows}} {
 172                         if {[catch {set p [exec cygpath --windir]} err]} {
 173                                 set _iscygwin 0
 174                         } else {
 175                                 set _iscygwin 1
 176                         }
 177                 } else {
 178                         set _iscygwin 0
 179                 }
 180         }
 181         return $_iscygwin
 182 }
 183
 184 proc is_enabled {option} {
 185         global enabled_options
 186         if {[catch {set on $enabled_options($option)}]} {return 0}
 187         return $on
 188 }
 189
 190 proc enable_option {option} {
 191         global enabled_options
 192         set enabled_options($option) 1
 193 }
 194
 195 proc disable_option {option} {
 196         global enabled_options
 197         set enabled_options($option) 0
 198 }
 199
 200 ######################################################################
 201 ##
 202 ## config
 203
 204 proc is_many_config {name} {
 205         switch -glob -- $name {
 206         remote.*.fetch -
 207         remote.*.push
 208                 {return 1}
 209         *
 210                 {return 0}
 211         }
 212 }
 213
 214 proc is_config_true {name} {
 215         global repo_config
 216         if {[catch {set v $repo_config($name)}]} {
 217                 return 0
 218         } elseif {$v eq {true} || $v eq {1} || $v eq {yes}} {
 219                 return 1
 220         } else {
 221                 return 0
 222         }
 223 }
 224
 225 proc get_config {name} {
 226         global repo_config
 227         if {[catch {set v $repo_config($name)}]} {
 228                 return {}
 229         } else {
 230                 return $v
 231         }
 232 }
 233
 234 proc load_config {include_global} {
 235         global repo_config global_config default_config
 236
 237         array unset global_config
 238         if {$include_global} {
 239                 catch {
 240                         set fd_rc [open "| git config --global --list" r]
 241                         while {[gets $fd_rc line] >= 0} {
 242                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 243                                         if {[is_many_config $name]} {
 244                                                 lappend global_config($name) $value
 245                                         } else {
 246                                                 set global_config($name) $value
 247                                         }
 248                                 }
 249                         }
 250                         close $fd_rc
 251                 }
 252         }
 253
 254         array unset repo_config
 255         catch {
 256                 set fd_rc [open "| git config --list" r]
 257                 while {[gets $fd_rc line] >= 0} {
 258                         if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 259                                 if {[is_many_config $name]} {
 260                                         lappend repo_config($name) $value
 261                                 } else {
 262                                         set repo_config($name) $value
 263                                 }
 264                         }
 265                 }
 266                 close $fd_rc
 267         }
 268
 269         foreach name [array names default_config] {
 270                 if {[catch {set v $global_config($name)}]} {
 271                         set global_config($name) $default_config($name)
 272                 }
 273                 if {[catch {set v $repo_config($name)}]} {
 274                         set repo_config($name) $default_config($name)
 275                 }
 276         }
 277 }
 278
 279 ######################################################################
 280 ##
 281 ## handy utils
 282
 283 proc git {args} {
 284         return [eval exec git $args]
 285 }
 286
 287 proc current-branch {} {
 288         set fd [open [gitdir HEAD] r]
 289         if {[gets $fd ref] < 1} {
 290                 set ref {}
 291         }
 292         close $fd
 293
 294         set pfx {ref: refs/heads/}
 295         set len [string length $pfx]
 296         if {[string equal -length $len $pfx $ref]} {
 297                 # We're on a branch.  It might not exist.  But
 298                 # HEAD looks good enough to be a branch.
 299                 #
 300                 return [string range $ref $len end]
 301         } else {
 302                 # Assume this is a detached head.
 303                 #
 304                 return HEAD
 305         }
 306 }
 307
 308 auto_load tk_optionMenu
 309 rename tk_optionMenu real__tkOptionMenu
 310 proc tk_optionMenu {w varName args} {
 311         set m [eval real__tkOptionMenu $w $varName $args]
 312         $m configure -font font_ui
 313         $w configure -font font_ui
 314         return $m
 315 }
 316
 317 ######################################################################
 318 ##
 319 ## version check
 320
 321 if {[catch {set _git_version [git --version]} err]} {
 322         catch {wm withdraw .}
 323         error_popup "Cannot determine Git version:
 324
 325 $err
 326
 327 [appname] requires Git 1.5.0 or later."
 328         exit 1
 329 }
 330 if {![regsub {^git version } $_git_version {} _git_version]} {
 331         catch {wm withdraw .}
 332         error_popup "Cannot parse Git version string:\n\n$_git_version"
 333         exit 1
 334 }
 335 regsub {\.[0-9]+\.g[0-9a-f]+$} $_git_version {} _git_version
 336 regsub {\.rc[0-9]+$} $_git_version {} _git_version
 337
 338 proc git-version {args} {
 339         global _git_version
 340
 341         switch [llength $args] {
 342         0 {
 343                 return $_git_version
 344         }
 345
 346         2 {
 347                 set op [lindex $args 0]
 348                 set vr [lindex $args 1]
 349                 set cm [package vcompare $_git_version $vr]
 350                 return [expr $cm $op 0]
 351         }
 352
 353         4 {
 354                 set type [lindex $args 0]
 355                 set name [lindex $args 1]
 356                 set parm [lindex $args 2]
 357                 set body [lindex $args 3]
 358
 359                 if {($type ne {proc} && $type ne {method})} {
 360                         error "Invalid arguments to git-version"
 361                 }
 362                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
 363                         error "Last arm of $type $name must be default"
 364                 }
 365
 366                 foreach {op vr cb} [lrange $body 0 end-2] {
 367                         if {[git-version $op $vr]} {
 368                                 return [uplevel [list $type $name $parm $cb]]
 369                         }
 370                 }
 371
 372                 return [uplevel [list $type $name $parm [lindex $body end]]]
 373         }
 374
 375         default {
 376                 error "git-version >= x"
 377         }
 378
 379         }
 380 }
 381
 382 if {[git-version < 1.5]} {
 383         catch {wm withdraw .}
 384         error_popup "[appname] requires Git 1.5.0 or later.
 385
 386 You are using [git-version]:
 387
 388 [git --version]"
 389         exit 1
 390 }
 391
 392 ######################################################################
 393 ##
 394 ## repository setup
 395
 396 if {[catch {
 397                 set _gitdir $env(GIT_DIR)
 398                 set _prefix {}
 399                 }]
 400         && [catch {
 401                 set _gitdir [git rev-parse --git-dir]
 402                 set _prefix [git rev-parse --show-prefix]
 403         } err]} {
 404         catch {wm withdraw .}
 405         error_popup "Cannot find the git directory:\n\n$err"
 406         exit 1
 407 }
 408 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
 409         catch {set _gitdir [exec cygpath --unix $_gitdir]}
 410 }
 411 if {![file isdirectory $_gitdir]} {
 412         catch {wm withdraw .}
 413         error_popup "Git directory not found:\n\n$_gitdir"
 414         exit 1
 415 }
 416 if {[lindex [file split $_gitdir] end] ne {.git}} {
 417         catch {wm withdraw .}
 418         error_popup "Cannot use funny .git directory:\n\n$_gitdir"
 419         exit 1
 420 }
 421 if {[catch {cd [file dirname $_gitdir]} err]} {
 422         catch {wm withdraw .}
 423         error_popup "No working directory [file dirname $_gitdir]:\n\n$err"
 424         exit 1
 425 }
 426 set _reponame [lindex [file split \
 427         [file normalize [file dirname $_gitdir]]] \
 428         end]
 429
 430 ######################################################################
 431 ##
 432 ## global init
 433
 434 set current_diff_path {}
 435 set current_diff_side {}
 436 set diff_actions [list]
 437 set ui_status_value {Initializing...}
 438
 439 set HEAD {}
 440 set PARENT {}
 441 set MERGE_HEAD [list]
 442 set commit_type {}
 443 set empty_tree {}
 444 set current_branch {}
 445 set current_diff_path {}
 446 set selected_commit_type new
 447
 448 ######################################################################
 449 ##
 450 ## task management
 451
 452 set rescan_active 0
 453 set diff_active 0
 454 set last_clicked {}
 455
 456 set disable_on_lock [list]
 457 set index_lock_type none
 458
 459 proc lock_index {type} {
 460         global index_lock_type disable_on_lock
 461
 462         if {$index_lock_type eq {none}} {
 463                 set index_lock_type $type
 464                 foreach w $disable_on_lock {
 465                         uplevel #0 $w disabled
 466                 }
 467                 return 1
 468         } elseif {$index_lock_type eq "begin-$type"} {
 469                 set index_lock_type $type
 470                 return 1
 471         }
 472         return 0
 473 }
 474
 475 proc unlock_index {} {
 476         global index_lock_type disable_on_lock
 477
 478         set index_lock_type none
 479         foreach w $disable_on_lock {
 480                 uplevel #0 $w normal
 481         }
 482 }
 483
 484 ######################################################################
 485 ##
 486 ## status
 487
 488 proc repository_state {ctvar hdvar mhvar} {
 489         global current_branch
 490         upvar $ctvar ct $hdvar hd $mhvar mh
 491
 492         set mh [list]
 493
 494         set current_branch [current-branch]
 495         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
 496                 set hd {}
 497                 set ct initial
 498                 return
 499         }
 500
 501         set merge_head [gitdir MERGE_HEAD]
 502         if {[file exists $merge_head]} {
 503                 set ct merge
 504                 set fd_mh [open $merge_head r]
 505                 while {[gets $fd_mh line] >= 0} {
 506                         lappend mh $line
 507                 }
 508                 close $fd_mh
 509                 return
 510         }
 511
 512         set ct normal
 513 }
 514
 515 proc PARENT {} {
 516         global PARENT empty_tree
 517
 518         set p [lindex $PARENT 0]
 519         if {$p ne {}} {
 520                 return $p
 521         }
 522         if {$empty_tree eq {}} {
 523                 set empty_tree [git mktree << {}]
 524         }
 525         return $empty_tree
 526 }
 527
 528 proc rescan {after {honor_trustmtime 1}} {
 529         global HEAD PARENT MERGE_HEAD commit_type
 530         global ui_index ui_workdir ui_status_value ui_comm
 531         global rescan_active file_states
 532         global repo_config
 533
 534         if {$rescan_active > 0 || ![lock_index read]} return
 535
 536         repository_state newType newHEAD newMERGE_HEAD
 537         if {[string match amend* $commit_type]
 538                 && $newType eq {normal}
 539                 && $newHEAD eq $HEAD} {
 540         } else {
 541                 set HEAD $newHEAD
 542                 set PARENT $newHEAD
 543                 set MERGE_HEAD $newMERGE_HEAD
 544                 set commit_type $newType
 545         }
 546
 547         array unset file_states
 548
 549         if {![$ui_comm edit modified]
 550                 || [string trim [$ui_comm get 0.0 end]] eq {}} {
 551                 if {[string match amend* $commit_type]} {
 552                 } elseif {[load_message GITGUI_MSG]} {
 553                 } elseif {[load_message MERGE_MSG]} {
 554                 } elseif {[load_message SQUASH_MSG]} {
 555                 }
 556                 $ui_comm edit reset
 557                 $ui_comm edit modified false
 558         }
 559
 560         if {[is_enabled branch]} {
 561                 load_all_heads
 562                 populate_branch_menu
 563         }
 564
 565         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
 566                 rescan_stage2 {} $after
 567         } else {
 568                 set rescan_active 1
 569                 set ui_status_value {Refreshing file status...}
 570                 set cmd [list git update-index]
 571                 lappend cmd -q
 572                 lappend cmd --unmerged
 573                 lappend cmd --ignore-missing
 574                 lappend cmd --refresh
 575                 set fd_rf [open "| $cmd" r]
 576                 fconfigure $fd_rf -blocking 0 -translation binary
 577                 fileevent $fd_rf readable \
 578                         [list rescan_stage2 $fd_rf $after]
 579         }
 580 }
 581
 582 proc rescan_stage2 {fd after} {
 583         global ui_status_value
 584         global rescan_active buf_rdi buf_rdf buf_rlo
 585
 586         if {$fd ne {}} {
 587                 read $fd
 588                 if {![eof $fd]} return
 589                 close $fd
 590         }
 591
 592         set ls_others [list | git ls-files --others -z \
 593                 --exclude-per-directory=.gitignore]
 594         set info_exclude [gitdir info exclude]
 595         if {[file readable $info_exclude]} {
 596                 lappend ls_others "--exclude-from=$info_exclude"
 597         }
 598
 599         set buf_rdi {}
 600         set buf_rdf {}
 601         set buf_rlo {}
 602
 603         set rescan_active 3
 604         set ui_status_value {Scanning for modified files ...}
 605         set fd_di [open "| git diff-index --cached -z [PARENT]" r]
 606         set fd_df [open "| git diff-files -z" r]
 607         set fd_lo [open $ls_others r]
 608
 609         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
 610         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
 611         fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
 612         fileevent $fd_di readable [list read_diff_index $fd_di $after]
 613         fileevent $fd_df readable [list read_diff_files $fd_df $after]
 614         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
 615 }
 616
 617 proc load_message {file} {
 618         global ui_comm
 619
 620         set f [gitdir $file]
 621         if {[file isfile $f]} {
 622                 if {[catch {set fd [open $f r]}]} {
 623                         return 0
 624                 }
 625                 set content [string trim [read $fd]]
 626                 close $fd
 627                 regsub -all -line {[ \r\t]+$} $content {} content
 628                 $ui_comm delete 0.0 end
 629                 $ui_comm insert end $content
 630                 return 1
 631         }
 632         return 0
 633 }
 634
 635 proc read_diff_index {fd after} {
 636         global buf_rdi
 637
 638         append buf_rdi [read $fd]
 639         set c 0
 640         set n [string length $buf_rdi]
 641         while {$c < $n} {
 642                 set z1 [string first "\0" $buf_rdi $c]
 643                 if {$z1 == -1} break
 644                 incr z1
 645                 set z2 [string first "\0" $buf_rdi $z1]
 646                 if {$z2 == -1} break
 647
 648                 incr c
 649                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
 650                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
 651                 merge_state \
 652                         [encoding convertfrom $p] \
 653                         [lindex $i 4]? \
 654                         [list [lindex $i 0] [lindex $i 2]] \
 655                         [list]
 656                 set c $z2
 657                 incr c
 658         }
 659         if {$c < $n} {
 660                 set buf_rdi [string range $buf_rdi $c end]
 661         } else {
 662                 set buf_rdi {}
 663         }
 664
 665         rescan_done $fd buf_rdi $after
 666 }
 667
 668 proc read_diff_files {fd after} {
 669         global buf_rdf
 670
 671         append buf_rdf [read $fd]
 672         set c 0
 673         set n [string length $buf_rdf]
 674         while {$c < $n} {
 675                 set z1 [string first "\0" $buf_rdf $c]
 676                 if {$z1 == -1} break
 677                 incr z1
 678                 set z2 [string first "\0" $buf_rdf $z1]
 679                 if {$z2 == -1} break
 680
 681                 incr c
 682                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
 683                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
 684                 merge_state \
 685                         [encoding convertfrom $p] \
 686                         ?[lindex $i 4] \
 687                         [list] \
 688                         [list [lindex $i 0] [lindex $i 2]]
 689                 set c $z2
 690                 incr c
 691         }
 692         if {$c < $n} {
 693                 set buf_rdf [string range $buf_rdf $c end]
 694         } else {
 695                 set buf_rdf {}
 696         }
 697
 698         rescan_done $fd buf_rdf $after
 699 }
 700
 701 proc read_ls_others {fd after} {
 702         global buf_rlo
 703
 704         append buf_rlo [read $fd]
 705         set pck [split $buf_rlo "\0"]
 706         set buf_rlo [lindex $pck end]
 707         foreach p [lrange $pck 0 end-1] {
 708                 merge_state [encoding convertfrom $p] ?O
 709         }
 710         rescan_done $fd buf_rlo $after
 711 }
 712
 713 proc rescan_done {fd buf after} {
 714         global rescan_active current_diff_path
 715         global file_states repo_config
 716         upvar $buf to_clear
 717
 718         if {![eof $fd]} return
 719         set to_clear {}
 720         close $fd
 721         if {[incr rescan_active -1] > 0} return
 722
 723         prune_selection
 724         unlock_index
 725         display_all_files
 726         if {$current_diff_path ne {}} reshow_diff
 727         uplevel #0 $after
 728 }
 729
 730 proc prune_selection {} {
 731         global file_states selected_paths
 732
 733         foreach path [array names selected_paths] {
 734                 if {[catch {set still_here $file_states($path)}]} {
 735                         unset selected_paths($path)
 736                 }
 737         }
 738 }
 739
 740 ######################################################################
 741 ##
 742 ## ui helpers
 743
 744 proc mapicon {w state path} {
 745         global all_icons
 746
 747         if {[catch {set r $all_icons($state$w)}]} {
 748                 puts "error: no icon for $w state={$state} $path"
 749                 return file_plain
 750         }
 751         return $r
 752 }
 753
 754 proc mapdesc {state path} {
 755         global all_descs
 756
 757         if {[catch {set r $all_descs($state)}]} {
 758                 puts "error: no desc for state={$state} $path"
 759                 return $state
 760         }
 761         return $r
 762 }
 763
 764 proc escape_path {path} {
 765         regsub -all {\\} $path "\\\\" path
 766         regsub -all "\n" $path "\\n" path
 767         return $path
 768 }
 769
 770 proc short_path {path} {
 771         return [escape_path [lindex [file split $path] end]]
 772 }
 773
 774 set next_icon_id 0
 775 set null_sha1 [string repeat 0 40]
 776
 777 proc merge_state {path new_state {head_info {}} {index_info {}}} {
 778         global file_states next_icon_id null_sha1
 779
 780         set s0 [string index $new_state 0]
 781         set s1 [string index $new_state 1]
 782
 783         if {[catch {set info $file_states($path)}]} {
 784                 set state __
 785                 set icon n[incr next_icon_id]
 786         } else {
 787                 set state [lindex $info 0]
 788                 set icon [lindex $info 1]
 789                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
 790                 if {$index_info eq {}} {set index_info [lindex $info 3]}
 791         }
 792
 793         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
 794         elseif {$s0 eq {_}} {set s0 _}
 795
 796         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
 797         elseif {$s1 eq {_}} {set s1 _}
 798
 799         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
 800                 set head_info [list 0 $null_sha1]
 801         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
 802                 && $head_info eq {}} {
 803                 set head_info $index_info
 804         }
 805
 806         set file_states($path) [list $s0$s1 $icon \
 807                 $head_info $index_info \
 808                 ]
 809         return $state
 810 }
 811
 812 proc display_file_helper {w path icon_name old_m new_m} {
 813         global file_lists
 814
 815         if {$new_m eq {_}} {
 816                 set lno [lsearch -sorted -exact $file_lists($w) $path]
 817                 if {$lno >= 0} {
 818                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
 819                         incr lno
 820                         $w conf -state normal
 821                         $w delete $lno.0 [expr {$lno + 1}].0
 822                         $w conf -state disabled
 823                 }
 824         } elseif {$old_m eq {_} && $new_m ne {_}} {
 825                 lappend file_lists($w) $path
 826                 set file_lists($w) [lsort -unique $file_lists($w)]
 827                 set lno [lsearch -sorted -exact $file_lists($w) $path]
 828                 incr lno
 829                 $w conf -state normal
 830                 $w image create $lno.0 \
 831                         -align center -padx 5 -pady 1 \
 832                         -name $icon_name \
 833                         -image [mapicon $w $new_m $path]
 834                 $w insert $lno.1 "[escape_path $path]\n"
 835                 $w conf -state disabled
 836         } elseif {$old_m ne $new_m} {
 837                 $w conf -state normal
 838                 $w image conf $icon_name -image [mapicon $w $new_m $path]
 839                 $w conf -state disabled
 840         }
 841 }
 842
 843 proc display_file {path state} {
 844         global file_states selected_paths
 845         global ui_index ui_workdir
 846
 847         set old_m [merge_state $path $state]
 848         set s $file_states($path)
 849         set new_m [lindex $s 0]
 850         set icon_name [lindex $s 1]
 851
 852         set o [string index $old_m 0]
 853         set n [string index $new_m 0]
 854         if {$o eq {U}} {
 855                 set o _
 856         }
 857         if {$n eq {U}} {
 858                 set n _
 859         }
 860         display_file_helper     $ui_index $path $icon_name $o $n
 861
 862         if {[string index $old_m 0] eq {U}} {
 863                 set o U
 864         } else {
 865                 set o [string index $old_m 1]
 866         }
 867         if {[string index $new_m 0] eq {U}} {
 868                 set n U
 869         } else {
 870                 set n [string index $new_m 1]
 871         }
 872         display_file_helper     $ui_workdir $path $icon_name $o $n
 873
 874         if {$new_m eq {__}} {
 875                 unset file_states($path)
 876                 catch {unset selected_paths($path)}
 877         }
 878 }
 879
 880 proc display_all_files_helper {w path icon_name m} {
 881         global file_lists
 882
 883         lappend file_lists($w) $path
 884         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
 885         $w image create end \
 886                 -align center -padx 5 -pady 1 \
 887                 -name $icon_name \
 888                 -image [mapicon $w $m $path]
 889         $w insert end "[escape_path $path]\n"
 890 }
 891
 892 proc display_all_files {} {
 893         global ui_index ui_workdir
 894         global file_states file_lists
 895         global last_clicked
 896
 897         $ui_index conf -state normal
 898         $ui_workdir conf -state normal
 899
 900         $ui_index delete 0.0 end
 901         $ui_workdir delete 0.0 end
 902         set last_clicked {}
 903
 904         set file_lists($ui_index) [list]
 905         set file_lists($ui_workdir) [list]
 906
 907         foreach path [lsort [array names file_states]] {
 908                 set s $file_states($path)
 909                 set m [lindex $s 0]
 910                 set icon_name [lindex $s 1]
 911
 912                 set s [string index $m 0]
 913                 if {$s ne {U} && $s ne {_}} {
 914                         display_all_files_helper $ui_index $path \
 915                                 $icon_name $s
 916                 }
 917
 918                 if {[string index $m 0] eq {U}} {
 919                         set s U
 920                 } else {
 921                         set s [string index $m 1]
 922                 }
 923                 if {$s ne {_}} {
 924                         display_all_files_helper $ui_workdir $path \
 925                                 $icon_name $s
 926                 }
 927         }
 928
 929         $ui_index conf -state disabled
 930         $ui_workdir conf -state disabled
 931 }
 932
 933 ######################################################################
 934 ##
 935 ## icons
 936
 937 set filemask {
 938 #define mask_width 14
 939 #define mask_height 15
 940 static unsigned char mask_bits[] = {
 941    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
 942    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
 943    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
 944 }
 945
 946 image create bitmap file_plain -background white -foreground black -data {
 947 #define plain_width 14
 948 #define plain_height 15
 949 static unsigned char plain_bits[] = {
 950    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
 951    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
 952    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
 953 } -maskdata $filemask
 954
 955 image create bitmap file_mod -background white -foreground blue -data {
 956 #define mod_width 14
 957 #define mod_height 15
 958 static unsigned char mod_bits[] = {
 959    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
 960    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
 961    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
 962 } -maskdata $filemask
 963
 964 image create bitmap file_fulltick -background white -foreground "#007000" -data {
 965 #define file_fulltick_width 14
 966 #define file_fulltick_height 15
 967 static unsigned char file_fulltick_bits[] = {
 968    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
 969    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
 970    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
 971 } -maskdata $filemask
 972
 973 image create bitmap file_parttick -background white -foreground "#005050" -data {
 974 #define parttick_width 14
 975 #define parttick_height 15
 976 static unsigned char parttick_bits[] = {
 977    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
 978    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
 979    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
 980 } -maskdata $filemask
 981
 982 image create bitmap file_question -background white -foreground black -data {
 983 #define file_question_width 14
 984 #define file_question_height 15
 985 static unsigned char file_question_bits[] = {
 986    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
 987    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
 988    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
 989 } -maskdata $filemask
 990
 991 image create bitmap file_removed -background white -foreground red -data {
 992 #define file_removed_width 14
 993 #define file_removed_height 15
 994 static unsigned char file_removed_bits[] = {
 995    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
 996    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
 997    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
 998 } -maskdata $filemask
 999
1000 image create bitmap file_merge -background white -foreground blue -data {
1001 #define file_merge_width 14
1002 #define file_merge_height 15
1003 static unsigned char file_merge_bits[] = {
1004    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1005    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1006    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1007 } -maskdata $filemask
1008
1009 set file_dir_data {
1010 #define file_width 18
1011 #define file_height 18
1012 static unsigned char file_bits[] = {
1013   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0xf8, 0x03, 0x00,
1014   0x0c, 0x03, 0x00, 0x04, 0xfe, 0x00, 0x06, 0x80, 0x00, 0xff, 0x9f, 0x00,
1015   0x03, 0x98, 0x00, 0x02, 0x90, 0x00, 0x06, 0xb0, 0x00, 0x04, 0xa0, 0x00,
1016   0x0c, 0xe0, 0x00, 0x08, 0xc0, 0x00, 0xf8, 0xff, 0x00, 0x00, 0x00, 0x00,
1017   0x00, 0x00, 0x00, 0x00, 0x00, 0x00};
1018 }
1019 image create bitmap file_dir -background white -foreground blue \
1020         -data $file_dir_data -maskdata $file_dir_data
1021 unset file_dir_data
1022
1023 set file_uplevel_data {
1024 #define up_width 15
1025 #define up_height 15
1026 static unsigned char up_bits[] = {
1027   0x80, 0x00, 0xc0, 0x01, 0xe0, 0x03, 0xf0, 0x07, 0xf8, 0x0f, 0xfc, 0x1f,
1028   0xfe, 0x3f, 0xc0, 0x01, 0xc0, 0x01, 0xc0, 0x01, 0xc0, 0x01, 0xc0, 0x01,
1029   0xc0, 0x01, 0xc0, 0x01, 0x00, 0x00};
1030 }
1031 image create bitmap file_uplevel -background white -foreground red \
1032         -data $file_uplevel_data -maskdata $file_uplevel_data
1033 unset file_uplevel_data
1034
1035 set ui_index .vpane.files.index.list
1036 set ui_workdir .vpane.files.workdir.list
1037
1038 set all_icons(_$ui_index)   file_plain
1039 set all_icons(A$ui_index)   file_fulltick
1040 set all_icons(M$ui_index)   file_fulltick
1041 set all_icons(D$ui_index)   file_removed
1042 set all_icons(U$ui_index)   file_merge
1043
1044 set all_icons(_$ui_workdir) file_plain
1045 set all_icons(M$ui_workdir) file_mod
1046 set all_icons(D$ui_workdir) file_question
1047 set all_icons(U$ui_workdir) file_merge
1048 set all_icons(O$ui_workdir) file_plain
1049
1050 set max_status_desc 0
1051 foreach i {
1052                 {__ "Unmodified"}
1053
1054                 {_M "Modified, not staged"}
1055                 {M_ "Staged for commit"}
1056                 {MM "Portions staged for commit"}
1057                 {MD "Staged for commit, missing"}
1058
1059                 {_O "Untracked, not staged"}
1060                 {A_ "Staged for commit"}
1061                 {AM "Portions staged for commit"}
1062                 {AD "Staged for commit, missing"}
1063
1064                 {_D "Missing"}
1065                 {D_ "Staged for removal"}
1066                 {DO "Staged for removal, still present"}
1067
1068                 {U_ "Requires merge resolution"}
1069                 {UU "Requires merge resolution"}
1070                 {UM "Requires merge resolution"}
1071                 {UD "Requires merge resolution"}
1072         } {
1073         if {$max_status_desc < [string length [lindex $i 1]]} {
1074                 set max_status_desc [string length [lindex $i 1]]
1075         }
1076         set all_descs([lindex $i 0]) [lindex $i 1]
1077 }
1078 unset i
1079
1080 ######################################################################
1081 ##
1082 ## util
1083
1084 proc bind_button3 {w cmd} {
1085         bind $w <Any-Button-3> $cmd
1086         if {[is_MacOSX]} {
1087                 bind $w <Control-Button-1> $cmd
1088         }
1089 }
1090
1091 proc scrollbar2many {list mode args} {
1092         foreach w $list {eval $w $mode $args}
1093 }
1094
1095 proc many2scrollbar {list mode sb top bottom} {
1096         $sb set $top $bottom
1097         foreach w $list {$w $mode moveto $top}
1098 }
1099
1100 proc incr_font_size {font {amt 1}} {
1101         set sz [font configure $font -size]
1102         incr sz $amt
1103         font configure $font -size $sz
1104         font configure ${font}bold -size $sz
1105         font configure ${font}italic -size $sz
1106 }
1107
1108 ######################################################################
1109 ##
1110 ## ui commands
1111
1112 set starting_gitk_msg {Starting gitk... please wait...}
1113
1114 proc do_gitk {revs} {
1115         global env ui_status_value starting_gitk_msg
1116
1117         # -- Always start gitk through whatever we were loaded with.  This
1118         #    lets us bypass using shell process on Windows systems.
1119         #
1120         set cmd [list [info nameofexecutable]]
1121         set exe [gitexec gitk]
1122         lappend cmd $exe
1123         if {$revs ne {}} {
1124                 append cmd { }
1125                 append cmd $revs
1126         }
1127
1128         if {! [file exists $exe]} {
1129                 error_popup "Unable to start gitk:\n\n$exe does not exist"
1130         } else {
1131                 eval exec $cmd &
1132                 set ui_status_value $starting_gitk_msg
1133                 after 10000 {
1134                         if {$ui_status_value eq $starting_gitk_msg} {
1135                                 set ui_status_value {Ready.}
1136                         }
1137                 }
1138         }
1139 }
1140
1141 set is_quitting 0
1142
1143 proc do_quit {} {
1144         global ui_comm is_quitting repo_config commit_type
1145
1146         if {$is_quitting} return
1147         set is_quitting 1
1148
1149         if {[winfo exists $ui_comm]} {
1150                 # -- Stash our current commit buffer.
1151                 #
1152                 set save [gitdir GITGUI_MSG]
1153                 set msg [string trim [$ui_comm get 0.0 end]]
1154                 regsub -all -line {[ \r\t]+$} $msg {} msg
1155                 if {(![string match amend* $commit_type]
1156                         || [$ui_comm edit modified])
1157                         && $msg ne {}} {
1158                         catch {
1159                                 set fd [open $save w]
1160                                 puts -nonewline $fd $msg
1161                                 close $fd
1162                         }
1163                 } else {
1164                         catch {file delete $save}
1165                 }
1166
1167                 # -- Stash our current window geometry into this repository.
1168                 #
1169                 set cfg_geometry [list]
1170                 lappend cfg_geometry [wm geometry .]
1171                 lappend cfg_geometry [lindex [.vpane sash coord 0] 1]
1172                 lappend cfg_geometry [lindex [.vpane.files sash coord 0] 0]
1173                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
1174                         set rc_geometry {}
1175                 }
1176                 if {$cfg_geometry ne $rc_geometry} {
1177                         catch {git config gui.geometry $cfg_geometry}
1178                 }
1179         }
1180
1181         destroy .
1182 }
1183
1184 proc do_rescan {} {
1185         rescan {set ui_status_value {Ready.}}
1186 }
1187
1188 proc do_commit {} {
1189         commit_tree
1190 }
1191
1192 proc toggle_or_diff {w x y} {
1193         global file_states file_lists current_diff_path ui_index ui_workdir
1194         global last_clicked selected_paths
1195
1196         set pos [split [$w index @$x,$y] .]
1197         set lno [lindex $pos 0]
1198         set col [lindex $pos 1]
1199         set path [lindex $file_lists($w) [expr {$lno - 1}]]
1200         if {$path eq {}} {
1201                 set last_clicked {}
1202                 return
1203         }
1204
1205         set last_clicked [list $w $lno]
1206         array unset selected_paths
1207         $ui_index tag remove in_sel 0.0 end
1208         $ui_workdir tag remove in_sel 0.0 end
1209
1210         if {$col == 0} {
1211                 if {$current_diff_path eq $path} {
1212                         set after {reshow_diff;}
1213                 } else {
1214                         set after {}
1215                 }
1216                 if {$w eq $ui_index} {
1217                         update_indexinfo \
1218                                 "Unstaging [short_path $path] from commit" \
1219                                 [list $path] \
1220                                 [concat $after {set ui_status_value {Ready.}}]
1221                 } elseif {$w eq $ui_workdir} {
1222                         update_index \
1223                                 "Adding [short_path $path]" \
1224                                 [list $path] \
1225                                 [concat $after {set ui_status_value {Ready.}}]
1226                 }
1227         } else {
1228                 show_diff $path $w $lno
1229         }
1230 }
1231
1232 proc add_one_to_selection {w x y} {
1233         global file_lists last_clicked selected_paths
1234
1235         set lno [lindex [split [$w index @$x,$y] .] 0]
1236         set path [lindex $file_lists($w) [expr {$lno - 1}]]
1237         if {$path eq {}} {
1238                 set last_clicked {}
1239                 return
1240         }
1241
1242         if {$last_clicked ne {}
1243                 && [lindex $last_clicked 0] ne $w} {
1244                 array unset selected_paths
1245                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
1246         }
1247
1248         set last_clicked [list $w $lno]
1249         if {[catch {set in_sel $selected_paths($path)}]} {
1250                 set in_sel 0
1251         }
1252         if {$in_sel} {
1253                 unset selected_paths($path)
1254                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
1255         } else {
1256                 set selected_paths($path) 1
1257                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
1258         }
1259 }
1260
1261 proc add_range_to_selection {w x y} {
1262         global file_lists last_clicked selected_paths
1263
1264         if {[lindex $last_clicked 0] ne $w} {
1265                 toggle_or_diff $w $x $y
1266                 return
1267         }
1268
1269         set lno [lindex [split [$w index @$x,$y] .] 0]
1270         set lc [lindex $last_clicked 1]
1271         if {$lc < $lno} {
1272                 set begin $lc
1273                 set end $lno
1274         } else {
1275                 set begin $lno
1276                 set end $lc
1277         }
1278
1279         foreach path [lrange $file_lists($w) \
1280                 [expr {$begin - 1}] \
1281                 [expr {$end - 1}]] {
1282                 set selected_paths($path) 1
1283         }
1284         $w tag add in_sel $begin.0 [expr {$end + 1}].0
1285 }
1286
1287 ######################################################################
1288 ##
1289 ## config defaults
1290
1291 set cursor_ptr arrow
1292 font create font_diff -family Courier -size 10
1293 font create font_ui
1294 catch {
1295         label .dummy
1296         eval font configure font_ui [font actual [.dummy cget -font]]
1297         destroy .dummy
1298 }
1299
1300 font create font_uiitalic
1301 font create font_uibold
1302 font create font_diffbold
1303 font create font_diffitalic
1304
1305 foreach class {Button Checkbutton Entry Label
1306                 Labelframe Listbox Menu Message
1307                 Radiobutton Spinbox Text} {
1308         option add *$class.font font_ui
1309 }
1310 unset class
1311
1312 if {[is_Windows] || [is_MacOSX]} {
1313         option add *Menu.tearOff 0
1314 }
1315
1316 if {[is_MacOSX]} {
1317         set M1B M1
1318         set M1T Cmd
1319 } else {
1320         set M1B Control
1321         set M1T Ctrl
1322 }
1323
1324 proc apply_config {} {
1325         global repo_config font_descs
1326
1327         foreach option $font_descs {
1328                 set name [lindex $option 0]
1329                 set font [lindex $option 1]
1330                 if {[catch {
1331                         foreach {cn cv} $repo_config(gui.$name) {
1332                                 font configure $font $cn $cv
1333                         }
1334                         } err]} {
1335                         error_popup "Invalid font specified in gui.$name:\n\n$err"
1336                 }
1337                 foreach {cn cv} [font configure $font] {
1338                         font configure ${font}bold $cn $cv
1339                         font configure ${font}italic $cn $cv
1340                 }
1341                 font configure ${font}bold -weight bold
1342                 font configure ${font}italic -slant italic
1343         }
1344 }
1345
1346 set default_config(merge.diffstat) true
1347 set default_config(merge.summary) false
1348 set default_config(merge.verbosity) 2
1349 set default_config(user.name) {}
1350 set default_config(user.email) {}
1351
1352 set default_config(gui.matchtrackingbranch) false
1353 set default_config(gui.pruneduringfetch) false
1354 set default_config(gui.trustmtime) false
1355 set default_config(gui.diffcontext) 5
1356 set default_config(gui.newbranchtemplate) {}
1357 set default_config(gui.fontui) [font configure font_ui]
1358 set default_config(gui.fontdiff) [font configure font_diff]
1359 set font_descs {
1360         {fontui   font_ui   {Main Font}}
1361         {fontdiff font_diff {Diff/Console Font}}
1362 }
1363 load_config 0
1364 apply_config
1365
1366 ######################################################################
1367 ##
1368 ## feature option selection
1369
1370 if {[regexp {^git-(.+)$} [appname] _junk subcommand]} {
1371         unset _junk
1372 } else {
1373         set subcommand gui
1374 }
1375 if {$subcommand eq {gui.sh}} {
1376         set subcommand gui
1377 }
1378 if {$subcommand eq {gui} && [llength $argv] > 0} {
1379         set subcommand [lindex $argv 0]
1380         set argv [lrange $argv 1 end]
1381 }
1382
1383 enable_option multicommit
1384 enable_option branch
1385 enable_option transport
1386
1387 switch -- $subcommand {
1388 browser -
1389 blame {
1390         disable_option multicommit
1391         disable_option branch
1392         disable_option transport
1393 }
1394 citool {
1395         enable_option singlecommit
1396
1397         disable_option multicommit
1398         disable_option branch
1399         disable_option transport
1400 }
1401 }
1402
1403 ######################################################################
1404 ##
1405 ## ui construction
1406
1407 set ui_comm {}
1408
1409 # -- Menu Bar
1410 #
1411 menu .mbar -tearoff 0
1412 .mbar add cascade -label Repository -menu .mbar.repository
1413 .mbar add cascade -label Edit -menu .mbar.edit
1414 if {[is_enabled branch]} {
1415         .mbar add cascade -label Branch -menu .mbar.branch
1416 }
1417 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
1418         .mbar add cascade -label Commit -menu .mbar.commit
1419 }
1420 if {[is_enabled transport]} {
1421         .mbar add cascade -label Merge -menu .mbar.merge
1422         .mbar add cascade -label Fetch -menu .mbar.fetch
1423         .mbar add cascade -label Push -menu .mbar.push
1424 }
1425 . configure -menu .mbar
1426
1427 # -- Repository Menu
1428 #
1429 menu .mbar.repository
1430
1431 .mbar.repository add command \
1432         -label {Browse Current Branch} \
1433         -command {browser::new $current_branch}
1434 trace add variable current_branch write ".mbar.repository entryconf [.mbar.repository index last] -label \"Browse \$current_branch\" ;#"
1435 .mbar.repository add separator
1436
1437 .mbar.repository add command \
1438         -label {Visualize Current Branch} \
1439         -command {do_gitk $current_branch}
1440 trace add variable current_branch write ".mbar.repository entryconf [.mbar.repository index last] -label \"Visualize \$current_branch\" ;#"
1441 .mbar.repository add command \
1442         -label {Visualize All Branches} \
1443         -command {do_gitk --all}
1444 .mbar.repository add separator
1445
1446 if {[is_enabled multicommit]} {
1447         .mbar.repository add command -label {Database Statistics} \
1448                 -command do_stats
1449
1450         .mbar.repository add command -label {Compress Database} \
1451                 -command do_gc
1452
1453         .mbar.repository add command -label {Verify Database} \
1454                 -command do_fsck_objects
1455
1456         .mbar.repository add separator
1457
1458         if {[is_Cygwin]} {
1459                 .mbar.repository add command \
1460                         -label {Create Desktop Icon} \
1461                         -command do_cygwin_shortcut
1462         } elseif {[is_Windows]} {
1463                 .mbar.repository add command \
1464                         -label {Create Desktop Icon} \
1465                         -command do_windows_shortcut
1466         } elseif {[is_MacOSX]} {
1467                 .mbar.repository add command \
1468                         -label {Create Desktop Icon} \
1469                         -command do_macosx_app
1470         }
1471 }
1472
1473 .mbar.repository add command -label Quit \
1474         -command do_quit \
1475         -accelerator $M1T-Q
1476
1477 # -- Edit Menu
1478 #
1479 menu .mbar.edit
1480 .mbar.edit add command -label Undo \
1481         -command {catch {[focus] edit undo}} \
1482         -accelerator $M1T-Z
1483 .mbar.edit add command -label Redo \
1484         -command {catch {[focus] edit redo}} \
1485         -accelerator $M1T-Y
1486 .mbar.edit add separator
1487 .mbar.edit add command -label Cut \
1488         -command {catch {tk_textCut [focus]}} \
1489         -accelerator $M1T-X
1490 .mbar.edit add command -label Copy \
1491         -command {catch {tk_textCopy [focus]}} \
1492         -accelerator $M1T-C
1493 .mbar.edit add command -label Paste \
1494         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
1495         -accelerator $M1T-V
1496 .mbar.edit add command -label Delete \
1497         -command {catch {[focus] delete sel.first sel.last}} \
1498         -accelerator Del
1499 .mbar.edit add separator
1500 .mbar.edit add command -label {Select All} \
1501         -command {catch {[focus] tag add sel 0.0 end}} \
1502         -accelerator $M1T-A
1503
1504 # -- Branch Menu
1505 #
1506 if {[is_enabled branch]} {
1507         menu .mbar.branch
1508
1509         .mbar.branch add command -label {Create...} \
1510                 -command branch_create::dialog \
1511                 -accelerator $M1T-N
1512         lappend disable_on_lock [list .mbar.branch entryconf \
1513                 [.mbar.branch index last] -state]
1514
1515         .mbar.branch add command -label {Rename...} \
1516                 -command branch_rename::dialog
1517         lappend disable_on_lock [list .mbar.branch entryconf \
1518                 [.mbar.branch index last] -state]
1519
1520         .mbar.branch add command -label {Delete...} \
1521                 -command branch_delete::dialog
1522         lappend disable_on_lock [list .mbar.branch entryconf \
1523                 [.mbar.branch index last] -state]
1524
1525         .mbar.branch add command -label {Reset...} \
1526                 -command merge::reset_hard
1527         lappend disable_on_lock [list .mbar.branch entryconf \
1528                 [.mbar.branch index last] -state]
1529 }
1530
1531 # -- Commit Menu
1532 #
1533 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
1534         menu .mbar.commit
1535
1536         .mbar.commit add radiobutton \
1537                 -label {New Commit} \
1538                 -command do_select_commit_type \
1539                 -variable selected_commit_type \
1540                 -value new
1541         lappend disable_on_lock \
1542                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1543
1544         .mbar.commit add radiobutton \
1545                 -label {Amend Last Commit} \
1546                 -command do_select_commit_type \
1547                 -variable selected_commit_type \
1548                 -value amend
1549         lappend disable_on_lock \
1550                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1551
1552         .mbar.commit add separator
1553
1554         .mbar.commit add command -label Rescan \
1555                 -command do_rescan \
1556                 -accelerator F5
1557         lappend disable_on_lock \
1558                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1559
1560         .mbar.commit add command -label {Add To Commit} \
1561                 -command do_add_selection
1562         lappend disable_on_lock \
1563                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1564
1565         .mbar.commit add command -label {Add Existing To Commit} \
1566                 -command do_add_all \
1567                 -accelerator $M1T-I
1568         lappend disable_on_lock \
1569                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1570
1571         .mbar.commit add command -label {Unstage From Commit} \
1572                 -command do_unstage_selection
1573         lappend disable_on_lock \
1574                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1575
1576         .mbar.commit add command -label {Revert Changes} \
1577                 -command do_revert_selection
1578         lappend disable_on_lock \
1579                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1580
1581         .mbar.commit add separator
1582
1583         .mbar.commit add command -label {Sign Off} \
1584                 -command do_signoff \
1585                 -accelerator $M1T-S
1586
1587         .mbar.commit add command -label Commit \
1588                 -command do_commit \
1589                 -accelerator $M1T-Return
1590         lappend disable_on_lock \
1591                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1592 }
1593
1594 # -- Merge Menu
1595 #
1596 if {[is_enabled branch]} {
1597         menu .mbar.merge
1598         .mbar.merge add command -label {Local Merge...} \
1599                 -command merge::dialog
1600         lappend disable_on_lock \
1601                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
1602         .mbar.merge add command -label {Abort Merge...} \
1603                 -command merge::reset_hard
1604         lappend disable_on_lock \
1605                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
1606
1607 }
1608
1609 # -- Transport Menu
1610 #
1611 if {[is_enabled transport]} {
1612         menu .mbar.fetch
1613
1614         menu .mbar.push
1615         .mbar.push add command -label {Push...} \
1616                 -command do_push_anywhere \
1617                 -accelerator $M1T-P
1618         .mbar.push add command -label {Delete...} \
1619                 -command remote_branch_delete::dialog
1620 }
1621
1622 if {[is_MacOSX]} {
1623         # -- Apple Menu (Mac OS X only)
1624         #
1625         .mbar add cascade -label Apple -menu .mbar.apple
1626         menu .mbar.apple
1627
1628         .mbar.apple add command -label "About [appname]" \
1629                 -command do_about
1630         .mbar.apple add command -label "Options..." \
1631                 -command do_options
1632 } else {
1633         # -- Edit Menu
1634         #
1635         .mbar.edit add separator
1636         .mbar.edit add command -label {Options...} \
1637                 -command do_options
1638
1639         # -- Tools Menu
1640         #
1641         if {[is_Cygwin] && [file exists /usr/local/miga/lib/gui-miga]} {
1642         proc do_miga {} {
1643                 global ui_status_value
1644                 if {![lock_index update]} return
1645                 set cmd [list sh --login -c "/usr/local/miga/lib/gui-miga \"[pwd]\""]
1646                 set miga_fd [open "|$cmd" r]
1647                 fconfigure $miga_fd -blocking 0
1648                 fileevent $miga_fd readable [list miga_done $miga_fd]
1649                 set ui_status_value {Running miga...}
1650         }
1651         proc miga_done {fd} {
1652                 read $fd 512
1653                 if {[eof $fd]} {
1654                         close $fd
1655                         unlock_index
1656                         rescan [list set ui_status_value {Ready.}]
1657                 }
1658         }
1659         .mbar add cascade -label Tools -menu .mbar.tools
1660         menu .mbar.tools
1661         .mbar.tools add command -label "Migrate" \
1662                 -command do_miga
1663         lappend disable_on_lock \
1664                 [list .mbar.tools entryconf [.mbar.tools index last] -state]
1665         }
1666 }
1667
1668 # -- Help Menu
1669 #
1670 .mbar add cascade -label Help -menu .mbar.help
1671 menu .mbar.help
1672
1673 if {![is_MacOSX]} {
1674         .mbar.help add command -label "About [appname]" \
1675                 -command do_about
1676 }
1677
1678 set browser {}
1679 catch {set browser $repo_config(instaweb.browser)}
1680 set doc_path [file dirname [gitexec]]
1681 set doc_path [file join $doc_path Documentation index.html]
1682
1683 if {[is_Cygwin]} {
1684         set doc_path [exec cygpath --mixed $doc_path]
1685 }
1686
1687 if {$browser eq {}} {
1688         if {[is_MacOSX]} {
1689                 set browser open
1690         } elseif {[is_Cygwin]} {
1691                 set program_files [file dirname [exec cygpath --windir]]
1692                 set program_files [file join $program_files {Program Files}]
1693                 set firefox [file join $program_files {Mozilla Firefox} firefox.exe]
1694                 set ie [file join $program_files {Internet Explorer} IEXPLORE.EXE]
1695                 if {[file exists $firefox]} {
1696                         set browser $firefox
1697                 } elseif {[file exists $ie]} {
1698                         set browser $ie
1699                 }
1700                 unset program_files firefox ie
1701         }
1702 }
1703
1704 if {[file isfile $doc_path]} {
1705         set doc_url "file:$doc_path"
1706 } else {
1707         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
1708 }
1709
1710 if {$browser ne {}} {
1711         .mbar.help add command -label {Online Documentation} \
1712                 -command [list exec $browser $doc_url &]
1713 }
1714 unset browser doc_path doc_url
1715
1716 # -- Standard bindings
1717 #
1718 wm protocol . WM_DELETE_WINDOW do_quit
1719 bind all <$M1B-Key-q> do_quit
1720 bind all <$M1B-Key-Q> do_quit
1721 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
1722 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
1723
1724 set subcommand_args {}
1725 proc usage {} {
1726         puts stderr "usage: $::argv0 $::subcommand $::subcommand_args"
1727         exit 1
1728 }
1729
1730 # -- Not a normal commit type invocation?  Do that instead!
1731 #
1732 switch -- $subcommand {
1733 browser {
1734         set subcommand_args {rev?}
1735         switch [llength $argv] {
1736         0 { set current_branch [current-branch] }
1737         1 { set current_branch [lindex $argv 0] }
1738         default usage
1739         }
1740         browser::new $current_branch
1741         return
1742 }
1743 blame {
1744         set subcommand_args {rev? path?}
1745         set head {}
1746         set path {}
1747         set is_path 0
1748         foreach a $argv {
1749                 if {$is_path || [file exists $_prefix$a]} {
1750                         if {$path ne {}} usage
1751                         set path $_prefix$a
1752                         break
1753                 } elseif {$a eq {--}} {
1754                         if {$path ne {}} {
1755                                 if {$head ne {}} usage
1756                                 set head $path
1757                                 set path {}
1758                         }
1759                         set is_path 1
1760                 } elseif {$head eq {}} {
1761                         if {$head ne {}} usage
1762                         set head $a
1763                 } else {
1764                         usage
1765                 }
1766         }
1767         unset is_path
1768
1769         if {$head eq {}} {
1770                 set current_branch [current-branch]
1771         } else {
1772                 set current_branch $head
1773         }
1774
1775         if {$path eq {}} usage
1776         blame::new $head $path
1777         return
1778 }
1779 citool -
1780 gui {
1781         if {[llength $argv] != 0} {
1782                 puts -nonewline stderr "usage: $argv0"
1783                 if {$subcommand ne {gui} && [appname] ne "git-$subcommand"} {
1784                         puts -nonewline stderr " $subcommand"
1785                 }
1786                 puts stderr {}
1787                 exit 1
1788         }
1789         # fall through to setup UI for commits
1790 }
1791 default {
1792         puts stderr "usage: $argv0 \[{blame|browser|citool}\]"
1793         exit 1
1794 }
1795 }
1796
1797 # -- Branch Control
1798 #
1799 frame .branch \
1800         -borderwidth 1 \
1801         -relief sunken
1802 label .branch.l1 \
1803         -text {Current Branch:} \
1804         -anchor w \
1805         -justify left
1806 label .branch.cb \
1807         -textvariable current_branch \
1808         -anchor w \
1809         -justify left
1810 pack .branch.l1 -side left
1811 pack .branch.cb -side left -fill x
1812 pack .branch -side top -fill x
1813
1814 # -- Main Window Layout
1815 #
1816 panedwindow .vpane -orient vertical
1817 panedwindow .vpane.files -orient horizontal
1818 .vpane add .vpane.files -sticky nsew -height 100 -width 200
1819 pack .vpane -anchor n -side top -fill both -expand 1
1820
1821 # -- Index File List
1822 #
1823 frame .vpane.files.index -height 100 -width 200
1824 label .vpane.files.index.title -text {Staged Changes (Will Be Committed)} \
1825         -background lightgreen
1826 text $ui_index -background white -borderwidth 0 \
1827         -width 20 -height 10 \
1828         -wrap none \
1829         -cursor $cursor_ptr \
1830         -xscrollcommand {.vpane.files.index.sx set} \
1831         -yscrollcommand {.vpane.files.index.sy set} \
1832         -state disabled
1833 scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
1834 scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
1835 pack .vpane.files.index.title -side top -fill x
1836 pack .vpane.files.index.sx -side bottom -fill x
1837 pack .vpane.files.index.sy -side right -fill y
1838 pack $ui_index -side left -fill both -expand 1
1839 .vpane.files add .vpane.files.index -sticky nsew
1840
1841 # -- Working Directory File List
1842 #
1843 frame .vpane.files.workdir -height 100 -width 200
1844 label .vpane.files.workdir.title -text {Unstaged Changes (Will Not Be Committed)} \
1845         -background lightsalmon
1846 text $ui_workdir -background white -borderwidth 0 \
1847         -width 20 -height 10 \
1848         -wrap none \
1849         -cursor $cursor_ptr \
1850         -xscrollcommand {.vpane.files.workdir.sx set} \
1851         -yscrollcommand {.vpane.files.workdir.sy set} \
1852         -state disabled
1853 scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
1854 scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
1855 pack .vpane.files.workdir.title -side top -fill x
1856 pack .vpane.files.workdir.sx -side bottom -fill x
1857 pack .vpane.files.workdir.sy -side right -fill y
1858 pack $ui_workdir -side left -fill both -expand 1
1859 .vpane.files add .vpane.files.workdir -sticky nsew
1860
1861 foreach i [list $ui_index $ui_workdir] {
1862         $i tag conf in_diff -background lightgray
1863         $i tag conf in_sel  -background lightgray
1864 }
1865 unset i
1866
1867 # -- Diff and Commit Area
1868 #
1869 frame .vpane.lower -height 300 -width 400
1870 frame .vpane.lower.commarea
1871 frame .vpane.lower.diff -relief sunken -borderwidth 1
1872 pack .vpane.lower.commarea -side top -fill x
1873 pack .vpane.lower.diff -side bottom -fill both -expand 1
1874 .vpane add .vpane.lower -sticky nsew
1875
1876 # -- Commit Area Buttons
1877 #
1878 frame .vpane.lower.commarea.buttons
1879 label .vpane.lower.commarea.buttons.l -text {} \
1880         -anchor w \
1881         -justify left
1882 pack .vpane.lower.commarea.buttons.l -side top -fill x
1883 pack .vpane.lower.commarea.buttons -side left -fill y
1884
1885 button .vpane.lower.commarea.buttons.rescan -text {Rescan} \
1886         -command do_rescan
1887 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
1888 lappend disable_on_lock \
1889         {.vpane.lower.commarea.buttons.rescan conf -state}
1890
1891 button .vpane.lower.commarea.buttons.incall -text {Add Existing} \
1892         -command do_add_all
1893 pack .vpane.lower.commarea.buttons.incall -side top -fill x
1894 lappend disable_on_lock \
1895         {.vpane.lower.commarea.buttons.incall conf -state}
1896
1897 button .vpane.lower.commarea.buttons.signoff -text {Sign Off} \
1898         -command do_signoff
1899 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
1900
1901 button .vpane.lower.commarea.buttons.commit -text {Commit} \
1902         -command do_commit
1903 pack .vpane.lower.commarea.buttons.commit -side top -fill x
1904 lappend disable_on_lock \
1905         {.vpane.lower.commarea.buttons.commit conf -state}
1906
1907 button .vpane.lower.commarea.buttons.push -text {Push} \
1908         -command do_push_anywhere
1909 pack .vpane.lower.commarea.buttons.push -side top -fill x
1910
1911 # -- Commit Message Buffer
1912 #
1913 frame .vpane.lower.commarea.buffer
1914 frame .vpane.lower.commarea.buffer.header
1915 set ui_comm .vpane.lower.commarea.buffer.t
1916 set ui_coml .vpane.lower.commarea.buffer.header.l
1917 radiobutton .vpane.lower.commarea.buffer.header.new \
1918         -text {New Commit} \
1919         -command do_select_commit_type \
1920         -variable selected_commit_type \
1921         -value new
1922 lappend disable_on_lock \
1923         [list .vpane.lower.commarea.buffer.header.new conf -state]
1924 radiobutton .vpane.lower.commarea.buffer.header.amend \
1925         -text {Amend Last Commit} \
1926         -command do_select_commit_type \
1927         -variable selected_commit_type \
1928         -value amend
1929 lappend disable_on_lock \
1930         [list .vpane.lower.commarea.buffer.header.amend conf -state]
1931 label $ui_coml \
1932         -anchor w \
1933         -justify left
1934 proc trace_commit_type {varname args} {
1935         global ui_coml commit_type
1936         switch -glob -- $commit_type {
1937         initial       {set txt {Initial Commit Message:}}
1938         amend         {set txt {Amended Commit Message:}}
1939         amend-initial {set txt {Amended Initial Commit Message:}}
1940         amend-merge   {set txt {Amended Merge Commit Message:}}
1941         merge         {set txt {Merge Commit Message:}}
1942         *             {set txt {Commit Message:}}
1943         }
1944         $ui_coml conf -text $txt
1945 }
1946 trace add variable commit_type write trace_commit_type
1947 pack $ui_coml -side left -fill x
1948 pack .vpane.lower.commarea.buffer.header.amend -side right
1949 pack .vpane.lower.commarea.buffer.header.new -side right
1950
1951 text $ui_comm -background white -borderwidth 1 \
1952         -undo true \
1953         -maxundo 20 \
1954         -autoseparators true \
1955         -relief sunken \
1956         -width 75 -height 9 -wrap none \
1957         -font font_diff \
1958         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
1959 scrollbar .vpane.lower.commarea.buffer.sby \
1960         -command [list $ui_comm yview]
1961 pack .vpane.lower.commarea.buffer.header -side top -fill x
1962 pack .vpane.lower.commarea.buffer.sby -side right -fill y
1963 pack $ui_comm -side left -fill y
1964 pack .vpane.lower.commarea.buffer -side left -fill y
1965
1966 # -- Commit Message Buffer Context Menu
1967 #
1968 set ctxm .vpane.lower.commarea.buffer.ctxm
1969 menu $ctxm -tearoff 0
1970 $ctxm add command \
1971         -label {Cut} \
1972         -command {tk_textCut $ui_comm}
1973 $ctxm add command \
1974         -label {Copy} \
1975         -command {tk_textCopy $ui_comm}
1976 $ctxm add command \
1977         -label {Paste} \
1978         -command {tk_textPaste $ui_comm}
1979 $ctxm add command \
1980         -label {Delete} \
1981         -command {$ui_comm delete sel.first sel.last}
1982 $ctxm add separator
1983 $ctxm add command \
1984         -label {Select All} \
1985         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
1986 $ctxm add command \
1987         -label {Copy All} \
1988         -command {
1989                 $ui_comm tag add sel 0.0 end
1990                 tk_textCopy $ui_comm
1991                 $ui_comm tag remove sel 0.0 end
1992         }
1993 $ctxm add separator
1994 $ctxm add command \
1995         -label {Sign Off} \
1996         -command do_signoff
1997 bind_button3 $ui_comm "tk_popup $ctxm %X %Y"
1998
1999 # -- Diff Header
2000 #
2001 proc trace_current_diff_path {varname args} {
2002         global current_diff_path diff_actions file_states
2003         if {$current_diff_path eq {}} {
2004                 set s {}
2005                 set f {}
2006                 set p {}
2007                 set o disabled
2008         } else {
2009                 set p $current_diff_path
2010                 set s [mapdesc [lindex $file_states($p) 0] $p]
2011                 set f {File:}
2012                 set p [escape_path $p]
2013                 set o normal
2014         }
2015
2016         .vpane.lower.diff.header.status configure -text $s
2017         .vpane.lower.diff.header.file configure -text $f
2018         .vpane.lower.diff.header.path configure -text $p
2019         foreach w $diff_actions {
2020                 uplevel #0 $w $o
2021         }
2022 }
2023 trace add variable current_diff_path write trace_current_diff_path
2024
2025 frame .vpane.lower.diff.header -background gold
2026 label .vpane.lower.diff.header.status \
2027         -background gold \
2028         -width $max_status_desc \
2029         -anchor w \
2030         -justify left
2031 label .vpane.lower.diff.header.file \
2032         -background gold \
2033         -anchor w \
2034         -justify left
2035 label .vpane.lower.diff.header.path \
2036         -background gold \
2037         -anchor w \
2038         -justify left
2039 pack .vpane.lower.diff.header.status -side left
2040 pack .vpane.lower.diff.header.file -side left
2041 pack .vpane.lower.diff.header.path -fill x
2042 set ctxm .vpane.lower.diff.header.ctxm
2043 menu $ctxm -tearoff 0
2044 $ctxm add command \
2045         -label {Copy} \
2046         -command {
2047                 clipboard clear
2048                 clipboard append \
2049                         -format STRING \
2050                         -type STRING \
2051                         -- $current_diff_path
2052         }
2053 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2054 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
2055
2056 # -- Diff Body
2057 #
2058 frame .vpane.lower.diff.body
2059 set ui_diff .vpane.lower.diff.body.t
2060 text $ui_diff -background white -borderwidth 0 \
2061         -width 80 -height 15 -wrap none \
2062         -font font_diff \
2063         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
2064         -yscrollcommand {.vpane.lower.diff.body.sby set} \
2065         -state disabled
2066 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
2067         -command [list $ui_diff xview]
2068 scrollbar .vpane.lower.diff.body.sby -orient vertical \
2069         -command [list $ui_diff yview]
2070 pack .vpane.lower.diff.body.sbx -side bottom -fill x
2071 pack .vpane.lower.diff.body.sby -side right -fill y
2072 pack $ui_diff -side left -fill both -expand 1
2073 pack .vpane.lower.diff.header -side top -fill x
2074 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
2075
2076 $ui_diff tag conf d_cr -elide true
2077 $ui_diff tag conf d_@ -foreground blue -font font_diffbold
2078 $ui_diff tag conf d_+ -foreground {#00a000}
2079 $ui_diff tag conf d_- -foreground red
2080
2081 $ui_diff tag conf d_++ -foreground {#00a000}
2082 $ui_diff tag conf d_-- -foreground red
2083 $ui_diff tag conf d_+s \
2084         -foreground {#00a000} \
2085         -background {#e2effa}
2086 $ui_diff tag conf d_-s \
2087         -foreground red \
2088         -background {#e2effa}
2089 $ui_diff tag conf d_s+ \
2090         -foreground {#00a000} \
2091         -background ivory1
2092 $ui_diff tag conf d_s- \
2093         -foreground red \
2094         -background ivory1
2095
2096 $ui_diff tag conf d<<<<<<< \
2097         -foreground orange \
2098         -font font_diffbold
2099 $ui_diff tag conf d======= \
2100         -foreground orange \
2101         -font font_diffbold
2102 $ui_diff tag conf d>>>>>>> \
2103         -foreground orange \
2104         -font font_diffbold
2105
2106 $ui_diff tag raise sel
2107
2108 # -- Diff Body Context Menu
2109 #
2110 set ctxm .vpane.lower.diff.body.ctxm
2111 menu $ctxm -tearoff 0
2112 $ctxm add command \
2113         -label {Refresh} \
2114         -command reshow_diff
2115 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2116 $ctxm add command \
2117         -label {Copy} \
2118         -command {tk_textCopy $ui_diff}
2119 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2120 $ctxm add command \
2121         -label {Select All} \
2122         -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
2123 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2124 $ctxm add command \
2125         -label {Copy All} \
2126         -command {
2127                 $ui_diff tag add sel 0.0 end
2128                 tk_textCopy $ui_diff
2129                 $ui_diff tag remove sel 0.0 end
2130         }
2131 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2132 $ctxm add separator
2133 $ctxm add command \
2134         -label {Apply/Reverse Hunk} \
2135         -command {apply_hunk $cursorX $cursorY}
2136 set ui_diff_applyhunk [$ctxm index last]
2137 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
2138 $ctxm add separator
2139 $ctxm add command \
2140         -label {Decrease Font Size} \
2141         -command {incr_font_size font_diff -1}
2142 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2143 $ctxm add command \
2144         -label {Increase Font Size} \
2145         -command {incr_font_size font_diff 1}
2146 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2147 $ctxm add separator
2148 $ctxm add command \
2149         -label {Show Less Context} \
2150         -command {if {$repo_config(gui.diffcontext) >= 1} {
2151                 incr repo_config(gui.diffcontext) -1
2152                 reshow_diff
2153         }}
2154 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2155 $ctxm add command \
2156         -label {Show More Context} \
2157         -command {if {$repo_config(gui.diffcontext) < 99} {
2158                 incr repo_config(gui.diffcontext)
2159                 reshow_diff
2160         }}
2161 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2162 $ctxm add separator
2163 $ctxm add command -label {Options...} \
2164         -command do_options
2165 bind_button3 $ui_diff "
2166         set cursorX %x
2167         set cursorY %y
2168         if {\$ui_index eq \$current_diff_side} {
2169                 $ctxm entryconf $ui_diff_applyhunk -label {Unstage Hunk From Commit}
2170         } else {
2171                 $ctxm entryconf $ui_diff_applyhunk -label {Stage Hunk For Commit}
2172         }
2173         tk_popup $ctxm %X %Y
2174 "
2175 unset ui_diff_applyhunk
2176
2177 # -- Status Bar
2178 #
2179 label .status -textvariable ui_status_value \
2180         -anchor w \
2181         -justify left \
2182         -borderwidth 1 \
2183         -relief sunken
2184 pack .status -anchor w -side bottom -fill x
2185
2186 # -- Load geometry
2187 #
2188 catch {
2189 set gm $repo_config(gui.geometry)
2190 wm geometry . [lindex $gm 0]
2191 .vpane sash place 0 \
2192         [lindex [.vpane sash coord 0] 0] \
2193         [lindex $gm 1]
2194 .vpane.files sash place 0 \
2195         [lindex $gm 2] \
2196         [lindex [.vpane.files sash coord 0] 1]
2197 unset gm
2198 }
2199
2200 # -- Key Bindings
2201 #
2202 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
2203 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
2204 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
2205 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
2206 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
2207 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
2208 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
2209 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
2210 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
2211 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
2212 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
2213
2214 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
2215 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
2216 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
2217 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
2218 bind $ui_diff <$M1B-Key-v> {break}
2219 bind $ui_diff <$M1B-Key-V> {break}
2220 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
2221 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
2222 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
2223 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
2224 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
2225 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
2226 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
2227 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
2228 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
2229 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
2230 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
2231 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
2232 bind $ui_diff <Button-1>   {focus %W}
2233
2234 if {[is_enabled branch]} {
2235         bind . <$M1B-Key-n> branch_create::dialog
2236         bind . <$M1B-Key-N> branch_create::dialog
2237 }
2238 if {[is_enabled transport]} {
2239         bind . <$M1B-Key-p> do_push_anywhere
2240         bind . <$M1B-Key-P> do_push_anywhere
2241 }
2242
2243 bind .   <Key-F5>     do_rescan
2244 bind .   <$M1B-Key-r> do_rescan
2245 bind .   <$M1B-Key-R> do_rescan
2246 bind .   <$M1B-Key-s> do_signoff
2247 bind .   <$M1B-Key-S> do_signoff
2248 bind .   <$M1B-Key-i> do_add_all
2249 bind .   <$M1B-Key-I> do_add_all
2250 bind .   <$M1B-Key-Return> do_commit
2251 foreach i [list $ui_index $ui_workdir] {
2252         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
2253         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
2254         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
2255 }
2256 unset i
2257
2258 set file_lists($ui_index) [list]
2259 set file_lists($ui_workdir) [list]
2260
2261 wm title . "[appname] ([reponame]) [file normalize [file dirname [gitdir]]]"
2262 focus -force $ui_comm
2263
2264 # -- Warn the user about environmental problems.  Cygwin's Tcl
2265 #    does *not* pass its env array onto any processes it spawns.
2266 #    This means that git processes get none of our environment.
2267 #
2268 if {[is_Cygwin]} {
2269         set ignored_env 0
2270         set suggest_user {}
2271         set msg "Possible environment issues exist.
2272
2273 The following environment variables are probably
2274 going to be ignored by any Git subprocess run
2275 by [appname]:
2276
2277 "
2278         foreach name [array names env] {
2279                 switch -regexp -- $name {
2280                 {^GIT_INDEX_FILE$} -
2281                 {^GIT_OBJECT_DIRECTORY$} -
2282                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
2283                 {^GIT_DIFF_OPTS$} -
2284                 {^GIT_EXTERNAL_DIFF$} -
2285                 {^GIT_PAGER$} -
2286                 {^GIT_TRACE$} -
2287                 {^GIT_CONFIG$} -
2288                 {^GIT_CONFIG_LOCAL$} -
2289                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
2290                         append msg " - $name\n"
2291                         incr ignored_env
2292                 }
2293                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
2294                         append msg " - $name\n"
2295                         incr ignored_env
2296                         set suggest_user $name
2297                 }
2298                 }
2299         }
2300         if {$ignored_env > 0} {
2301                 append msg "
2302 This is due to a known issue with the
2303 Tcl binary distributed by Cygwin."
2304
2305                 if {$suggest_user ne {}} {
2306                         append msg "
2307
2308 A good replacement for $suggest_user
2309 is placing values for the user.name and
2310 user.email settings into your personal
2311 ~/.gitconfig file.
2312 "
2313                 }
2314                 warn_popup $msg
2315         }
2316         unset ignored_env msg suggest_user name
2317 }
2318
2319 # -- Only initialize complex UI if we are going to stay running.
2320 #
2321 if {[is_enabled transport]} {
2322         load_all_remotes
2323         load_all_heads
2324
2325         populate_branch_menu
2326         populate_fetch_menu
2327         populate_push_menu
2328 }
2329
2330 # -- Only suggest a gc run if we are going to stay running.
2331 #
2332 if {[is_enabled multicommit]} {
2333         set object_limit 2000
2334         if {[is_Windows]} {set object_limit 200}
2335         regexp {^([0-9]+) objects,} [git count-objects] _junk objects_current
2336         if {$objects_current >= $object_limit} {
2337                 if {[ask_popup \
2338                         "This repository currently has $objects_current loose objects.
2339
2340 To maintain optimal performance it is strongly recommended that you compress the database when more than $object_limit loose objects exist.
2341
2342 Compress the database now?"] eq yes} {
2343                         do_gc
2344                 }
2345         }
2346         unset object_limit _junk objects_current
2347 }
2348
2349 lock_index begin-read
2350 after 1 do_rescan