git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3 exec wish "$0" -- "$@"
   4
   5 set appvers {@@GIT_VERSION@@}
   6 set copyright {
   7 Copyright © 2006, 2007 Shawn Pearce, Paul Mackerras.
   8
   9 This program is free software; you can redistribute it and/or modify
  10 it under the terms of the GNU General Public License as published by
  11 the Free Software Foundation; either version 2 of the License, or
  12 (at your option) any later version.
  13
  14 This program is distributed in the hope that it will be useful,
  15 but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 GNU General Public License for more details.
  18
  19 You should have received a copy of the GNU General Public License
  20 along with this program; if not, write to the Free Software
  21 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}
  22
  23 ######################################################################
  24 ##
  25 ## read only globals
  26
  27 set _appname [lindex [file split $argv0] end]
  28 set _gitdir {}
  29 set _reponame {}
  30
  31 proc appname {} {
  32         global _appname
  33         return $_appname
  34 }
  35
  36 proc gitdir {args} {
  37         global _gitdir
  38         if {$args eq {}} {
  39                 return $_gitdir
  40         }
  41         return [eval [concat [list file join $_gitdir] $args]]
  42 }
  43
  44 proc reponame {} {
  45         global _reponame
  46         return $_reponame
  47 }
  48
  49 ######################################################################
  50 ##
  51 ## config
  52
  53 proc is_many_config {name} {
  54         switch -glob -- $name {
  55         remote.*.fetch -
  56         remote.*.push
  57                 {return 1}
  58         *
  59                 {return 0}
  60         }
  61 }
  62
  63 proc load_config {include_global} {
  64         global repo_config global_config default_config
  65
  66         array unset global_config
  67         if {$include_global} {
  68                 catch {
  69                         set fd_rc [open "| git repo-config --global --list" r]
  70                         while {[gets $fd_rc line] >= 0} {
  71                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  72                                         if {[is_many_config $name]} {
  73                                                 lappend global_config($name) $value
  74                                         } else {
  75                                                 set global_config($name) $value
  76                                         }
  77                                 }
  78                         }
  79                         close $fd_rc
  80                 }
  81         }
  82
  83         array unset repo_config
  84         catch {
  85                 set fd_rc [open "| git repo-config --list" r]
  86                 while {[gets $fd_rc line] >= 0} {
  87                         if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  88                                 if {[is_many_config $name]} {
  89                                         lappend repo_config($name) $value
  90                                 } else {
  91                                         set repo_config($name) $value
  92                                 }
  93                         }
  94                 }
  95                 close $fd_rc
  96         }
  97
  98         foreach name [array names default_config] {
  99                 if {[catch {set v $global_config($name)}]} {
 100                         set global_config($name) $default_config($name)
 101                 }
 102                 if {[catch {set v $repo_config($name)}]} {
 103                         set repo_config($name) $default_config($name)
 104                 }
 105         }
 106 }
 107
 108 proc save_config {} {
 109         global default_config font_descs
 110         global repo_config global_config
 111         global repo_config_new global_config_new
 112
 113         foreach option $font_descs {
 114                 set name [lindex $option 0]
 115                 set font [lindex $option 1]
 116                 font configure $font \
 117                         -family $global_config_new(gui.$font^^family) \
 118                         -size $global_config_new(gui.$font^^size)
 119                 font configure ${font}bold \
 120                         -family $global_config_new(gui.$font^^family) \
 121                         -size $global_config_new(gui.$font^^size)
 122                 set global_config_new(gui.$name) [font configure $font]
 123                 unset global_config_new(gui.$font^^family)
 124                 unset global_config_new(gui.$font^^size)
 125         }
 126
 127         foreach name [array names default_config] {
 128                 set value $global_config_new($name)
 129                 if {$value ne $global_config($name)} {
 130                         if {$value eq $default_config($name)} {
 131                                 catch {exec git repo-config --global --unset $name}
 132                         } else {
 133                                 regsub -all "\[{}\]" $value {"} value
 134                                 exec git repo-config --global $name $value
 135                         }
 136                         set global_config($name) $value
 137                         if {$value eq $repo_config($name)} {
 138                                 catch {exec git repo-config --unset $name}
 139                                 set repo_config($name) $value
 140                         }
 141                 }
 142         }
 143
 144         foreach name [array names default_config] {
 145                 set value $repo_config_new($name)
 146                 if {$value ne $repo_config($name)} {
 147                         if {$value eq $global_config($name)} {
 148                                 catch {exec git repo-config --unset $name}
 149                         } else {
 150                                 regsub -all "\[{}\]" $value {"} value
 151                                 exec git repo-config $name $value
 152                         }
 153                         set repo_config($name) $value
 154                 }
 155         }
 156 }
 157
 158 proc error_popup {msg} {
 159         set title [appname]
 160         if {[reponame] ne {}} {
 161                 append title " ([reponame])"
 162         }
 163         set cmd [list tk_messageBox \
 164                 -icon error \
 165                 -type ok \
 166                 -title "$title: error" \
 167                 -message $msg]
 168         if {[winfo ismapped .]} {
 169                 lappend cmd -parent .
 170         }
 171         eval $cmd
 172 }
 173
 174 proc warn_popup {msg} {
 175         set title [appname]
 176         if {[reponame] ne {}} {
 177                 append title " ([reponame])"
 178         }
 179         set cmd [list tk_messageBox \
 180                 -icon warning \
 181                 -type ok \
 182                 -title "$title: warning" \
 183                 -message $msg]
 184         if {[winfo ismapped .]} {
 185                 lappend cmd -parent .
 186         }
 187         eval $cmd
 188 }
 189
 190 proc info_popup {msg} {
 191         set title [appname]
 192         if {[reponame] ne {}} {
 193                 append title " ([reponame])"
 194         }
 195         tk_messageBox \
 196                 -parent . \
 197                 -icon info \
 198                 -type ok \
 199                 -title $title \
 200                 -message $msg
 201 }
 202
 203 proc ask_popup {msg} {
 204         set title [appname]
 205         if {[reponame] ne {}} {
 206                 append title " ([reponame])"
 207         }
 208         return [tk_messageBox \
 209                 -parent . \
 210                 -icon question \
 211                 -type yesno \
 212                 -title $title \
 213                 -message $msg]
 214 }
 215
 216 ######################################################################
 217 ##
 218 ## repository setup
 219
 220 if {   [catch {set _gitdir $env(GIT_DIR)}]
 221         && [catch {set _gitdir [exec git rev-parse --git-dir]} err]} {
 222         catch {wm withdraw .}
 223         error_popup "Cannot find the git directory:\n\n$err"
 224         exit 1
 225 }
 226 if {![file isdirectory $_gitdir]} {
 227         catch {wm withdraw .}
 228         error_popup "Git directory not found:\n\n$_gitdir"
 229         exit 1
 230 }
 231 if {[lindex [file split $_gitdir] end] ne {.git}} {
 232         catch {wm withdraw .}
 233         error_popup "Cannot use funny .git directory:\n\n$gitdir"
 234         exit 1
 235 }
 236 if {[catch {cd [file dirname $_gitdir]} err]} {
 237         catch {wm withdraw .}
 238         error_popup "No working directory [file dirname $_gitdir]:\n\n$err"
 239         exit 1
 240 }
 241 set _reponame [lindex [file split \
 242         [file normalize [file dirname $_gitdir]]] \
 243         end]
 244
 245 set single_commit 0
 246 if {[appname] eq {git-citool}} {
 247         set single_commit 1
 248 }
 249
 250 ######################################################################
 251 ##
 252 ## task management
 253
 254 set rescan_active 0
 255 set diff_active 0
 256 set last_clicked {}
 257
 258 set disable_on_lock [list]
 259 set index_lock_type none
 260
 261 proc lock_index {type} {
 262         global index_lock_type disable_on_lock
 263
 264         if {$index_lock_type eq {none}} {
 265                 set index_lock_type $type
 266                 foreach w $disable_on_lock {
 267                         uplevel #0 $w disabled
 268                 }
 269                 return 1
 270         } elseif {$index_lock_type eq "begin-$type"} {
 271                 set index_lock_type $type
 272                 return 1
 273         }
 274         return 0
 275 }
 276
 277 proc unlock_index {} {
 278         global index_lock_type disable_on_lock
 279
 280         set index_lock_type none
 281         foreach w $disable_on_lock {
 282                 uplevel #0 $w normal
 283         }
 284 }
 285
 286 ######################################################################
 287 ##
 288 ## status
 289
 290 proc repository_state {ctvar hdvar mhvar} {
 291         global current_branch
 292         upvar $ctvar ct $hdvar hd $mhvar mh
 293
 294         set mh [list]
 295
 296         if {[catch {set current_branch [exec git symbolic-ref HEAD]}]} {
 297                 set current_branch {}
 298         } else {
 299                 regsub ^refs/((heads|tags|remotes)/)? \
 300                         $current_branch \
 301                         {} \
 302                         current_branch
 303         }
 304
 305         if {[catch {set hd [exec git rev-parse --verify HEAD]}]} {
 306                 set hd {}
 307                 set ct initial
 308                 return
 309         }
 310
 311         set merge_head [gitdir MERGE_HEAD]
 312         if {[file exists $merge_head]} {
 313                 set ct merge
 314                 set fd_mh [open $merge_head r]
 315                 while {[gets $fd_mh line] >= 0} {
 316                         lappend mh $line
 317                 }
 318                 close $fd_mh
 319                 return
 320         }
 321
 322         set ct normal
 323 }
 324
 325 proc PARENT {} {
 326         global PARENT empty_tree
 327
 328         set p [lindex $PARENT 0]
 329         if {$p ne {}} {
 330                 return $p
 331         }
 332         if {$empty_tree eq {}} {
 333                 set empty_tree [exec git mktree << {}]
 334         }
 335         return $empty_tree
 336 }
 337
 338 proc rescan {after} {
 339         global HEAD PARENT MERGE_HEAD commit_type
 340         global ui_index ui_workdir ui_status_value ui_comm
 341         global rescan_active file_states
 342         global repo_config
 343
 344         if {$rescan_active > 0 || ![lock_index read]} return
 345
 346         repository_state newType newHEAD newMERGE_HEAD
 347         if {[string match amend* $commit_type]
 348                 && $newType eq {normal}
 349                 && $newHEAD eq $HEAD} {
 350         } else {
 351                 set HEAD $newHEAD
 352                 set PARENT $newHEAD
 353                 set MERGE_HEAD $newMERGE_HEAD
 354                 set commit_type $newType
 355         }
 356
 357         array unset file_states
 358
 359         if {![$ui_comm edit modified]
 360                 || [string trim [$ui_comm get 0.0 end]] eq {}} {
 361                 if {[load_message GITGUI_MSG]} {
 362                 } elseif {[load_message MERGE_MSG]} {
 363                 } elseif {[load_message SQUASH_MSG]} {
 364                 }
 365                 $ui_comm edit reset
 366                 $ui_comm edit modified false
 367         }
 368
 369         if {$repo_config(gui.trustmtime) eq {true}} {
 370                 rescan_stage2 {} $after
 371         } else {
 372                 set rescan_active 1
 373                 set ui_status_value {Refreshing file status...}
 374                 set cmd [list git update-index]
 375                 lappend cmd -q
 376                 lappend cmd --unmerged
 377                 lappend cmd --ignore-missing
 378                 lappend cmd --refresh
 379                 set fd_rf [open "| $cmd" r]
 380                 fconfigure $fd_rf -blocking 0 -translation binary
 381                 fileevent $fd_rf readable \
 382                         [list rescan_stage2 $fd_rf $after]
 383         }
 384 }
 385
 386 proc rescan_stage2 {fd after} {
 387         global ui_status_value
 388         global rescan_active buf_rdi buf_rdf buf_rlo
 389
 390         if {$fd ne {}} {
 391                 read $fd
 392                 if {![eof $fd]} return
 393                 close $fd
 394         }
 395
 396         set ls_others [list | git ls-files --others -z \
 397                 --exclude-per-directory=.gitignore]
 398         set info_exclude [gitdir info exclude]
 399         if {[file readable $info_exclude]} {
 400                 lappend ls_others "--exclude-from=$info_exclude"
 401         }
 402
 403         set buf_rdi {}
 404         set buf_rdf {}
 405         set buf_rlo {}
 406
 407         set rescan_active 3
 408         set ui_status_value {Scanning for modified files ...}
 409         set fd_di [open "| git diff-index --cached -z [PARENT]" r]
 410         set fd_df [open "| git diff-files -z" r]
 411         set fd_lo [open $ls_others r]
 412
 413         fconfigure $fd_di -blocking 0 -translation binary
 414         fconfigure $fd_df -blocking 0 -translation binary
 415         fconfigure $fd_lo -blocking 0 -translation binary
 416         fileevent $fd_di readable [list read_diff_index $fd_di $after]
 417         fileevent $fd_df readable [list read_diff_files $fd_df $after]
 418         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
 419 }
 420
 421 proc load_message {file} {
 422         global ui_comm
 423
 424         set f [gitdir $file]
 425         if {[file isfile $f]} {
 426                 if {[catch {set fd [open $f r]}]} {
 427                         return 0
 428                 }
 429                 set content [string trim [read $fd]]
 430                 close $fd
 431                 $ui_comm delete 0.0 end
 432                 $ui_comm insert end $content
 433                 return 1
 434         }
 435         return 0
 436 }
 437
 438 proc read_diff_index {fd after} {
 439         global buf_rdi
 440
 441         append buf_rdi [read $fd]
 442         set c 0
 443         set n [string length $buf_rdi]
 444         while {$c < $n} {
 445                 set z1 [string first "\0" $buf_rdi $c]
 446                 if {$z1 == -1} break
 447                 incr z1
 448                 set z2 [string first "\0" $buf_rdi $z1]
 449                 if {$z2 == -1} break
 450
 451                 incr c
 452                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
 453                 merge_state \
 454                         [string range $buf_rdi $z1 [expr {$z2 - 1}]] \
 455                         [lindex $i 4]? \
 456                         [list [lindex $i 0] [lindex $i 2]] \
 457                         [list]
 458                 set c $z2
 459                 incr c
 460         }
 461         if {$c < $n} {
 462                 set buf_rdi [string range $buf_rdi $c end]
 463         } else {
 464                 set buf_rdi {}
 465         }
 466
 467         rescan_done $fd buf_rdi $after
 468 }
 469
 470 proc read_diff_files {fd after} {
 471         global buf_rdf
 472
 473         append buf_rdf [read $fd]
 474         set c 0
 475         set n [string length $buf_rdf]
 476         while {$c < $n} {
 477                 set z1 [string first "\0" $buf_rdf $c]
 478                 if {$z1 == -1} break
 479                 incr z1
 480                 set z2 [string first "\0" $buf_rdf $z1]
 481                 if {$z2 == -1} break
 482
 483                 incr c
 484                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
 485                 merge_state \
 486                         [string range $buf_rdf $z1 [expr {$z2 - 1}]] \
 487                         ?[lindex $i 4] \
 488                         [list] \
 489                         [list [lindex $i 0] [lindex $i 2]]
 490                 set c $z2
 491                 incr c
 492         }
 493         if {$c < $n} {
 494                 set buf_rdf [string range $buf_rdf $c end]
 495         } else {
 496                 set buf_rdf {}
 497         }
 498
 499         rescan_done $fd buf_rdf $after
 500 }
 501
 502 proc read_ls_others {fd after} {
 503         global buf_rlo
 504
 505         append buf_rlo [read $fd]
 506         set pck [split $buf_rlo "\0"]
 507         set buf_rlo [lindex $pck end]
 508         foreach p [lrange $pck 0 end-1] {
 509                 merge_state $p ?O
 510         }
 511         rescan_done $fd buf_rlo $after
 512 }
 513
 514 proc rescan_done {fd buf after} {
 515         global rescan_active
 516         global file_states repo_config
 517         upvar $buf to_clear
 518
 519         if {![eof $fd]} return
 520         set to_clear {}
 521         close $fd
 522         if {[incr rescan_active -1] > 0} return
 523
 524         prune_selection
 525         unlock_index
 526         display_all_files
 527         reshow_diff
 528         uplevel #0 $after
 529 }
 530
 531 proc prune_selection {} {
 532         global file_states selected_paths
 533
 534         foreach path [array names selected_paths] {
 535                 if {[catch {set still_here $file_states($path)}]} {
 536                         unset selected_paths($path)
 537                 }
 538         }
 539 }
 540
 541 ######################################################################
 542 ##
 543 ## diff
 544
 545 proc clear_diff {} {
 546         global ui_diff current_diff_path ui_index ui_workdir
 547
 548         $ui_diff conf -state normal
 549         $ui_diff delete 0.0 end
 550         $ui_diff conf -state disabled
 551
 552         set current_diff_path {}
 553
 554         $ui_index tag remove in_diff 0.0 end
 555         $ui_workdir tag remove in_diff 0.0 end
 556 }
 557
 558 proc reshow_diff {} {
 559         global ui_status_value file_states file_lists
 560         global current_diff_path current_diff_side
 561
 562         set p $current_diff_path
 563         if {$p eq {}
 564                 || $current_diff_side eq {}
 565                 || [catch {set s $file_states($p)}]
 566                 || [lsearch -sorted $file_lists($current_diff_side) $p] == -1} {
 567                 clear_diff
 568         } else {
 569                 show_diff $p $current_diff_side
 570         }
 571 }
 572
 573 proc handle_empty_diff {} {
 574         global current_diff_path file_states file_lists
 575
 576         set path $current_diff_path
 577         set s $file_states($path)
 578         if {[lindex $s 0] ne {_M}} return
 579
 580         info_popup "No differences detected.
 581
 582 [short_path $path] has no changes.
 583
 584 The modification date of this file was updated
 585 by another application and you currently have
 586 the Trust File Modification Timestamps option
 587 enabled, so Git did not automatically detect
 588 that there are no content differences in this
 589 file.
 590
 591 This file will now be removed from the modified
 592 files list, to prevent possible confusion.
 593 "
 594         if {[catch {exec git update-index -- $path} err]} {
 595                 error_popup "Failed to refresh index:\n\n$err"
 596         }
 597
 598         clear_diff
 599         display_file $path __
 600 }
 601
 602 proc show_diff {path w {lno {}}} {
 603         global file_states file_lists
 604         global is_3way_diff diff_active repo_config
 605         global ui_diff ui_status_value ui_index ui_workdir
 606         global current_diff_path current_diff_side
 607
 608         if {$diff_active || ![lock_index read]} return
 609
 610         clear_diff
 611         if {$w eq {} || $lno == {}} {
 612                 foreach w [array names file_lists] {
 613                         set lno [lsearch -sorted $file_lists($w) $path]
 614                         if {$lno >= 0} {
 615                                 incr lno
 616                                 break
 617                         }
 618                 }
 619         }
 620         if {$w ne {} && $lno >= 1} {
 621                 $w tag add in_diff $lno.0 [expr {$lno + 1}].0
 622         }
 623
 624         set s $file_states($path)
 625         set m [lindex $s 0]
 626         set is_3way_diff 0
 627         set diff_active 1
 628         set current_diff_path $path
 629         set current_diff_side $w
 630         set ui_status_value "Loading diff of [escape_path $path]..."
 631
 632         # - Git won't give us the diff, there's nothing to compare to!
 633         #
 634         if {$m eq {_O}} {
 635                 if {[catch {
 636                                 set fd [open $path r]
 637                                 set content [read $fd]
 638                                 close $fd
 639                         } err ]} {
 640                         set diff_active 0
 641                         unlock_index
 642                         set ui_status_value "Unable to display [escape_path $path]"
 643                         error_popup "Error loading file:\n\n$err"
 644                         return
 645                 }
 646                 $ui_diff conf -state normal
 647                 $ui_diff insert end $content
 648                 $ui_diff conf -state disabled
 649                 set diff_active 0
 650                 unlock_index
 651                 set ui_status_value {Ready.}
 652                 return
 653         }
 654
 655         set cmd [list | git]
 656         if {$w eq $ui_index} {
 657                 lappend cmd diff-index
 658                 lappend cmd --cached
 659         } elseif {$w eq $ui_workdir} {
 660                 if {[string index $m 0] eq {U}} {
 661                         lappend cmd diff
 662                 } else {
 663                         lappend cmd diff-files
 664                 }
 665         }
 666
 667         lappend cmd -p
 668         lappend cmd --no-color
 669         if {$repo_config(gui.diffcontext) > 0} {
 670                 lappend cmd "-U$repo_config(gui.diffcontext)"
 671         }
 672         if {$w eq $ui_index} {
 673                 lappend cmd [PARENT]
 674         }
 675         lappend cmd --
 676         lappend cmd $path
 677
 678         if {[catch {set fd [open $cmd r]} err]} {
 679                 set diff_active 0
 680                 unlock_index
 681                 set ui_status_value "Unable to display [escape_path $path]"
 682                 error_popup "Error loading diff:\n\n$err"
 683                 return
 684         }
 685
 686         fconfigure $fd -blocking 0 -translation auto
 687         fileevent $fd readable [list read_diff $fd]
 688 }
 689
 690 proc read_diff {fd} {
 691         global ui_diff ui_status_value is_3way_diff diff_active
 692         global repo_config
 693
 694         $ui_diff conf -state normal
 695         while {[gets $fd line] >= 0} {
 696                 # -- Cleanup uninteresting diff header lines.
 697                 #
 698                 if {[string match {diff --git *}      $line]} continue
 699                 if {[string match {diff --cc *}       $line]} continue
 700                 if {[string match {diff --combined *} $line]} continue
 701                 if {[string match {--- *}             $line]} continue
 702                 if {[string match {+++ *}             $line]} continue
 703                 if {$line eq {deleted file mode 120000}} {
 704                         set line "deleted symlink"
 705                 }
 706
 707                 # -- Automatically detect if this is a 3 way diff.
 708                 #
 709                 if {[string match {@@@ *} $line]} {set is_3way_diff 1}
 710
 711                 if {[string match {index *} $line]
 712                         || [regexp {^\* Unmerged path } $line]} {
 713                         set tags {}
 714                 } elseif {$is_3way_diff} {
 715                         set op [string range $line 0 1]
 716                         switch -- $op {
 717                         {  } {set tags {}}
 718                         {@@} {set tags d_@}
 719                         { +} {set tags d_s+}
 720                         { -} {set tags d_s-}
 721                         {+ } {set tags d_+s}
 722                         {- } {set tags d_-s}
 723                         {--} {set tags d_--}
 724                         {++} {
 725                                 if {[regexp {^\+\+([<>]{7} |={7})} $line _g op]} {
 726                                         set line [string replace $line 0 1 {  }]
 727                                         set tags d$op
 728                                 } else {
 729                                         set tags d_++
 730                                 }
 731                         }
 732                         default {
 733                                 puts "error: Unhandled 3 way diff marker: {$op}"
 734                                 set tags {}
 735                         }
 736                         }
 737                 } else {
 738                         set op [string index $line 0]
 739                         switch -- $op {
 740                         { } {set tags {}}
 741                         {@} {set tags d_@}
 742                         {-} {set tags d_-}
 743                         {+} {
 744                                 if {[regexp {^\+([<>]{7} |={7})} $line _g op]} {
 745                                         set line [string replace $line 0 0 { }]
 746                                         set tags d$op
 747                                 } else {
 748                                         set tags d_+
 749                                 }
 750                         }
 751                         default {
 752                                 puts "error: Unhandled 2 way diff marker: {$op}"
 753                                 set tags {}
 754                         }
 755                         }
 756                 }
 757                 $ui_diff insert end $line $tags
 758                 $ui_diff insert end "\n" $tags
 759         }
 760         $ui_diff conf -state disabled
 761
 762         if {[eof $fd]} {
 763                 close $fd
 764                 set diff_active 0
 765                 unlock_index
 766                 set ui_status_value {Ready.}
 767
 768                 if {$repo_config(gui.trustmtime) eq {true}
 769                         && [$ui_diff index end] eq {2.0}} {
 770                         handle_empty_diff
 771                 }
 772         }
 773 }
 774
 775 ######################################################################
 776 ##
 777 ## commit
 778
 779 proc load_last_commit {} {
 780         global HEAD PARENT MERGE_HEAD commit_type ui_comm
 781
 782         if {[llength $PARENT] == 0} {
 783                 error_popup {There is nothing to amend.
 784
 785 You are about to create the initial commit.
 786 There is no commit before this to amend.
 787 }
 788                 return
 789         }
 790
 791         repository_state curType curHEAD curMERGE_HEAD
 792         if {$curType eq {merge}} {
 793                 error_popup {Cannot amend while merging.
 794
 795 You are currently in the middle of a merge that
 796 has not been fully completed.  You cannot amend
 797 the prior commit unless you first abort the
 798 current merge activity.
 799 }
 800                 return
 801         }
 802
 803         set msg {}
 804         set parents [list]
 805         if {[catch {
 806                         set fd [open "| git cat-file commit $curHEAD" r]
 807                         while {[gets $fd line] > 0} {
 808                                 if {[string match {parent *} $line]} {
 809                                         lappend parents [string range $line 7 end]
 810                                 }
 811                         }
 812                         set msg [string trim [read $fd]]
 813                         close $fd
 814                 } err]} {
 815                 error_popup "Error loading commit data for amend:\n\n$err"
 816                 return
 817         }
 818
 819         set HEAD $curHEAD
 820         set PARENT $parents
 821         set MERGE_HEAD [list]
 822         switch -- [llength $parents] {
 823         0       {set commit_type amend-initial}
 824         1       {set commit_type amend}
 825         default {set commit_type amend-merge}
 826         }
 827
 828         $ui_comm delete 0.0 end
 829         $ui_comm insert end $msg
 830         $ui_comm edit reset
 831         $ui_comm edit modified false
 832         rescan {set ui_status_value {Ready.}}
 833 }
 834
 835 proc create_new_commit {} {
 836         global commit_type ui_comm
 837
 838         set commit_type normal
 839         $ui_comm delete 0.0 end
 840         $ui_comm edit reset
 841         $ui_comm edit modified false
 842         rescan {set ui_status_value {Ready.}}
 843 }
 844
 845 set GIT_COMMITTER_IDENT {}
 846
 847 proc committer_ident {} {
 848         global GIT_COMMITTER_IDENT
 849
 850         if {$GIT_COMMITTER_IDENT eq {}} {
 851                 if {[catch {set me [exec git var GIT_COMMITTER_IDENT]} err]} {
 852                         error_popup "Unable to obtain your identity:\n\n$err"
 853                         return {}
 854                 }
 855                 if {![regexp {^(.*) [0-9]+ [-+0-9]+$} \
 856                         $me me GIT_COMMITTER_IDENT]} {
 857                         error_popup "Invalid GIT_COMMITTER_IDENT:\n\n$me"
 858                         return {}
 859                 }
 860         }
 861
 862         return $GIT_COMMITTER_IDENT
 863 }
 864
 865 proc commit_tree {} {
 866         global HEAD commit_type file_states ui_comm repo_config
 867         global ui_status_value pch_error
 868
 869         if {![lock_index update]} return
 870         if {[committer_ident] eq {}} return
 871
 872         # -- Our in memory state should match the repository.
 873         #
 874         repository_state curType curHEAD curMERGE_HEAD
 875         if {[string match amend* $commit_type]
 876                 && $curType eq {normal}
 877                 && $curHEAD eq $HEAD} {
 878         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
 879                 info_popup {Last scanned state does not match repository state.
 880
 881 Another Git program has modified this repository
 882 since the last scan.  A rescan must be performed
 883 before another commit can be created.
 884
 885 The rescan will be automatically started now.
 886 }
 887                 unlock_index
 888                 rescan {set ui_status_value {Ready.}}
 889                 return
 890         }
 891
 892         # -- At least one file should differ in the index.
 893         #
 894         set files_ready 0
 895         foreach path [array names file_states] {
 896                 switch -glob -- [lindex $file_states($path) 0] {
 897                 _? {continue}
 898                 A? -
 899                 D? -
 900                 M? {set files_ready 1}
 901                 U? {
 902                         error_popup "Unmerged files cannot be committed.
 903
 904 File [short_path $path] has merge conflicts.
 905 You must resolve them and add the file before committing.
 906 "
 907                         unlock_index
 908                         return
 909                 }
 910                 default {
 911                         error_popup "Unknown file state [lindex $s 0] detected.
 912
 913 File [short_path $path] cannot be committed by this program.
 914 "
 915                 }
 916                 }
 917         }
 918         if {!$files_ready} {
 919                 info_popup {No changes to commit.
 920
 921 You must add at least 1 file before you can commit.
 922 }
 923                 unlock_index
 924                 return
 925         }
 926
 927         # -- A message is required.
 928         #
 929         set msg [string trim [$ui_comm get 1.0 end]]
 930         if {$msg eq {}} {
 931                 error_popup {Please supply a commit message.
 932
 933 A good commit message has the following format:
 934
 935 - First line: Describe in one sentance what you did.
 936 - Second line: Blank
 937 - Remaining lines: Describe why this change is good.
 938 }
 939                 unlock_index
 940                 return
 941         }
 942
 943         # -- Run the pre-commit hook.
 944         #
 945         set pchook [gitdir hooks pre-commit]
 946
 947         # On Cygwin [file executable] might lie so we need to ask
 948         # the shell if the hook is executable.  Yes that's annoying.
 949         #
 950         if {[is_Windows] && [file isfile $pchook]} {
 951                 set pchook [list sh -c [concat \
 952                         "if test -x \"$pchook\";" \
 953                         "then exec \"$pchook\" 2>&1;" \
 954                         "fi"]]
 955         } elseif {[file executable $pchook]} {
 956                 set pchook [list $pchook |& cat]
 957         } else {
 958                 commit_writetree $curHEAD $msg
 959                 return
 960         }
 961
 962         set ui_status_value {Calling pre-commit hook...}
 963         set pch_error {}
 964         set fd_ph [open "| $pchook" r]
 965         fconfigure $fd_ph -blocking 0 -translation binary
 966         fileevent $fd_ph readable \
 967                 [list commit_prehook_wait $fd_ph $curHEAD $msg]
 968 }
 969
 970 proc commit_prehook_wait {fd_ph curHEAD msg} {
 971         global pch_error ui_status_value
 972
 973         append pch_error [read $fd_ph]
 974         fconfigure $fd_ph -blocking 1
 975         if {[eof $fd_ph]} {
 976                 if {[catch {close $fd_ph}]} {
 977                         set ui_status_value {Commit declined by pre-commit hook.}
 978                         hook_failed_popup pre-commit $pch_error
 979                         unlock_index
 980                 } else {
 981                         commit_writetree $curHEAD $msg
 982                 }
 983                 set pch_error {}
 984                 return
 985         }
 986         fconfigure $fd_ph -blocking 0
 987 }
 988
 989 proc commit_writetree {curHEAD msg} {
 990         global ui_status_value
 991
 992         set ui_status_value {Committing changes...}
 993         set fd_wt [open "| git write-tree" r]
 994         fileevent $fd_wt readable \
 995                 [list commit_committree $fd_wt $curHEAD $msg]
 996 }
 997
 998 proc commit_committree {fd_wt curHEAD msg} {
 999         global HEAD PARENT MERGE_HEAD commit_type
1000         global single_commit
1001         global ui_status_value ui_comm selected_commit_type
1002         global file_states selected_paths rescan_active
1003
1004         gets $fd_wt tree_id
1005         if {$tree_id eq {} || [catch {close $fd_wt} err]} {
1006                 error_popup "write-tree failed:\n\n$err"
1007                 set ui_status_value {Commit failed.}
1008                 unlock_index
1009                 return
1010         }
1011
1012         # -- Create the commit.
1013         #
1014         set cmd [list git commit-tree $tree_id]
1015         set parents [concat $PARENT $MERGE_HEAD]
1016         if {[llength $parents] > 0} {
1017                 foreach p $parents {
1018                         lappend cmd -p $p
1019                 }
1020         } else {
1021                 # git commit-tree writes to stderr during initial commit.
1022                 lappend cmd 2>/dev/null
1023         }
1024         lappend cmd << $msg
1025         if {[catch {set cmt_id [eval exec $cmd]} err]} {
1026                 error_popup "commit-tree failed:\n\n$err"
1027                 set ui_status_value {Commit failed.}
1028                 unlock_index
1029                 return
1030         }
1031
1032         # -- Update the HEAD ref.
1033         #
1034         set reflogm commit
1035         if {$commit_type ne {normal}} {
1036                 append reflogm " ($commit_type)"
1037         }
1038         set i [string first "\n" $msg]
1039         if {$i >= 0} {
1040                 append reflogm {: } [string range $msg 0 [expr {$i - 1}]]
1041         } else {
1042                 append reflogm {: } $msg
1043         }
1044         set cmd [list git update-ref -m $reflogm HEAD $cmt_id $curHEAD]
1045         if {[catch {eval exec $cmd} err]} {
1046                 error_popup "update-ref failed:\n\n$err"
1047                 set ui_status_value {Commit failed.}
1048                 unlock_index
1049                 return
1050         }
1051
1052         # -- Cleanup after ourselves.
1053         #
1054         catch {file delete [gitdir MERGE_HEAD]}
1055         catch {file delete [gitdir MERGE_MSG]}
1056         catch {file delete [gitdir SQUASH_MSG]}
1057         catch {file delete [gitdir GITGUI_MSG]}
1058
1059         # -- Let rerere do its thing.
1060         #
1061         if {[file isdirectory [gitdir rr-cache]]} {
1062                 catch {exec git rerere}
1063         }
1064
1065         # -- Run the post-commit hook.
1066         #
1067         set pchook [gitdir hooks post-commit]
1068         if {[is_Windows] && [file isfile $pchook]} {
1069                 set pchook [list sh -c [concat \
1070                         "if test -x \"$pchook\";" \
1071                         "then exec \"$pchook\";" \
1072                         "fi"]]
1073         } elseif {![file executable $pchook]} {
1074                 set pchook {}
1075         }
1076         if {$pchook ne {}} {
1077                 catch {exec $pchook &}
1078         }
1079
1080         $ui_comm delete 0.0 end
1081         $ui_comm edit reset
1082         $ui_comm edit modified false
1083
1084         if {$single_commit} do_quit
1085
1086         # -- Update in memory status
1087         #
1088         set selected_commit_type new
1089         set commit_type normal
1090         set HEAD $cmt_id
1091         set PARENT $cmt_id
1092         set MERGE_HEAD [list]
1093
1094         foreach path [array names file_states] {
1095                 set s $file_states($path)
1096                 set m [lindex $s 0]
1097                 switch -glob -- $m {
1098                 _O -
1099                 _M -
1100                 _D {continue}
1101                 __ -
1102                 A_ -
1103                 M_ -
1104                 D_ {
1105                         unset file_states($path)
1106                         catch {unset selected_paths($path)}
1107                 }
1108                 DO {
1109                         set file_states($path) [list _O [lindex $s 1] {} {}]
1110                 }
1111                 AM -
1112                 AD -
1113                 MM -
1114                 MD {
1115                         set file_states($path) [list \
1116                                 _[string index $m 1] \
1117                                 [lindex $s 1] \
1118                                 [lindex $s 3] \
1119                                 {}]
1120                 }
1121                 }
1122         }
1123
1124         display_all_files
1125         unlock_index
1126         reshow_diff
1127         set ui_status_value \
1128                 "Changes committed as [string range $cmt_id 0 7]."
1129 }
1130
1131 ######################################################################
1132 ##
1133 ## fetch pull push
1134
1135 proc fetch_from {remote} {
1136         set w [new_console "fetch $remote" \
1137                 "Fetching new changes from $remote"]
1138         set cmd [list git fetch]
1139         lappend cmd $remote
1140         console_exec $w $cmd
1141 }
1142
1143 proc pull_remote {remote branch} {
1144         global HEAD commit_type file_states repo_config
1145
1146         if {![lock_index update]} return
1147
1148         # -- Our in memory state should match the repository.
1149         #
1150         repository_state curType curHEAD curMERGE_HEAD
1151         if {$commit_type ne $curType || $HEAD ne $curHEAD} {
1152                 info_popup {Last scanned state does not match repository state.
1153
1154 Another Git program has modified this repository
1155 since the last scan.  A rescan must be performed
1156 before a pull operation can be started.
1157
1158 The rescan will be automatically started now.
1159 }
1160                 unlock_index
1161                 rescan {set ui_status_value {Ready.}}
1162                 return
1163         }
1164
1165         # -- No differences should exist before a pull.
1166         #
1167         if {[array size file_states] != 0} {
1168                 error_popup {Uncommitted but modified files are present.
1169
1170 You should not perform a pull with unmodified
1171 files in your working directory as Git will be
1172 unable to recover from an incorrect merge.
1173
1174 You should commit or revert all changes before
1175 starting a pull operation.
1176 }
1177                 unlock_index
1178                 return
1179         }
1180
1181         set w [new_console "pull $remote $branch" \
1182                 "Pulling new changes from branch $branch in $remote"]
1183         set cmd [list git pull]
1184         if {$repo_config(gui.pullsummary) eq {false}} {
1185                 lappend cmd --no-summary
1186         }
1187         lappend cmd $remote
1188         lappend cmd $branch
1189         console_exec $w $cmd [list post_pull_remote $remote $branch]
1190 }
1191
1192 proc post_pull_remote {remote branch success} {
1193         global HEAD PARENT MERGE_HEAD commit_type selected_commit_type
1194         global ui_status_value
1195
1196         unlock_index
1197         if {$success} {
1198                 repository_state commit_type HEAD MERGE_HEAD
1199                 set PARENT $HEAD
1200                 set selected_commit_type new
1201                 set ui_status_value "Pulling $branch from $remote complete."
1202         } else {
1203                 rescan [list set ui_status_value \
1204                         "Conflicts detected while pulling $branch from $remote."]
1205         }
1206 }
1207
1208 proc push_to {remote} {
1209         set w [new_console "push $remote" \
1210                 "Pushing changes to $remote"]
1211         set cmd [list git push]
1212         lappend cmd $remote
1213         console_exec $w $cmd
1214 }
1215
1216 ######################################################################
1217 ##
1218 ## ui helpers
1219
1220 proc mapicon {w state path} {
1221         global all_icons
1222
1223         if {[catch {set r $all_icons($state$w)}]} {
1224                 puts "error: no icon for $w state={$state} $path"
1225                 return file_plain
1226         }
1227         return $r
1228 }
1229
1230 proc mapdesc {state path} {
1231         global all_descs
1232
1233         if {[catch {set r $all_descs($state)}]} {
1234                 puts "error: no desc for state={$state} $path"
1235                 return $state
1236         }
1237         return $r
1238 }
1239
1240 proc escape_path {path} {
1241         regsub -all "\n" $path "\\n" path
1242         return $path
1243 }
1244
1245 proc short_path {path} {
1246         return [escape_path [lindex [file split $path] end]]
1247 }
1248
1249 set next_icon_id 0
1250 set null_sha1 [string repeat 0 40]
1251
1252 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1253         global file_states next_icon_id null_sha1
1254
1255         set s0 [string index $new_state 0]
1256         set s1 [string index $new_state 1]
1257
1258         if {[catch {set info $file_states($path)}]} {
1259                 set state __
1260                 set icon n[incr next_icon_id]
1261         } else {
1262                 set state [lindex $info 0]
1263                 set icon [lindex $info 1]
1264                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1265                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1266         }
1267
1268         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1269         elseif {$s0 eq {_}} {set s0 _}
1270
1271         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1272         elseif {$s1 eq {_}} {set s1 _}
1273
1274         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1275                 set head_info [list 0 $null_sha1]
1276         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1277                 && $head_info eq {}} {
1278                 set head_info $index_info
1279         }
1280
1281         set file_states($path) [list $s0$s1 $icon \
1282                 $head_info $index_info \
1283                 ]
1284         return $state
1285 }
1286
1287 proc display_file_helper {w path icon_name old_m new_m} {
1288         global file_lists
1289
1290         if {$new_m eq {_}} {
1291                 set lno [lsearch -sorted $file_lists($w) $path]
1292                 if {$lno >= 0} {
1293                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1294                         incr lno
1295                         $w conf -state normal
1296                         $w delete $lno.0 [expr {$lno + 1}].0
1297                         $w conf -state disabled
1298                 }
1299         } elseif {$old_m eq {_} && $new_m ne {_}} {
1300                 lappend file_lists($w) $path
1301                 set file_lists($w) [lsort -unique $file_lists($w)]
1302                 set lno [lsearch -sorted $file_lists($w) $path]
1303                 incr lno
1304                 $w conf -state normal
1305                 $w image create $lno.0 \
1306                         -align center -padx 5 -pady 1 \
1307                         -name $icon_name \
1308                         -image [mapicon $w $new_m $path]
1309                 $w insert $lno.1 "[escape_path $path]\n"
1310                 $w conf -state disabled
1311         } elseif {$old_m ne $new_m} {
1312                 $w conf -state normal
1313                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1314                 $w conf -state disabled
1315         }
1316 }
1317
1318 proc display_file {path state} {
1319         global file_states selected_paths
1320         global ui_index ui_workdir
1321
1322         set old_m [merge_state $path $state]
1323         set s $file_states($path)
1324         set new_m [lindex $s 0]
1325         set icon_name [lindex $s 1]
1326
1327         set o [string index $old_m 0]
1328         set n [string index $new_m 0]
1329         if {$o eq {U}} {
1330                 set o _
1331         }
1332         if {$n eq {U}} {
1333                 set n _
1334         }
1335         display_file_helper     $ui_index $path $icon_name $o $n
1336
1337         if {[string index $old_m 0] eq {U}} {
1338                 set o U
1339         } else {
1340                 set o [string index $old_m 1]
1341         }
1342         if {[string index $new_m 0] eq {U}} {
1343                 set n U
1344         } else {
1345                 set n [string index $new_m 1]
1346         }
1347         display_file_helper     $ui_workdir $path $icon_name $o $n
1348
1349         if {$new_m eq {__}} {
1350                 unset file_states($path)
1351                 catch {unset selected_paths($path)}
1352         }
1353 }
1354
1355 proc display_all_files_helper {w path icon_name m} {
1356         global file_lists
1357
1358         lappend file_lists($w) $path
1359         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1360         $w image create end \
1361                 -align center -padx 5 -pady 1 \
1362                 -name $icon_name \
1363                 -image [mapicon $w $m $path]
1364         $w insert end "[escape_path $path]\n"
1365 }
1366
1367 proc display_all_files {} {
1368         global ui_index ui_workdir
1369         global file_states file_lists
1370         global last_clicked
1371
1372         $ui_index conf -state normal
1373         $ui_workdir conf -state normal
1374
1375         $ui_index delete 0.0 end
1376         $ui_workdir delete 0.0 end
1377         set last_clicked {}
1378
1379         set file_lists($ui_index) [list]
1380         set file_lists($ui_workdir) [list]
1381
1382         foreach path [lsort [array names file_states]] {
1383                 set s $file_states($path)
1384                 set m [lindex $s 0]
1385                 set icon_name [lindex $s 1]
1386
1387                 set s [string index $m 0]
1388                 if {$s ne {U} && $s ne {_}} {
1389                         display_all_files_helper $ui_index $path \
1390                                 $icon_name $s
1391                 }
1392
1393                 if {[string index $m 0] eq {U}} {
1394                         set s U
1395                 } else {
1396                         set s [string index $m 1]
1397                 }
1398                 if {$s ne {_}} {
1399                         display_all_files_helper $ui_workdir $path \
1400                                 $icon_name $s
1401                 }
1402         }
1403
1404         $ui_index conf -state disabled
1405         $ui_workdir conf -state disabled
1406 }
1407
1408 proc update_indexinfo {msg pathList after} {
1409         global update_index_cp ui_status_value
1410
1411         if {![lock_index update]} return
1412
1413         set update_index_cp 0
1414         set pathList [lsort $pathList]
1415         set totalCnt [llength $pathList]
1416         set batch [expr {int($totalCnt * .01) + 1}]
1417         if {$batch > 25} {set batch 25}
1418
1419         set ui_status_value [format \
1420                 "$msg... %i/%i files (%.2f%%)" \
1421                 $update_index_cp \
1422                 $totalCnt \
1423                 0.0]
1424         set fd [open "| git update-index -z --index-info" w]
1425         fconfigure $fd \
1426                 -blocking 0 \
1427                 -buffering full \
1428                 -buffersize 512 \
1429                 -translation binary
1430         fileevent $fd writable [list \
1431                 write_update_indexinfo \
1432                 $fd \
1433                 $pathList \
1434                 $totalCnt \
1435                 $batch \
1436                 $msg \
1437                 $after \
1438                 ]
1439 }
1440
1441 proc write_update_indexinfo {fd pathList totalCnt batch msg after} {
1442         global update_index_cp ui_status_value
1443         global file_states current_diff_path
1444
1445         if {$update_index_cp >= $totalCnt} {
1446                 close $fd
1447                 unlock_index
1448                 uplevel #0 $after
1449                 return
1450         }
1451
1452         for {set i $batch} \
1453                 {$update_index_cp < $totalCnt && $i > 0} \
1454                 {incr i -1} {
1455                 set path [lindex $pathList $update_index_cp]
1456                 incr update_index_cp
1457
1458                 set s $file_states($path)
1459                 switch -glob -- [lindex $s 0] {
1460                 A? {set new _O}
1461                 M? {set new _M}
1462                 D_ {set new _D}
1463                 D? {set new _?}
1464                 ?? {continue}
1465                 }
1466                 set info [lindex $s 2]
1467                 if {$info eq {}} continue
1468
1469                 puts -nonewline $fd "$info\t$path\0"
1470                 display_file $path $new
1471         }
1472
1473         set ui_status_value [format \
1474                 "$msg... %i/%i files (%.2f%%)" \
1475                 $update_index_cp \
1476                 $totalCnt \
1477                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1478 }
1479
1480 proc update_index {msg pathList after} {
1481         global update_index_cp ui_status_value
1482
1483         if {![lock_index update]} return
1484
1485         set update_index_cp 0
1486         set pathList [lsort $pathList]
1487         set totalCnt [llength $pathList]
1488         set batch [expr {int($totalCnt * .01) + 1}]
1489         if {$batch > 25} {set batch 25}
1490
1491         set ui_status_value [format \
1492                 "$msg... %i/%i files (%.2f%%)" \
1493                 $update_index_cp \
1494                 $totalCnt \
1495                 0.0]
1496         set fd [open "| git update-index --add --remove -z --stdin" w]
1497         fconfigure $fd \
1498                 -blocking 0 \
1499                 -buffering full \
1500                 -buffersize 512 \
1501                 -translation binary
1502         fileevent $fd writable [list \
1503                 write_update_index \
1504                 $fd \
1505                 $pathList \
1506                 $totalCnt \
1507                 $batch \
1508                 $msg \
1509                 $after \
1510                 ]
1511 }
1512
1513 proc write_update_index {fd pathList totalCnt batch msg after} {
1514         global update_index_cp ui_status_value
1515         global file_states current_diff_path
1516
1517         if {$update_index_cp >= $totalCnt} {
1518                 close $fd
1519                 unlock_index
1520                 uplevel #0 $after
1521                 return
1522         }
1523
1524         for {set i $batch} \
1525                 {$update_index_cp < $totalCnt && $i > 0} \
1526                 {incr i -1} {
1527                 set path [lindex $pathList $update_index_cp]
1528                 incr update_index_cp
1529
1530                 switch -glob -- [lindex $file_states($path) 0] {
1531                 AD {set new __}
1532                 ?D {set new D_}
1533                 _O -
1534                 AM {set new A_}
1535                 U? {
1536                         if {[file exists $path]} {
1537                                 set new M_
1538                         } else {
1539                                 set new D_
1540                         }
1541                 }
1542                 ?M {set new M_}
1543                 ?? {continue}
1544                 }
1545                 puts -nonewline $fd "$path\0"
1546                 display_file $path $new
1547         }
1548
1549         set ui_status_value [format \
1550                 "$msg... %i/%i files (%.2f%%)" \
1551                 $update_index_cp \
1552                 $totalCnt \
1553                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1554 }
1555
1556 proc checkout_index {msg pathList after} {
1557         global update_index_cp ui_status_value
1558
1559         if {![lock_index update]} return
1560
1561         set update_index_cp 0
1562         set pathList [lsort $pathList]
1563         set totalCnt [llength $pathList]
1564         set batch [expr {int($totalCnt * .01) + 1}]
1565         if {$batch > 25} {set batch 25}
1566
1567         set ui_status_value [format \
1568                 "$msg... %i/%i files (%.2f%%)" \
1569                 $update_index_cp \
1570                 $totalCnt \
1571                 0.0]
1572         set cmd [list git checkout-index]
1573         lappend cmd --index
1574         lappend cmd --quiet
1575         lappend cmd --force
1576         lappend cmd -z
1577         lappend cmd --stdin
1578         set fd [open "| $cmd " w]
1579         fconfigure $fd \
1580                 -blocking 0 \
1581                 -buffering full \
1582                 -buffersize 512 \
1583                 -translation binary
1584         fileevent $fd writable [list \
1585                 write_checkout_index \
1586                 $fd \
1587                 $pathList \
1588                 $totalCnt \
1589                 $batch \
1590                 $msg \
1591                 $after \
1592                 ]
1593 }
1594
1595 proc write_checkout_index {fd pathList totalCnt batch msg after} {
1596         global update_index_cp ui_status_value
1597         global file_states current_diff_path
1598
1599         if {$update_index_cp >= $totalCnt} {
1600                 close $fd
1601                 unlock_index
1602                 uplevel #0 $after
1603                 return
1604         }
1605
1606         for {set i $batch} \
1607                 {$update_index_cp < $totalCnt && $i > 0} \
1608                 {incr i -1} {
1609                 set path [lindex $pathList $update_index_cp]
1610                 incr update_index_cp
1611                 switch -glob -- [lindex $file_states($path) 0] {
1612                 U? {continue}
1613                 ?M -
1614                 ?D {
1615                         puts -nonewline $fd "$path\0"
1616                         display_file $path ?_
1617                 }
1618                 }
1619         }
1620
1621         set ui_status_value [format \
1622                 "$msg... %i/%i files (%.2f%%)" \
1623                 $update_index_cp \
1624                 $totalCnt \
1625                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1626 }
1627
1628 ######################################################################
1629 ##
1630 ## branch management
1631
1632 proc load_all_heads {} {
1633         global all_heads tracking_branches
1634
1635         set all_heads [list]
1636         set cmd [list git for-each-ref]
1637         lappend cmd --format=%(refname)
1638         lappend cmd refs/heads
1639         set fd [open "| $cmd" r]
1640         while {[gets $fd line] > 0} {
1641                 if {![catch {set info $tracking_branches($line)}]} continue
1642                 if {![regsub ^refs/heads/ $line {} name]} continue
1643                 lappend all_heads $name
1644         }
1645         close $fd
1646
1647         set all_heads [lsort $all_heads]
1648 }
1649
1650 proc populate_branch_menu {} {
1651         global all_heads disable_on_lock
1652
1653         set m .mbar.branch
1654         set last [$m index last]
1655         for {set i 0} {$i <= $last} {incr i} {
1656                 if {[$m type $i] eq {separator}} {
1657                         $m delete $i last
1658                         set new_dol [list]
1659                         foreach a $disable_on_lock {
1660                                 if {[lindex $a 0] ne $m || [lindex $a 2] < $i} {
1661                                         lappend new_dol $a
1662                                 }
1663                         }
1664                         set disable_on_lock $new_dol
1665                         break
1666                 }
1667         }
1668
1669         $m add separator
1670         foreach b $all_heads {
1671                 $m add radiobutton \
1672                         -label $b \
1673                         -command [list switch_branch $b] \
1674                         -variable current_branch \
1675                         -value $b \
1676                         -font font_ui
1677                 lappend disable_on_lock \
1678                         [list $m entryconf [$m index last] -state]
1679         }
1680 }
1681
1682 proc all_tracking_branches {} {
1683         global tracking_branches
1684
1685         set all_trackings [list]
1686         foreach b [array names tracking_branches] {
1687                 regsub ^refs/(heads|remotes)/ $b {} b
1688                 lappend all_trackings $b
1689         }
1690         return [lsort -unique $all_trackings]
1691 }
1692
1693 proc do_create_branch_action {w} {
1694         global all_heads null_sha1 repo_config
1695         global create_branch_checkout create_branch_revtype
1696         global create_branch_head create_branch_trackinghead
1697
1698         set newbranch [string trim [$w.desc.name_t get 0.0 end]]
1699         if {$newbranch eq {}
1700                 || $newbranch eq $repo_config(gui.newbranchtemplate)} {
1701                 tk_messageBox \
1702                         -icon error \
1703                         -type ok \
1704                         -title [wm title $w] \
1705                         -parent $w \
1706                         -message "Please supply a branch name."
1707                 focus $w.desc.name_t
1708                 return
1709         }
1710         if {![catch {exec git show-ref --verify -- "refs/heads/$newbranch"}]} {
1711                 tk_messageBox \
1712                         -icon error \
1713                         -type ok \
1714                         -title [wm title $w] \
1715                         -parent $w \
1716                         -message "Branch '$newbranch' already exists."
1717                 focus $w.desc.name_t
1718                 return
1719         }
1720         if {[catch {exec git check-ref-format "heads/$newbranch"}]} {
1721                 tk_messageBox \
1722                         -icon error \
1723                         -type ok \
1724                         -title [wm title $w] \
1725                         -parent $w \
1726                         -message "We do not like '$newbranch' as a branch name."
1727                 focus $w.desc.name_t
1728                 return
1729         }
1730
1731         set rev {}
1732         switch -- $create_branch_revtype {
1733         head {set rev $create_branch_head}
1734         tracking {set rev $create_branch_trackinghead}
1735         expression {set rev [string trim [$w.from.exp_t get 0.0 end]]}
1736         }
1737         if {[catch {set cmt [exec git rev-parse --verify "${rev}^0"]}]} {
1738                 tk_messageBox \
1739                         -icon error \
1740                         -type ok \
1741                         -title [wm title $w] \
1742                         -parent $w \
1743                         -message "Invalid starting revision: $rev"
1744                 return
1745         }
1746         set cmd [list git update-ref]
1747         lappend cmd -m
1748         lappend cmd "branch: Created from $rev"
1749         lappend cmd "refs/heads/$newbranch"
1750         lappend cmd $cmt
1751         lappend cmd $null_sha1
1752         if {[catch {eval exec $cmd} err]} {
1753                 tk_messageBox \
1754                         -icon error \
1755                         -type ok \
1756                         -title [wm title $w] \
1757                         -parent $w \
1758                         -message "Failed to create '$newbranch'.\n\n$err"
1759                 return
1760         }
1761
1762         lappend all_heads $newbranch
1763         set all_heads [lsort $all_heads]
1764         populate_branch_menu
1765         destroy $w
1766         if {$create_branch_checkout} {
1767                 switch_branch $newbranch
1768         }
1769 }
1770
1771 proc radio_selector {varname value args} {
1772         upvar #0 $varname var
1773         set var $value
1774 }
1775
1776 trace add variable create_branch_head write \
1777         [list radio_selector create_branch_revtype head]
1778 trace add variable create_branch_trackinghead write \
1779         [list radio_selector create_branch_revtype tracking]
1780
1781 trace add variable delete_branch_head write \
1782         [list radio_selector delete_branch_checktype head]
1783 trace add variable delete_branch_trackinghead write \
1784         [list radio_selector delete_branch_checktype tracking]
1785
1786 proc do_create_branch {} {
1787         global all_heads current_branch repo_config
1788         global create_branch_checkout create_branch_revtype
1789         global create_branch_head create_branch_trackinghead
1790
1791         set w .branch_editor
1792         toplevel $w
1793         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
1794
1795         label $w.header -text {Create New Branch} \
1796                 -font font_uibold
1797         pack $w.header -side top -fill x
1798
1799         frame $w.buttons
1800         button $w.buttons.create -text Create \
1801                 -font font_ui \
1802                 -default active \
1803                 -command [list do_create_branch_action $w]
1804         pack $w.buttons.create -side right
1805         button $w.buttons.cancel -text {Cancel} \
1806                 -font font_ui \
1807                 -command [list destroy $w]
1808         pack $w.buttons.cancel -side right -padx 5
1809         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
1810
1811         labelframe $w.desc \
1812                 -text {Branch Description} \
1813                 -font font_ui
1814         label $w.desc.name_l -text {Name:} -font font_ui
1815         text $w.desc.name_t \
1816                 -borderwidth 1 \
1817                 -relief sunken \
1818                 -height 1 \
1819                 -width 40 \
1820                 -font font_ui
1821         $w.desc.name_t insert 0.0 $repo_config(gui.newbranchtemplate)
1822         grid $w.desc.name_l $w.desc.name_t -stick we -padx {0 5}
1823         bind $w.desc.name_t <Shift-Key-Tab> {focus [tk_focusPrev %W];break}
1824         bind $w.desc.name_t <Key-Tab> {focus [tk_focusNext %W];break}
1825         bind $w.desc.name_t <Key-Return> "do_create_branch_action $w;break"
1826         bind $w.desc.name_t <Key> {
1827                 if {{%K} ne {BackSpace}
1828                         && {%K} ne {Tab}
1829                         && {%K} ne {Escape}
1830                         && {%K} ne {Return}} {
1831                         if {%k <= 32} break
1832                         if {[string first %A {~^:?*[}] >= 0} break
1833                 }
1834         }
1835         grid columnconfigure $w.desc 1 -weight 1
1836         pack $w.desc -anchor nw -fill x -pady 5 -padx 5
1837
1838         labelframe $w.from \
1839                 -text {Starting Revision} \
1840                 -font font_ui
1841         radiobutton $w.from.head_r \
1842                 -text {Local Branch:} \
1843                 -value head \
1844                 -variable create_branch_revtype \
1845                 -font font_ui
1846         eval tk_optionMenu $w.from.head_m create_branch_head $all_heads
1847         grid $w.from.head_r $w.from.head_m -sticky w
1848         set all_trackings [all_tracking_branches]
1849         if {$all_trackings ne {}} {
1850                 set create_branch_trackinghead [lindex $all_trackings 0]
1851                 radiobutton $w.from.tracking_r \
1852                         -text {Tracking Branch:} \
1853                         -value tracking \
1854                         -variable create_branch_revtype \
1855                         -font font_ui
1856                 eval tk_optionMenu $w.from.tracking_m \
1857                         create_branch_trackinghead \
1858                         $all_trackings
1859                 grid $w.from.tracking_r $w.from.tracking_m -sticky w
1860         }
1861         radiobutton $w.from.exp_r \
1862                 -text {Revision Expression:} \
1863                 -value expression \
1864                 -variable create_branch_revtype \
1865                 -font font_ui
1866         text $w.from.exp_t \
1867                 -borderwidth 1 \
1868                 -relief sunken \
1869                 -height 1 \
1870                 -width 50 \
1871                 -font font_ui
1872         grid $w.from.exp_r $w.from.exp_t -stick we -padx {0 5}
1873         bind $w.from.exp_t <Shift-Key-Tab> {focus [tk_focusPrev %W];break}
1874         bind $w.from.exp_t <Key-Tab> {focus [tk_focusNext %W];break}
1875         bind $w.from.exp_t <Key-Return> "do_create_branch_action $w;break"
1876         bind $w.from.exp_t <Key-space> break
1877         bind $w.from.exp_t <Key> {set create_branch_revtype expression}
1878         grid columnconfigure $w.from 1 -weight 1
1879         pack $w.from -anchor nw -fill x -pady 5 -padx 5
1880
1881         labelframe $w.postActions \
1882                 -text {Post Creation Actions} \
1883                 -font font_ui
1884         checkbutton $w.postActions.checkout \
1885                 -text {Checkout after creation} \
1886                 -variable create_branch_checkout \
1887                 -font font_ui
1888         pack $w.postActions.checkout -anchor nw
1889         pack $w.postActions -anchor nw -fill x -pady 5 -padx 5
1890
1891         set create_branch_checkout 1
1892         set create_branch_head $current_branch
1893         set create_branch_revtype head
1894
1895         bind $w <Visibility> "grab $w; focus $w.desc.name_t"
1896         bind $w <Key-Escape> "destroy $w"
1897         bind $w <Key-Return> "do_create_branch_action $w;break"
1898         wm title $w "[appname] ([reponame]): Create Branch"
1899         tkwait window $w
1900 }
1901
1902 proc do_delete_branch_action {w} {
1903         global all_heads
1904         global delete_branch_checktype delete_branch_head delete_branch_trackinghead
1905
1906         set check_rev {}
1907         switch -- $delete_branch_checktype {
1908         head {set check_rev $delete_branch_head}
1909         tracking {set check_rev $delete_branch_trackinghead}
1910         always {set check_rev {:none}}
1911         }
1912         if {$check_rev eq {:none}} {
1913                 set check_cmt {}
1914         } elseif {[catch {set check_cmt [exec git rev-parse --verify "${check_rev}^0"]}]} {
1915                 tk_messageBox \
1916                         -icon error \
1917                         -type ok \
1918                         -title [wm title $w] \
1919                         -parent $w \
1920                         -message "Invalid check revision: $check_rev"
1921                 return
1922         }
1923
1924         set to_delete [list]
1925         set not_merged [list]
1926         foreach i [$w.list.l curselection] {
1927                 set b [$w.list.l get $i]
1928                 if {[catch {set o [exec git rev-parse --verify $b]}]} continue
1929                 if {$check_cmt ne {}} {
1930                         if {$b eq $check_rev} continue
1931                         if {[catch {set m [exec git merge-base $o $check_cmt]}]} continue
1932                         if {$o ne $m} {
1933                                 lappend not_merged $b
1934                                 continue
1935                         }
1936                 }
1937                 lappend to_delete [list $b $o]
1938         }
1939         if {$not_merged ne {}} {
1940                 set msg "The following branches are not completely merged into $check_rev:
1941
1942  - [join $not_merged "\n - "]"
1943                 tk_messageBox \
1944                         -icon info \
1945                         -type ok \
1946                         -title [wm title $w] \
1947                         -parent $w \
1948                         -message $msg
1949         }
1950         if {$to_delete eq {}} return
1951         if {$delete_branch_checktype eq {always}} {
1952                 set msg {Recovering deleted branches is difficult.
1953
1954 Delete the selected branches?}
1955                 if {[tk_messageBox \
1956                         -icon warning \
1957                         -type yesno \
1958                         -title [wm title $w] \
1959                         -parent $w \
1960                         -message $msg] ne yes} {
1961                         return
1962                 }
1963         }
1964
1965         set failed {}
1966         foreach i $to_delete {
1967                 set b [lindex $i 0]
1968                 set o [lindex $i 1]
1969                 if {[catch {exec git update-ref -d "refs/heads/$b" $o} err]} {
1970                         append failed " - $b: $err\n"
1971                 } else {
1972                         set x [lsearch -sorted $all_heads $b]
1973                         if {$x >= 0} {
1974                                 set all_heads [lreplace $all_heads $x $x]
1975                         }
1976                 }
1977         }
1978
1979         if {$failed ne {}} {
1980                 tk_messageBox \
1981                         -icon error \
1982                         -type ok \
1983                         -title [wm title $w] \
1984                         -parent $w \
1985                         -message "Failed to delete branches:\n$failed"
1986         }
1987
1988         set all_heads [lsort $all_heads]
1989         populate_branch_menu
1990         destroy $w
1991 }
1992
1993 proc do_delete_branch {} {
1994         global all_heads tracking_branches current_branch
1995         global delete_branch_checktype delete_branch_head delete_branch_trackinghead
1996
1997         set w .branch_editor
1998         toplevel $w
1999         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2000
2001         label $w.header -text {Delete Local Branch} \
2002                 -font font_uibold
2003         pack $w.header -side top -fill x
2004
2005         frame $w.buttons
2006         button $w.buttons.create -text Delete \
2007                 -font font_ui \
2008                 -command [list do_delete_branch_action $w]
2009         pack $w.buttons.create -side right
2010         button $w.buttons.cancel -text {Cancel} \
2011                 -font font_ui \
2012                 -command [list destroy $w]
2013         pack $w.buttons.cancel -side right -padx 5
2014         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2015
2016         labelframe $w.list \
2017                 -text {Local Branches} \
2018                 -font font_ui
2019         listbox $w.list.l \
2020                 -height 10 \
2021                 -width 50 \
2022                 -selectmode extended \
2023                 -font font_ui
2024         foreach h $all_heads {
2025                 if {$h ne $current_branch} {
2026                         $w.list.l insert end $h
2027                 }
2028         }
2029         pack $w.list.l -fill both -pady 5 -padx 5
2030         pack $w.list -fill both -pady 5 -padx 5
2031
2032         labelframe $w.validate \
2033                 -text {Delete Only If} \
2034                 -font font_ui
2035         radiobutton $w.validate.head_r \
2036                 -text {Merged Into Local Branch:} \
2037                 -value head \
2038                 -variable delete_branch_checktype \
2039                 -font font_ui
2040         eval tk_optionMenu $w.validate.head_m delete_branch_head $all_heads
2041         grid $w.validate.head_r $w.validate.head_m -sticky w
2042         set all_trackings [all_tracking_branches]
2043         if {$all_trackings ne {}} {
2044                 set delete_branch_trackinghead [lindex $all_trackings 0]
2045                 radiobutton $w.validate.tracking_r \
2046                         -text {Merged Into Tracking Branch:} \
2047                         -value tracking \
2048                         -variable delete_branch_checktype \
2049                         -font font_ui
2050                 eval tk_optionMenu $w.validate.tracking_m \
2051                         delete_branch_trackinghead \
2052                         $all_trackings
2053                 grid $w.validate.tracking_r $w.validate.tracking_m -sticky w
2054         }
2055         radiobutton $w.validate.always_r \
2056                 -text {Always (Do not perform merge checks)} \
2057                 -value always \
2058                 -variable delete_branch_checktype \
2059                 -font font_ui
2060         grid $w.validate.always_r -columnspan 2 -sticky w
2061         grid columnconfigure $w.validate 1 -weight 1
2062         pack $w.validate -anchor nw -fill x -pady 5 -padx 5
2063
2064         set delete_branch_head $current_branch
2065         set delete_branch_checktype head
2066
2067         bind $w <Visibility> "grab $w; focus $w"
2068         bind $w <Key-Escape> "destroy $w"
2069         wm title $w "[appname] ([reponame]): Delete Branch"
2070         tkwait window $w
2071 }
2072
2073 proc switch_branch {b} {
2074         global HEAD commit_type file_states current_branch
2075         global selected_commit_type ui_comm
2076
2077         if {![lock_index switch]} return
2078
2079         # -- Backup the selected branch (repository_state resets it)
2080         #
2081         set new_branch $current_branch
2082
2083         # -- Our in memory state should match the repository.
2084         #
2085         repository_state curType curHEAD curMERGE_HEAD
2086         if {[string match amend* $commit_type]
2087                 && $curType eq {normal}
2088                 && $curHEAD eq $HEAD} {
2089         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
2090                 info_popup {Last scanned state does not match repository state.
2091
2092 Another Git program has modified this repository
2093 since the last scan.  A rescan must be performed
2094 before the current branch can be changed.
2095
2096 The rescan will be automatically started now.
2097 }
2098                 unlock_index
2099                 rescan {set ui_status_value {Ready.}}
2100                 return
2101         }
2102
2103         # -- Toss the message buffer if we are in amend mode.
2104         #
2105         if {[string match amend* $curType]} {
2106                 $ui_comm delete 0.0 end
2107                 $ui_comm edit reset
2108                 $ui_comm edit modified false
2109         }
2110
2111         set selected_commit_type new
2112         set current_branch $new_branch
2113
2114         unlock_index
2115         error "NOT FINISHED"
2116 }
2117
2118 ######################################################################
2119 ##
2120 ## remote management
2121
2122 proc load_all_remotes {} {
2123         global repo_config
2124         global all_remotes tracking_branches
2125
2126         set all_remotes [list]
2127         array unset tracking_branches
2128
2129         set rm_dir [gitdir remotes]
2130         if {[file isdirectory $rm_dir]} {
2131                 set all_remotes [glob \
2132                         -types f \
2133                         -tails \
2134                         -nocomplain \
2135                         -directory $rm_dir *]
2136
2137                 foreach name $all_remotes {
2138                         catch {
2139                                 set fd [open [file join $rm_dir $name] r]
2140                                 while {[gets $fd line] >= 0} {
2141                                         if {![regexp {^Pull:[   ]*([^:]+):(.+)$} \
2142                                                 $line line src dst]} continue
2143                                         if {![regexp ^refs/ $dst]} {
2144                                                 set dst "refs/heads/$dst"
2145                                         }
2146                                         set tracking_branches($dst) [list $name $src]
2147                                 }
2148                                 close $fd
2149                         }
2150                 }
2151         }
2152
2153         foreach line [array names repo_config remote.*.url] {
2154                 if {![regexp ^remote\.(.*)\.url\$ $line line name]} continue
2155                 lappend all_remotes $name
2156
2157                 if {[catch {set fl $repo_config(remote.$name.fetch)}]} {
2158                         set fl {}
2159                 }
2160                 foreach line $fl {
2161                         if {![regexp {^([^:]+):(.+)$} $line line src dst]} continue
2162                         if {![regexp ^refs/ $dst]} {
2163                                 set dst "refs/heads/$dst"
2164                         }
2165                         set tracking_branches($dst) [list $name $src]
2166                 }
2167         }
2168
2169         set all_remotes [lsort -unique $all_remotes]
2170 }
2171
2172 proc populate_fetch_menu {m} {
2173         global all_remotes repo_config
2174
2175         foreach r $all_remotes {
2176                 set enable 0
2177                 if {![catch {set a $repo_config(remote.$r.url)}]} {
2178                         if {![catch {set a $repo_config(remote.$r.fetch)}]} {
2179                                 set enable 1
2180                         }
2181                 } else {
2182                         catch {
2183                                 set fd [open [gitdir remotes $r] r]
2184                                 while {[gets $fd n] >= 0} {
2185                                         if {[regexp {^Pull:[ \t]*([^:]+):} $n]} {
2186                                                 set enable 1
2187                                                 break
2188                                         }
2189                                 }
2190                                 close $fd
2191                         }
2192                 }
2193
2194                 if {$enable} {
2195                         $m add command \
2196                                 -label "Fetch from $r..." \
2197                                 -command [list fetch_from $r] \
2198                                 -font font_ui
2199                 }
2200         }
2201 }
2202
2203 proc populate_push_menu {m} {
2204         global all_remotes repo_config
2205
2206         foreach r $all_remotes {
2207                 set enable 0
2208                 if {![catch {set a $repo_config(remote.$r.url)}]} {
2209                         if {![catch {set a $repo_config(remote.$r.push)}]} {
2210                                 set enable 1
2211                         }
2212                 } else {
2213                         catch {
2214                                 set fd [open [gitdir remotes $r] r]
2215                                 while {[gets $fd n] >= 0} {
2216                                         if {[regexp {^Push:[ \t]*([^:]+):} $n]} {
2217                                                 set enable 1
2218                                                 break
2219                                         }
2220                                 }
2221                                 close $fd
2222                         }
2223                 }
2224
2225                 if {$enable} {
2226                         $m add command \
2227                                 -label "Push to $r..." \
2228                                 -command [list push_to $r] \
2229                                 -font font_ui
2230                 }
2231         }
2232 }
2233
2234 proc populate_pull_menu {m} {
2235         global repo_config all_remotes disable_on_lock
2236
2237         foreach remote $all_remotes {
2238                 set rb_list [list]
2239                 if {[array get repo_config remote.$remote.url] ne {}} {
2240                         if {[array get repo_config remote.$remote.fetch] ne {}} {
2241                                 foreach line $repo_config(remote.$remote.fetch) {
2242                                         if {[regexp {^([^:]+):} $line line rb]} {
2243                                                 lappend rb_list $rb
2244                                         }
2245                                 }
2246                         }
2247                 } else {
2248                         catch {
2249                                 set fd [open [gitdir remotes $remote] r]
2250                                 while {[gets $fd line] >= 0} {
2251                                         if {[regexp {^Pull:[ \t]*([^:]+):} $line line rb]} {
2252                                                 lappend rb_list $rb
2253                                         }
2254                                 }
2255                                 close $fd
2256                         }
2257                 }
2258
2259                 foreach rb $rb_list {
2260                         regsub ^refs/heads/ $rb {} rb_short
2261                         $m add command \
2262                                 -label "Branch $rb_short from $remote..." \
2263                                 -command [list pull_remote $remote $rb] \
2264                                 -font font_ui
2265                         lappend disable_on_lock \
2266                                 [list $m entryconf [$m index last] -state]
2267                 }
2268         }
2269 }
2270
2271 ######################################################################
2272 ##
2273 ## icons
2274
2275 set filemask {
2276 #define mask_width 14
2277 #define mask_height 15
2278 static unsigned char mask_bits[] = {
2279    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2280    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2281    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
2282 }
2283
2284 image create bitmap file_plain -background white -foreground black -data {
2285 #define plain_width 14
2286 #define plain_height 15
2287 static unsigned char plain_bits[] = {
2288    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2289    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
2290    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2291 } -maskdata $filemask
2292
2293 image create bitmap file_mod -background white -foreground blue -data {
2294 #define mod_width 14
2295 #define mod_height 15
2296 static unsigned char mod_bits[] = {
2297    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2298    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2299    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2300 } -maskdata $filemask
2301
2302 image create bitmap file_fulltick -background white -foreground "#007000" -data {
2303 #define file_fulltick_width 14
2304 #define file_fulltick_height 15
2305 static unsigned char file_fulltick_bits[] = {
2306    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
2307    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
2308    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2309 } -maskdata $filemask
2310
2311 image create bitmap file_parttick -background white -foreground "#005050" -data {
2312 #define parttick_width 14
2313 #define parttick_height 15
2314 static unsigned char parttick_bits[] = {
2315    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2316    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
2317    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2318 } -maskdata $filemask
2319
2320 image create bitmap file_question -background white -foreground black -data {
2321 #define file_question_width 14
2322 #define file_question_height 15
2323 static unsigned char file_question_bits[] = {
2324    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
2325    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
2326    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2327 } -maskdata $filemask
2328
2329 image create bitmap file_removed -background white -foreground red -data {
2330 #define file_removed_width 14
2331 #define file_removed_height 15
2332 static unsigned char file_removed_bits[] = {
2333    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2334    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
2335    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
2336 } -maskdata $filemask
2337
2338 image create bitmap file_merge -background white -foreground blue -data {
2339 #define file_merge_width 14
2340 #define file_merge_height 15
2341 static unsigned char file_merge_bits[] = {
2342    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
2343    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2344    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2345 } -maskdata $filemask
2346
2347 set ui_index .vpane.files.index.list
2348 set ui_workdir .vpane.files.workdir.list
2349
2350 set all_icons(_$ui_index)   file_plain
2351 set all_icons(A$ui_index)   file_fulltick
2352 set all_icons(M$ui_index)   file_fulltick
2353 set all_icons(D$ui_index)   file_removed
2354 set all_icons(U$ui_index)   file_merge
2355
2356 set all_icons(_$ui_workdir) file_plain
2357 set all_icons(M$ui_workdir) file_mod
2358 set all_icons(D$ui_workdir) file_question
2359 set all_icons(U$ui_workdir) file_merge
2360 set all_icons(O$ui_workdir) file_plain
2361
2362 set max_status_desc 0
2363 foreach i {
2364                 {__ "Unmodified"}
2365
2366                 {_M "Modified, not staged"}
2367                 {M_ "Staged for commit"}
2368                 {MM "Portions staged for commit"}
2369                 {MD "Staged for commit, missing"}
2370
2371                 {_O "Untracked, not staged"}
2372                 {A_ "Staged for commit"}
2373                 {AM "Portions staged for commit"}
2374                 {AD "Staged for commit, missing"}
2375
2376                 {_D "Missing"}
2377                 {D_ "Staged for removal"}
2378                 {DO "Staged for removal, still present"}
2379
2380                 {U_ "Requires merge resolution"}
2381                 {UU "Requires merge resolution"}
2382                 {UM "Requires merge resolution"}
2383                 {UD "Requires merge resolution"}
2384         } {
2385         if {$max_status_desc < [string length [lindex $i 1]]} {
2386                 set max_status_desc [string length [lindex $i 1]]
2387         }
2388         set all_descs([lindex $i 0]) [lindex $i 1]
2389 }
2390 unset i
2391
2392 ######################################################################
2393 ##
2394 ## util
2395
2396 proc is_MacOSX {} {
2397         global tcl_platform tk_library
2398         if {[tk windowingsystem] eq {aqua}} {
2399                 return 1
2400         }
2401         return 0
2402 }
2403
2404 proc is_Windows {} {
2405         global tcl_platform
2406         if {$tcl_platform(platform) eq {windows}} {
2407                 return 1
2408         }
2409         return 0
2410 }
2411
2412 proc bind_button3 {w cmd} {
2413         bind $w <Any-Button-3> $cmd
2414         if {[is_MacOSX]} {
2415                 bind $w <Control-Button-1> $cmd
2416         }
2417 }
2418
2419 proc incr_font_size {font {amt 1}} {
2420         set sz [font configure $font -size]
2421         incr sz $amt
2422         font configure $font -size $sz
2423         font configure ${font}bold -size $sz
2424 }
2425
2426 proc hook_failed_popup {hook msg} {
2427         set w .hookfail
2428         toplevel $w
2429
2430         frame $w.m
2431         label $w.m.l1 -text "$hook hook failed:" \
2432                 -anchor w \
2433                 -justify left \
2434                 -font font_uibold
2435         text $w.m.t \
2436                 -background white -borderwidth 1 \
2437                 -relief sunken \
2438                 -width 80 -height 10 \
2439                 -font font_diff \
2440                 -yscrollcommand [list $w.m.sby set]
2441         label $w.m.l2 \
2442                 -text {You must correct the above errors before committing.} \
2443                 -anchor w \
2444                 -justify left \
2445                 -font font_uibold
2446         scrollbar $w.m.sby -command [list $w.m.t yview]
2447         pack $w.m.l1 -side top -fill x
2448         pack $w.m.l2 -side bottom -fill x
2449         pack $w.m.sby -side right -fill y
2450         pack $w.m.t -side left -fill both -expand 1
2451         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2452
2453         $w.m.t insert 1.0 $msg
2454         $w.m.t conf -state disabled
2455
2456         button $w.ok -text OK \
2457                 -width 15 \
2458                 -font font_ui \
2459                 -command "destroy $w"
2460         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2461
2462         bind $w <Visibility> "grab $w; focus $w"
2463         bind $w <Key-Return> "destroy $w"
2464         wm title $w "[appname] ([reponame]): error"
2465         tkwait window $w
2466 }
2467
2468 set next_console_id 0
2469
2470 proc new_console {short_title long_title} {
2471         global next_console_id console_data
2472         set w .console[incr next_console_id]
2473         set console_data($w) [list $short_title $long_title]
2474         return [console_init $w]
2475 }
2476
2477 proc console_init {w} {
2478         global console_cr console_data M1B
2479
2480         set console_cr($w) 1.0
2481         toplevel $w
2482         frame $w.m
2483         label $w.m.l1 -text "[lindex $console_data($w) 1]:" \
2484                 -anchor w \
2485                 -justify left \
2486                 -font font_uibold
2487         text $w.m.t \
2488                 -background white -borderwidth 1 \
2489                 -relief sunken \
2490                 -width 80 -height 10 \
2491                 -font font_diff \
2492                 -state disabled \
2493                 -yscrollcommand [list $w.m.sby set]
2494         label $w.m.s -text {Working... please wait...} \
2495                 -anchor w \
2496                 -justify left \
2497                 -font font_uibold
2498         scrollbar $w.m.sby -command [list $w.m.t yview]
2499         pack $w.m.l1 -side top -fill x
2500         pack $w.m.s -side bottom -fill x
2501         pack $w.m.sby -side right -fill y
2502         pack $w.m.t -side left -fill both -expand 1
2503         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2504
2505         menu $w.ctxm -tearoff 0
2506         $w.ctxm add command -label "Copy" \
2507                 -font font_ui \
2508                 -command "tk_textCopy $w.m.t"
2509         $w.ctxm add command -label "Select All" \
2510                 -font font_ui \
2511                 -command "$w.m.t tag add sel 0.0 end"
2512         $w.ctxm add command -label "Copy All" \
2513                 -font font_ui \
2514                 -command "
2515                         $w.m.t tag add sel 0.0 end
2516                         tk_textCopy $w.m.t
2517                         $w.m.t tag remove sel 0.0 end
2518                 "
2519
2520         button $w.ok -text {Close} \
2521                 -font font_ui \
2522                 -state disabled \
2523                 -command "destroy $w"
2524         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2525
2526         bind_button3 $w.m.t "tk_popup $w.ctxm %X %Y"
2527         bind $w.m.t <$M1B-Key-a> "$w.m.t tag add sel 0.0 end;break"
2528         bind $w.m.t <$M1B-Key-A> "$w.m.t tag add sel 0.0 end;break"
2529         bind $w <Visibility> "focus $w"
2530         wm title $w "[appname] ([reponame]): [lindex $console_data($w) 0]"
2531         return $w
2532 }
2533
2534 proc console_exec {w cmd {after {}}} {
2535         # -- Windows tosses the enviroment when we exec our child.
2536         #    But most users need that so we have to relogin. :-(
2537         #
2538         if {[is_Windows]} {
2539                 set cmd [list sh --login -c "cd \"[pwd]\" && [join $cmd { }]"]
2540         }
2541
2542         # -- Tcl won't let us redirect both stdout and stderr to
2543         #    the same pipe.  So pass it through cat...
2544         #
2545         set cmd [concat | $cmd |& cat]
2546
2547         set fd_f [open $cmd r]
2548         fconfigure $fd_f -blocking 0 -translation binary
2549         fileevent $fd_f readable [list console_read $w $fd_f $after]
2550 }
2551
2552 proc console_read {w fd after} {
2553         global console_cr console_data
2554
2555         set buf [read $fd]
2556         if {$buf ne {}} {
2557                 if {![winfo exists $w]} {console_init $w}
2558                 $w.m.t conf -state normal
2559                 set c 0
2560                 set n [string length $buf]
2561                 while {$c < $n} {
2562                         set cr [string first "\r" $buf $c]
2563                         set lf [string first "\n" $buf $c]
2564                         if {$cr < 0} {set cr [expr {$n + 1}]}
2565                         if {$lf < 0} {set lf [expr {$n + 1}]}
2566
2567                         if {$lf < $cr} {
2568                                 $w.m.t insert end [string range $buf $c $lf]
2569                                 set console_cr($w) [$w.m.t index {end -1c}]
2570                                 set c $lf
2571                                 incr c
2572                         } else {
2573                                 $w.m.t delete $console_cr($w) end
2574                                 $w.m.t insert end "\n"
2575                                 $w.m.t insert end [string range $buf $c $cr]
2576                                 set c $cr
2577                                 incr c
2578                         }
2579                 }
2580                 $w.m.t conf -state disabled
2581                 $w.m.t see end
2582         }
2583
2584         fconfigure $fd -blocking 1
2585         if {[eof $fd]} {
2586                 if {[catch {close $fd}]} {
2587                         if {![winfo exists $w]} {console_init $w}
2588                         $w.m.s conf -background red -text {Error: Command Failed}
2589                         $w.ok conf -state normal
2590                         set ok 0
2591                 } elseif {[winfo exists $w]} {
2592                         $w.m.s conf -background green -text {Success}
2593                         $w.ok conf -state normal
2594                         set ok 1
2595                 }
2596                 array unset console_cr $w
2597                 array unset console_data $w
2598                 if {$after ne {}} {
2599                         uplevel #0 $after $ok
2600                 }
2601                 return
2602         }
2603         fconfigure $fd -blocking 0
2604 }
2605
2606 ######################################################################
2607 ##
2608 ## ui commands
2609
2610 set starting_gitk_msg {Starting gitk... please wait...}
2611
2612 proc do_gitk {revs} {
2613         global ui_status_value starting_gitk_msg
2614
2615         set cmd gitk
2616         if {$revs ne {}} {
2617                 append cmd { }
2618                 append cmd $revs
2619         }
2620         if {[is_Windows]} {
2621                 set cmd "sh -c \"exec $cmd\""
2622         }
2623         append cmd { &}
2624
2625         if {[catch {eval exec $cmd} err]} {
2626                 error_popup "Failed to start gitk:\n\n$err"
2627         } else {
2628                 set ui_status_value $starting_gitk_msg
2629                 after 10000 {
2630                         if {$ui_status_value eq $starting_gitk_msg} {
2631                                 set ui_status_value {Ready.}
2632                         }
2633                 }
2634         }
2635 }
2636
2637 proc do_gc {} {
2638         set w [new_console {gc} {Compressing the object database}]
2639         console_exec $w {git gc}
2640 }
2641
2642 proc do_fsck_objects {} {
2643         set w [new_console {fsck-objects} \
2644                 {Verifying the object database with fsck-objects}]
2645         set cmd [list git fsck-objects]
2646         lappend cmd --full
2647         lappend cmd --cache
2648         lappend cmd --strict
2649         console_exec $w $cmd
2650 }
2651
2652 set is_quitting 0
2653
2654 proc do_quit {} {
2655         global ui_comm is_quitting repo_config commit_type
2656
2657         if {$is_quitting} return
2658         set is_quitting 1
2659
2660         # -- Stash our current commit buffer.
2661         #
2662         set save [gitdir GITGUI_MSG]
2663         set msg [string trim [$ui_comm get 0.0 end]]
2664         if {![string match amend* $commit_type]
2665                 && [$ui_comm edit modified]
2666                 && $msg ne {}} {
2667                 catch {
2668                         set fd [open $save w]
2669                         puts $fd [string trim [$ui_comm get 0.0 end]]
2670                         close $fd
2671                 }
2672         } else {
2673                 catch {file delete $save}
2674         }
2675
2676         # -- Stash our current window geometry into this repository.
2677         #
2678         set cfg_geometry [list]
2679         lappend cfg_geometry [wm geometry .]
2680         lappend cfg_geometry [lindex [.vpane sash coord 0] 1]
2681         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 0]
2682         if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2683                 set rc_geometry {}
2684         }
2685         if {$cfg_geometry ne $rc_geometry} {
2686                 catch {exec git repo-config gui.geometry $cfg_geometry}
2687         }
2688
2689         destroy .
2690 }
2691
2692 proc do_rescan {} {
2693         rescan {set ui_status_value {Ready.}}
2694 }
2695
2696 proc unstage_helper {txt paths} {
2697         global file_states current_diff_path
2698
2699         if {![lock_index begin-update]} return
2700
2701         set pathList [list]
2702         set after {}
2703         foreach path $paths {
2704                 switch -glob -- [lindex $file_states($path) 0] {
2705                 A? -
2706                 M? -
2707                 D? {
2708                         lappend pathList $path
2709                         if {$path eq $current_diff_path} {
2710                                 set after {reshow_diff;}
2711                         }
2712                 }
2713                 }
2714         }
2715         if {$pathList eq {}} {
2716                 unlock_index
2717         } else {
2718                 update_indexinfo \
2719                         $txt \
2720                         $pathList \
2721                         [concat $after {set ui_status_value {Ready.}}]
2722         }
2723 }
2724
2725 proc do_unstage_selection {} {
2726         global current_diff_path selected_paths
2727
2728         if {[array size selected_paths] > 0} {
2729                 unstage_helper \
2730                         {Unstaging selected files from commit} \
2731                         [array names selected_paths]
2732         } elseif {$current_diff_path ne {}} {
2733                 unstage_helper \
2734                         "Unstaging [short_path $current_diff_path] from commit" \
2735                         [list $current_diff_path]
2736         }
2737 }
2738
2739 proc add_helper {txt paths} {
2740         global file_states current_diff_path
2741
2742         if {![lock_index begin-update]} return
2743
2744         set pathList [list]
2745         set after {}
2746         foreach path $paths {
2747                 switch -glob -- [lindex $file_states($path) 0] {
2748                 _O -
2749                 ?M -
2750                 ?D -
2751                 U? {
2752                         lappend pathList $path
2753                         if {$path eq $current_diff_path} {
2754                                 set after {reshow_diff;}
2755                         }
2756                 }
2757                 }
2758         }
2759         if {$pathList eq {}} {
2760                 unlock_index
2761         } else {
2762                 update_index \
2763                         $txt \
2764                         $pathList \
2765                         [concat $after {set ui_status_value {Ready to commit.}}]
2766         }
2767 }
2768
2769 proc do_add_selection {} {
2770         global current_diff_path selected_paths
2771
2772         if {[array size selected_paths] > 0} {
2773                 add_helper \
2774                         {Adding selected files} \
2775                         [array names selected_paths]
2776         } elseif {$current_diff_path ne {}} {
2777                 add_helper \
2778                         "Adding [short_path $current_diff_path]" \
2779                         [list $current_diff_path]
2780         }
2781 }
2782
2783 proc do_add_all {} {
2784         global file_states
2785
2786         set paths [list]
2787         foreach path [array names file_states] {
2788                 switch -glob -- [lindex $file_states($path) 0] {
2789                 U? {continue}
2790                 ?M -
2791                 ?D {lappend paths $path}
2792                 }
2793         }
2794         add_helper {Adding all changed files} $paths
2795 }
2796
2797 proc revert_helper {txt paths} {
2798         global file_states current_diff_path
2799
2800         if {![lock_index begin-update]} return
2801
2802         set pathList [list]
2803         set after {}
2804         foreach path $paths {
2805                 switch -glob -- [lindex $file_states($path) 0] {
2806                 U? {continue}
2807                 ?M -
2808                 ?D {
2809                         lappend pathList $path
2810                         if {$path eq $current_diff_path} {
2811                                 set after {reshow_diff;}
2812                         }
2813                 }
2814                 }
2815         }
2816
2817         set n [llength $pathList]
2818         if {$n == 0} {
2819                 unlock_index
2820                 return
2821         } elseif {$n == 1} {
2822                 set s "[short_path [lindex $pathList]]"
2823         } else {
2824                 set s "these $n files"
2825         }
2826
2827         set reply [tk_dialog \
2828                 .confirm_revert \
2829                 "[appname] ([reponame])" \
2830                 "Revert changes in $s?
2831
2832 Any unadded changes will be permanently lost by the revert." \
2833                 question \
2834                 1 \
2835                 {Do Nothing} \
2836                 {Revert Changes} \
2837                 ]
2838         if {$reply == 1} {
2839                 checkout_index \
2840                         $txt \
2841                         $pathList \
2842                         [concat $after {set ui_status_value {Ready.}}]
2843         } else {
2844                 unlock_index
2845         }
2846 }
2847
2848 proc do_revert_selection {} {
2849         global current_diff_path selected_paths
2850
2851         if {[array size selected_paths] > 0} {
2852                 revert_helper \
2853                         {Reverting selected files} \
2854                         [array names selected_paths]
2855         } elseif {$current_diff_path ne {}} {
2856                 revert_helper \
2857                         "Reverting [short_path $current_diff_path]" \
2858                         [list $current_diff_path]
2859         }
2860 }
2861
2862 proc do_signoff {} {
2863         global ui_comm
2864
2865         set me [committer_ident]
2866         if {$me eq {}} return
2867
2868         set sob "Signed-off-by: $me"
2869         set last [$ui_comm get {end -1c linestart} {end -1c}]
2870         if {$last ne $sob} {
2871                 $ui_comm edit separator
2872                 if {$last ne {}
2873                         && ![regexp {^[A-Z][A-Za-z]*-[A-Za-z-]+: *} $last]} {
2874                         $ui_comm insert end "\n"
2875                 }
2876                 $ui_comm insert end "\n$sob"
2877                 $ui_comm edit separator
2878                 $ui_comm see end
2879         }
2880 }
2881
2882 proc do_select_commit_type {} {
2883         global commit_type selected_commit_type
2884
2885         if {$selected_commit_type eq {new}
2886                 && [string match amend* $commit_type]} {
2887                 create_new_commit
2888         } elseif {$selected_commit_type eq {amend}
2889                 && ![string match amend* $commit_type]} {
2890                 load_last_commit
2891
2892                 # The amend request was rejected...
2893                 #
2894                 if {![string match amend* $commit_type]} {
2895                         set selected_commit_type new
2896                 }
2897         }
2898 }
2899
2900 proc do_commit {} {
2901         commit_tree
2902 }
2903
2904 proc do_about {} {
2905         global appvers copyright
2906         global tcl_patchLevel tk_patchLevel
2907
2908         set w .about_dialog
2909         toplevel $w
2910         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2911
2912         label $w.header -text "About [appname]" \
2913                 -font font_uibold
2914         pack $w.header -side top -fill x
2915
2916         frame $w.buttons
2917         button $w.buttons.close -text {Close} \
2918                 -font font_ui \
2919                 -command [list destroy $w]
2920         pack $w.buttons.close -side right
2921         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2922
2923         label $w.desc \
2924                 -text "[appname] - a commit creation tool for Git.
2925 $copyright" \
2926                 -padx 5 -pady 5 \
2927                 -justify left \
2928                 -anchor w \
2929                 -borderwidth 1 \
2930                 -relief solid \
2931                 -font font_ui
2932         pack $w.desc -side top -fill x -padx 5 -pady 5
2933
2934         set v {}
2935         append v "[appname] version $appvers\n"
2936         append v "[exec git version]\n"
2937         append v "\n"
2938         if {$tcl_patchLevel eq $tk_patchLevel} {
2939                 append v "Tcl/Tk version $tcl_patchLevel"
2940         } else {
2941                 append v "Tcl version $tcl_patchLevel"
2942                 append v ", Tk version $tk_patchLevel"
2943         }
2944
2945         label $w.vers \
2946                 -text $v \
2947                 -padx 5 -pady 5 \
2948                 -justify left \
2949                 -anchor w \
2950                 -borderwidth 1 \
2951                 -relief solid \
2952                 -font font_ui
2953         pack $w.vers -side top -fill x -padx 5 -pady 5
2954
2955         menu $w.ctxm -tearoff 0
2956         $w.ctxm add command \
2957                 -label {Copy} \
2958                 -font font_ui \
2959                 -command "
2960                 clipboard clear
2961                 clipboard append -format STRING -type STRING -- \[$w.vers cget -text\]
2962         "
2963
2964         bind $w <Visibility> "grab $w; focus $w"
2965         bind $w <Key-Escape> "destroy $w"
2966         bind_button3 $w.vers "tk_popup $w.ctxm %X %Y; grab $w; focus $w"
2967         wm title $w "About [appname]"
2968         tkwait window $w
2969 }
2970
2971 proc do_options {} {
2972         global repo_config global_config font_descs
2973         global repo_config_new global_config_new
2974
2975         array unset repo_config_new
2976         array unset global_config_new
2977         foreach name [array names repo_config] {
2978                 set repo_config_new($name) $repo_config($name)
2979         }
2980         load_config 1
2981         foreach name [array names repo_config] {
2982                 switch -- $name {
2983                 gui.diffcontext {continue}
2984                 }
2985                 set repo_config_new($name) $repo_config($name)
2986         }
2987         foreach name [array names global_config] {
2988                 set global_config_new($name) $global_config($name)
2989         }
2990
2991         set w .options_editor
2992         toplevel $w
2993         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2994
2995         label $w.header -text "[appname] Options" \
2996                 -font font_uibold
2997         pack $w.header -side top -fill x
2998
2999         frame $w.buttons
3000         button $w.buttons.restore -text {Restore Defaults} \
3001                 -font font_ui \
3002                 -command do_restore_defaults
3003         pack $w.buttons.restore -side left
3004         button $w.buttons.save -text Save \
3005                 -font font_ui \
3006                 -command "
3007                         catch {eval \[bind \[focus -displayof $w\] <FocusOut>\]}
3008                         do_save_config $w
3009                 "
3010         pack $w.buttons.save -side right
3011         button $w.buttons.cancel -text {Cancel} \
3012                 -font font_ui \
3013                 -command [list destroy $w]
3014         pack $w.buttons.cancel -side right -padx 5
3015         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
3016
3017         labelframe $w.repo -text "[reponame] Repository" \
3018                 -font font_ui \
3019                 -relief raised -borderwidth 2
3020         labelframe $w.global -text {Global (All Repositories)} \
3021                 -font font_ui \
3022                 -relief raised -borderwidth 2
3023         pack $w.repo -side left -fill both -expand 1 -pady 5 -padx 5
3024         pack $w.global -side right -fill both -expand 1 -pady 5 -padx 5
3025
3026         foreach option {
3027                 {b pullsummary {Show Pull Summary}}
3028                 {b trustmtime  {Trust File Modification Timestamps}}
3029                 {i diffcontext {Number of Diff Context Lines}}
3030                 {t newbranchtemplate {New Branch Name Template}}
3031                 } {
3032                 set type [lindex $option 0]
3033                 set name [lindex $option 1]
3034                 set text [lindex $option 2]
3035                 foreach f {repo global} {
3036                         switch $type {
3037                         b {
3038                                 checkbutton $w.$f.$name -text $text \
3039                                         -variable ${f}_config_new(gui.$name) \
3040                                         -onvalue true \
3041                                         -offvalue false \
3042                                         -font font_ui
3043                                 pack $w.$f.$name -side top -anchor w
3044                         }
3045                         i {
3046                                 frame $w.$f.$name
3047                                 label $w.$f.$name.l -text "$text:" -font font_ui
3048                                 pack $w.$f.$name.l -side left -anchor w -fill x
3049                                 spinbox $w.$f.$name.v \
3050                                         -textvariable ${f}_config_new(gui.$name) \
3051                                         -from 1 -to 99 -increment 1 \
3052                                         -width 3 \
3053                                         -font font_ui
3054                                 bind $w.$f.$name.v <FocusIn> {%W selection range 0 end}
3055                                 pack $w.$f.$name.v -side right -anchor e -padx 5
3056                                 pack $w.$f.$name -side top -anchor w -fill x
3057                         }
3058                         t {
3059                                 frame $w.$f.$name
3060                                 label $w.$f.$name.l -text "$text:" -font font_ui
3061                                 text $w.$f.$name.v \
3062                                         -borderwidth 1 \
3063                                         -relief sunken \
3064                                         -height 1 \
3065                                         -width 20 \
3066                                         -font font_ui
3067                                 $w.$f.$name.v insert 0.0 [set ${f}_config_new(gui.$name)]
3068                                 bind $w.$f.$name.v <Shift-Key-Tab> {focus [tk_focusPrev %W];break}
3069                                 bind $w.$f.$name.v <Key-Tab> {focus [tk_focusNext %W];break}
3070                                 bind $w.$f.$name.v <Key-Return> break
3071                                 bind $w.$f.$name.v <FocusIn> "$w.$f.$name.v tag add sel 0.0 end"
3072                                 bind $w.$f.$name.v <FocusOut> "
3073                                         set ${f}_config_new(gui.$name) \
3074                                         \[string trim \[$w.$f.$name.v get 0.0 end\]\]
3075                                 "
3076                                 pack $w.$f.$name.l -side left -anchor w
3077                                 pack $w.$f.$name.v -side left -anchor w \
3078                                         -fill x -expand 1 \
3079                                         -padx 5
3080                                 pack $w.$f.$name -side top -anchor w -fill x
3081                         }
3082                         }
3083                 }
3084         }
3085
3086         set all_fonts [lsort [font families]]
3087         foreach option $font_descs {
3088                 set name [lindex $option 0]
3089                 set font [lindex $option 1]
3090                 set text [lindex $option 2]
3091
3092                 set global_config_new(gui.$font^^family) \
3093                         [font configure $font -family]
3094                 set global_config_new(gui.$font^^size) \
3095                         [font configure $font -size]
3096
3097                 frame $w.global.$name
3098                 label $w.global.$name.l -text "$text:" -font font_ui
3099                 pack $w.global.$name.l -side left -anchor w -fill x
3100                 eval tk_optionMenu $w.global.$name.family \
3101                         global_config_new(gui.$font^^family) \
3102                         $all_fonts
3103                 spinbox $w.global.$name.size \
3104                         -textvariable global_config_new(gui.$font^^size) \
3105                         -from 2 -to 80 -increment 1 \
3106                         -width 3 \
3107                         -font font_ui
3108                 bind $w.global.$name.size <FocusIn> {%W selection range 0 end}
3109                 pack $w.global.$name.size -side right -anchor e
3110                 pack $w.global.$name.family -side right -anchor e
3111                 pack $w.global.$name -side top -anchor w -fill x
3112         }
3113
3114         bind $w <Visibility> "grab $w; focus $w"
3115         bind $w <Key-Escape> "destroy $w"
3116         wm title $w "[appname] ([reponame]): Options"
3117         tkwait window $w
3118 }
3119
3120 proc do_restore_defaults {} {
3121         global font_descs default_config repo_config
3122         global repo_config_new global_config_new
3123
3124         foreach name [array names default_config] {
3125                 set repo_config_new($name) $default_config($name)
3126                 set global_config_new($name) $default_config($name)
3127         }
3128
3129         foreach option $font_descs {
3130                 set name [lindex $option 0]
3131                 set repo_config(gui.$name) $default_config(gui.$name)
3132         }
3133         apply_config
3134
3135         foreach option $font_descs {
3136                 set name [lindex $option 0]
3137                 set font [lindex $option 1]
3138                 set global_config_new(gui.$font^^family) \
3139                         [font configure $font -family]
3140                 set global_config_new(gui.$font^^size) \
3141                         [font configure $font -size]
3142         }
3143 }
3144
3145 proc do_save_config {w} {
3146         if {[catch {save_config} err]} {
3147                 error_popup "Failed to completely save options:\n\n$err"
3148         }
3149         reshow_diff
3150         destroy $w
3151 }
3152
3153 proc do_windows_shortcut {} {
3154         global argv0
3155
3156         if {[catch {
3157                 set desktop [exec cygpath \
3158                         --windows \
3159                         --absolute \
3160                         --long-name \
3161                         --desktop]
3162                 }]} {
3163                         set desktop .
3164         }
3165         set fn [tk_getSaveFile \
3166                 -parent . \
3167                 -title "[appname] ([reponame]): Create Desktop Icon" \
3168                 -initialdir $desktop \
3169                 -initialfile "Git [reponame].bat"]
3170         if {$fn != {}} {
3171                 if {[catch {
3172                                 set fd [open $fn w]
3173                                 set sh [exec cygpath \
3174                                         --windows \
3175                                         --absolute \
3176                                         /bin/sh]
3177                                 set me [exec cygpath \
3178                                         --unix \
3179                                         --absolute \
3180                                         $argv0]
3181                                 set gd [exec cygpath \
3182                                         --unix \
3183                                         --absolute \
3184                                         [gitdir]]
3185                                 set gw [exec cygpath \
3186                                         --windows \
3187                                         --absolute \
3188                                         [file dirname [gitdir]]]
3189                                 regsub -all ' $me "'\\''" me
3190                                 regsub -all ' $gd "'\\''" gd
3191                                 puts $fd "@ECHO Entering $gw"
3192                                 puts $fd "@ECHO Starting git-gui... please wait..."
3193                                 puts -nonewline $fd "@\"$sh\" --login -c \""
3194                                 puts -nonewline $fd "GIT_DIR='$gd'"
3195                                 puts -nonewline $fd " '$me'"
3196                                 puts $fd "&\""
3197                                 close $fd
3198                         } err]} {
3199                         error_popup "Cannot write script:\n\n$err"
3200                 }
3201         }
3202 }
3203
3204 proc do_macosx_app {} {
3205         global argv0 env
3206
3207         set fn [tk_getSaveFile \
3208                 -parent . \
3209                 -title "[appname] ([reponame]): Create Desktop Icon" \
3210                 -initialdir [file join $env(HOME) Desktop] \
3211                 -initialfile "Git [reponame].app"]
3212         if {$fn != {}} {
3213                 if {[catch {
3214                                 set Contents [file join $fn Contents]
3215                                 set MacOS [file join $Contents MacOS]
3216                                 set exe [file join $MacOS git-gui]
3217
3218                                 file mkdir $MacOS
3219
3220                                 set fd [open [file join $Contents Info.plist] w]
3221                                 puts $fd {<?xml version="1.0" encoding="UTF-8"?>
3222 <!DOCTYPE plist PUBLIC "-//Apple Computer//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
3223 <plist version="1.0">
3224 <dict>
3225         <key>CFBundleDevelopmentRegion</key>
3226         <string>English</string>
3227         <key>CFBundleExecutable</key>
3228         <string>git-gui</string>
3229         <key>CFBundleIdentifier</key>
3230         <string>org.spearce.git-gui</string>
3231         <key>CFBundleInfoDictionaryVersion</key>
3232         <string>6.0</string>
3233         <key>CFBundlePackageType</key>
3234         <string>APPL</string>
3235         <key>CFBundleSignature</key>
3236         <string>????</string>
3237         <key>CFBundleVersion</key>
3238         <string>1.0</string>
3239         <key>NSPrincipalClass</key>
3240         <string>NSApplication</string>
3241 </dict>
3242 </plist>}
3243                                 close $fd
3244
3245                                 set fd [open $exe w]
3246                                 set gd [file normalize [gitdir]]
3247                                 set ep [file normalize [exec git --exec-path]]
3248                                 regsub -all ' $gd "'\\''" gd
3249                                 regsub -all ' $ep "'\\''" ep
3250                                 puts $fd "#!/bin/sh"
3251                                 foreach name [array names env] {
3252                                         if {[string match GIT_* $name]} {
3253                                                 regsub -all ' $env($name) "'\\''" v
3254                                                 puts $fd "export $name='$v'"
3255                                         }
3256                                 }
3257                                 puts $fd "export PATH='$ep':\$PATH"
3258                                 puts $fd "export GIT_DIR='$gd'"
3259                                 puts $fd "exec [file normalize $argv0]"
3260                                 close $fd
3261
3262                                 file attributes $exe -permissions u+x,g+x,o+x
3263                         } err]} {
3264                         error_popup "Cannot write icon:\n\n$err"
3265                 }
3266         }
3267 }
3268
3269 proc toggle_or_diff {w x y} {
3270         global file_states file_lists current_diff_path ui_index ui_workdir
3271         global last_clicked selected_paths
3272
3273         set pos [split [$w index @$x,$y] .]
3274         set lno [lindex $pos 0]
3275         set col [lindex $pos 1]
3276         set path [lindex $file_lists($w) [expr {$lno - 1}]]
3277         if {$path eq {}} {
3278                 set last_clicked {}
3279                 return
3280         }
3281
3282         set last_clicked [list $w $lno]
3283         array unset selected_paths
3284         $ui_index tag remove in_sel 0.0 end
3285         $ui_workdir tag remove in_sel 0.0 end
3286
3287         if {$col == 0} {
3288                 if {$current_diff_path eq $path} {
3289                         set after {reshow_diff;}
3290                 } else {
3291                         set after {}
3292                 }
3293                 if {$w eq $ui_index} {
3294                         update_indexinfo \
3295                                 "Unstaging [short_path $path] from commit" \
3296                                 [list $path] \
3297                                 [concat $after {set ui_status_value {Ready.}}]
3298                 } elseif {$w eq $ui_workdir} {
3299                         update_index \
3300                                 "Adding [short_path $path]" \
3301                                 [list $path] \
3302                                 [concat $after {set ui_status_value {Ready.}}]
3303                 }
3304         } else {
3305                 show_diff $path $w $lno
3306         }
3307 }
3308
3309 proc add_one_to_selection {w x y} {
3310         global file_lists last_clicked selected_paths
3311
3312         set lno [lindex [split [$w index @$x,$y] .] 0]
3313         set path [lindex $file_lists($w) [expr {$lno - 1}]]
3314         if {$path eq {}} {
3315                 set last_clicked {}
3316                 return
3317         }
3318
3319         if {$last_clicked ne {}
3320                 && [lindex $last_clicked 0] ne $w} {
3321                 array unset selected_paths
3322                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
3323         }
3324
3325         set last_clicked [list $w $lno]
3326         if {[catch {set in_sel $selected_paths($path)}]} {
3327                 set in_sel 0
3328         }
3329         if {$in_sel} {
3330                 unset selected_paths($path)
3331                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
3332         } else {
3333                 set selected_paths($path) 1
3334                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
3335         }
3336 }
3337
3338 proc add_range_to_selection {w x y} {
3339         global file_lists last_clicked selected_paths
3340
3341         if {[lindex $last_clicked 0] ne $w} {
3342                 toggle_or_diff $w $x $y
3343                 return
3344         }
3345
3346         set lno [lindex [split [$w index @$x,$y] .] 0]
3347         set lc [lindex $last_clicked 1]
3348         if {$lc < $lno} {
3349                 set begin $lc
3350                 set end $lno
3351         } else {
3352                 set begin $lno
3353                 set end $lc
3354         }
3355
3356         foreach path [lrange $file_lists($w) \
3357                 [expr {$begin - 1}] \
3358                 [expr {$end - 1}]] {
3359                 set selected_paths($path) 1
3360         }
3361         $w tag add in_sel $begin.0 [expr {$end + 1}].0
3362 }
3363
3364 ######################################################################
3365 ##
3366 ## config defaults
3367
3368 set cursor_ptr arrow
3369 font create font_diff -family Courier -size 10
3370 font create font_ui
3371 catch {
3372         label .dummy
3373         eval font configure font_ui [font actual [.dummy cget -font]]
3374         destroy .dummy
3375 }
3376
3377 font create font_uibold
3378 font create font_diffbold
3379
3380 if {[is_Windows]} {
3381         set M1B Control
3382         set M1T Ctrl
3383 } elseif {[is_MacOSX]} {
3384         set M1B M1
3385         set M1T Cmd
3386 } else {
3387         set M1B M1
3388         set M1T M1
3389 }
3390
3391 proc apply_config {} {
3392         global repo_config font_descs
3393
3394         foreach option $font_descs {
3395                 set name [lindex $option 0]
3396                 set font [lindex $option 1]
3397                 if {[catch {
3398                         foreach {cn cv} $repo_config(gui.$name) {
3399                                 font configure $font $cn $cv
3400                         }
3401                         } err]} {
3402                         error_popup "Invalid font specified in gui.$name:\n\n$err"
3403                 }
3404                 foreach {cn cv} [font configure $font] {
3405                         font configure ${font}bold $cn $cv
3406                 }
3407                 font configure ${font}bold -weight bold
3408         }
3409 }
3410
3411 set default_config(gui.trustmtime) false
3412 set default_config(gui.pullsummary) true
3413 set default_config(gui.diffcontext) 5
3414 set default_config(gui.newbranchtemplate) {}
3415 set default_config(gui.fontui) [font configure font_ui]
3416 set default_config(gui.fontdiff) [font configure font_diff]
3417 set font_descs {
3418         {fontui   font_ui   {Main Font}}
3419         {fontdiff font_diff {Diff/Console Font}}
3420 }
3421 load_config 0
3422 apply_config
3423
3424 ######################################################################
3425 ##
3426 ## ui construction
3427
3428 # -- Menu Bar
3429 #
3430 menu .mbar -tearoff 0
3431 .mbar add cascade -label Repository -menu .mbar.repository
3432 .mbar add cascade -label Edit -menu .mbar.edit
3433 if {!$single_commit} {
3434         .mbar add cascade -label Branch -menu .mbar.branch
3435 }
3436 .mbar add cascade -label Commit -menu .mbar.commit
3437 if {!$single_commit} {
3438         .mbar add cascade -label Fetch -menu .mbar.fetch
3439         .mbar add cascade -label Pull -menu .mbar.pull
3440         .mbar add cascade -label Push -menu .mbar.push
3441 }
3442 . configure -menu .mbar
3443
3444 # -- Repository Menu
3445 #
3446 menu .mbar.repository
3447 .mbar.repository add command \
3448         -label {Visualize Current Branch} \
3449         -command {do_gitk {}} \
3450         -font font_ui
3451 if {![is_MacOSX]} {
3452         .mbar.repository add command \
3453                 -label {Visualize All Branches} \
3454                 -command {do_gitk {--all}} \
3455                 -font font_ui
3456 }
3457 .mbar.repository add separator
3458
3459 if {!$single_commit} {
3460         .mbar.repository add command -label {Compress Database} \
3461                 -command do_gc \
3462                 -font font_ui
3463
3464         .mbar.repository add command -label {Verify Database} \
3465                 -command do_fsck_objects \
3466                 -font font_ui
3467
3468         .mbar.repository add separator
3469
3470         if {[is_Windows]} {
3471                 .mbar.repository add command \
3472                         -label {Create Desktop Icon} \
3473                         -command do_windows_shortcut \
3474                         -font font_ui
3475         } elseif {[is_MacOSX]} {
3476                 .mbar.repository add command \
3477                         -label {Create Desktop Icon} \
3478                         -command do_macosx_app \
3479                         -font font_ui
3480         }
3481 }
3482
3483 .mbar.repository add command -label Quit \
3484         -command do_quit \
3485         -accelerator $M1T-Q \
3486         -font font_ui
3487
3488 # -- Edit Menu
3489 #
3490 menu .mbar.edit
3491 .mbar.edit add command -label Undo \
3492         -command {catch {[focus] edit undo}} \
3493         -accelerator $M1T-Z \
3494         -font font_ui
3495 .mbar.edit add command -label Redo \
3496         -command {catch {[focus] edit redo}} \
3497         -accelerator $M1T-Y \
3498         -font font_ui
3499 .mbar.edit add separator
3500 .mbar.edit add command -label Cut \
3501         -command {catch {tk_textCut [focus]}} \
3502         -accelerator $M1T-X \
3503         -font font_ui
3504 .mbar.edit add command -label Copy \
3505         -command {catch {tk_textCopy [focus]}} \
3506         -accelerator $M1T-C \
3507         -font font_ui
3508 .mbar.edit add command -label Paste \
3509         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
3510         -accelerator $M1T-V \
3511         -font font_ui
3512 .mbar.edit add command -label Delete \
3513         -command {catch {[focus] delete sel.first sel.last}} \
3514         -accelerator Del \
3515         -font font_ui
3516 .mbar.edit add separator
3517 .mbar.edit add command -label {Select All} \
3518         -command {catch {[focus] tag add sel 0.0 end}} \
3519         -accelerator $M1T-A \
3520         -font font_ui
3521
3522 # -- Branch Menu
3523 #
3524 if {!$single_commit} {
3525         menu .mbar.branch
3526
3527         .mbar.branch add command -label {Create...} \
3528                 -command do_create_branch \
3529                 -accelerator $M1T-N \
3530                 -font font_ui
3531         lappend disable_on_lock [list .mbar.branch entryconf \
3532                 [.mbar.branch index last] -state]
3533
3534         .mbar.branch add command -label {Delete...} \
3535                 -command do_delete_branch \
3536                 -font font_ui
3537         lappend disable_on_lock [list .mbar.branch entryconf \
3538                 [.mbar.branch index last] -state]
3539 }
3540
3541 # -- Commit Menu
3542 #
3543 menu .mbar.commit
3544
3545 .mbar.commit add radiobutton \
3546         -label {New Commit} \
3547         -command do_select_commit_type \
3548         -variable selected_commit_type \
3549         -value new \
3550         -font font_ui
3551 lappend disable_on_lock \
3552         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3553
3554 .mbar.commit add radiobutton \
3555         -label {Amend Last Commit} \
3556         -command do_select_commit_type \
3557         -variable selected_commit_type \
3558         -value amend \
3559         -font font_ui
3560 lappend disable_on_lock \
3561         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3562
3563 .mbar.commit add separator
3564
3565 .mbar.commit add command -label Rescan \
3566         -command do_rescan \
3567         -accelerator F5 \
3568         -font font_ui
3569 lappend disable_on_lock \
3570         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3571
3572 .mbar.commit add command -label {Add To Commit} \
3573         -command do_add_selection \
3574         -font font_ui
3575 lappend disable_on_lock \
3576         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3577
3578 .mbar.commit add command -label {Add All To Commit} \
3579         -command do_add_all \
3580         -accelerator $M1T-I \
3581         -font font_ui
3582 lappend disable_on_lock \
3583         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3584
3585 .mbar.commit add command -label {Unstage From Commit} \
3586         -command do_unstage_selection \
3587         -font font_ui
3588 lappend disable_on_lock \
3589         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3590
3591 .mbar.commit add command -label {Revert Changes} \
3592         -command do_revert_selection \
3593         -font font_ui
3594 lappend disable_on_lock \
3595         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3596
3597 .mbar.commit add separator
3598
3599 .mbar.commit add command -label {Sign Off} \
3600         -command do_signoff \
3601         -accelerator $M1T-S \
3602         -font font_ui
3603
3604 .mbar.commit add command -label Commit \
3605         -command do_commit \
3606         -accelerator $M1T-Return \
3607         -font font_ui
3608 lappend disable_on_lock \
3609         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3610
3611 # -- Transport menus
3612 #
3613 if {!$single_commit} {
3614         menu .mbar.fetch
3615         menu .mbar.pull
3616         menu .mbar.push
3617 }
3618
3619 if {[is_MacOSX]} {
3620         # -- Apple Menu (Mac OS X only)
3621         #
3622         .mbar add cascade -label Apple -menu .mbar.apple
3623         menu .mbar.apple
3624
3625         .mbar.apple add command -label "About [appname]" \
3626                 -command do_about \
3627                 -font font_ui
3628         .mbar.apple add command -label "[appname] Options..." \
3629                 -command do_options \
3630                 -font font_ui
3631 } else {
3632         # -- Edit Menu
3633         #
3634         .mbar.edit add separator
3635         .mbar.edit add command -label {Options...} \
3636                 -command do_options \
3637                 -font font_ui
3638
3639         # -- Tools Menu
3640         #
3641         if {[file exists /usr/local/miga/lib/gui-miga]
3642                 && [file exists .pvcsrc]} {
3643         proc do_miga {} {
3644                 global ui_status_value
3645                 if {![lock_index update]} return
3646                 set cmd [list sh --login -c "/usr/local/miga/lib/gui-miga \"[pwd]\""]
3647                 set miga_fd [open "|$cmd" r]
3648                 fconfigure $miga_fd -blocking 0
3649                 fileevent $miga_fd readable [list miga_done $miga_fd]
3650                 set ui_status_value {Running miga...}
3651         }
3652         proc miga_done {fd} {
3653                 read $fd 512
3654                 if {[eof $fd]} {
3655                         close $fd
3656                         unlock_index
3657                         rescan [list set ui_status_value {Ready.}]
3658                 }
3659         }
3660         .mbar add cascade -label Tools -menu .mbar.tools
3661         menu .mbar.tools
3662         .mbar.tools add command -label "Migrate" \
3663                 -command do_miga \
3664                 -font font_ui
3665         lappend disable_on_lock \
3666                 [list .mbar.tools entryconf [.mbar.tools index last] -state]
3667         }
3668
3669         # -- Help Menu
3670         #
3671         .mbar add cascade -label Help -menu .mbar.help
3672         menu .mbar.help
3673
3674         .mbar.help add command -label "About [appname]" \
3675                 -command do_about \
3676                 -font font_ui
3677 }
3678
3679
3680 # -- Branch Control
3681 #
3682 frame .branch \
3683         -borderwidth 1 \
3684         -relief sunken
3685 label .branch.l1 \
3686         -text {Current Branch:} \
3687         -anchor w \
3688         -justify left \
3689         -font font_ui
3690 label .branch.cb \
3691         -textvariable current_branch \
3692         -anchor w \
3693         -justify left \
3694         -font font_ui
3695 pack .branch.l1 -side left
3696 pack .branch.cb -side left -fill x
3697 pack .branch -side top -fill x
3698
3699 # -- Main Window Layout
3700 #
3701 panedwindow .vpane -orient vertical
3702 panedwindow .vpane.files -orient horizontal
3703 .vpane add .vpane.files -sticky nsew -height 100 -width 400
3704 pack .vpane -anchor n -side top -fill both -expand 1
3705
3706 # -- Index File List
3707 #
3708 frame .vpane.files.index -height 100 -width 400
3709 label .vpane.files.index.title -text {Changes To Be Committed} \
3710         -background green \
3711         -font font_ui
3712 text $ui_index -background white -borderwidth 0 \
3713         -width 40 -height 10 \
3714         -wrap none \
3715         -font font_ui \
3716         -cursor $cursor_ptr \
3717         -xscrollcommand {.vpane.files.index.sx set} \
3718         -yscrollcommand {.vpane.files.index.sy set} \
3719         -state disabled
3720 scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
3721 scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
3722 pack .vpane.files.index.title -side top -fill x
3723 pack .vpane.files.index.sx -side bottom -fill x
3724 pack .vpane.files.index.sy -side right -fill y
3725 pack $ui_index -side left -fill both -expand 1
3726 .vpane.files add .vpane.files.index -sticky nsew
3727
3728 # -- Working Directory File List
3729 #
3730 frame .vpane.files.workdir -height 100 -width 100
3731 label .vpane.files.workdir.title -text {Changed But Not Updated} \
3732         -background red \
3733         -font font_ui
3734 text $ui_workdir -background white -borderwidth 0 \
3735         -width 40 -height 10 \
3736         -wrap none \
3737         -font font_ui \
3738         -cursor $cursor_ptr \
3739         -xscrollcommand {.vpane.files.workdir.sx set} \
3740         -yscrollcommand {.vpane.files.workdir.sy set} \
3741         -state disabled
3742 scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
3743 scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
3744 pack .vpane.files.workdir.title -side top -fill x
3745 pack .vpane.files.workdir.sx -side bottom -fill x
3746 pack .vpane.files.workdir.sy -side right -fill y
3747 pack $ui_workdir -side left -fill both -expand 1
3748 .vpane.files add .vpane.files.workdir -sticky nsew
3749
3750 foreach i [list $ui_index $ui_workdir] {
3751         $i tag conf in_diff -font font_uibold
3752         $i tag conf in_sel \
3753                 -background [$i cget -foreground] \
3754                 -foreground [$i cget -background]
3755 }
3756 unset i
3757
3758 # -- Diff and Commit Area
3759 #
3760 frame .vpane.lower -height 300 -width 400
3761 frame .vpane.lower.commarea
3762 frame .vpane.lower.diff -relief sunken -borderwidth 1
3763 pack .vpane.lower.commarea -side top -fill x
3764 pack .vpane.lower.diff -side bottom -fill both -expand 1
3765 .vpane add .vpane.lower -stick nsew
3766
3767 # -- Commit Area Buttons
3768 #
3769 frame .vpane.lower.commarea.buttons
3770 label .vpane.lower.commarea.buttons.l -text {} \
3771         -anchor w \
3772         -justify left \
3773         -font font_ui
3774 pack .vpane.lower.commarea.buttons.l -side top -fill x
3775 pack .vpane.lower.commarea.buttons -side left -fill y
3776
3777 button .vpane.lower.commarea.buttons.rescan -text {Rescan} \
3778         -command do_rescan \
3779         -font font_ui
3780 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3781 lappend disable_on_lock \
3782         {.vpane.lower.commarea.buttons.rescan conf -state}
3783
3784 button .vpane.lower.commarea.buttons.incall -text {Add All} \
3785         -command do_add_all \
3786         -font font_ui
3787 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3788 lappend disable_on_lock \
3789         {.vpane.lower.commarea.buttons.incall conf -state}
3790
3791 button .vpane.lower.commarea.buttons.signoff -text {Sign Off} \
3792         -command do_signoff \
3793         -font font_ui
3794 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3795
3796 button .vpane.lower.commarea.buttons.commit -text {Commit} \
3797         -command do_commit \
3798         -font font_ui
3799 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3800 lappend disable_on_lock \
3801         {.vpane.lower.commarea.buttons.commit conf -state}
3802
3803 # -- Commit Message Buffer
3804 #
3805 frame .vpane.lower.commarea.buffer
3806 frame .vpane.lower.commarea.buffer.header
3807 set ui_comm .vpane.lower.commarea.buffer.t
3808 set ui_coml .vpane.lower.commarea.buffer.header.l
3809 radiobutton .vpane.lower.commarea.buffer.header.new \
3810         -text {New Commit} \
3811         -command do_select_commit_type \
3812         -variable selected_commit_type \
3813         -value new \
3814         -font font_ui
3815 lappend disable_on_lock \
3816         [list .vpane.lower.commarea.buffer.header.new conf -state]
3817 radiobutton .vpane.lower.commarea.buffer.header.amend \
3818         -text {Amend Last Commit} \
3819         -command do_select_commit_type \
3820         -variable selected_commit_type \
3821         -value amend \
3822         -font font_ui
3823 lappend disable_on_lock \
3824         [list .vpane.lower.commarea.buffer.header.amend conf -state]
3825 label $ui_coml \
3826         -anchor w \
3827         -justify left \
3828         -font font_ui
3829 proc trace_commit_type {varname args} {
3830         global ui_coml commit_type
3831         switch -glob -- $commit_type {
3832         initial       {set txt {Initial Commit Message:}}
3833         amend         {set txt {Amended Commit Message:}}
3834         amend-initial {set txt {Amended Initial Commit Message:}}
3835         amend-merge   {set txt {Amended Merge Commit Message:}}
3836         merge         {set txt {Merge Commit Message:}}
3837         *             {set txt {Commit Message:}}
3838         }
3839         $ui_coml conf -text $txt
3840 }
3841 trace add variable commit_type write trace_commit_type
3842 pack $ui_coml -side left -fill x
3843 pack .vpane.lower.commarea.buffer.header.amend -side right
3844 pack .vpane.lower.commarea.buffer.header.new -side right
3845
3846 text $ui_comm -background white -borderwidth 1 \
3847         -undo true \
3848         -maxundo 20 \
3849         -autoseparators true \
3850         -relief sunken \
3851         -width 75 -height 9 -wrap none \
3852         -font font_diff \
3853         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3854 scrollbar .vpane.lower.commarea.buffer.sby \
3855         -command [list $ui_comm yview]
3856 pack .vpane.lower.commarea.buffer.header -side top -fill x
3857 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3858 pack $ui_comm -side left -fill y
3859 pack .vpane.lower.commarea.buffer -side left -fill y
3860
3861 # -- Commit Message Buffer Context Menu
3862 #
3863 set ctxm .vpane.lower.commarea.buffer.ctxm
3864 menu $ctxm -tearoff 0
3865 $ctxm add command \
3866         -label {Cut} \
3867         -font font_ui \
3868         -command {tk_textCut $ui_comm}
3869 $ctxm add command \
3870         -label {Copy} \
3871         -font font_ui \
3872         -command {tk_textCopy $ui_comm}
3873 $ctxm add command \
3874         -label {Paste} \
3875         -font font_ui \
3876         -command {tk_textPaste $ui_comm}
3877 $ctxm add command \
3878         -label {Delete} \
3879         -font font_ui \
3880         -command {$ui_comm delete sel.first sel.last}
3881 $ctxm add separator
3882 $ctxm add command \
3883         -label {Select All} \
3884         -font font_ui \
3885         -command {$ui_comm tag add sel 0.0 end}
3886 $ctxm add command \
3887         -label {Copy All} \
3888         -font font_ui \
3889         -command {
3890                 $ui_comm tag add sel 0.0 end
3891                 tk_textCopy $ui_comm
3892                 $ui_comm tag remove sel 0.0 end
3893         }
3894 $ctxm add separator
3895 $ctxm add command \
3896         -label {Sign Off} \
3897         -font font_ui \
3898         -command do_signoff
3899 bind_button3 $ui_comm "tk_popup $ctxm %X %Y"
3900
3901 # -- Diff Header
3902 #
3903 set current_diff_path {}
3904 set diff_actions [list]
3905 proc trace_current_diff_path {varname args} {
3906         global current_diff_path diff_actions file_states
3907         if {$current_diff_path eq {}} {
3908                 set s {}
3909                 set f {}
3910                 set p {}
3911                 set o disabled
3912         } else {
3913                 set p $current_diff_path
3914                 set s [mapdesc [lindex $file_states($p) 0] $p]
3915                 set f {File:}
3916                 set p [escape_path $p]
3917                 set o normal
3918         }
3919
3920         .vpane.lower.diff.header.status configure -text $s
3921         .vpane.lower.diff.header.file configure -text $f
3922         .vpane.lower.diff.header.path configure -text $p
3923         foreach w $diff_actions {
3924                 uplevel #0 $w $o
3925         }
3926 }
3927 trace add variable current_diff_path write trace_current_diff_path
3928
3929 frame .vpane.lower.diff.header -background orange
3930 label .vpane.lower.diff.header.status \
3931         -background orange \
3932         -width $max_status_desc \
3933         -anchor w \
3934         -justify left \
3935         -font font_ui
3936 label .vpane.lower.diff.header.file \
3937         -background orange \
3938         -anchor w \
3939         -justify left \
3940         -font font_ui
3941 label .vpane.lower.diff.header.path \
3942         -background orange \
3943         -anchor w \
3944         -justify left \
3945         -font font_ui
3946 pack .vpane.lower.diff.header.status -side left
3947 pack .vpane.lower.diff.header.file -side left
3948 pack .vpane.lower.diff.header.path -fill x
3949 set ctxm .vpane.lower.diff.header.ctxm
3950 menu $ctxm -tearoff 0
3951 $ctxm add command \
3952         -label {Copy} \
3953         -font font_ui \
3954         -command {
3955                 clipboard clear
3956                 clipboard append \
3957                         -format STRING \
3958                         -type STRING \
3959                         -- $current_diff_path
3960         }
3961 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3962 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3963
3964 # -- Diff Body
3965 #
3966 frame .vpane.lower.diff.body
3967 set ui_diff .vpane.lower.diff.body.t
3968 text $ui_diff -background white -borderwidth 0 \
3969         -width 80 -height 15 -wrap none \
3970         -font font_diff \
3971         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3972         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3973         -state disabled
3974 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3975         -command [list $ui_diff xview]
3976 scrollbar .vpane.lower.diff.body.sby -orient vertical \
3977         -command [list $ui_diff yview]
3978 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3979 pack .vpane.lower.diff.body.sby -side right -fill y
3980 pack $ui_diff -side left -fill both -expand 1
3981 pack .vpane.lower.diff.header -side top -fill x
3982 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3983
3984 $ui_diff tag conf d_@ -foreground blue -font font_diffbold
3985 $ui_diff tag conf d_+ -foreground {#00a000}
3986 $ui_diff tag conf d_- -foreground red
3987
3988 $ui_diff tag conf d_++ -foreground {#00a000}
3989 $ui_diff tag conf d_-- -foreground red
3990 $ui_diff tag conf d_+s \
3991         -foreground {#00a000} \
3992         -background {#e2effa}
3993 $ui_diff tag conf d_-s \
3994         -foreground red \
3995         -background {#e2effa}
3996 $ui_diff tag conf d_s+ \
3997         -foreground {#00a000} \
3998         -background ivory1
3999 $ui_diff tag conf d_s- \
4000         -foreground red \
4001         -background ivory1
4002
4003 $ui_diff tag conf d<<<<<<< \
4004         -foreground orange \
4005         -font font_diffbold
4006 $ui_diff tag conf d======= \
4007         -foreground orange \
4008         -font font_diffbold
4009 $ui_diff tag conf d>>>>>>> \
4010         -foreground orange \
4011         -font font_diffbold
4012
4013 $ui_diff tag raise sel
4014
4015 # -- Diff Body Context Menu
4016 #
4017 set ctxm .vpane.lower.diff.body.ctxm
4018 menu $ctxm -tearoff 0
4019 $ctxm add command \
4020         -label {Refresh} \
4021         -font font_ui \
4022         -command reshow_diff
4023 $ctxm add command \
4024         -label {Copy} \
4025         -font font_ui \
4026         -command {tk_textCopy $ui_diff}
4027 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
4028 $ctxm add command \
4029         -label {Select All} \
4030         -font font_ui \
4031         -command {$ui_diff tag add sel 0.0 end}
4032 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
4033 $ctxm add command \
4034         -label {Copy All} \
4035         -font font_ui \
4036         -command {
4037                 $ui_diff tag add sel 0.0 end
4038                 tk_textCopy $ui_diff
4039                 $ui_diff tag remove sel 0.0 end
4040         }
4041 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
4042 $ctxm add separator
4043 $ctxm add command \
4044         -label {Decrease Font Size} \
4045         -font font_ui \
4046         -command {incr_font_size font_diff -1}
4047 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
4048 $ctxm add command \
4049         -label {Increase Font Size} \
4050         -font font_ui \
4051         -command {incr_font_size font_diff 1}
4052 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
4053 $ctxm add separator
4054 $ctxm add command \
4055         -label {Show Less Context} \
4056         -font font_ui \
4057         -command {if {$repo_config(gui.diffcontext) >= 2} {
4058                 incr repo_config(gui.diffcontext) -1
4059                 reshow_diff
4060         }}
4061 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
4062 $ctxm add command \
4063         -label {Show More Context} \
4064         -font font_ui \
4065         -command {
4066                 incr repo_config(gui.diffcontext)
4067                 reshow_diff
4068         }
4069 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
4070 $ctxm add separator
4071 $ctxm add command -label {Options...} \
4072         -font font_ui \
4073         -command do_options
4074 bind_button3 $ui_diff "tk_popup $ctxm %X %Y"
4075
4076 # -- Status Bar
4077 #
4078 set ui_status_value {Initializing...}
4079 label .status -textvariable ui_status_value \
4080         -anchor w \
4081         -justify left \
4082         -borderwidth 1 \
4083         -relief sunken \
4084         -font font_ui
4085 pack .status -anchor w -side bottom -fill x
4086
4087 # -- Load geometry
4088 #
4089 catch {
4090 set gm $repo_config(gui.geometry)
4091 wm geometry . [lindex $gm 0]
4092 .vpane sash place 0 \
4093         [lindex [.vpane sash coord 0] 0] \
4094         [lindex $gm 1]
4095 .vpane.files sash place 0 \
4096         [lindex $gm 2] \
4097         [lindex [.vpane.files sash coord 0] 1]
4098 unset gm
4099 }
4100
4101 # -- Key Bindings
4102 #
4103 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
4104 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
4105 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
4106 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
4107 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
4108 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
4109 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
4110 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
4111 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
4112 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
4113 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
4114
4115 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
4116 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
4117 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
4118 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
4119 bind $ui_diff <$M1B-Key-v> {break}
4120 bind $ui_diff <$M1B-Key-V> {break}
4121 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
4122 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
4123 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
4124 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
4125 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
4126 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
4127
4128 if {!$single_commit} {
4129         bind . <$M1B-Key-n> do_create_branch
4130         bind . <$M1B-Key-N> do_create_branch
4131 }
4132
4133 bind .   <Destroy> do_quit
4134 bind all <Key-F5> do_rescan
4135 bind all <$M1B-Key-r> do_rescan
4136 bind all <$M1B-Key-R> do_rescan
4137 bind .   <$M1B-Key-s> do_signoff
4138 bind .   <$M1B-Key-S> do_signoff
4139 bind .   <$M1B-Key-i> do_add_all
4140 bind .   <$M1B-Key-I> do_add_all
4141 bind .   <$M1B-Key-Return> do_commit
4142 bind all <$M1B-Key-q> do_quit
4143 bind all <$M1B-Key-Q> do_quit
4144 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
4145 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
4146 foreach i [list $ui_index $ui_workdir] {
4147         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
4148         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
4149         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
4150 }
4151 unset i
4152
4153 set file_lists($ui_index) [list]
4154 set file_lists($ui_workdir) [list]
4155
4156 set HEAD {}
4157 set PARENT {}
4158 set MERGE_HEAD [list]
4159 set commit_type {}
4160 set empty_tree {}
4161 set current_branch {}
4162 set current_diff_path {}
4163 set selected_commit_type new
4164
4165 wm title . "[appname] ([file normalize [file dirname [gitdir]]])"
4166 focus -force $ui_comm
4167
4168 # -- Warn the user about environmental problems.  Cygwin's Tcl
4169 #    does *not* pass its env array onto any processes it spawns.
4170 #    This means that git processes get none of our environment.
4171 #
4172 if {[is_Windows]} {
4173         set ignored_env 0
4174         set suggest_user {}
4175         set msg "Possible environment issues exist.
4176
4177 The following environment variables are probably
4178 going to be ignored by any Git subprocess run
4179 by [appname]:
4180
4181 "
4182         foreach name [array names env] {
4183                 switch -regexp -- $name {
4184                 {^GIT_INDEX_FILE$} -
4185                 {^GIT_OBJECT_DIRECTORY$} -
4186                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
4187                 {^GIT_DIFF_OPTS$} -
4188                 {^GIT_EXTERNAL_DIFF$} -
4189                 {^GIT_PAGER$} -
4190                 {^GIT_TRACE$} -
4191                 {^GIT_CONFIG$} -
4192                 {^GIT_CONFIG_LOCAL$} -
4193                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
4194                         append msg " - $name\n"
4195                         incr ignored_env
4196                 }
4197                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
4198                         append msg " - $name\n"
4199                         incr ignored_env
4200                         set suggest_user $name
4201                 }
4202                 }
4203         }
4204         if {$ignored_env > 0} {
4205                 append msg "
4206 This is due to a known issue with the
4207 Tcl binary distributed by Cygwin."
4208
4209                 if {$suggest_user ne {}} {
4210                         append msg "
4211
4212 A good replacement for $suggest_user
4213 is placing values for the user.name and
4214 user.email settings into your personal
4215 ~/.gitconfig file.
4216 "
4217                 }
4218                 warn_popup $msg
4219         }
4220         unset ignored_env msg suggest_user name
4221 }
4222
4223 # -- Only initialize complex UI if we are going to stay running.
4224 #
4225 if {!$single_commit} {
4226         load_all_remotes
4227         load_all_heads
4228
4229         populate_branch_menu
4230         populate_fetch_menu .mbar.fetch
4231         populate_pull_menu .mbar.pull
4232         populate_push_menu .mbar.push
4233 }
4234
4235 # -- Only suggest a gc run if we are going to stay running.
4236 #
4237 if {!$single_commit} {
4238         set object_limit 2000
4239         if {[is_Windows]} {set object_limit 200}
4240         regexp {^([0-9]+) objects,} [exec git count-objects] _junk objects_current
4241         if {$objects_current >= $object_limit} {
4242                 if {[ask_popup \
4243                         "This repository currently has $objects_current loose objects.
4244
4245 To maintain optimal performance it is strongly
4246 recommended that you compress the database
4247 when more than $object_limit loose objects exist.
4248
4249 Compress the database now?"] eq yes} {
4250                         do_gc
4251                 }
4252         }
4253         unset object_limit _junk objects_current
4254 }
4255
4256 lock_index begin-read
4257 after 1 do_rescan