git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3 exec wish "$0" -- "$@"
   4
   5 set appvers {@@GIT_VERSION@@}
   6 set copyright {
   7 Copyright © 2006, 2007 Shawn Pearce, Paul Mackerras.
   8
   9 This program is free software; you can redistribute it and/or modify
  10 it under the terms of the GNU General Public License as published by
  11 the Free Software Foundation; either version 2 of the License, or
  12 (at your option) any later version.
  13
  14 This program is distributed in the hope that it will be useful,
  15 but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 GNU General Public License for more details.
  18
  19 You should have received a copy of the GNU General Public License
  20 along with this program; if not, write to the Free Software
  21 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}
  22
  23 ######################################################################
  24 ##
  25 ## read only globals
  26
  27 set _appname [lindex [file split $argv0] end]
  28 set _gitdir {}
  29 set _reponame {}
  30
  31 proc appname {} {
  32         global _appname
  33         return $_appname
  34 }
  35
  36 proc gitdir {args} {
  37         global _gitdir
  38         if {$args eq {}} {
  39                 return $_gitdir
  40         }
  41         return [eval [concat [list file join $_gitdir] $args]]
  42 }
  43
  44 proc reponame {} {
  45         global _reponame
  46         return $_reponame
  47 }
  48
  49 ######################################################################
  50 ##
  51 ## config
  52
  53 proc is_many_config {name} {
  54         switch -glob -- $name {
  55         remote.*.fetch -
  56         remote.*.push
  57                 {return 1}
  58         *
  59                 {return 0}
  60         }
  61 }
  62
  63 proc load_config {include_global} {
  64         global repo_config global_config default_config
  65
  66         array unset global_config
  67         if {$include_global} {
  68                 catch {
  69                         set fd_rc [open "| git repo-config --global --list" r]
  70                         while {[gets $fd_rc line] >= 0} {
  71                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  72                                         if {[is_many_config $name]} {
  73                                                 lappend global_config($name) $value
  74                                         } else {
  75                                                 set global_config($name) $value
  76                                         }
  77                                 }
  78                         }
  79                         close $fd_rc
  80                 }
  81         }
  82
  83         array unset repo_config
  84         catch {
  85                 set fd_rc [open "| git repo-config --list" r]
  86                 while {[gets $fd_rc line] >= 0} {
  87                         if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  88                                 if {[is_many_config $name]} {
  89                                         lappend repo_config($name) $value
  90                                 } else {
  91                                         set repo_config($name) $value
  92                                 }
  93                         }
  94                 }
  95                 close $fd_rc
  96         }
  97
  98         foreach name [array names default_config] {
  99                 if {[catch {set v $global_config($name)}]} {
 100                         set global_config($name) $default_config($name)
 101                 }
 102                 if {[catch {set v $repo_config($name)}]} {
 103                         set repo_config($name) $default_config($name)
 104                 }
 105         }
 106 }
 107
 108 proc save_config {} {
 109         global default_config font_descs
 110         global repo_config global_config
 111         global repo_config_new global_config_new
 112
 113         foreach option $font_descs {
 114                 set name [lindex $option 0]
 115                 set font [lindex $option 1]
 116                 font configure $font \
 117                         -family $global_config_new(gui.$font^^family) \
 118                         -size $global_config_new(gui.$font^^size)
 119                 font configure ${font}bold \
 120                         -family $global_config_new(gui.$font^^family) \
 121                         -size $global_config_new(gui.$font^^size)
 122                 set global_config_new(gui.$name) [font configure $font]
 123                 unset global_config_new(gui.$font^^family)
 124                 unset global_config_new(gui.$font^^size)
 125         }
 126
 127         foreach name [array names default_config] {
 128                 set value $global_config_new($name)
 129                 if {$value ne $global_config($name)} {
 130                         if {$value eq $default_config($name)} {
 131                                 catch {exec git repo-config --global --unset $name}
 132                         } else {
 133                                 regsub -all "\[{}\]" $value {"} value
 134                                 exec git repo-config --global $name $value
 135                         }
 136                         set global_config($name) $value
 137                         if {$value eq $repo_config($name)} {
 138                                 catch {exec git repo-config --unset $name}
 139                                 set repo_config($name) $value
 140                         }
 141                 }
 142         }
 143
 144         foreach name [array names default_config] {
 145                 set value $repo_config_new($name)
 146                 if {$value ne $repo_config($name)} {
 147                         if {$value eq $global_config($name)} {
 148                                 catch {exec git repo-config --unset $name}
 149                         } else {
 150                                 regsub -all "\[{}\]" $value {"} value
 151                                 exec git repo-config $name $value
 152                         }
 153                         set repo_config($name) $value
 154                 }
 155         }
 156 }
 157
 158 proc error_popup {msg} {
 159         set title [appname]
 160         if {[reponame] ne {}} {
 161                 append title " ([reponame])"
 162         }
 163         set cmd [list tk_messageBox \
 164                 -icon error \
 165                 -type ok \
 166                 -title "$title: error" \
 167                 -message $msg]
 168         if {[winfo ismapped .]} {
 169                 lappend cmd -parent .
 170         }
 171         eval $cmd
 172 }
 173
 174 proc warn_popup {msg} {
 175         set title [appname]
 176         if {[reponame] ne {}} {
 177                 append title " ([reponame])"
 178         }
 179         set cmd [list tk_messageBox \
 180                 -icon warning \
 181                 -type ok \
 182                 -title "$title: warning" \
 183                 -message $msg]
 184         if {[winfo ismapped .]} {
 185                 lappend cmd -parent .
 186         }
 187         eval $cmd
 188 }
 189
 190 proc info_popup {msg} {
 191         set title [appname]
 192         if {[reponame] ne {}} {
 193                 append title " ([reponame])"
 194         }
 195         tk_messageBox \
 196                 -parent . \
 197                 -icon info \
 198                 -type ok \
 199                 -title $title \
 200                 -message $msg
 201 }
 202
 203 proc ask_popup {msg} {
 204         set title [appname]
 205         if {[reponame] ne {}} {
 206                 append title " ([reponame])"
 207         }
 208         return [tk_messageBox \
 209                 -parent . \
 210                 -icon question \
 211                 -type yesno \
 212                 -title $title \
 213                 -message $msg]
 214 }
 215
 216 ######################################################################
 217 ##
 218 ## repository setup
 219
 220 if {   [catch {set _gitdir $env(GIT_DIR)}]
 221         && [catch {set _gitdir [exec git rev-parse --git-dir]} err]} {
 222         catch {wm withdraw .}
 223         error_popup "Cannot find the git directory:\n\n$err"
 224         exit 1
 225 }
 226 if {![file isdirectory $_gitdir]} {
 227         catch {wm withdraw .}
 228         error_popup "Git directory not found:\n\n$_gitdir"
 229         exit 1
 230 }
 231 if {[lindex [file split $_gitdir] end] ne {.git}} {
 232         catch {wm withdraw .}
 233         error_popup "Cannot use funny .git directory:\n\n$gitdir"
 234         exit 1
 235 }
 236 if {[catch {cd [file dirname $_gitdir]} err]} {
 237         catch {wm withdraw .}
 238         error_popup "No working directory [file dirname $_gitdir]:\n\n$err"
 239         exit 1
 240 }
 241 set _reponame [lindex [file split \
 242         [file normalize [file dirname $_gitdir]]] \
 243         end]
 244
 245 set single_commit 0
 246 if {[appname] eq {git-citool}} {
 247         set single_commit 1
 248 }
 249
 250 ######################################################################
 251 ##
 252 ## task management
 253
 254 set rescan_active 0
 255 set diff_active 0
 256 set last_clicked {}
 257
 258 set disable_on_lock [list]
 259 set index_lock_type none
 260
 261 proc lock_index {type} {
 262         global index_lock_type disable_on_lock
 263
 264         if {$index_lock_type eq {none}} {
 265                 set index_lock_type $type
 266                 foreach w $disable_on_lock {
 267                         uplevel #0 $w disabled
 268                 }
 269                 return 1
 270         } elseif {$index_lock_type eq "begin-$type"} {
 271                 set index_lock_type $type
 272                 return 1
 273         }
 274         return 0
 275 }
 276
 277 proc unlock_index {} {
 278         global index_lock_type disable_on_lock
 279
 280         set index_lock_type none
 281         foreach w $disable_on_lock {
 282                 uplevel #0 $w normal
 283         }
 284 }
 285
 286 ######################################################################
 287 ##
 288 ## status
 289
 290 proc repository_state {ctvar hdvar mhvar} {
 291         global current_branch
 292         upvar $ctvar ct $hdvar hd $mhvar mh
 293
 294         set mh [list]
 295
 296         if {[catch {set current_branch [exec git symbolic-ref HEAD]}]} {
 297                 set current_branch {}
 298         } else {
 299                 regsub ^refs/((heads|tags|remotes)/)? \
 300                         $current_branch \
 301                         {} \
 302                         current_branch
 303         }
 304
 305         if {[catch {set hd [exec git rev-parse --verify HEAD]}]} {
 306                 set hd {}
 307                 set ct initial
 308                 return
 309         }
 310
 311         set merge_head [gitdir MERGE_HEAD]
 312         if {[file exists $merge_head]} {
 313                 set ct merge
 314                 set fd_mh [open $merge_head r]
 315                 while {[gets $fd_mh line] >= 0} {
 316                         lappend mh $line
 317                 }
 318                 close $fd_mh
 319                 return
 320         }
 321
 322         set ct normal
 323 }
 324
 325 proc PARENT {} {
 326         global PARENT empty_tree
 327
 328         set p [lindex $PARENT 0]
 329         if {$p ne {}} {
 330                 return $p
 331         }
 332         if {$empty_tree eq {}} {
 333                 set empty_tree [exec git mktree << {}]
 334         }
 335         return $empty_tree
 336 }
 337
 338 proc rescan {after} {
 339         global HEAD PARENT MERGE_HEAD commit_type
 340         global ui_index ui_workdir ui_status_value ui_comm
 341         global rescan_active file_states
 342         global repo_config
 343
 344         if {$rescan_active > 0 || ![lock_index read]} return
 345
 346         repository_state newType newHEAD newMERGE_HEAD
 347         if {[string match amend* $commit_type]
 348                 && $newType eq {normal}
 349                 && $newHEAD eq $HEAD} {
 350         } else {
 351                 set HEAD $newHEAD
 352                 set PARENT $newHEAD
 353                 set MERGE_HEAD $newMERGE_HEAD
 354                 set commit_type $newType
 355         }
 356
 357         array unset file_states
 358
 359         if {![$ui_comm edit modified]
 360                 || [string trim [$ui_comm get 0.0 end]] eq {}} {
 361                 if {[load_message GITGUI_MSG]} {
 362                 } elseif {[load_message MERGE_MSG]} {
 363                 } elseif {[load_message SQUASH_MSG]} {
 364                 }
 365                 $ui_comm edit reset
 366                 $ui_comm edit modified false
 367         }
 368
 369         if {$repo_config(gui.trustmtime) eq {true}} {
 370                 rescan_stage2 {} $after
 371         } else {
 372                 set rescan_active 1
 373                 set ui_status_value {Refreshing file status...}
 374                 set cmd [list git update-index]
 375                 lappend cmd -q
 376                 lappend cmd --unmerged
 377                 lappend cmd --ignore-missing
 378                 lappend cmd --refresh
 379                 set fd_rf [open "| $cmd" r]
 380                 fconfigure $fd_rf -blocking 0 -translation binary
 381                 fileevent $fd_rf readable \
 382                         [list rescan_stage2 $fd_rf $after]
 383         }
 384 }
 385
 386 proc rescan_stage2 {fd after} {
 387         global ui_status_value
 388         global rescan_active buf_rdi buf_rdf buf_rlo
 389
 390         if {$fd ne {}} {
 391                 read $fd
 392                 if {![eof $fd]} return
 393                 close $fd
 394         }
 395
 396         set ls_others [list | git ls-files --others -z \
 397                 --exclude-per-directory=.gitignore]
 398         set info_exclude [gitdir info exclude]
 399         if {[file readable $info_exclude]} {
 400                 lappend ls_others "--exclude-from=$info_exclude"
 401         }
 402
 403         set buf_rdi {}
 404         set buf_rdf {}
 405         set buf_rlo {}
 406
 407         set rescan_active 3
 408         set ui_status_value {Scanning for modified files ...}
 409         set fd_di [open "| git diff-index --cached -z [PARENT]" r]
 410         set fd_df [open "| git diff-files -z" r]
 411         set fd_lo [open $ls_others r]
 412
 413         fconfigure $fd_di -blocking 0 -translation binary
 414         fconfigure $fd_df -blocking 0 -translation binary
 415         fconfigure $fd_lo -blocking 0 -translation binary
 416         fileevent $fd_di readable [list read_diff_index $fd_di $after]
 417         fileevent $fd_df readable [list read_diff_files $fd_df $after]
 418         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
 419 }
 420
 421 proc load_message {file} {
 422         global ui_comm
 423
 424         set f [gitdir $file]
 425         if {[file isfile $f]} {
 426                 if {[catch {set fd [open $f r]}]} {
 427                         return 0
 428                 }
 429                 set content [string trim [read $fd]]
 430                 close $fd
 431                 $ui_comm delete 0.0 end
 432                 $ui_comm insert end $content
 433                 return 1
 434         }
 435         return 0
 436 }
 437
 438 proc read_diff_index {fd after} {
 439         global buf_rdi
 440
 441         append buf_rdi [read $fd]
 442         set c 0
 443         set n [string length $buf_rdi]
 444         while {$c < $n} {
 445                 set z1 [string first "\0" $buf_rdi $c]
 446                 if {$z1 == -1} break
 447                 incr z1
 448                 set z2 [string first "\0" $buf_rdi $z1]
 449                 if {$z2 == -1} break
 450
 451                 incr c
 452                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
 453                 merge_state \
 454                         [string range $buf_rdi $z1 [expr {$z2 - 1}]] \
 455                         [lindex $i 4]? \
 456                         [list [lindex $i 0] [lindex $i 2]] \
 457                         [list]
 458                 set c $z2
 459                 incr c
 460         }
 461         if {$c < $n} {
 462                 set buf_rdi [string range $buf_rdi $c end]
 463         } else {
 464                 set buf_rdi {}
 465         }
 466
 467         rescan_done $fd buf_rdi $after
 468 }
 469
 470 proc read_diff_files {fd after} {
 471         global buf_rdf
 472
 473         append buf_rdf [read $fd]
 474         set c 0
 475         set n [string length $buf_rdf]
 476         while {$c < $n} {
 477                 set z1 [string first "\0" $buf_rdf $c]
 478                 if {$z1 == -1} break
 479                 incr z1
 480                 set z2 [string first "\0" $buf_rdf $z1]
 481                 if {$z2 == -1} break
 482
 483                 incr c
 484                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
 485                 merge_state \
 486                         [string range $buf_rdf $z1 [expr {$z2 - 1}]] \
 487                         ?[lindex $i 4] \
 488                         [list] \
 489                         [list [lindex $i 0] [lindex $i 2]]
 490                 set c $z2
 491                 incr c
 492         }
 493         if {$c < $n} {
 494                 set buf_rdf [string range $buf_rdf $c end]
 495         } else {
 496                 set buf_rdf {}
 497         }
 498
 499         rescan_done $fd buf_rdf $after
 500 }
 501
 502 proc read_ls_others {fd after} {
 503         global buf_rlo
 504
 505         append buf_rlo [read $fd]
 506         set pck [split $buf_rlo "\0"]
 507         set buf_rlo [lindex $pck end]
 508         foreach p [lrange $pck 0 end-1] {
 509                 merge_state $p ?O
 510         }
 511         rescan_done $fd buf_rlo $after
 512 }
 513
 514 proc rescan_done {fd buf after} {
 515         global rescan_active
 516         global file_states repo_config
 517         upvar $buf to_clear
 518
 519         if {![eof $fd]} return
 520         set to_clear {}
 521         close $fd
 522         if {[incr rescan_active -1] > 0} return
 523
 524         prune_selection
 525         unlock_index
 526         display_all_files
 527
 528         if {$repo_config(gui.partialinclude) ne {true}} {
 529                 set pathList [list]
 530                 foreach path [array names file_states] {
 531                         switch -- [lindex $file_states($path) 0] {
 532                         A? -
 533                         M? {lappend pathList $path}
 534                         }
 535                 }
 536                 if {$pathList ne {}} {
 537                         update_index \
 538                                 "Updating included files" \
 539                                 $pathList \
 540                                 [concat {reshow_diff;} $after]
 541                         return
 542                 }
 543         }
 544
 545         reshow_diff
 546         uplevel #0 $after
 547 }
 548
 549 proc prune_selection {} {
 550         global file_states selected_paths
 551
 552         foreach path [array names selected_paths] {
 553                 if {[catch {set still_here $file_states($path)}]} {
 554                         unset selected_paths($path)
 555                 }
 556         }
 557 }
 558
 559 ######################################################################
 560 ##
 561 ## diff
 562
 563 proc clear_diff {} {
 564         global ui_diff current_diff ui_index ui_workdir
 565
 566         $ui_diff conf -state normal
 567         $ui_diff delete 0.0 end
 568         $ui_diff conf -state disabled
 569
 570         set current_diff {}
 571
 572         $ui_index tag remove in_diff 0.0 end
 573         $ui_workdir tag remove in_diff 0.0 end
 574 }
 575
 576 proc reshow_diff {} {
 577         global current_diff ui_status_value file_states
 578
 579         if {$current_diff eq {}
 580                 || [catch {set s $file_states($current_diff)}]} {
 581                 clear_diff
 582         } else {
 583                 show_diff $current_diff
 584         }
 585 }
 586
 587 proc handle_empty_diff {} {
 588         global current_diff file_states file_lists
 589
 590         set path $current_diff
 591         set s $file_states($path)
 592         if {[lindex $s 0] ne {_M}} return
 593
 594         info_popup "No differences detected.
 595
 596 [short_path $path] has no changes.
 597
 598 The modification date of this file was updated
 599 by another application and you currently have
 600 the Trust File Modification Timestamps option
 601 enabled, so Git did not automatically detect
 602 that there are no content differences in this
 603 file.
 604
 605 This file will now be removed from the modified
 606 files list, to prevent possible confusion.
 607 "
 608         if {[catch {exec git update-index -- $path} err]} {
 609                 error_popup "Failed to refresh index:\n\n$err"
 610         }
 611
 612         clear_diff
 613         display_file $path __
 614 }
 615
 616 proc show_diff {path {w {}} {lno {}}} {
 617         global file_states file_lists
 618         global is_3way_diff diff_active repo_config
 619         global ui_diff current_diff ui_status_value
 620
 621         if {$diff_active || ![lock_index read]} return
 622
 623         clear_diff
 624         if {$w eq {} || $lno == {}} {
 625                 foreach w [array names file_lists] {
 626                         set lno [lsearch -sorted $file_lists($w) $path]
 627                         if {$lno >= 0} {
 628                                 incr lno
 629                                 break
 630                         }
 631                 }
 632         }
 633         if {$w ne {} && $lno >= 1} {
 634                 $w tag add in_diff $lno.0 [expr {$lno + 1}].0
 635         }
 636
 637         set s $file_states($path)
 638         set m [lindex $s 0]
 639         set is_3way_diff 0
 640         set diff_active 1
 641         set current_diff $path
 642         set ui_status_value "Loading diff of [escape_path $path]..."
 643
 644         set cmd [list | git diff-index]
 645         lappend cmd --no-color
 646         if {$repo_config(gui.diffcontext) > 0} {
 647                 lappend cmd "-U$repo_config(gui.diffcontext)"
 648         }
 649         lappend cmd -p
 650
 651         switch $m {
 652         MM {
 653                 lappend cmd -c
 654         }
 655         _O {
 656                 if {[catch {
 657                                 set fd [open $path r]
 658                                 set content [read $fd]
 659                                 close $fd
 660                         } err ]} {
 661                         set diff_active 0
 662                         unlock_index
 663                         set ui_status_value "Unable to display [escape_path $path]"
 664                         error_popup "Error loading file:\n\n$err"
 665                         return
 666                 }
 667                 $ui_diff conf -state normal
 668                 $ui_diff insert end $content
 669                 $ui_diff conf -state disabled
 670                 set diff_active 0
 671                 unlock_index
 672                 set ui_status_value {Ready.}
 673                 return
 674         }
 675         }
 676
 677         lappend cmd [PARENT]
 678         lappend cmd --
 679         lappend cmd $path
 680
 681         if {[catch {set fd [open $cmd r]} err]} {
 682                 set diff_active 0
 683                 unlock_index
 684                 set ui_status_value "Unable to display [escape_path $path]"
 685                 error_popup "Error loading diff:\n\n$err"
 686                 return
 687         }
 688
 689         fconfigure $fd -blocking 0 -translation auto
 690         fileevent $fd readable [list read_diff $fd]
 691 }
 692
 693 proc read_diff {fd} {
 694         global ui_diff ui_status_value is_3way_diff diff_active
 695         global repo_config
 696
 697         $ui_diff conf -state normal
 698         while {[gets $fd line] >= 0} {
 699                 # -- Cleanup uninteresting diff header lines.
 700                 #
 701                 if {[string match {diff --git *}      $line]} continue
 702                 if {[string match {diff --combined *} $line]} continue
 703                 if {[string match {--- *}             $line]} continue
 704                 if {[string match {+++ *}             $line]} continue
 705                 if {$line eq {deleted file mode 120000}} {
 706                         set line "deleted symlink"
 707                 }
 708
 709                 # -- Automatically detect if this is a 3 way diff.
 710                 #
 711                 if {[string match {@@@ *} $line]} {set is_3way_diff 1}
 712
 713                 # -- Reformat a 3 way diff, 'cause its too weird.
 714                 #
 715                 if {$is_3way_diff} {
 716                         set op [string range $line 0 1]
 717                         switch -- $op {
 718                         {@@} {set tags d_@}
 719                         {++} {set tags d_+ ; set op { +}}
 720                         {--} {set tags d_- ; set op { -}}
 721                         { +} {set tags d_++; set op {++}}
 722                         { -} {set tags d_--; set op {--}}
 723                         {+ } {set tags d_-+; set op {-+}}
 724                         {- } {set tags d_+-; set op {+-}}
 725                         default {set tags {}}
 726                         }
 727                         set line [string replace $line 0 1 $op]
 728                 } else {
 729                         switch -- [string index $line 0] {
 730                         @ {set tags d_@}
 731                         + {set tags d_+}
 732                         - {set tags d_-}
 733                         default {set tags {}}
 734                         }
 735                 }
 736                 $ui_diff insert end $line $tags
 737                 $ui_diff insert end "\n" $tags
 738         }
 739         $ui_diff conf -state disabled
 740
 741         if {[eof $fd]} {
 742                 close $fd
 743                 set diff_active 0
 744                 unlock_index
 745                 set ui_status_value {Ready.}
 746
 747                 if {$repo_config(gui.trustmtime) eq {true}
 748                         && [$ui_diff index end] eq {2.0}} {
 749                         handle_empty_diff
 750                 }
 751         }
 752 }
 753
 754 ######################################################################
 755 ##
 756 ## commit
 757
 758 proc load_last_commit {} {
 759         global HEAD PARENT MERGE_HEAD commit_type ui_comm
 760
 761         if {[llength $PARENT] == 0} {
 762                 error_popup {There is nothing to amend.
 763
 764 You are about to create the initial commit.
 765 There is no commit before this to amend.
 766 }
 767                 return
 768         }
 769
 770         repository_state curType curHEAD curMERGE_HEAD
 771         if {$curType eq {merge}} {
 772                 error_popup {Cannot amend while merging.
 773
 774 You are currently in the middle of a merge that
 775 has not been fully completed.  You cannot amend
 776 the prior commit unless you first abort the
 777 current merge activity.
 778 }
 779                 return
 780         }
 781
 782         set msg {}
 783         set parents [list]
 784         if {[catch {
 785                         set fd [open "| git cat-file commit $curHEAD" r]
 786                         while {[gets $fd line] > 0} {
 787                                 if {[string match {parent *} $line]} {
 788                                         lappend parents [string range $line 7 end]
 789                                 }
 790                         }
 791                         set msg [string trim [read $fd]]
 792                         close $fd
 793                 } err]} {
 794                 error_popup "Error loading commit data for amend:\n\n$err"
 795                 return
 796         }
 797
 798         set HEAD $curHEAD
 799         set PARENT $parents
 800         set MERGE_HEAD [list]
 801         switch -- [llength $parents] {
 802         0       {set commit_type amend-initial}
 803         1       {set commit_type amend}
 804         default {set commit_type amend-merge}
 805         }
 806
 807         $ui_comm delete 0.0 end
 808         $ui_comm insert end $msg
 809         $ui_comm edit reset
 810         $ui_comm edit modified false
 811         rescan {set ui_status_value {Ready.}}
 812 }
 813
 814 proc create_new_commit {} {
 815         global commit_type ui_comm
 816
 817         set commit_type normal
 818         $ui_comm delete 0.0 end
 819         $ui_comm edit reset
 820         $ui_comm edit modified false
 821         rescan {set ui_status_value {Ready.}}
 822 }
 823
 824 set GIT_COMMITTER_IDENT {}
 825
 826 proc committer_ident {} {
 827         global GIT_COMMITTER_IDENT
 828
 829         if {$GIT_COMMITTER_IDENT eq {}} {
 830                 if {[catch {set me [exec git var GIT_COMMITTER_IDENT]} err]} {
 831                         error_popup "Unable to obtain your identity:\n\n$err"
 832                         return {}
 833                 }
 834                 if {![regexp {^(.*) [0-9]+ [-+0-9]+$} \
 835                         $me me GIT_COMMITTER_IDENT]} {
 836                         error_popup "Invalid GIT_COMMITTER_IDENT:\n\n$me"
 837                         return {}
 838                 }
 839         }
 840
 841         return $GIT_COMMITTER_IDENT
 842 }
 843
 844 proc commit_tree {} {
 845         global HEAD commit_type file_states ui_comm repo_config
 846
 847         if {![lock_index update]} return
 848         if {[committer_ident] eq {}} return
 849
 850         # -- Our in memory state should match the repository.
 851         #
 852         repository_state curType curHEAD curMERGE_HEAD
 853         if {[string match amend* $commit_type]
 854                 && $curType eq {normal}
 855                 && $curHEAD eq $HEAD} {
 856         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
 857                 info_popup {Last scanned state does not match repository state.
 858
 859 Another Git program has modified this repository
 860 since the last scan.  A rescan must be performed
 861 before another commit can be created.
 862
 863 The rescan will be automatically started now.
 864 }
 865                 unlock_index
 866                 rescan {set ui_status_value {Ready.}}
 867                 return
 868         }
 869
 870         # -- At least one file should differ in the index.
 871         #
 872         set files_ready 0
 873         foreach path [array names file_states] {
 874                 switch -glob -- [lindex $file_states($path) 0] {
 875                 _? {continue}
 876                 A? -
 877                 D? -
 878                 M? {set files_ready 1; break}
 879                 U? {
 880                         error_popup "Unmerged files cannot be committed.
 881
 882 File [short_path $path] has merge conflicts.
 883 You must resolve them and include the file before committing.
 884 "
 885                         unlock_index
 886                         return
 887                 }
 888                 default {
 889                         error_popup "Unknown file state [lindex $s 0] detected.
 890
 891 File [short_path $path] cannot be committed by this program.
 892 "
 893                 }
 894                 }
 895         }
 896         if {!$files_ready} {
 897                 error_popup {No included files to commit.
 898
 899 You must include at least 1 file before you can commit.
 900 }
 901                 unlock_index
 902                 return
 903         }
 904
 905         # -- A message is required.
 906         #
 907         set msg [string trim [$ui_comm get 1.0 end]]
 908         if {$msg eq {}} {
 909                 error_popup {Please supply a commit message.
 910
 911 A good commit message has the following format:
 912
 913 - First line: Describe in one sentance what you did.
 914 - Second line: Blank
 915 - Remaining lines: Describe why this change is good.
 916 }
 917                 unlock_index
 918                 return
 919         }
 920
 921         # -- Update included files if partialincludes are off.
 922         #
 923         if {$repo_config(gui.partialinclude) ne {true}} {
 924                 set pathList [list]
 925                 foreach path [array names file_states] {
 926                         switch -glob -- [lindex $file_states($path) 0] {
 927                         A? -
 928                         M? {lappend pathList $path}
 929                         }
 930                 }
 931                 if {$pathList ne {}} {
 932                         unlock_index
 933                         update_index \
 934                                 "Updating included files" \
 935                                 $pathList \
 936                                 [concat {lock_index update;} \
 937                                         [list commit_prehook $curHEAD $msg]]
 938                         return
 939                 }
 940         }
 941
 942         commit_prehook $curHEAD $msg
 943 }
 944
 945 proc commit_prehook {curHEAD msg} {
 946         global ui_status_value pch_error
 947
 948         set pchook [gitdir hooks pre-commit]
 949
 950         # On Cygwin [file executable] might lie so we need to ask
 951         # the shell if the hook is executable.  Yes that's annoying.
 952         #
 953         if {[is_Windows] && [file isfile $pchook]} {
 954                 set pchook [list sh -c [concat \
 955                         "if test -x \"$pchook\";" \
 956                         "then exec \"$pchook\" 2>&1;" \
 957                         "fi"]]
 958         } elseif {[file executable $pchook]} {
 959                 set pchook [list $pchook |& cat]
 960         } else {
 961                 commit_writetree $curHEAD $msg
 962                 return
 963         }
 964
 965         set ui_status_value {Calling pre-commit hook...}
 966         set pch_error {}
 967         set fd_ph [open "| $pchook" r]
 968         fconfigure $fd_ph -blocking 0 -translation binary
 969         fileevent $fd_ph readable \
 970                 [list commit_prehook_wait $fd_ph $curHEAD $msg]
 971 }
 972
 973 proc commit_prehook_wait {fd_ph curHEAD msg} {
 974         global pch_error ui_status_value
 975
 976         append pch_error [read $fd_ph]
 977         fconfigure $fd_ph -blocking 1
 978         if {[eof $fd_ph]} {
 979                 if {[catch {close $fd_ph}]} {
 980                         set ui_status_value {Commit declined by pre-commit hook.}
 981                         hook_failed_popup pre-commit $pch_error
 982                         unlock_index
 983                 } else {
 984                         commit_writetree $curHEAD $msg
 985                 }
 986                 set pch_error {}
 987                 return
 988         }
 989         fconfigure $fd_ph -blocking 0
 990 }
 991
 992 proc commit_writetree {curHEAD msg} {
 993         global ui_status_value
 994
 995         set ui_status_value {Committing changes...}
 996         set fd_wt [open "| git write-tree" r]
 997         fileevent $fd_wt readable \
 998                 [list commit_committree $fd_wt $curHEAD $msg]
 999 }
1000
1001 proc commit_committree {fd_wt curHEAD msg} {
1002         global HEAD PARENT MERGE_HEAD commit_type
1003         global single_commit
1004         global ui_status_value ui_comm selected_commit_type
1005         global file_states selected_paths rescan_active
1006
1007         gets $fd_wt tree_id
1008         if {$tree_id eq {} || [catch {close $fd_wt} err]} {
1009                 error_popup "write-tree failed:\n\n$err"
1010                 set ui_status_value {Commit failed.}
1011                 unlock_index
1012                 return
1013         }
1014
1015         # -- Create the commit.
1016         #
1017         set cmd [list git commit-tree $tree_id]
1018         set parents [concat $PARENT $MERGE_HEAD]
1019         if {[llength $parents] > 0} {
1020                 foreach p $parents {
1021                         lappend cmd -p $p
1022                 }
1023         } else {
1024                 # git commit-tree writes to stderr during initial commit.
1025                 lappend cmd 2>/dev/null
1026         }
1027         lappend cmd << $msg
1028         if {[catch {set cmt_id [eval exec $cmd]} err]} {
1029                 error_popup "commit-tree failed:\n\n$err"
1030                 set ui_status_value {Commit failed.}
1031                 unlock_index
1032                 return
1033         }
1034
1035         # -- Update the HEAD ref.
1036         #
1037         set reflogm commit
1038         if {$commit_type ne {normal}} {
1039                 append reflogm " ($commit_type)"
1040         }
1041         set i [string first "\n" $msg]
1042         if {$i >= 0} {
1043                 append reflogm {: } [string range $msg 0 [expr {$i - 1}]]
1044         } else {
1045                 append reflogm {: } $msg
1046         }
1047         set cmd [list git update-ref -m $reflogm HEAD $cmt_id $curHEAD]
1048         if {[catch {eval exec $cmd} err]} {
1049                 error_popup "update-ref failed:\n\n$err"
1050                 set ui_status_value {Commit failed.}
1051                 unlock_index
1052                 return
1053         }
1054
1055         # -- Cleanup after ourselves.
1056         #
1057         catch {file delete [gitdir MERGE_HEAD]}
1058         catch {file delete [gitdir MERGE_MSG]}
1059         catch {file delete [gitdir SQUASH_MSG]}
1060         catch {file delete [gitdir GITGUI_MSG]}
1061
1062         # -- Let rerere do its thing.
1063         #
1064         if {[file isdirectory [gitdir rr-cache]]} {
1065                 catch {exec git rerere}
1066         }
1067
1068         # -- Run the post-commit hook.
1069         #
1070         set pchook [gitdir hooks post-commit]
1071         if {[is_Windows] && [file isfile $pchook]} {
1072                 set pchook [list sh -c [concat \
1073                         "if test -x \"$pchook\";" \
1074                         "then exec \"$pchook\";" \
1075                         "fi"]]
1076         } elseif {![file executable $pchook]} {
1077                 set pchook {}
1078         }
1079         if {$pchook ne {}} {
1080                 catch {exec $pchook &}
1081         }
1082
1083         $ui_comm delete 0.0 end
1084         $ui_comm edit reset
1085         $ui_comm edit modified false
1086
1087         if {$single_commit} do_quit
1088
1089         # -- Update in memory status
1090         #
1091         set selected_commit_type new
1092         set commit_type normal
1093         set HEAD $cmt_id
1094         set PARENT $cmt_id
1095         set MERGE_HEAD [list]
1096
1097         foreach path [array names file_states] {
1098                 set s $file_states($path)
1099                 set m [lindex $s 0]
1100                 switch -glob -- $m {
1101                 _O -
1102                 _M -
1103                 _D {continue}
1104                 __ -
1105                 A_ -
1106                 M_ -
1107                 D_ {
1108                         unset file_states($path)
1109                         catch {unset selected_paths($path)}
1110                 }
1111                 DO {
1112                         set file_states($path) [list _O [lindex $s 1] {} {}]
1113                 }
1114                 AM -
1115                 AD -
1116                 MM -
1117                 MD {
1118                         set file_states($path) [list \
1119                                 _[string index $m 1] \
1120                                 [lindex $s 1] \
1121                                 [lindex $s 3] \
1122                                 {}]
1123                 }
1124                 }
1125         }
1126
1127         display_all_files
1128         unlock_index
1129         reshow_diff
1130         set ui_status_value \
1131                 "Changes committed as [string range $cmt_id 0 7]."
1132 }
1133
1134 ######################################################################
1135 ##
1136 ## fetch pull push
1137
1138 proc fetch_from {remote} {
1139         set w [new_console "fetch $remote" \
1140                 "Fetching new changes from $remote"]
1141         set cmd [list git fetch]
1142         lappend cmd $remote
1143         console_exec $w $cmd
1144 }
1145
1146 proc pull_remote {remote branch} {
1147         global HEAD commit_type file_states repo_config
1148
1149         if {![lock_index update]} return
1150
1151         # -- Our in memory state should match the repository.
1152         #
1153         repository_state curType curHEAD curMERGE_HEAD
1154         if {$commit_type ne $curType || $HEAD ne $curHEAD} {
1155                 info_popup {Last scanned state does not match repository state.
1156
1157 Another Git program has modified this repository
1158 since the last scan.  A rescan must be performed
1159 before a pull operation can be started.
1160
1161 The rescan will be automatically started now.
1162 }
1163                 unlock_index
1164                 rescan {set ui_status_value {Ready.}}
1165                 return
1166         }
1167
1168         # -- No differences should exist before a pull.
1169         #
1170         if {[array size file_states] != 0} {
1171                 error_popup {Uncommitted but modified files are present.
1172
1173 You should not perform a pull with unmodified
1174 files in your working directory as Git will be
1175 unable to recover from an incorrect merge.
1176
1177 You should commit or revert all changes before
1178 starting a pull operation.
1179 }
1180                 unlock_index
1181                 return
1182         }
1183
1184         set w [new_console "pull $remote $branch" \
1185                 "Pulling new changes from branch $branch in $remote"]
1186         set cmd [list git pull]
1187         if {$repo_config(gui.pullsummary) eq {false}} {
1188                 lappend cmd --no-summary
1189         }
1190         lappend cmd $remote
1191         lappend cmd $branch
1192         console_exec $w $cmd [list post_pull_remote $remote $branch]
1193 }
1194
1195 proc post_pull_remote {remote branch success} {
1196         global HEAD PARENT MERGE_HEAD commit_type selected_commit_type
1197         global ui_status_value
1198
1199         unlock_index
1200         if {$success} {
1201                 repository_state commit_type HEAD MERGE_HEAD
1202                 set PARENT $HEAD
1203                 set selected_commit_type new
1204                 set ui_status_value "Pulling $branch from $remote complete."
1205         } else {
1206                 rescan [list set ui_status_value \
1207                         "Conflicts detected while pulling $branch from $remote."]
1208         }
1209 }
1210
1211 proc push_to {remote} {
1212         set w [new_console "push $remote" \
1213                 "Pushing changes to $remote"]
1214         set cmd [list git push]
1215         lappend cmd $remote
1216         console_exec $w $cmd
1217 }
1218
1219 ######################################################################
1220 ##
1221 ## ui helpers
1222
1223 proc mapicon {w state path} {
1224         global all_icons
1225
1226         if {[catch {set r $all_icons($state$w)}]} {
1227                 puts "error: no icon for $w state={$state} $path"
1228                 return file_plain
1229         }
1230         return $r
1231 }
1232
1233 proc mapdesc {state path} {
1234         global all_descs
1235
1236         if {[catch {set r $all_descs($state)}]} {
1237                 puts "error: no desc for state={$state} $path"
1238                 return $state
1239         }
1240         return $r
1241 }
1242
1243 proc escape_path {path} {
1244         regsub -all "\n" $path "\\n" path
1245         return $path
1246 }
1247
1248 proc short_path {path} {
1249         return [escape_path [lindex [file split $path] end]]
1250 }
1251
1252 set next_icon_id 0
1253 set null_sha1 [string repeat 0 40]
1254
1255 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1256         global file_states next_icon_id null_sha1
1257
1258         set s0 [string index $new_state 0]
1259         set s1 [string index $new_state 1]
1260
1261         if {[catch {set info $file_states($path)}]} {
1262                 set state __
1263                 set icon n[incr next_icon_id]
1264         } else {
1265                 set state [lindex $info 0]
1266                 set icon [lindex $info 1]
1267                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1268                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1269         }
1270
1271         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1272         elseif {$s0 eq {_}} {set s0 _}
1273
1274         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1275         elseif {$s1 eq {_}} {set s1 _}
1276
1277         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1278                 set head_info [list 0 $null_sha1]
1279         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1280                 && $head_info eq {}} {
1281                 set head_info $index_info
1282         }
1283
1284         set file_states($path) [list $s0$s1 $icon \
1285                 $head_info $index_info \
1286                 ]
1287         return $state
1288 }
1289
1290 proc display_file_helper {w path icon_name old_m new_m} {
1291         global file_lists
1292
1293         if {$new_m eq {_}} {
1294                 set lno [lsearch -sorted $file_lists($w) $path]
1295                 if {$lno >= 0} {
1296                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1297                         incr lno
1298                         $w conf -state normal
1299                         $w delete $lno.0 [expr {$lno + 1}].0
1300                         $w conf -state disabled
1301                 }
1302         } elseif {$old_m eq {_} && $new_m ne {_}} {
1303                 lappend file_lists($w) $path
1304                 set file_lists($w) [lsort -unique $file_lists($w)]
1305                 set lno [lsearch -sorted $file_lists($w) $path]
1306                 incr lno
1307                 $w conf -state normal
1308                 $w image create $lno.0 \
1309                         -align center -padx 5 -pady 1 \
1310                         -name $icon_name \
1311                         -image [mapicon $w $new_m $path]
1312                 $w insert $lno.1 "[escape_path $path]\n"
1313                 $w conf -state disabled
1314         } elseif {$old_m ne $new_m} {
1315                 $w conf -state normal
1316                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1317                 $w conf -state disabled
1318         }
1319 }
1320
1321 proc display_file {path state} {
1322         global file_states selected_paths
1323         global ui_index ui_workdir
1324
1325         set old_m [merge_state $path $state]
1326         set s $file_states($path)
1327         set new_m [lindex $s 0]
1328         set icon_name [lindex $s 1]
1329
1330         display_file_helper     $ui_index $path $icon_name \
1331                 [string index $old_m 0] \
1332                 [string index $new_m 0]
1333         display_file_helper     $ui_workdir $path $icon_name \
1334                 [string index $old_m 1] \
1335                 [string index $new_m 1]
1336
1337         if {$new_m eq {__}} {
1338                 unset file_states($path)
1339                 catch {unset selected_paths($path)}
1340         }
1341 }
1342
1343 proc display_all_files_helper {w path icon_name m} {
1344         global file_lists
1345
1346         lappend file_lists($w) $path
1347         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1348         $w image create end \
1349                 -align center -padx 5 -pady 1 \
1350                 -name $icon_name \
1351                 -image [mapicon $w $m $path]
1352         $w insert end "[escape_path $path]\n"
1353 }
1354
1355 proc display_all_files {} {
1356         global ui_index ui_workdir
1357         global file_states file_lists
1358         global last_clicked
1359
1360         $ui_index conf -state normal
1361         $ui_workdir conf -state normal
1362
1363         $ui_index delete 0.0 end
1364         $ui_workdir delete 0.0 end
1365         set last_clicked {}
1366
1367         set file_lists($ui_index) [list]
1368         set file_lists($ui_workdir) [list]
1369
1370         foreach path [lsort [array names file_states]] {
1371                 set s $file_states($path)
1372                 set m [lindex $s 0]
1373                 set icon_name [lindex $s 1]
1374
1375                 if {[string index $m 0] ne {_}} {
1376                         display_all_files_helper $ui_index $path \
1377                                 $icon_name [string index $m 0]
1378                 }
1379                 if {[string index $m 1] ne {_}} {
1380                         display_all_files_helper $ui_workdir $path \
1381                                 $icon_name [string index $m 1]
1382                 }
1383         }
1384
1385         $ui_index conf -state disabled
1386         $ui_workdir conf -state disabled
1387 }
1388
1389 proc update_indexinfo {msg pathList after} {
1390         global update_index_cp ui_status_value
1391
1392         if {![lock_index update]} return
1393
1394         set update_index_cp 0
1395         set pathList [lsort $pathList]
1396         set totalCnt [llength $pathList]
1397         set batch [expr {int($totalCnt * .01) + 1}]
1398         if {$batch > 25} {set batch 25}
1399
1400         set ui_status_value [format \
1401                 "$msg... %i/%i files (%.2f%%)" \
1402                 $update_index_cp \
1403                 $totalCnt \
1404                 0.0]
1405         set fd [open "| git update-index -z --index-info" w]
1406         fconfigure $fd \
1407                 -blocking 0 \
1408                 -buffering full \
1409                 -buffersize 512 \
1410                 -translation binary
1411         fileevent $fd writable [list \
1412                 write_update_indexinfo \
1413                 $fd \
1414                 $pathList \
1415                 $totalCnt \
1416                 $batch \
1417                 $msg \
1418                 $after \
1419                 ]
1420 }
1421
1422 proc write_update_indexinfo {fd pathList totalCnt batch msg after} {
1423         global update_index_cp ui_status_value
1424         global file_states current_diff
1425
1426         if {$update_index_cp >= $totalCnt} {
1427                 close $fd
1428                 unlock_index
1429                 uplevel #0 $after
1430                 return
1431         }
1432
1433         for {set i $batch} \
1434                 {$update_index_cp < $totalCnt && $i > 0} \
1435                 {incr i -1} {
1436                 set path [lindex $pathList $update_index_cp]
1437                 incr update_index_cp
1438
1439                 set s $file_states($path)
1440                 switch -glob -- [lindex $s 0] {
1441                 A? {set new _O}
1442                 M? {set new _M}
1443                 D_ {set new _D}
1444                 D? {set new _?}
1445                 ?? {continue}
1446                 }
1447                 set info [lindex $s 2]
1448                 if {$info eq {}} continue
1449
1450                 puts -nonewline $fd "$info\t$path\0"
1451                 display_file $path $new
1452         }
1453
1454         set ui_status_value [format \
1455                 "$msg... %i/%i files (%.2f%%)" \
1456                 $update_index_cp \
1457                 $totalCnt \
1458                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1459 }
1460
1461 proc update_index {msg pathList after} {
1462         global update_index_cp ui_status_value
1463
1464         if {![lock_index update]} return
1465
1466         set update_index_cp 0
1467         set pathList [lsort $pathList]
1468         set totalCnt [llength $pathList]
1469         set batch [expr {int($totalCnt * .01) + 1}]
1470         if {$batch > 25} {set batch 25}
1471
1472         set ui_status_value [format \
1473                 "$msg... %i/%i files (%.2f%%)" \
1474                 $update_index_cp \
1475                 $totalCnt \
1476                 0.0]
1477         set fd [open "| git update-index --add --remove -z --stdin" w]
1478         fconfigure $fd \
1479                 -blocking 0 \
1480                 -buffering full \
1481                 -buffersize 512 \
1482                 -translation binary
1483         fileevent $fd writable [list \
1484                 write_update_index \
1485                 $fd \
1486                 $pathList \
1487                 $totalCnt \
1488                 $batch \
1489                 $msg \
1490                 $after \
1491                 ]
1492 }
1493
1494 proc write_update_index {fd pathList totalCnt batch msg after} {
1495         global update_index_cp ui_status_value
1496         global file_states current_diff
1497
1498         if {$update_index_cp >= $totalCnt} {
1499                 close $fd
1500                 unlock_index
1501                 uplevel #0 $after
1502                 return
1503         }
1504
1505         for {set i $batch} \
1506                 {$update_index_cp < $totalCnt && $i > 0} \
1507                 {incr i -1} {
1508                 set path [lindex $pathList $update_index_cp]
1509                 incr update_index_cp
1510
1511                 switch -glob -- [lindex $file_states($path) 0] {
1512                 AD {set new __}
1513                 ?D {set new D_}
1514                 _O -
1515                 AM {set new A_}
1516                 U_ -
1517                 ?M {set new M_}
1518                 ?? {continue}
1519                 }
1520                 puts -nonewline $fd "$path\0"
1521                 display_file $path $new
1522         }
1523
1524         set ui_status_value [format \
1525                 "$msg... %i/%i files (%.2f%%)" \
1526                 $update_index_cp \
1527                 $totalCnt \
1528                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1529 }
1530
1531 proc checkout_index {msg pathList after} {
1532         global update_index_cp ui_status_value
1533
1534         if {![lock_index update]} return
1535
1536         set update_index_cp 0
1537         set pathList [lsort $pathList]
1538         set totalCnt [llength $pathList]
1539         set batch [expr {int($totalCnt * .01) + 1}]
1540         if {$batch > 25} {set batch 25}
1541
1542         set ui_status_value [format \
1543                 "$msg... %i/%i files (%.2f%%)" \
1544                 $update_index_cp \
1545                 $totalCnt \
1546                 0.0]
1547         set cmd [list git checkout-index]
1548         lappend cmd --index
1549         lappend cmd --quiet
1550         lappend cmd --force
1551         lappend cmd -z
1552         lappend cmd --stdin
1553         set fd [open "| $cmd " w]
1554         fconfigure $fd \
1555                 -blocking 0 \
1556                 -buffering full \
1557                 -buffersize 512 \
1558                 -translation binary
1559         fileevent $fd writable [list \
1560                 write_checkout_index \
1561                 $fd \
1562                 $pathList \
1563                 $totalCnt \
1564                 $batch \
1565                 $msg \
1566                 $after \
1567                 ]
1568 }
1569
1570 proc write_checkout_index {fd pathList totalCnt batch msg after} {
1571         global update_index_cp ui_status_value
1572         global file_states current_diff
1573
1574         if {$update_index_cp >= $totalCnt} {
1575                 close $fd
1576                 unlock_index
1577                 uplevel #0 $after
1578                 return
1579         }
1580
1581         for {set i $batch} \
1582                 {$update_index_cp < $totalCnt && $i > 0} \
1583                 {incr i -1} {
1584                 set path [lindex $pathList $update_index_cp]
1585                 incr update_index_cp
1586                 switch -glob -- [lindex $file_states($path) 0] {
1587                 U? {continue}
1588                 ?M -
1589                 ?D {
1590                         puts -nonewline $fd "$path\0"
1591                         display_file $path ?_
1592                 }
1593                 }
1594         }
1595
1596         set ui_status_value [format \
1597                 "$msg... %i/%i files (%.2f%%)" \
1598                 $update_index_cp \
1599                 $totalCnt \
1600                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1601 }
1602
1603 ######################################################################
1604 ##
1605 ## branch management
1606
1607 proc load_all_heads {} {
1608         global all_heads tracking_branches
1609
1610         set all_heads [list]
1611         set cmd [list git for-each-ref]
1612         lappend cmd --format=%(refname)
1613         lappend cmd refs/heads
1614         set fd [open "| $cmd" r]
1615         while {[gets $fd line] > 0} {
1616                 if {![catch {set info $tracking_branches($line)}]} continue
1617                 if {![regsub ^refs/heads/ $line {} name]} continue
1618                 lappend all_heads $name
1619         }
1620         close $fd
1621
1622         set all_heads [lsort $all_heads]
1623 }
1624
1625 proc populate_branch_menu {} {
1626         global all_heads disable_on_lock
1627
1628         set m .mbar.branch
1629         set last [$m index last]
1630         for {set i 0} {$i <= $last} {incr i} {
1631                 if {[$m type $i] eq {separator}} {
1632                         $m delete $i last
1633                         set new_dol [list]
1634                         foreach a $disable_on_lock {
1635                                 if {[lindex $a 0] ne $m || [lindex $a 2] < $i} {
1636                                         lappend new_dol $a
1637                                 }
1638                         }
1639                         set disable_on_lock $new_dol
1640                         break
1641                 }
1642         }
1643
1644         $m add separator
1645         foreach b $all_heads {
1646                 $m add radiobutton \
1647                         -label $b \
1648                         -command [list switch_branch $b] \
1649                         -variable current_branch \
1650                         -value $b \
1651                         -font font_ui
1652                 lappend disable_on_lock \
1653                         [list $m entryconf [$m index last] -state]
1654         }
1655 }
1656
1657 proc do_create_branch_action {w} {
1658         global all_heads null_sha1
1659         global create_branch_checkout create_branch_revtype
1660         global create_branch_head create_branch_trackinghead
1661
1662         set newbranch [string trim [$w.name.t get 0.0 end]]
1663         if {![catch {exec git show-ref --verify -- "refs/heads/$newbranch"}]} {
1664                 tk_messageBox \
1665                         -icon error \
1666                         -type ok \
1667                         -title [wm title $w] \
1668                         -parent $w \
1669                         -message "Branch '$newbranch' already exists."
1670                 focus $w.name.t
1671                 return
1672         }
1673         if {[catch {exec git check-ref-format "heads/$newbranch"}]} {
1674                 tk_messageBox \
1675                         -icon error \
1676                         -type ok \
1677                         -title [wm title $w] \
1678                         -parent $w \
1679                         -message "We do not like '$newbranch' as a branch name."
1680                 focus $w.name.t
1681                 return
1682         }
1683
1684         set rev {}
1685         switch -- $create_branch_revtype {
1686         head {set rev $create_branch_head}
1687         tracking {set rev $create_branch_trackinghead}
1688         expression {set rev [string trim [$w.from.exp.t get 0.0 end]]}
1689         }
1690         if {[catch {set cmt [exec git rev-parse --verify "${rev}^0"]}]} {
1691                 tk_messageBox \
1692                         -icon error \
1693                         -type ok \
1694                         -title [wm title $w] \
1695                         -parent $w \
1696                         -message "Invalid starting revision: $rev"
1697                 return
1698         }
1699         set cmd [list git update-ref]
1700         lappend cmd -m
1701         lappend cmd "branch: Created from $rev"
1702         lappend cmd "refs/heads/$newbranch"
1703         lappend cmd $cmt
1704         lappend cmd $null_sha1
1705         if {[catch {eval exec $cmd} err]} {
1706                 tk_messageBox \
1707                         -icon error \
1708                         -type ok \
1709                         -title [wm title $w] \
1710                         -parent $w \
1711                         -message "Failed to create '$newbranch'.\n\n$err"
1712                 return
1713         }
1714
1715         lappend all_heads $newbranch
1716         set all_heads [lsort $all_heads]
1717         populate_branch_menu
1718         destroy $w
1719 }
1720
1721 proc do_create_branch {} {
1722         global all_heads current_branch tracking_branches
1723         global create_branch_checkout create_branch_revtype
1724         global create_branch_head create_branch_trackinghead
1725
1726         set create_branch_checkout true
1727         set create_branch_revtype head
1728         set create_branch_head $current_branch
1729         set create_branch_trackinghead {}
1730
1731         set w .branch_editor
1732         toplevel $w
1733         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
1734
1735         label $w.header -text {Create New Branch} \
1736                 -font font_uibold
1737         pack $w.header -side top -fill x
1738
1739         frame $w.buttons
1740         button $w.buttons.create -text Create \
1741                 -font font_ui \
1742                 -default active \
1743                 -command [list do_create_branch_action $w]
1744         pack $w.buttons.create -side right
1745         button $w.buttons.cancel -text {Cancel} \
1746                 -font font_ui \
1747                 -command [list destroy $w]
1748         pack $w.buttons.cancel -side right -padx 5
1749         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
1750
1751         labelframe $w.name \
1752                 -text {Branch Description} \
1753                 -font font_ui
1754         label $w.name.l -text {Name:} -font font_ui
1755         text $w.name.t \
1756                 -borderwidth 1 \
1757                 -relief sunken \
1758                 -height 1 \
1759                 -width 40 \
1760                 -font font_ui
1761         bind $w.name.t <Shift-Key-Tab> "focus $w.postActions.checkout;break"
1762         bind $w.name.t <Key-Tab> "focus $w.from.exp.t;break"
1763         bind $w.name.t <Key-Return> "do_create_branch_action $w;break"
1764         bind $w.name.t <Key> {
1765                 if {{%K} ne {BackSpace}
1766                         && {%K} ne {Tab}
1767                         && {%K} ne {Escape}
1768                         && {%K} ne {Return}} {
1769                         if {%k <= 32} break
1770                         if {[string first %A {~^:?*[}] >= 0} break
1771                 }
1772         }
1773         pack $w.name.l -side left -padx 5
1774         pack $w.name.t -side left -fill x -expand 1
1775         pack $w.name -anchor nw -fill x -pady 5 -padx 5
1776
1777         set all_trackings [list]
1778         foreach b [array names tracking_branches] {
1779                 regsub ^refs/(heads|remotes)/ $b {} b
1780                 lappend all_trackings $b
1781         }
1782         set all_trackings [lsort -unique $all_trackings]
1783         if {$all_trackings ne {}} {
1784                 set create_branch_trackinghead [lindex $all_trackings 0]
1785         }
1786
1787         labelframe $w.from \
1788                 -text {Starting Revision} \
1789                 -font font_ui
1790         frame $w.from.head
1791         radiobutton $w.from.head.r \
1792                 -text {Local Branch:} \
1793                 -value head \
1794                 -variable create_branch_revtype \
1795                 -font font_ui
1796         eval tk_optionMenu $w.from.head.m create_branch_head $all_heads
1797         pack $w.from.head.r -side left
1798         pack $w.from.head.m -side left
1799         frame $w.from.tracking
1800         radiobutton $w.from.tracking.r \
1801                 -text {Tracking Branch:} \
1802                 -value tracking \
1803                 -variable create_branch_revtype \
1804                 -font font_ui
1805         eval tk_optionMenu $w.from.tracking.m \
1806                 create_branch_trackinghead \
1807                 $all_trackings
1808         pack $w.from.tracking.r -side left
1809         pack $w.from.tracking.m -side left
1810         frame $w.from.exp
1811         radiobutton $w.from.exp.r \
1812                 -text {Revision Expression:} \
1813                 -value expression \
1814                 -variable create_branch_revtype \
1815                 -font font_ui
1816         text $w.from.exp.t \
1817                 -borderwidth 1 \
1818                 -relief sunken \
1819                 -height 1 \
1820                 -width 50 \
1821                 -font font_ui
1822         bind $w.from.exp.t <Shift-Key-Tab> "focus $w.name.t;break"
1823         bind $w.from.exp.t <Key-Tab> "focus $w.postActions.checkout;break"
1824         bind $w.from.exp.t <Key-Return> "do_create_branch_action $w;break"
1825         pack $w.from.exp.r -side left
1826         pack $w.from.exp.t -side left -fill x -expand 1
1827         pack $w.from.head -padx 5 -fill x -expand 1
1828         pack $w.from.tracking -padx 5 -fill x -expand 1
1829         pack $w.from.exp -padx 5 -fill x -expand 1
1830         pack $w.from -anchor nw -fill x -pady 5 -padx 5
1831
1832         labelframe $w.postActions \
1833                 -text {Post Creation Actions} \
1834                 -font font_ui
1835         checkbutton $w.postActions.checkout \
1836                 -text {Checkout after creation} \
1837                 -offvalue false \
1838                 -onvalue true \
1839                 -variable create_branch_checkout \
1840                 -font font_ui
1841         pack $w.postActions.checkout -anchor nw
1842         pack $w.postActions -anchor nw -fill x -pady 5 -padx 5
1843
1844         bind $w <Visibility> "grab $w; focus $w.name.t"
1845         bind $w <Key-Escape> "destroy $w"
1846         bind $w <Key-Return> "do_create_branch_action $w;break"
1847         wm title $w "[appname] ([reponame]): Create Branch"
1848         tkwait window $w
1849 }
1850
1851 proc do_delete_branch_action {w} {
1852         global all_heads
1853         global delete_branch_checkhead delete_branch_head
1854
1855         set to_delete [list]
1856         set msg {Are you sure you want to delete the following branches?
1857
1858 }
1859         foreach i [$w.list.l curselection] {
1860                 set b [$w.list.l get $i]
1861                 if {[catch {set o [exec git rev-parse --verify $b]}]} continue
1862                 if {$delete_branch_checkhead} {
1863                         if {[catch {set m [exec git merge-base $o $delete_branch_head]}]} continue
1864                         if {$o ne $m} continue
1865                 }
1866                 lappend to_delete [list $b $o]
1867                 append msg " - $b\n"
1868         }
1869         if {$to_delete eq {}} {
1870                 tk_messageBox \
1871                         -icon info \
1872                         -type ok \
1873                         -title [wm title $w] \
1874                         -parent $w \
1875                         -message {No branches are able to be deleted.
1876
1877 This is likely because you did not select any branches,
1878 or all selected branches are not completely merged.
1879 }
1880                 return
1881         }
1882         append msg {
1883 It can be difficult to recover deleted branches.
1884
1885 Delete the above branches?}
1886         if {[tk_messageBox \
1887                 -icon warning \
1888                 -type yesno \
1889                 -title [wm title $w] \
1890                 -parent $w \
1891                 -message $msg] ne yes} {
1892                 return
1893         }
1894
1895         set failed {}
1896         foreach i $to_delete {
1897                 set b [lindex $i 0]
1898                 set o [lindex $i 1]
1899                 if {[catch {exec git update-ref -d "refs/heads/$b" $o} err]} {
1900                         append failed " - $b: $err\n"
1901                 } else {
1902                         set x [lsearch -sorted $all_heads $b]
1903                         if {$x >= 0} {
1904                                 set all_heads [lreplace $all_heads $x $x]
1905                         }
1906                 }
1907         }
1908
1909         if {$failed ne {}} {
1910                 tk_messageBox \
1911                         -icon error \
1912                         -type ok \
1913                         -title [wm title $w] \
1914                         -parent $w \
1915                         -message "Failed to delete branches:\n$failed"
1916         }
1917
1918         set all_heads [lsort $all_heads]
1919         populate_branch_menu
1920         destroy $w
1921 }
1922
1923 proc do_delete_branch {} {
1924         global all_heads tracking_branches current_branch
1925         global delete_branch_checkhead delete_branch_head
1926
1927         set delete_branch_checkhead 1
1928         set delete_branch_head $current_branch
1929
1930         set w .branch_editor
1931         toplevel $w
1932         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
1933
1934         label $w.header -text {Delete Local Branch} \
1935                 -font font_uibold
1936         pack $w.header -side top -fill x
1937
1938         frame $w.buttons
1939         button $w.buttons.create -text Delete \
1940                 -font font_ui \
1941                 -command [list do_delete_branch_action $w]
1942         pack $w.buttons.create -side right
1943         button $w.buttons.cancel -text {Cancel} \
1944                 -font font_ui \
1945                 -command [list destroy $w]
1946         pack $w.buttons.cancel -side right -padx 5
1947         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
1948
1949         labelframe $w.list \
1950                 -text {Local Branches} \
1951                 -font font_ui
1952         listbox $w.list.l \
1953                 -height 10 \
1954                 -width 50 \
1955                 -selectmode extended \
1956                 -font font_ui
1957         foreach h $all_heads {
1958                 if {$h ne $current_branch} {
1959                         $w.list.l insert end $h
1960                 }
1961         }
1962         pack $w.list.l -fill both -pady 5 -padx 5
1963         pack $w.list -fill both -pady 5 -padx 5
1964
1965         set all_trackings [list]
1966         foreach b [array names tracking_branches] {
1967                 regsub ^refs/(heads|remotes)/ $b {} b
1968                 lappend all_trackings $b
1969         }
1970
1971         labelframe $w.validate \
1972                 -text {Only Delete If} \
1973                 -font font_ui
1974         frame $w.validate.head
1975         checkbutton $w.validate.head.r \
1976                 -text {Already Merged Into:} \
1977                 -variable delete_branch_checkhead \
1978                 -font font_ui
1979         eval tk_optionMenu $w.validate.head.m delete_branch_head \
1980                 $all_heads \
1981                 [lsort -unique $all_trackings]
1982         pack $w.validate.head.r -side left
1983         pack $w.validate.head.m -side left
1984         pack $w.validate.head -padx 5 -fill x -expand 1
1985         pack $w.validate -anchor nw -fill x -pady 5 -padx 5
1986
1987         bind $w <Visibility> "grab $w; focus $w"
1988         bind $w <Key-Escape> "destroy $w"
1989         wm title $w "[appname] ([reponame]): Delete Branch"
1990         tkwait window $w
1991 }
1992
1993 proc switch_branch {b} {
1994         global HEAD commit_type file_states current_branch
1995         global selected_commit_type ui_comm
1996
1997         if {![lock_index switch]} return
1998
1999         # -- Backup the selected branch (repository_state resets it)
2000         #
2001         set new_branch $current_branch
2002
2003         # -- Our in memory state should match the repository.
2004         #
2005         repository_state curType curHEAD curMERGE_HEAD
2006         if {[string match amend* $commit_type]
2007                 && $curType eq {normal}
2008                 && $curHEAD eq $HEAD} {
2009         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
2010                 info_popup {Last scanned state does not match repository state.
2011
2012 Another Git program has modified this repository
2013 since the last scan.  A rescan must be performed
2014 before the current branch can be changed.
2015
2016 The rescan will be automatically started now.
2017 }
2018                 unlock_index
2019                 rescan {set ui_status_value {Ready.}}
2020                 return
2021         }
2022
2023         # -- Toss the message buffer if we are in amend mode.
2024         #
2025         if {[string match amend* $curType]} {
2026                 $ui_comm delete 0.0 end
2027                 $ui_comm edit reset
2028                 $ui_comm edit modified false
2029         }
2030
2031         set selected_commit_type new
2032         set current_branch $new_branch
2033
2034         unlock_index
2035         error "NOT FINISHED"
2036 }
2037
2038 ######################################################################
2039 ##
2040 ## remote management
2041
2042 proc load_all_remotes {} {
2043         global repo_config
2044         global all_remotes tracking_branches
2045
2046         set all_remotes [list]
2047         array unset tracking_branches
2048
2049         set rm_dir [gitdir remotes]
2050         if {[file isdirectory $rm_dir]} {
2051                 set all_remotes [glob \
2052                         -types f \
2053                         -tails \
2054                         -nocomplain \
2055                         -directory $rm_dir *]
2056
2057                 foreach name $all_remotes {
2058                         catch {
2059                                 set fd [open [file join $rm_dir $name] r]
2060                                 while {[gets $fd line] >= 0} {
2061                                         if {![regexp {^Pull:[   ]*([^:]+):(.+)$} \
2062                                                 $line line src dst]} continue
2063                                         if {![regexp ^refs/ $dst]} {
2064                                                 set dst "refs/heads/$dst"
2065                                         }
2066                                         set tracking_branches($dst) [list $name $src]
2067                                 }
2068                                 close $fd
2069                         }
2070                 }
2071         }
2072
2073         foreach line [array names repo_config remote.*.url] {
2074                 if {![regexp ^remote\.(.*)\.url\$ $line line name]} continue
2075                 lappend all_remotes $name
2076
2077                 if {[catch {set fl $repo_config(remote.$name.fetch)}]} {
2078                         set fl {}
2079                 }
2080                 foreach line $fl {
2081                         if {![regexp {^([^:]+):(.+)$} $line line src dst]} continue
2082                         if {![regexp ^refs/ $dst]} {
2083                                 set dst "refs/heads/$dst"
2084                         }
2085                         set tracking_branches($dst) [list $name $src]
2086                 }
2087         }
2088
2089         set all_remotes [lsort -unique $all_remotes]
2090 }
2091
2092 proc populate_fetch_menu {m} {
2093         global all_remotes repo_config
2094
2095         foreach r $all_remotes {
2096                 set enable 0
2097                 if {![catch {set a $repo_config(remote.$r.url)}]} {
2098                         if {![catch {set a $repo_config(remote.$r.fetch)}]} {
2099                                 set enable 1
2100                         }
2101                 } else {
2102                         catch {
2103                                 set fd [open [gitdir remotes $r] r]
2104                                 while {[gets $fd n] >= 0} {
2105                                         if {[regexp {^Pull:[ \t]*([^:]+):} $n]} {
2106                                                 set enable 1
2107                                                 break
2108                                         }
2109                                 }
2110                                 close $fd
2111                         }
2112                 }
2113
2114                 if {$enable} {
2115                         $m add command \
2116                                 -label "Fetch from $r..." \
2117                                 -command [list fetch_from $r] \
2118                                 -font font_ui
2119                 }
2120         }
2121 }
2122
2123 proc populate_push_menu {m} {
2124         global all_remotes repo_config
2125
2126         foreach r $all_remotes {
2127                 set enable 0
2128                 if {![catch {set a $repo_config(remote.$r.url)}]} {
2129                         if {![catch {set a $repo_config(remote.$r.push)}]} {
2130                                 set enable 1
2131                         }
2132                 } else {
2133                         catch {
2134                                 set fd [open [gitdir remotes $r] r]
2135                                 while {[gets $fd n] >= 0} {
2136                                         if {[regexp {^Push:[ \t]*([^:]+):} $n]} {
2137                                                 set enable 1
2138                                                 break
2139                                         }
2140                                 }
2141                                 close $fd
2142                         }
2143                 }
2144
2145                 if {$enable} {
2146                         $m add command \
2147                                 -label "Push to $r..." \
2148                                 -command [list push_to $r] \
2149                                 -font font_ui
2150                 }
2151         }
2152 }
2153
2154 proc populate_pull_menu {m} {
2155         global repo_config all_remotes disable_on_lock
2156
2157         foreach remote $all_remotes {
2158                 set rb_list [list]
2159                 if {[array get repo_config remote.$remote.url] ne {}} {
2160                         if {[array get repo_config remote.$remote.fetch] ne {}} {
2161                                 foreach line $repo_config(remote.$remote.fetch) {
2162                                         if {[regexp {^([^:]+):} $line line rb]} {
2163                                                 lappend rb_list $rb
2164                                         }
2165                                 }
2166                         }
2167                 } else {
2168                         catch {
2169                                 set fd [open [gitdir remotes $remote] r]
2170                                 while {[gets $fd line] >= 0} {
2171                                         if {[regexp {^Pull:[ \t]*([^:]+):} $line line rb]} {
2172                                                 lappend rb_list $rb
2173                                         }
2174                                 }
2175                                 close $fd
2176                         }
2177                 }
2178
2179                 foreach rb $rb_list {
2180                         regsub ^refs/heads/ $rb {} rb_short
2181                         $m add command \
2182                                 -label "Branch $rb_short from $remote..." \
2183                                 -command [list pull_remote $remote $rb] \
2184                                 -font font_ui
2185                         lappend disable_on_lock \
2186                                 [list $m entryconf [$m index last] -state]
2187                 }
2188         }
2189 }
2190
2191 ######################################################################
2192 ##
2193 ## icons
2194
2195 set filemask {
2196 #define mask_width 14
2197 #define mask_height 15
2198 static unsigned char mask_bits[] = {
2199    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2200    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2201    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
2202 }
2203
2204 image create bitmap file_plain -background white -foreground black -data {
2205 #define plain_width 14
2206 #define plain_height 15
2207 static unsigned char plain_bits[] = {
2208    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2209    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
2210    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2211 } -maskdata $filemask
2212
2213 image create bitmap file_mod -background white -foreground blue -data {
2214 #define mod_width 14
2215 #define mod_height 15
2216 static unsigned char mod_bits[] = {
2217    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2218    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2219    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2220 } -maskdata $filemask
2221
2222 image create bitmap file_fulltick -background white -foreground "#007000" -data {
2223 #define file_fulltick_width 14
2224 #define file_fulltick_height 15
2225 static unsigned char file_fulltick_bits[] = {
2226    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
2227    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
2228    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2229 } -maskdata $filemask
2230
2231 image create bitmap file_parttick -background white -foreground "#005050" -data {
2232 #define parttick_width 14
2233 #define parttick_height 15
2234 static unsigned char parttick_bits[] = {
2235    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2236    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
2237    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2238 } -maskdata $filemask
2239
2240 image create bitmap file_question -background white -foreground black -data {
2241 #define file_question_width 14
2242 #define file_question_height 15
2243 static unsigned char file_question_bits[] = {
2244    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
2245    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
2246    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2247 } -maskdata $filemask
2248
2249 image create bitmap file_removed -background white -foreground red -data {
2250 #define file_removed_width 14
2251 #define file_removed_height 15
2252 static unsigned char file_removed_bits[] = {
2253    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2254    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
2255    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
2256 } -maskdata $filemask
2257
2258 image create bitmap file_merge -background white -foreground blue -data {
2259 #define file_merge_width 14
2260 #define file_merge_height 15
2261 static unsigned char file_merge_bits[] = {
2262    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
2263    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2264    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2265 } -maskdata $filemask
2266
2267 set ui_index .vpane.files.index.list
2268 set ui_workdir .vpane.files.workdir.list
2269
2270 set all_icons(_$ui_index)   file_plain
2271 set all_icons(A$ui_index)   file_fulltick
2272 set all_icons(M$ui_index)   file_fulltick
2273 set all_icons(D$ui_index)   file_removed
2274 set all_icons(U$ui_index)   file_merge
2275
2276 set all_icons(_$ui_workdir) file_plain
2277 set all_icons(M$ui_workdir) file_mod
2278 set all_icons(D$ui_workdir) file_question
2279 set all_icons(O$ui_workdir) file_plain
2280
2281 set max_status_desc 0
2282 foreach i {
2283                 {__ "Unmodified"}
2284
2285                 {_M "Modified, not staged"}
2286                 {M_ "Staged for commit"}
2287                 {MM "Portions staged for commit"}
2288                 {MD "Staged for commit, missing"}
2289
2290                 {_O "Untracked, not staged"}
2291                 {A_ "Staged for commit"}
2292                 {AM "Portions staged for commit"}
2293                 {AD "Staged for commit, missing"}
2294
2295                 {_D "Missing"}
2296                 {D_ "Staged for removal"}
2297                 {DO "Staged for removal, still present"}
2298
2299                 {U_ "Requires merge resolution"}
2300                 {UM "Requires merge resolution"}
2301                 {UD "Requires merge resolution"}
2302         } {
2303         if {$max_status_desc < [string length [lindex $i 1]]} {
2304                 set max_status_desc [string length [lindex $i 1]]
2305         }
2306         set all_descs([lindex $i 0]) [lindex $i 1]
2307 }
2308 unset i
2309
2310 ######################################################################
2311 ##
2312 ## util
2313
2314 proc is_MacOSX {} {
2315         global tcl_platform tk_library
2316         if {[tk windowingsystem] eq {aqua}} {
2317                 return 1
2318         }
2319         return 0
2320 }
2321
2322 proc is_Windows {} {
2323         global tcl_platform
2324         if {$tcl_platform(platform) eq {windows}} {
2325                 return 1
2326         }
2327         return 0
2328 }
2329
2330 proc bind_button3 {w cmd} {
2331         bind $w <Any-Button-3> $cmd
2332         if {[is_MacOSX]} {
2333                 bind $w <Control-Button-1> $cmd
2334         }
2335 }
2336
2337 proc incr_font_size {font {amt 1}} {
2338         set sz [font configure $font -size]
2339         incr sz $amt
2340         font configure $font -size $sz
2341         font configure ${font}bold -size $sz
2342 }
2343
2344 proc hook_failed_popup {hook msg} {
2345         set w .hookfail
2346         toplevel $w
2347
2348         frame $w.m
2349         label $w.m.l1 -text "$hook hook failed:" \
2350                 -anchor w \
2351                 -justify left \
2352                 -font font_uibold
2353         text $w.m.t \
2354                 -background white -borderwidth 1 \
2355                 -relief sunken \
2356                 -width 80 -height 10 \
2357                 -font font_diff \
2358                 -yscrollcommand [list $w.m.sby set]
2359         label $w.m.l2 \
2360                 -text {You must correct the above errors before committing.} \
2361                 -anchor w \
2362                 -justify left \
2363                 -font font_uibold
2364         scrollbar $w.m.sby -command [list $w.m.t yview]
2365         pack $w.m.l1 -side top -fill x
2366         pack $w.m.l2 -side bottom -fill x
2367         pack $w.m.sby -side right -fill y
2368         pack $w.m.t -side left -fill both -expand 1
2369         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2370
2371         $w.m.t insert 1.0 $msg
2372         $w.m.t conf -state disabled
2373
2374         button $w.ok -text OK \
2375                 -width 15 \
2376                 -font font_ui \
2377                 -command "destroy $w"
2378         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2379
2380         bind $w <Visibility> "grab $w; focus $w"
2381         bind $w <Key-Return> "destroy $w"
2382         wm title $w "[appname] ([reponame]): error"
2383         tkwait window $w
2384 }
2385
2386 set next_console_id 0
2387
2388 proc new_console {short_title long_title} {
2389         global next_console_id console_data
2390         set w .console[incr next_console_id]
2391         set console_data($w) [list $short_title $long_title]
2392         return [console_init $w]
2393 }
2394
2395 proc console_init {w} {
2396         global console_cr console_data M1B
2397
2398         set console_cr($w) 1.0
2399         toplevel $w
2400         frame $w.m
2401         label $w.m.l1 -text "[lindex $console_data($w) 1]:" \
2402                 -anchor w \
2403                 -justify left \
2404                 -font font_uibold
2405         text $w.m.t \
2406                 -background white -borderwidth 1 \
2407                 -relief sunken \
2408                 -width 80 -height 10 \
2409                 -font font_diff \
2410                 -state disabled \
2411                 -yscrollcommand [list $w.m.sby set]
2412         label $w.m.s -text {Working... please wait...} \
2413                 -anchor w \
2414                 -justify left \
2415                 -font font_uibold
2416         scrollbar $w.m.sby -command [list $w.m.t yview]
2417         pack $w.m.l1 -side top -fill x
2418         pack $w.m.s -side bottom -fill x
2419         pack $w.m.sby -side right -fill y
2420         pack $w.m.t -side left -fill both -expand 1
2421         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2422
2423         menu $w.ctxm -tearoff 0
2424         $w.ctxm add command -label "Copy" \
2425                 -font font_ui \
2426                 -command "tk_textCopy $w.m.t"
2427         $w.ctxm add command -label "Select All" \
2428                 -font font_ui \
2429                 -command "$w.m.t tag add sel 0.0 end"
2430         $w.ctxm add command -label "Copy All" \
2431                 -font font_ui \
2432                 -command "
2433                         $w.m.t tag add sel 0.0 end
2434                         tk_textCopy $w.m.t
2435                         $w.m.t tag remove sel 0.0 end
2436                 "
2437
2438         button $w.ok -text {Close} \
2439                 -font font_ui \
2440                 -state disabled \
2441                 -command "destroy $w"
2442         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2443
2444         bind_button3 $w.m.t "tk_popup $w.ctxm %X %Y"
2445         bind $w.m.t <$M1B-Key-a> "$w.m.t tag add sel 0.0 end;break"
2446         bind $w.m.t <$M1B-Key-A> "$w.m.t tag add sel 0.0 end;break"
2447         bind $w <Visibility> "focus $w"
2448         wm title $w "[appname] ([reponame]): [lindex $console_data($w) 0]"
2449         return $w
2450 }
2451
2452 proc console_exec {w cmd {after {}}} {
2453         # -- Windows tosses the enviroment when we exec our child.
2454         #    But most users need that so we have to relogin. :-(
2455         #
2456         if {[is_Windows]} {
2457                 set cmd [list sh --login -c "cd \"[pwd]\" && [join $cmd { }]"]
2458         }
2459
2460         # -- Tcl won't let us redirect both stdout and stderr to
2461         #    the same pipe.  So pass it through cat...
2462         #
2463         set cmd [concat | $cmd |& cat]
2464
2465         set fd_f [open $cmd r]
2466         fconfigure $fd_f -blocking 0 -translation binary
2467         fileevent $fd_f readable [list console_read $w $fd_f $after]
2468 }
2469
2470 proc console_read {w fd after} {
2471         global console_cr console_data
2472
2473         set buf [read $fd]
2474         if {$buf ne {}} {
2475                 if {![winfo exists $w]} {console_init $w}
2476                 $w.m.t conf -state normal
2477                 set c 0
2478                 set n [string length $buf]
2479                 while {$c < $n} {
2480                         set cr [string first "\r" $buf $c]
2481                         set lf [string first "\n" $buf $c]
2482                         if {$cr < 0} {set cr [expr {$n + 1}]}
2483                         if {$lf < 0} {set lf [expr {$n + 1}]}
2484
2485                         if {$lf < $cr} {
2486                                 $w.m.t insert end [string range $buf $c $lf]
2487                                 set console_cr($w) [$w.m.t index {end -1c}]
2488                                 set c $lf
2489                                 incr c
2490                         } else {
2491                                 $w.m.t delete $console_cr($w) end
2492                                 $w.m.t insert end "\n"
2493                                 $w.m.t insert end [string range $buf $c $cr]
2494                                 set c $cr
2495                                 incr c
2496                         }
2497                 }
2498                 $w.m.t conf -state disabled
2499                 $w.m.t see end
2500         }
2501
2502         fconfigure $fd -blocking 1
2503         if {[eof $fd]} {
2504                 if {[catch {close $fd}]} {
2505                         if {![winfo exists $w]} {console_init $w}
2506                         $w.m.s conf -background red -text {Error: Command Failed}
2507                         $w.ok conf -state normal
2508                         set ok 0
2509                 } elseif {[winfo exists $w]} {
2510                         $w.m.s conf -background green -text {Success}
2511                         $w.ok conf -state normal
2512                         set ok 1
2513                 }
2514                 array unset console_cr $w
2515                 array unset console_data $w
2516                 if {$after ne {}} {
2517                         uplevel #0 $after $ok
2518                 }
2519                 return
2520         }
2521         fconfigure $fd -blocking 0
2522 }
2523
2524 ######################################################################
2525 ##
2526 ## ui commands
2527
2528 set starting_gitk_msg {Starting gitk... please wait...}
2529
2530 proc do_gitk {revs} {
2531         global ui_status_value starting_gitk_msg
2532
2533         set cmd gitk
2534         if {$revs ne {}} {
2535                 append cmd { }
2536                 append cmd $revs
2537         }
2538         if {[is_Windows]} {
2539                 set cmd "sh -c \"exec $cmd\""
2540         }
2541         append cmd { &}
2542
2543         if {[catch {eval exec $cmd} err]} {
2544                 error_popup "Failed to start gitk:\n\n$err"
2545         } else {
2546                 set ui_status_value $starting_gitk_msg
2547                 after 10000 {
2548                         if {$ui_status_value eq $starting_gitk_msg} {
2549                                 set ui_status_value {Ready.}
2550                         }
2551                 }
2552         }
2553 }
2554
2555 proc do_gc {} {
2556         set w [new_console {gc} {Compressing the object database}]
2557         console_exec $w {git gc}
2558 }
2559
2560 proc do_fsck_objects {} {
2561         set w [new_console {fsck-objects} \
2562                 {Verifying the object database with fsck-objects}]
2563         set cmd [list git fsck-objects]
2564         lappend cmd --full
2565         lappend cmd --cache
2566         lappend cmd --strict
2567         console_exec $w $cmd
2568 }
2569
2570 set is_quitting 0
2571
2572 proc do_quit {} {
2573         global ui_comm is_quitting repo_config commit_type
2574
2575         if {$is_quitting} return
2576         set is_quitting 1
2577
2578         # -- Stash our current commit buffer.
2579         #
2580         set save [gitdir GITGUI_MSG]
2581         set msg [string trim [$ui_comm get 0.0 end]]
2582         if {![string match amend* $commit_type]
2583                 && [$ui_comm edit modified]
2584                 && $msg ne {}} {
2585                 catch {
2586                         set fd [open $save w]
2587                         puts $fd [string trim [$ui_comm get 0.0 end]]
2588                         close $fd
2589                 }
2590         } else {
2591                 catch {file delete $save}
2592         }
2593
2594         # -- Stash our current window geometry into this repository.
2595         #
2596         set cfg_geometry [list]
2597         lappend cfg_geometry [wm geometry .]
2598         lappend cfg_geometry [lindex [.vpane sash coord 0] 1]
2599         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 0]
2600         if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2601                 set rc_geometry {}
2602         }
2603         if {$cfg_geometry ne $rc_geometry} {
2604                 catch {exec git repo-config gui.geometry $cfg_geometry}
2605         }
2606
2607         destroy .
2608 }
2609
2610 proc do_rescan {} {
2611         rescan {set ui_status_value {Ready.}}
2612 }
2613
2614 proc unstage_helper {txt paths} {
2615         global file_states current_diff
2616
2617         if {![lock_index begin-update]} return
2618
2619         set pathList [list]
2620         set after {}
2621         foreach path $paths {
2622                 switch -glob -- [lindex $file_states($path) 0] {
2623                 A? -
2624                 M? -
2625                 D? {
2626                         lappend pathList $path
2627                         if {$path eq $current_diff} {
2628                                 set after {reshow_diff;}
2629                         }
2630                 }
2631                 }
2632         }
2633         if {$pathList eq {}} {
2634                 unlock_index
2635         } else {
2636                 update_indexinfo \
2637                         $txt \
2638                         $pathList \
2639                         [concat $after {set ui_status_value {Ready.}}]
2640         }
2641 }
2642
2643 proc do_unstage_selection {} {
2644         global current_diff selected_paths
2645
2646         if {[array size selected_paths] > 0} {
2647                 unstage_helper \
2648                         {Unstaging selected files from commit} \
2649                         [array names selected_paths]
2650         } elseif {$current_diff ne {}} {
2651                 unstage_helper \
2652                         "Unstaging [short_path $current_diff] from commit" \
2653                         [list $current_diff]
2654         }
2655 }
2656
2657 proc add_helper {txt paths} {
2658         global file_states current_diff
2659
2660         if {![lock_index begin-update]} return
2661
2662         set pathList [list]
2663         set after {}
2664         foreach path $paths {
2665                 switch -glob -- [lindex $file_states($path) 0] {
2666                 _O -
2667                 ?M -
2668                 ?D -
2669                 U? {
2670                         lappend pathList $path
2671                         if {$path eq $current_diff} {
2672                                 set after {reshow_diff;}
2673                         }
2674                 }
2675                 }
2676         }
2677         if {$pathList eq {}} {
2678                 unlock_index
2679         } else {
2680                 update_index \
2681                         $txt \
2682                         $pathList \
2683                         [concat $after {set ui_status_value {Ready to commit.}}]
2684         }
2685 }
2686
2687 proc do_add_selection {} {
2688         global current_diff selected_paths
2689
2690         if {[array size selected_paths] > 0} {
2691                 add_helper \
2692                         {Adding selected files} \
2693                         [array names selected_paths]
2694         } elseif {$current_diff ne {}} {
2695                 add_helper \
2696                         "Adding [short_path $current_diff]" \
2697                         [list $current_diff]
2698         }
2699 }
2700
2701 proc do_add_all {} {
2702         global file_states
2703
2704         set paths [list]
2705         foreach path [array names file_states] {
2706                 switch -glob -- [lindex $file_states($path) 0] {
2707                 U? {continue}
2708                 ?M -
2709                 ?D {lappend paths $path}
2710                 }
2711         }
2712         add_helper {Adding all changed files} $paths
2713 }
2714
2715 proc revert_helper {txt paths} {
2716         global file_states current_diff
2717
2718         if {![lock_index begin-update]} return
2719
2720         set pathList [list]
2721         set after {}
2722         foreach path $paths {
2723                 switch -glob -- [lindex $file_states($path) 0] {
2724                 U? {continue}
2725                 ?M -
2726                 ?D {
2727                         lappend pathList $path
2728                         if {$path eq $current_diff} {
2729                                 set after {reshow_diff;}
2730                         }
2731                 }
2732                 }
2733         }
2734
2735         set n [llength $pathList]
2736         if {$n == 0} {
2737                 unlock_index
2738                 return
2739         } elseif {$n == 1} {
2740                 set s "[short_path [lindex $pathList]]"
2741         } else {
2742                 set s "these $n files"
2743         }
2744
2745         set reply [tk_dialog \
2746                 .confirm_revert \
2747                 "[appname] ([reponame])" \
2748                 "Revert changes in $s?
2749
2750 Any unadded changes will be permanently lost by the revert." \
2751                 question \
2752                 1 \
2753                 {Do Nothing} \
2754                 {Revert Changes} \
2755                 ]
2756         if {$reply == 1} {
2757                 checkout_index \
2758                         $txt \
2759                         $pathList \
2760                         [concat $after {set ui_status_value {Ready.}}]
2761         } else {
2762                 unlock_index
2763         }
2764 }
2765
2766 proc do_revert_selection {} {
2767         global current_diff selected_paths
2768
2769         if {[array size selected_paths] > 0} {
2770                 revert_helper \
2771                         {Reverting selected files} \
2772                         [array names selected_paths]
2773         } elseif {$current_diff ne {}} {
2774                 revert_helper \
2775                         "Reverting [short_path $current_diff]" \
2776                         [list $current_diff]
2777         }
2778 }
2779
2780 proc do_signoff {} {
2781         global ui_comm
2782
2783         set me [committer_ident]
2784         if {$me eq {}} return
2785
2786         set sob "Signed-off-by: $me"
2787         set last [$ui_comm get {end -1c linestart} {end -1c}]
2788         if {$last ne $sob} {
2789                 $ui_comm edit separator
2790                 if {$last ne {}
2791                         && ![regexp {^[A-Z][A-Za-z]*-[A-Za-z-]+: *} $last]} {
2792                         $ui_comm insert end "\n"
2793                 }
2794                 $ui_comm insert end "\n$sob"
2795                 $ui_comm edit separator
2796                 $ui_comm see end
2797         }
2798 }
2799
2800 proc do_select_commit_type {} {
2801         global commit_type selected_commit_type
2802
2803         if {$selected_commit_type eq {new}
2804                 && [string match amend* $commit_type]} {
2805                 create_new_commit
2806         } elseif {$selected_commit_type eq {amend}
2807                 && ![string match amend* $commit_type]} {
2808                 load_last_commit
2809
2810                 # The amend request was rejected...
2811                 #
2812                 if {![string match amend* $commit_type]} {
2813                         set selected_commit_type new
2814                 }
2815         }
2816 }
2817
2818 proc do_commit {} {
2819         commit_tree
2820 }
2821
2822 proc do_about {} {
2823         global appvers copyright
2824         global tcl_patchLevel tk_patchLevel
2825
2826         set w .about_dialog
2827         toplevel $w
2828         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2829
2830         label $w.header -text "About [appname]" \
2831                 -font font_uibold
2832         pack $w.header -side top -fill x
2833
2834         frame $w.buttons
2835         button $w.buttons.close -text {Close} \
2836                 -font font_ui \
2837                 -command [list destroy $w]
2838         pack $w.buttons.close -side right
2839         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2840
2841         label $w.desc \
2842                 -text "[appname] - a commit creation tool for Git.
2843 $copyright" \
2844                 -padx 5 -pady 5 \
2845                 -justify left \
2846                 -anchor w \
2847                 -borderwidth 1 \
2848                 -relief solid \
2849                 -font font_ui
2850         pack $w.desc -side top -fill x -padx 5 -pady 5
2851
2852         set v {}
2853         append v "[appname] version $appvers\n"
2854         append v "[exec git version]\n"
2855         append v "\n"
2856         if {$tcl_patchLevel eq $tk_patchLevel} {
2857                 append v "Tcl/Tk version $tcl_patchLevel"
2858         } else {
2859                 append v "Tcl version $tcl_patchLevel"
2860                 append v ", Tk version $tk_patchLevel"
2861         }
2862
2863         label $w.vers \
2864                 -text $v \
2865                 -padx 5 -pady 5 \
2866                 -justify left \
2867                 -anchor w \
2868                 -borderwidth 1 \
2869                 -relief solid \
2870                 -font font_ui
2871         pack $w.vers -side top -fill x -padx 5 -pady 5
2872
2873         menu $w.ctxm -tearoff 0
2874         $w.ctxm add command \
2875                 -label {Copy} \
2876                 -font font_ui \
2877                 -command "
2878                 clipboard clear
2879                 clipboard append -format STRING -type STRING -- \[$w.vers cget -text\]
2880         "
2881
2882         bind $w <Visibility> "grab $w; focus $w"
2883         bind $w <Key-Escape> "destroy $w"
2884         bind_button3 $w.vers "tk_popup $w.ctxm %X %Y; grab $w; focus $w"
2885         wm title $w "About [appname]"
2886         tkwait window $w
2887 }
2888
2889 proc do_options {} {
2890         global repo_config global_config font_descs
2891         global repo_config_new global_config_new
2892
2893         array unset repo_config_new
2894         array unset global_config_new
2895         foreach name [array names repo_config] {
2896                 set repo_config_new($name) $repo_config($name)
2897         }
2898         load_config 1
2899         foreach name [array names repo_config] {
2900                 switch -- $name {
2901                 gui.diffcontext {continue}
2902                 }
2903                 set repo_config_new($name) $repo_config($name)
2904         }
2905         foreach name [array names global_config] {
2906                 set global_config_new($name) $global_config($name)
2907         }
2908
2909         set w .options_editor
2910         toplevel $w
2911         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2912
2913         label $w.header -text "[appname] Options" \
2914                 -font font_uibold
2915         pack $w.header -side top -fill x
2916
2917         frame $w.buttons
2918         button $w.buttons.restore -text {Restore Defaults} \
2919                 -font font_ui \
2920                 -command do_restore_defaults
2921         pack $w.buttons.restore -side left
2922         button $w.buttons.save -text Save \
2923                 -font font_ui \
2924                 -command [list do_save_config $w]
2925         pack $w.buttons.save -side right
2926         button $w.buttons.cancel -text {Cancel} \
2927                 -font font_ui \
2928                 -command [list destroy $w]
2929         pack $w.buttons.cancel -side right -padx 5
2930         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2931
2932         labelframe $w.repo -text "[reponame] Repository" \
2933                 -font font_ui \
2934                 -relief raised -borderwidth 2
2935         labelframe $w.global -text {Global (All Repositories)} \
2936                 -font font_ui \
2937                 -relief raised -borderwidth 2
2938         pack $w.repo -side left -fill both -expand 1 -pady 5 -padx 5
2939         pack $w.global -side right -fill both -expand 1 -pady 5 -padx 5
2940
2941         foreach option {
2942                 {b partialinclude {Allow Partially Added Files}}
2943                 {b pullsummary {Show Pull Summary}}
2944                 {b trustmtime  {Trust File Modification Timestamps}}
2945                 {i diffcontext {Number of Diff Context Lines}}
2946                 } {
2947                 set type [lindex $option 0]
2948                 set name [lindex $option 1]
2949                 set text [lindex $option 2]
2950                 foreach f {repo global} {
2951                         switch $type {
2952                         b {
2953                                 checkbutton $w.$f.$name -text $text \
2954                                         -variable ${f}_config_new(gui.$name) \
2955                                         -onvalue true \
2956                                         -offvalue false \
2957                                         -font font_ui
2958                                 pack $w.$f.$name -side top -anchor w
2959                         }
2960                         i {
2961                                 frame $w.$f.$name
2962                                 label $w.$f.$name.l -text "$text:" -font font_ui
2963                                 pack $w.$f.$name.l -side left -anchor w -fill x
2964                                 spinbox $w.$f.$name.v \
2965                                         -textvariable ${f}_config_new(gui.$name) \
2966                                         -from 1 -to 99 -increment 1 \
2967                                         -width 3 \
2968                                         -font font_ui
2969                                 pack $w.$f.$name.v -side right -anchor e
2970                                 pack $w.$f.$name -side top -anchor w -fill x
2971                         }
2972                         }
2973                 }
2974         }
2975
2976         set all_fonts [lsort [font families]]
2977         foreach option $font_descs {
2978                 set name [lindex $option 0]
2979                 set font [lindex $option 1]
2980                 set text [lindex $option 2]
2981
2982                 set global_config_new(gui.$font^^family) \
2983                         [font configure $font -family]
2984                 set global_config_new(gui.$font^^size) \
2985                         [font configure $font -size]
2986
2987                 frame $w.global.$name
2988                 label $w.global.$name.l -text "$text:" -font font_ui
2989                 pack $w.global.$name.l -side left -anchor w -fill x
2990                 eval tk_optionMenu $w.global.$name.family \
2991                         global_config_new(gui.$font^^family) \
2992                         $all_fonts
2993                 spinbox $w.global.$name.size \
2994                         -textvariable global_config_new(gui.$font^^size) \
2995                         -from 2 -to 80 -increment 1 \
2996                         -width 3 \
2997                         -font font_ui
2998                 pack $w.global.$name.size -side right -anchor e
2999                 pack $w.global.$name.family -side right -anchor e
3000                 pack $w.global.$name -side top -anchor w -fill x
3001         }
3002
3003         bind $w <Visibility> "grab $w; focus $w"
3004         bind $w <Key-Escape> "destroy $w"
3005         wm title $w "[appname] ([reponame]): Options"
3006         tkwait window $w
3007 }
3008
3009 proc do_restore_defaults {} {
3010         global font_descs default_config repo_config
3011         global repo_config_new global_config_new
3012
3013         foreach name [array names default_config] {
3014                 set repo_config_new($name) $default_config($name)
3015                 set global_config_new($name) $default_config($name)
3016         }
3017
3018         foreach option $font_descs {
3019                 set name [lindex $option 0]
3020                 set repo_config(gui.$name) $default_config(gui.$name)
3021         }
3022         apply_config
3023
3024         foreach option $font_descs {
3025                 set name [lindex $option 0]
3026                 set font [lindex $option 1]
3027                 set global_config_new(gui.$font^^family) \
3028                         [font configure $font -family]
3029                 set global_config_new(gui.$font^^size) \
3030                         [font configure $font -size]
3031         }
3032 }
3033
3034 proc do_save_config {w} {
3035         if {[catch {save_config} err]} {
3036                 error_popup "Failed to completely save options:\n\n$err"
3037         }
3038         reshow_diff
3039         destroy $w
3040 }
3041
3042 proc do_windows_shortcut {} {
3043         global argv0
3044
3045         if {[catch {
3046                 set desktop [exec cygpath \
3047                         --windows \
3048                         --absolute \
3049                         --long-name \
3050                         --desktop]
3051                 }]} {
3052                         set desktop .
3053         }
3054         set fn [tk_getSaveFile \
3055                 -parent . \
3056                 -title "[appname] ([reponame]): Create Desktop Icon" \
3057                 -initialdir $desktop \
3058                 -initialfile "Git [reponame].bat"]
3059         if {$fn != {}} {
3060                 if {[catch {
3061                                 set fd [open $fn w]
3062                                 set sh [exec cygpath \
3063                                         --windows \
3064                                         --absolute \
3065                                         /bin/sh]
3066                                 set me [exec cygpath \
3067                                         --unix \
3068                                         --absolute \
3069                                         $argv0]
3070                                 set gd [exec cygpath \
3071                                         --unix \
3072                                         --absolute \
3073                                         [gitdir]]
3074                                 set gw [exec cygpath \
3075                                         --windows \
3076                                         --absolute \
3077                                         [file dirname [gitdir]]]
3078                                 regsub -all ' $me "'\\''" me
3079                                 regsub -all ' $gd "'\\''" gd
3080                                 puts $fd "@ECHO Entering $gw"
3081                                 puts $fd "@ECHO Starting git-gui... please wait..."
3082                                 puts -nonewline $fd "@\"$sh\" --login -c \""
3083                                 puts -nonewline $fd "GIT_DIR='$gd'"
3084                                 puts -nonewline $fd " '$me'"
3085                                 puts $fd "&\""
3086                                 close $fd
3087                         } err]} {
3088                         error_popup "Cannot write script:\n\n$err"
3089                 }
3090         }
3091 }
3092
3093 proc do_macosx_app {} {
3094         global argv0 env
3095
3096         set fn [tk_getSaveFile \
3097                 -parent . \
3098                 -title "[appname] ([reponame]): Create Desktop Icon" \
3099                 -initialdir [file join $env(HOME) Desktop] \
3100                 -initialfile "Git [reponame].app"]
3101         if {$fn != {}} {
3102                 if {[catch {
3103                                 set Contents [file join $fn Contents]
3104                                 set MacOS [file join $Contents MacOS]
3105                                 set exe [file join $MacOS git-gui]
3106
3107                                 file mkdir $MacOS
3108
3109                                 set fd [open [file join $Contents Info.plist] w]
3110                                 puts $fd {<?xml version="1.0" encoding="UTF-8"?>
3111 <!DOCTYPE plist PUBLIC "-//Apple Computer//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
3112 <plist version="1.0">
3113 <dict>
3114         <key>CFBundleDevelopmentRegion</key>
3115         <string>English</string>
3116         <key>CFBundleExecutable</key>
3117         <string>git-gui</string>
3118         <key>CFBundleIdentifier</key>
3119         <string>org.spearce.git-gui</string>
3120         <key>CFBundleInfoDictionaryVersion</key>
3121         <string>6.0</string>
3122         <key>CFBundlePackageType</key>
3123         <string>APPL</string>
3124         <key>CFBundleSignature</key>
3125         <string>????</string>
3126         <key>CFBundleVersion</key>
3127         <string>1.0</string>
3128         <key>NSPrincipalClass</key>
3129         <string>NSApplication</string>
3130 </dict>
3131 </plist>}
3132                                 close $fd
3133
3134                                 set fd [open $exe w]
3135                                 set gd [file normalize [gitdir]]
3136                                 set ep [file normalize [exec git --exec-path]]
3137                                 regsub -all ' $gd "'\\''" gd
3138                                 regsub -all ' $ep "'\\''" ep
3139                                 puts $fd "#!/bin/sh"
3140                                 foreach name [array names env] {
3141                                         if {[string match GIT_* $name]} {
3142                                                 regsub -all ' $env($name) "'\\''" v
3143                                                 puts $fd "export $name='$v'"
3144                                         }
3145                                 }
3146                                 puts $fd "export PATH='$ep':\$PATH"
3147                                 puts $fd "export GIT_DIR='$gd'"
3148                                 puts $fd "exec [file normalize $argv0]"
3149                                 close $fd
3150
3151                                 file attributes $exe -permissions u+x,g+x,o+x
3152                         } err]} {
3153                         error_popup "Cannot write icon:\n\n$err"
3154                 }
3155         }
3156 }
3157
3158 proc toggle_or_diff {w x y} {
3159         global file_states file_lists current_diff ui_index ui_workdir
3160         global last_clicked selected_paths
3161
3162         set pos [split [$w index @$x,$y] .]
3163         set lno [lindex $pos 0]
3164         set col [lindex $pos 1]
3165         set path [lindex $file_lists($w) [expr {$lno - 1}]]
3166         if {$path eq {}} {
3167                 set last_clicked {}
3168                 return
3169         }
3170
3171         set last_clicked [list $w $lno]
3172         array unset selected_paths
3173         $ui_index tag remove in_sel 0.0 end
3174         $ui_workdir tag remove in_sel 0.0 end
3175
3176         if {$col == 0} {
3177                 if {$current_diff eq $path} {
3178                         set after {reshow_diff;}
3179                 } else {
3180                         set after {}
3181                 }
3182                 if {$w eq $ui_index} {
3183                         update_indexinfo \
3184                                 "Unstaging [short_path $path] from commit" \
3185                                 [list $path] \
3186                                 [concat $after {set ui_status_value {Ready.}}]
3187                 } elseif {$w eq $ui_workdir} {
3188                         update_index \
3189                                 "Adding [short_path $path]" \
3190                                 [list $path] \
3191                                 [concat $after {set ui_status_value {Ready.}}]
3192                 }
3193         } else {
3194                 show_diff $path $w $lno
3195         }
3196 }
3197
3198 proc add_one_to_selection {w x y} {
3199         global file_lists last_clicked selected_paths
3200
3201         set lno [lindex [split [$w index @$x,$y] .] 0]
3202         set path [lindex $file_lists($w) [expr {$lno - 1}]]
3203         if {$path eq {}} {
3204                 set last_clicked {}
3205                 return
3206         }
3207
3208         if {$last_clicked ne {}
3209                 && [lindex $last_clicked 0] ne $w} {
3210                 array unset selected_paths
3211                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
3212         }
3213
3214         set last_clicked [list $w $lno]
3215         if {[catch {set in_sel $selected_paths($path)}]} {
3216                 set in_sel 0
3217         }
3218         if {$in_sel} {
3219                 unset selected_paths($path)
3220                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
3221         } else {
3222                 set selected_paths($path) 1
3223                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
3224         }
3225 }
3226
3227 proc add_range_to_selection {w x y} {
3228         global file_lists last_clicked selected_paths
3229
3230         if {[lindex $last_clicked 0] ne $w} {
3231                 toggle_or_diff $w $x $y
3232                 return
3233         }
3234
3235         set lno [lindex [split [$w index @$x,$y] .] 0]
3236         set lc [lindex $last_clicked 1]
3237         if {$lc < $lno} {
3238                 set begin $lc
3239                 set end $lno
3240         } else {
3241                 set begin $lno
3242                 set end $lc
3243         }
3244
3245         foreach path [lrange $file_lists($w) \
3246                 [expr {$begin - 1}] \
3247                 [expr {$end - 1}]] {
3248                 set selected_paths($path) 1
3249         }
3250         $w tag add in_sel $begin.0 [expr {$end + 1}].0
3251 }
3252
3253 ######################################################################
3254 ##
3255 ## config defaults
3256
3257 set cursor_ptr arrow
3258 font create font_diff -family Courier -size 10
3259 font create font_ui
3260 catch {
3261         label .dummy
3262         eval font configure font_ui [font actual [.dummy cget -font]]
3263         destroy .dummy
3264 }
3265
3266 font create font_uibold
3267 font create font_diffbold
3268
3269 if {[is_Windows]} {
3270         set M1B Control
3271         set M1T Ctrl
3272 } elseif {[is_MacOSX]} {
3273         set M1B M1
3274         set M1T Cmd
3275 } else {
3276         set M1B M1
3277         set M1T M1
3278 }
3279
3280 proc apply_config {} {
3281         global repo_config font_descs
3282
3283         foreach option $font_descs {
3284                 set name [lindex $option 0]
3285                 set font [lindex $option 1]
3286                 if {[catch {
3287                         foreach {cn cv} $repo_config(gui.$name) {
3288                                 font configure $font $cn $cv
3289                         }
3290                         } err]} {
3291                         error_popup "Invalid font specified in gui.$name:\n\n$err"
3292                 }
3293                 foreach {cn cv} [font configure $font] {
3294                         font configure ${font}bold $cn $cv
3295                 }
3296                 font configure ${font}bold -weight bold
3297         }
3298 }
3299
3300 set default_config(gui.trustmtime) false
3301 set default_config(gui.pullsummary) true
3302 set default_config(gui.partialinclude) false
3303 set default_config(gui.diffcontext) 5
3304 set default_config(gui.fontui) [font configure font_ui]
3305 set default_config(gui.fontdiff) [font configure font_diff]
3306 set font_descs {
3307         {fontui   font_ui   {Main Font}}
3308         {fontdiff font_diff {Diff/Console Font}}
3309 }
3310 load_config 0
3311 apply_config
3312
3313 ######################################################################
3314 ##
3315 ## ui construction
3316
3317 # -- Menu Bar
3318 #
3319 menu .mbar -tearoff 0
3320 .mbar add cascade -label Repository -menu .mbar.repository
3321 .mbar add cascade -label Edit -menu .mbar.edit
3322 if {!$single_commit} {
3323         .mbar add cascade -label Branch -menu .mbar.branch
3324 }
3325 .mbar add cascade -label Commit -menu .mbar.commit
3326 if {!$single_commit} {
3327         .mbar add cascade -label Fetch -menu .mbar.fetch
3328         .mbar add cascade -label Pull -menu .mbar.pull
3329         .mbar add cascade -label Push -menu .mbar.push
3330 }
3331 . configure -menu .mbar
3332
3333 # -- Repository Menu
3334 #
3335 menu .mbar.repository
3336 .mbar.repository add command \
3337         -label {Visualize Current Branch} \
3338         -command {do_gitk {}} \
3339         -font font_ui
3340 if {![is_MacOSX]} {
3341         .mbar.repository add command \
3342                 -label {Visualize All Branches} \
3343                 -command {do_gitk {--all}} \
3344                 -font font_ui
3345 }
3346 .mbar.repository add separator
3347
3348 if {!$single_commit} {
3349         .mbar.repository add command -label {Compress Database} \
3350                 -command do_gc \
3351                 -font font_ui
3352
3353         .mbar.repository add command -label {Verify Database} \
3354                 -command do_fsck_objects \
3355                 -font font_ui
3356
3357         .mbar.repository add separator
3358
3359         if {[is_Windows]} {
3360                 .mbar.repository add command \
3361                         -label {Create Desktop Icon} \
3362                         -command do_windows_shortcut \
3363                         -font font_ui
3364         } elseif {[is_MacOSX]} {
3365                 .mbar.repository add command \
3366                         -label {Create Desktop Icon} \
3367                         -command do_macosx_app \
3368                         -font font_ui
3369         }
3370 }
3371
3372 .mbar.repository add command -label Quit \
3373         -command do_quit \
3374         -accelerator $M1T-Q \
3375         -font font_ui
3376
3377 # -- Edit Menu
3378 #
3379 menu .mbar.edit
3380 .mbar.edit add command -label Undo \
3381         -command {catch {[focus] edit undo}} \
3382         -accelerator $M1T-Z \
3383         -font font_ui
3384 .mbar.edit add command -label Redo \
3385         -command {catch {[focus] edit redo}} \
3386         -accelerator $M1T-Y \
3387         -font font_ui
3388 .mbar.edit add separator
3389 .mbar.edit add command -label Cut \
3390         -command {catch {tk_textCut [focus]}} \
3391         -accelerator $M1T-X \
3392         -font font_ui
3393 .mbar.edit add command -label Copy \
3394         -command {catch {tk_textCopy [focus]}} \
3395         -accelerator $M1T-C \
3396         -font font_ui
3397 .mbar.edit add command -label Paste \
3398         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
3399         -accelerator $M1T-V \
3400         -font font_ui
3401 .mbar.edit add command -label Delete \
3402         -command {catch {[focus] delete sel.first sel.last}} \
3403         -accelerator Del \
3404         -font font_ui
3405 .mbar.edit add separator
3406 .mbar.edit add command -label {Select All} \
3407         -command {catch {[focus] tag add sel 0.0 end}} \
3408         -accelerator $M1T-A \
3409         -font font_ui
3410
3411 # -- Branch Menu
3412 #
3413 if {!$single_commit} {
3414         menu .mbar.branch
3415
3416         .mbar.branch add command -label {Create...} \
3417                 -command do_create_branch \
3418                 -accelerator $M1T-N \
3419                 -font font_ui
3420         lappend disable_on_lock [list .mbar.branch entryconf \
3421                 [.mbar.branch index last] -state]
3422
3423         .mbar.branch add command -label {Delete...} \
3424                 -command do_delete_branch \
3425                 -font font_ui
3426         lappend disable_on_lock [list .mbar.branch entryconf \
3427                 [.mbar.branch index last] -state]
3428 }
3429
3430 # -- Commit Menu
3431 #
3432 menu .mbar.commit
3433
3434 .mbar.commit add radiobutton \
3435         -label {New Commit} \
3436         -command do_select_commit_type \
3437         -variable selected_commit_type \
3438         -value new \
3439         -font font_ui
3440 lappend disable_on_lock \
3441         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3442
3443 .mbar.commit add radiobutton \
3444         -label {Amend Last Commit} \
3445         -command do_select_commit_type \
3446         -variable selected_commit_type \
3447         -value amend \
3448         -font font_ui
3449 lappend disable_on_lock \
3450         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3451
3452 .mbar.commit add separator
3453
3454 .mbar.commit add command -label Rescan \
3455         -command do_rescan \
3456         -accelerator F5 \
3457         -font font_ui
3458 lappend disable_on_lock \
3459         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3460
3461 .mbar.commit add command -label {Add To Commit} \
3462         -command do_add_selection \
3463         -font font_ui
3464 lappend disable_on_lock \
3465         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3466
3467 .mbar.commit add command -label {Add All To Commit} \
3468         -command do_add_all \
3469         -accelerator $M1T-I \
3470         -font font_ui
3471 lappend disable_on_lock \
3472         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3473
3474 .mbar.commit add command -label {Unstage From Commit} \
3475         -command do_unstage_selection \
3476         -font font_ui
3477 lappend disable_on_lock \
3478         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3479
3480 .mbar.commit add command -label {Revert Changes} \
3481         -command do_revert_selection \
3482         -font font_ui
3483 lappend disable_on_lock \
3484         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3485
3486 .mbar.commit add separator
3487
3488 .mbar.commit add command -label {Sign Off} \
3489         -command do_signoff \
3490         -accelerator $M1T-S \
3491         -font font_ui
3492
3493 .mbar.commit add command -label Commit \
3494         -command do_commit \
3495         -accelerator $M1T-Return \
3496         -font font_ui
3497 lappend disable_on_lock \
3498         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3499
3500 # -- Transport menus
3501 #
3502 if {!$single_commit} {
3503         menu .mbar.fetch
3504         menu .mbar.pull
3505         menu .mbar.push
3506 }
3507
3508 if {[is_MacOSX]} {
3509         # -- Apple Menu (Mac OS X only)
3510         #
3511         .mbar add cascade -label Apple -menu .mbar.apple
3512         menu .mbar.apple
3513
3514         .mbar.apple add command -label "About [appname]" \
3515                 -command do_about \
3516                 -font font_ui
3517         .mbar.apple add command -label "[appname] Options..." \
3518                 -command do_options \
3519                 -font font_ui
3520 } else {
3521         # -- Edit Menu
3522         #
3523         .mbar.edit add separator
3524         .mbar.edit add command -label {Options...} \
3525                 -command do_options \
3526                 -font font_ui
3527
3528         # -- Tools Menu
3529         #
3530         if {[file exists /usr/local/miga/lib/gui-miga]
3531                 && [file exists .pvcsrc]} {
3532         proc do_miga {} {
3533                 global ui_status_value
3534                 if {![lock_index update]} return
3535                 set cmd [list sh --login -c "/usr/local/miga/lib/gui-miga \"[pwd]\""]
3536                 set miga_fd [open "|$cmd" r]
3537                 fconfigure $miga_fd -blocking 0
3538                 fileevent $miga_fd readable [list miga_done $miga_fd]
3539                 set ui_status_value {Running miga...}
3540         }
3541         proc miga_done {fd} {
3542                 read $fd 512
3543                 if {[eof $fd]} {
3544                         close $fd
3545                         unlock_index
3546                         rescan [list set ui_status_value {Ready.}]
3547                 }
3548         }
3549         .mbar add cascade -label Tools -menu .mbar.tools
3550         menu .mbar.tools
3551         .mbar.tools add command -label "Migrate" \
3552                 -command do_miga \
3553                 -font font_ui
3554         lappend disable_on_lock \
3555                 [list .mbar.tools entryconf [.mbar.tools index last] -state]
3556         }
3557
3558         # -- Help Menu
3559         #
3560         .mbar add cascade -label Help -menu .mbar.help
3561         menu .mbar.help
3562
3563         .mbar.help add command -label "About [appname]" \
3564                 -command do_about \
3565                 -font font_ui
3566 }
3567
3568
3569 # -- Branch Control
3570 #
3571 frame .branch \
3572         -borderwidth 1 \
3573         -relief sunken
3574 label .branch.l1 \
3575         -text {Current Branch:} \
3576         -anchor w \
3577         -justify left \
3578         -font font_ui
3579 label .branch.cb \
3580         -textvariable current_branch \
3581         -anchor w \
3582         -justify left \
3583         -font font_ui
3584 pack .branch.l1 -side left
3585 pack .branch.cb -side left -fill x
3586 pack .branch -side top -fill x
3587
3588 # -- Main Window Layout
3589 #
3590 panedwindow .vpane -orient vertical
3591 panedwindow .vpane.files -orient horizontal
3592 .vpane add .vpane.files -sticky nsew -height 100 -width 400
3593 pack .vpane -anchor n -side top -fill both -expand 1
3594
3595 # -- Index File List
3596 #
3597 frame .vpane.files.index -height 100 -width 400
3598 label .vpane.files.index.title -text {Changes To Be Committed} \
3599         -background green \
3600         -font font_ui
3601 text $ui_index -background white -borderwidth 0 \
3602         -width 40 -height 10 \
3603         -font font_ui \
3604         -cursor $cursor_ptr \
3605         -yscrollcommand {.vpane.files.index.sb set} \
3606         -state disabled
3607 scrollbar .vpane.files.index.sb -command [list $ui_index yview]
3608 pack .vpane.files.index.title -side top -fill x
3609 pack .vpane.files.index.sb -side right -fill y
3610 pack $ui_index -side left -fill both -expand 1
3611 .vpane.files add .vpane.files.index -sticky nsew
3612
3613 # -- Working Directory File List
3614 #
3615 frame .vpane.files.workdir -height 100 -width 100
3616 label .vpane.files.workdir.title -text {Changed But Not Updated} \
3617         -background red \
3618         -font font_ui
3619 text $ui_workdir -background white -borderwidth 0 \
3620         -width 40 -height 10 \
3621         -font font_ui \
3622         -cursor $cursor_ptr \
3623         -yscrollcommand {.vpane.files.workdir.sb set} \
3624         -state disabled
3625 scrollbar .vpane.files.workdir.sb -command [list $ui_workdir yview]
3626 pack .vpane.files.workdir.title -side top -fill x
3627 pack .vpane.files.workdir.sb -side right -fill y
3628 pack $ui_workdir -side left -fill both -expand 1
3629 .vpane.files add .vpane.files.workdir -sticky nsew
3630
3631 foreach i [list $ui_index $ui_workdir] {
3632         $i tag conf in_diff -font font_uibold
3633         $i tag conf in_sel \
3634                 -background [$i cget -foreground] \
3635                 -foreground [$i cget -background]
3636 }
3637 unset i
3638
3639 # -- Diff and Commit Area
3640 #
3641 frame .vpane.lower -height 300 -width 400
3642 frame .vpane.lower.commarea
3643 frame .vpane.lower.diff -relief sunken -borderwidth 1
3644 pack .vpane.lower.commarea -side top -fill x
3645 pack .vpane.lower.diff -side bottom -fill both -expand 1
3646 .vpane add .vpane.lower -stick nsew
3647
3648 # -- Commit Area Buttons
3649 #
3650 frame .vpane.lower.commarea.buttons
3651 label .vpane.lower.commarea.buttons.l -text {} \
3652         -anchor w \
3653         -justify left \
3654         -font font_ui
3655 pack .vpane.lower.commarea.buttons.l -side top -fill x
3656 pack .vpane.lower.commarea.buttons -side left -fill y
3657
3658 button .vpane.lower.commarea.buttons.rescan -text {Rescan} \
3659         -command do_rescan \
3660         -font font_ui
3661 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3662 lappend disable_on_lock \
3663         {.vpane.lower.commarea.buttons.rescan conf -state}
3664
3665 button .vpane.lower.commarea.buttons.incall -text {Add All} \
3666         -command do_add_all \
3667         -font font_ui
3668 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3669 lappend disable_on_lock \
3670         {.vpane.lower.commarea.buttons.incall conf -state}
3671
3672 button .vpane.lower.commarea.buttons.signoff -text {Sign Off} \
3673         -command do_signoff \
3674         -font font_ui
3675 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3676
3677 button .vpane.lower.commarea.buttons.commit -text {Commit} \
3678         -command do_commit \
3679         -font font_ui
3680 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3681 lappend disable_on_lock \
3682         {.vpane.lower.commarea.buttons.commit conf -state}
3683
3684 # -- Commit Message Buffer
3685 #
3686 frame .vpane.lower.commarea.buffer
3687 frame .vpane.lower.commarea.buffer.header
3688 set ui_comm .vpane.lower.commarea.buffer.t
3689 set ui_coml .vpane.lower.commarea.buffer.header.l
3690 radiobutton .vpane.lower.commarea.buffer.header.new \
3691         -text {New Commit} \
3692         -command do_select_commit_type \
3693         -variable selected_commit_type \
3694         -value new \
3695         -font font_ui
3696 lappend disable_on_lock \
3697         [list .vpane.lower.commarea.buffer.header.new conf -state]
3698 radiobutton .vpane.lower.commarea.buffer.header.amend \
3699         -text {Amend Last Commit} \
3700         -command do_select_commit_type \
3701         -variable selected_commit_type \
3702         -value amend \
3703         -font font_ui
3704 lappend disable_on_lock \
3705         [list .vpane.lower.commarea.buffer.header.amend conf -state]
3706 label $ui_coml \
3707         -anchor w \
3708         -justify left \
3709         -font font_ui
3710 proc trace_commit_type {varname args} {
3711         global ui_coml commit_type
3712         switch -glob -- $commit_type {
3713         initial       {set txt {Initial Commit Message:}}
3714         amend         {set txt {Amended Commit Message:}}
3715         amend-initial {set txt {Amended Initial Commit Message:}}
3716         amend-merge   {set txt {Amended Merge Commit Message:}}
3717         merge         {set txt {Merge Commit Message:}}
3718         *             {set txt {Commit Message:}}
3719         }
3720         $ui_coml conf -text $txt
3721 }
3722 trace add variable commit_type write trace_commit_type
3723 pack $ui_coml -side left -fill x
3724 pack .vpane.lower.commarea.buffer.header.amend -side right
3725 pack .vpane.lower.commarea.buffer.header.new -side right
3726
3727 text $ui_comm -background white -borderwidth 1 \
3728         -undo true \
3729         -maxundo 20 \
3730         -autoseparators true \
3731         -relief sunken \
3732         -width 75 -height 9 -wrap none \
3733         -font font_diff \
3734         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3735 scrollbar .vpane.lower.commarea.buffer.sby \
3736         -command [list $ui_comm yview]
3737 pack .vpane.lower.commarea.buffer.header -side top -fill x
3738 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3739 pack $ui_comm -side left -fill y
3740 pack .vpane.lower.commarea.buffer -side left -fill y
3741
3742 # -- Commit Message Buffer Context Menu
3743 #
3744 set ctxm .vpane.lower.commarea.buffer.ctxm
3745 menu $ctxm -tearoff 0
3746 $ctxm add command \
3747         -label {Cut} \
3748         -font font_ui \
3749         -command {tk_textCut $ui_comm}
3750 $ctxm add command \
3751         -label {Copy} \
3752         -font font_ui \
3753         -command {tk_textCopy $ui_comm}
3754 $ctxm add command \
3755         -label {Paste} \
3756         -font font_ui \
3757         -command {tk_textPaste $ui_comm}
3758 $ctxm add command \
3759         -label {Delete} \
3760         -font font_ui \
3761         -command {$ui_comm delete sel.first sel.last}
3762 $ctxm add separator
3763 $ctxm add command \
3764         -label {Select All} \
3765         -font font_ui \
3766         -command {$ui_comm tag add sel 0.0 end}
3767 $ctxm add command \
3768         -label {Copy All} \
3769         -font font_ui \
3770         -command {
3771                 $ui_comm tag add sel 0.0 end
3772                 tk_textCopy $ui_comm
3773                 $ui_comm tag remove sel 0.0 end
3774         }
3775 $ctxm add separator
3776 $ctxm add command \
3777         -label {Sign Off} \
3778         -font font_ui \
3779         -command do_signoff
3780 bind_button3 $ui_comm "tk_popup $ctxm %X %Y"
3781
3782 # -- Diff Header
3783 #
3784 set current_diff {}
3785 set diff_actions [list]
3786 proc trace_current_diff {varname args} {
3787         global current_diff diff_actions file_states
3788         if {$current_diff eq {}} {
3789                 set s {}
3790                 set f {}
3791                 set p {}
3792                 set o disabled
3793         } else {
3794                 set p $current_diff
3795                 set s [mapdesc [lindex $file_states($p) 0] $p]
3796                 set f {File:}
3797                 set p [escape_path $p]
3798                 set o normal
3799         }
3800
3801         .vpane.lower.diff.header.status configure -text $s
3802         .vpane.lower.diff.header.file configure -text $f
3803         .vpane.lower.diff.header.path configure -text $p
3804         foreach w $diff_actions {
3805                 uplevel #0 $w $o
3806         }
3807 }
3808 trace add variable current_diff write trace_current_diff
3809
3810 frame .vpane.lower.diff.header -background orange
3811 label .vpane.lower.diff.header.status \
3812         -background orange \
3813         -width $max_status_desc \
3814         -anchor w \
3815         -justify left \
3816         -font font_ui
3817 label .vpane.lower.diff.header.file \
3818         -background orange \
3819         -anchor w \
3820         -justify left \
3821         -font font_ui
3822 label .vpane.lower.diff.header.path \
3823         -background orange \
3824         -anchor w \
3825         -justify left \
3826         -font font_ui
3827 pack .vpane.lower.diff.header.status -side left
3828 pack .vpane.lower.diff.header.file -side left
3829 pack .vpane.lower.diff.header.path -fill x
3830 set ctxm .vpane.lower.diff.header.ctxm
3831 menu $ctxm -tearoff 0
3832 $ctxm add command \
3833         -label {Copy} \
3834         -font font_ui \
3835         -command {
3836                 clipboard clear
3837                 clipboard append \
3838                         -format STRING \
3839                         -type STRING \
3840                         -- $current_diff
3841         }
3842 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3843 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3844
3845 # -- Diff Body
3846 #
3847 frame .vpane.lower.diff.body
3848 set ui_diff .vpane.lower.diff.body.t
3849 text $ui_diff -background white -borderwidth 0 \
3850         -width 80 -height 15 -wrap none \
3851         -font font_diff \
3852         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3853         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3854         -state disabled
3855 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3856         -command [list $ui_diff xview]
3857 scrollbar .vpane.lower.diff.body.sby -orient vertical \
3858         -command [list $ui_diff yview]
3859 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3860 pack .vpane.lower.diff.body.sby -side right -fill y
3861 pack $ui_diff -side left -fill both -expand 1
3862 pack .vpane.lower.diff.header -side top -fill x
3863 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3864
3865 $ui_diff tag conf d_@ -font font_diffbold
3866 $ui_diff tag conf d_+  -foreground blue
3867 $ui_diff tag conf d_-  -foreground red
3868 $ui_diff tag conf d_++ -foreground {#00a000}
3869 $ui_diff tag conf d_-- -foreground {#a000a0}
3870 $ui_diff tag conf d_+- \
3871         -foreground red \
3872         -background {light goldenrod yellow}
3873 $ui_diff tag conf d_-+ \
3874         -foreground blue \
3875         -background azure2
3876
3877 # -- Diff Body Context Menu
3878 #
3879 set ctxm .vpane.lower.diff.body.ctxm
3880 menu $ctxm -tearoff 0
3881 $ctxm add command \
3882         -label {Copy} \
3883         -font font_ui \
3884         -command {tk_textCopy $ui_diff}
3885 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3886 $ctxm add command \
3887         -label {Select All} \
3888         -font font_ui \
3889         -command {$ui_diff tag add sel 0.0 end}
3890 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3891 $ctxm add command \
3892         -label {Copy All} \
3893         -font font_ui \
3894         -command {
3895                 $ui_diff tag add sel 0.0 end
3896                 tk_textCopy $ui_diff
3897                 $ui_diff tag remove sel 0.0 end
3898         }
3899 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3900 $ctxm add separator
3901 $ctxm add command \
3902         -label {Decrease Font Size} \
3903         -font font_ui \
3904         -command {incr_font_size font_diff -1}
3905 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3906 $ctxm add command \
3907         -label {Increase Font Size} \
3908         -font font_ui \
3909         -command {incr_font_size font_diff 1}
3910 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3911 $ctxm add separator
3912 $ctxm add command \
3913         -label {Show Less Context} \
3914         -font font_ui \
3915         -command {if {$repo_config(gui.diffcontext) >= 2} {
3916                 incr repo_config(gui.diffcontext) -1
3917                 reshow_diff
3918         }}
3919 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3920 $ctxm add command \
3921         -label {Show More Context} \
3922         -font font_ui \
3923         -command {
3924                 incr repo_config(gui.diffcontext)
3925                 reshow_diff
3926         }
3927 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3928 $ctxm add separator
3929 $ctxm add command -label {Options...} \
3930         -font font_ui \
3931         -command do_options
3932 bind_button3 $ui_diff "tk_popup $ctxm %X %Y"
3933
3934 # -- Status Bar
3935 #
3936 set ui_status_value {Initializing...}
3937 label .status -textvariable ui_status_value \
3938         -anchor w \
3939         -justify left \
3940         -borderwidth 1 \
3941         -relief sunken \
3942         -font font_ui
3943 pack .status -anchor w -side bottom -fill x
3944
3945 # -- Load geometry
3946 #
3947 catch {
3948 set gm $repo_config(gui.geometry)
3949 wm geometry . [lindex $gm 0]
3950 .vpane sash place 0 \
3951         [lindex [.vpane sash coord 0] 0] \
3952         [lindex $gm 1]
3953 .vpane.files sash place 0 \
3954         [lindex $gm 2] \
3955         [lindex [.vpane.files sash coord 0] 1]
3956 unset gm
3957 }
3958
3959 # -- Key Bindings
3960 #
3961 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3962 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3963 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3964 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3965 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3966 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3967 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3968 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3969 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3970 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3971 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3972
3973 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3974 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3975 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3976 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3977 bind $ui_diff <$M1B-Key-v> {break}
3978 bind $ui_diff <$M1B-Key-V> {break}
3979 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3980 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3981 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3982 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3983 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3984 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3985
3986 if {!$single_commit} {
3987         bind . <$M1B-Key-n> do_create_branch
3988         bind . <$M1B-Key-N> do_create_branch
3989 }
3990
3991 bind .   <Destroy> do_quit
3992 bind all <Key-F5> do_rescan
3993 bind all <$M1B-Key-r> do_rescan
3994 bind all <$M1B-Key-R> do_rescan
3995 bind .   <$M1B-Key-s> do_signoff
3996 bind .   <$M1B-Key-S> do_signoff
3997 bind .   <$M1B-Key-i> do_add_all
3998 bind .   <$M1B-Key-I> do_add_all
3999 bind .   <$M1B-Key-Return> do_commit
4000 bind all <$M1B-Key-q> do_quit
4001 bind all <$M1B-Key-Q> do_quit
4002 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
4003 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
4004 foreach i [list $ui_index $ui_workdir] {
4005         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
4006         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
4007         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
4008 }
4009 unset i
4010
4011 set file_lists($ui_index) [list]
4012 set file_lists($ui_workdir) [list]
4013
4014 set HEAD {}
4015 set PARENT {}
4016 set MERGE_HEAD [list]
4017 set commit_type {}
4018 set empty_tree {}
4019 set current_branch {}
4020 set current_diff {}
4021 set selected_commit_type new
4022
4023 wm title . "[appname] ([file normalize [file dirname [gitdir]]])"
4024 focus -force $ui_comm
4025
4026 # -- Warn the user about environmental problems.  Cygwin's Tcl
4027 #    does *not* pass its env array onto any processes it spawns.
4028 #    This means that git processes get none of our environment.
4029 #
4030 if {[is_Windows]} {
4031         set ignored_env 0
4032         set suggest_user {}
4033         set msg "Possible environment issues exist.
4034
4035 The following environment variables are probably
4036 going to be ignored by any Git subprocess run
4037 by [appname]:
4038
4039 "
4040         foreach name [array names env] {
4041                 switch -regexp -- $name {
4042                 {^GIT_INDEX_FILE$} -
4043                 {^GIT_OBJECT_DIRECTORY$} -
4044                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
4045                 {^GIT_DIFF_OPTS$} -
4046                 {^GIT_EXTERNAL_DIFF$} -
4047                 {^GIT_PAGER$} -
4048                 {^GIT_TRACE$} -
4049                 {^GIT_CONFIG$} -
4050                 {^GIT_CONFIG_LOCAL$} -
4051                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
4052                         append msg " - $name\n"
4053                         incr ignored_env
4054                 }
4055                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
4056                         append msg " - $name\n"
4057                         incr ignored_env
4058                         set suggest_user $name
4059                 }
4060                 }
4061         }
4062         if {$ignored_env > 0} {
4063                 append msg "
4064 This is due to a known issue with the
4065 Tcl binary distributed by Cygwin."
4066
4067                 if {$suggest_user ne {}} {
4068                         append msg "
4069
4070 A good replacement for $suggest_user
4071 is placing values for the user.name and
4072 user.email settings into your personal
4073 ~/.gitconfig file.
4074 "
4075                 }
4076                 warn_popup $msg
4077         }
4078         unset ignored_env msg suggest_user name
4079 }
4080
4081 # -- Only initialize complex UI if we are going to stay running.
4082 #
4083 if {!$single_commit} {
4084         load_all_remotes
4085         load_all_heads
4086
4087         populate_branch_menu
4088         populate_fetch_menu .mbar.fetch
4089         populate_pull_menu .mbar.pull
4090         populate_push_menu .mbar.push
4091 }
4092
4093 # -- Only suggest a gc run if we are going to stay running.
4094 #
4095 if {!$single_commit} {
4096         set object_limit 2000
4097         if {[is_Windows]} {set object_limit 200}
4098         regexp {^([0-9]+) objects,} [exec git count-objects] _junk objects_current
4099         if {$objects_current >= $object_limit} {
4100                 if {[ask_popup \
4101                         "This repository currently has $objects_current loose objects.
4102
4103 To maintain optimal performance it is strongly
4104 recommended that you compress the database
4105 when more than $object_limit loose objects exist.
4106
4107 Compress the database now?"] eq yes} {
4108                         do_gc
4109                 }
4110         }
4111         unset object_limit _junk objects_current
4112 }
4113
4114 lock_index begin-read
4115 after 1 do_rescan