git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  exec wish "$0" -- "$@"
  10
  11 set appvers {@@GITGUI_VERSION@@}
  12 set copyright {
  13 Copyright © 2006, 2007 Shawn Pearce, et. al.
  14
  15 This program is free software; you can redistribute it and/or modify
  16 it under the terms of the GNU General Public License as published by
  17 the Free Software Foundation; either version 2 of the License, or
  18 (at your option) any later version.
  19
  20 This program is distributed in the hope that it will be useful,
  21 but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 GNU General Public License for more details.
  24
  25 You should have received a copy of the GNU General Public License
  26 along with this program; if not, write to the Free Software
  27 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}
  28
  29 ######################################################################
  30 ##
  31 ## Tcl/Tk sanity check
  32
  33 if {[catch {package require Tcl 8.4} err]
  34  || [catch {package require Tk  8.4} err]
  35 } {
  36         catch {wm withdraw .}
  37         tk_messageBox \
  38                 -icon error \
  39                 -type ok \
  40                 -title "git-gui: fatal error" \
  41                 -message $err
  42         exit 1
  43 }
  44
  45 ######################################################################
  46 ##
  47 ## enable verbose loading?
  48
  49 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  50         unset _verbose
  51         rename auto_load real__auto_load
  52         proc auto_load {name args} {
  53                 puts stderr "auto_load $name"
  54                 return [uplevel 1 real__auto_load $name $args]
  55         }
  56         rename source real__source
  57         proc source {name} {
  58                 puts stderr "source    $name"
  59                 uplevel 1 real__source $name
  60         }
  61 }
  62
  63 ######################################################################
  64 ##
  65 ## configure our library
  66
  67 set oguilib {@@GITGUI_LIBDIR@@}
  68 set oguirel {@@GITGUI_RELATIVE@@}
  69 if {$oguirel eq {1}} {
  70         set oguilib [file dirname [file dirname [file normalize $argv0]]]
  71         set oguilib [file join $oguilib share git-gui lib]
  72 } elseif {[string match @@* $oguirel]} {
  73         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  74 }
  75
  76 set idx [file join $oguilib tclIndex]
  77 if {[catch {set fd [open $idx r]} err]} {
  78         catch {wm withdraw .}
  79         tk_messageBox \
  80                 -icon error \
  81                 -type ok \
  82                 -title "git-gui: fatal error" \
  83                 -message $err
  84         exit 1
  85 }
  86 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
  87         set idx [list]
  88         while {[gets $fd n] >= 0} {
  89                 if {$n ne {} && ![string match #* $n]} {
  90                         lappend idx $n
  91                 }
  92         }
  93 } else {
  94         set idx {}
  95 }
  96 close $fd
  97
  98 if {$idx ne {}} {
  99         set loaded [list]
 100         foreach p $idx {
 101                 if {[lsearch -exact $loaded $p] >= 0} continue
 102                 source [file join $oguilib $p]
 103                 lappend loaded $p
 104         }
 105         unset loaded p
 106 } else {
 107         set auto_path [concat [list $oguilib] $auto_path]
 108 }
 109 unset -nocomplain oguirel idx fd
 110
 111 ######################################################################
 112 ##
 113 ## read only globals
 114
 115 set _appname [lindex [file split $argv0] end]
 116 set _gitdir {}
 117 set _gitexec {}
 118 set _reponame {}
 119 set _iscygwin {}
 120
 121 proc appname {} {
 122         global _appname
 123         return $_appname
 124 }
 125
 126 proc gitdir {args} {
 127         global _gitdir
 128         if {$args eq {}} {
 129                 return $_gitdir
 130         }
 131         return [eval [concat [list file join $_gitdir] $args]]
 132 }
 133
 134 proc gitexec {args} {
 135         global _gitexec
 136         if {$_gitexec eq {}} {
 137                 if {[catch {set _gitexec [git --exec-path]} err]} {
 138                         error "Git not installed?\n\n$err"
 139                 }
 140         }
 141         if {$args eq {}} {
 142                 return $_gitexec
 143         }
 144         return [eval [concat [list file join $_gitexec] $args]]
 145 }
 146
 147 proc reponame {} {
 148         global _reponame
 149         return $_reponame
 150 }
 151
 152 proc is_MacOSX {} {
 153         global tcl_platform tk_library
 154         if {[tk windowingsystem] eq {aqua}} {
 155                 return 1
 156         }
 157         return 0
 158 }
 159
 160 proc is_Windows {} {
 161         global tcl_platform
 162         if {$tcl_platform(platform) eq {windows}} {
 163                 return 1
 164         }
 165         return 0
 166 }
 167
 168 proc is_Cygwin {} {
 169         global tcl_platform _iscygwin
 170         if {$_iscygwin eq {}} {
 171                 if {$tcl_platform(platform) eq {windows}} {
 172                         if {[catch {set p [exec cygpath --windir]} err]} {
 173                                 set _iscygwin 0
 174                         } else {
 175                                 set _iscygwin 1
 176                         }
 177                 } else {
 178                         set _iscygwin 0
 179                 }
 180         }
 181         return $_iscygwin
 182 }
 183
 184 proc is_enabled {option} {
 185         global enabled_options
 186         if {[catch {set on $enabled_options($option)}]} {return 0}
 187         return $on
 188 }
 189
 190 proc enable_option {option} {
 191         global enabled_options
 192         set enabled_options($option) 1
 193 }
 194
 195 proc disable_option {option} {
 196         global enabled_options
 197         set enabled_options($option) 0
 198 }
 199
 200 ######################################################################
 201 ##
 202 ## config
 203
 204 proc is_many_config {name} {
 205         switch -glob -- $name {
 206         remote.*.fetch -
 207         remote.*.push
 208                 {return 1}
 209         *
 210                 {return 0}
 211         }
 212 }
 213
 214 proc is_config_true {name} {
 215         global repo_config
 216         if {[catch {set v $repo_config($name)}]} {
 217                 return 0
 218         } elseif {$v eq {true} || $v eq {1} || $v eq {yes}} {
 219                 return 1
 220         } else {
 221                 return 0
 222         }
 223 }
 224
 225 proc get_config {name} {
 226         global repo_config
 227         if {[catch {set v $repo_config($name)}]} {
 228                 return {}
 229         } else {
 230                 return $v
 231         }
 232 }
 233
 234 proc load_config {include_global} {
 235         global repo_config global_config default_config
 236
 237         array unset global_config
 238         if {$include_global} {
 239                 catch {
 240                         set fd_rc [open "| git config --global --list" r]
 241                         while {[gets $fd_rc line] >= 0} {
 242                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 243                                         if {[is_many_config $name]} {
 244                                                 lappend global_config($name) $value
 245                                         } else {
 246                                                 set global_config($name) $value
 247                                         }
 248                                 }
 249                         }
 250                         close $fd_rc
 251                 }
 252         }
 253
 254         array unset repo_config
 255         catch {
 256                 set fd_rc [open "| git config --list" r]
 257                 while {[gets $fd_rc line] >= 0} {
 258                         if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 259                                 if {[is_many_config $name]} {
 260                                         lappend repo_config($name) $value
 261                                 } else {
 262                                         set repo_config($name) $value
 263                                 }
 264                         }
 265                 }
 266                 close $fd_rc
 267         }
 268
 269         foreach name [array names default_config] {
 270                 if {[catch {set v $global_config($name)}]} {
 271                         set global_config($name) $default_config($name)
 272                 }
 273                 if {[catch {set v $repo_config($name)}]} {
 274                         set repo_config($name) $default_config($name)
 275                 }
 276         }
 277 }
 278
 279 ######################################################################
 280 ##
 281 ## handy utils
 282
 283 proc git {args} {
 284         return [eval exec git $args]
 285 }
 286
 287 proc current-branch {} {
 288         set fd [open [gitdir HEAD] r]
 289         if {[gets $fd ref] < 1} {
 290                 set ref {}
 291         }
 292         close $fd
 293
 294         set pfx {ref: refs/heads/}
 295         set len [string length $pfx]
 296         if {[string equal -length $len $pfx $ref]} {
 297                 # We're on a branch.  It might not exist.  But
 298                 # HEAD looks good enough to be a branch.
 299                 #
 300                 return [string range $ref $len end]
 301         } else {
 302                 # Assume this is a detached head.
 303                 #
 304                 return HEAD
 305         }
 306 }
 307
 308 auto_load tk_optionMenu
 309 rename tk_optionMenu real__tkOptionMenu
 310 proc tk_optionMenu {w varName args} {
 311         set m [eval real__tkOptionMenu $w $varName $args]
 312         $m configure -font font_ui
 313         $w configure -font font_ui
 314         return $m
 315 }
 316
 317 ######################################################################
 318 ##
 319 ## version check
 320
 321 if {[catch {set _git_version [git --version]} err]} {
 322         catch {wm withdraw .}
 323         error_popup "Cannot determine Git version:
 324
 325 $err
 326
 327 [appname] requires Git 1.5.0 or later."
 328         exit 1
 329 }
 330 if {![regsub {^git version } $_git_version {} _git_version]} {
 331         catch {wm withdraw .}
 332         error_popup "Cannot parse Git version string:\n\n$_git_version"
 333         exit 1
 334 }
 335 regsub {\.[0-9]+\.g[0-9a-f]+$} $_git_version {} _git_version
 336 regsub {\.rc[0-9]+$} $_git_version {} _git_version
 337
 338 proc git-version {args} {
 339         global _git_version
 340
 341         switch [llength $args] {
 342         0 {
 343                 return $_git_version
 344         }
 345
 346         2 {
 347                 set op [lindex $args 0]
 348                 set vr [lindex $args 1]
 349                 set cm [package vcompare $_git_version $vr]
 350                 return [expr $cm $op 0]
 351         }
 352
 353         4 {
 354                 set type [lindex $args 0]
 355                 set name [lindex $args 1]
 356                 set parm [lindex $args 2]
 357                 set body [lindex $args 3]
 358
 359                 if {($type ne {proc} && $type ne {method})} {
 360                         error "Invalid arguments to git-version"
 361                 }
 362                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
 363                         error "Last arm of $type $name must be default"
 364                 }
 365
 366                 foreach {op vr cb} [lrange $body 0 end-2] {
 367                         if {[git-version $op $vr]} {
 368                                 return [uplevel [list $type $name $parm $cb]]
 369                         }
 370                 }
 371
 372                 return [uplevel [list $type $name $parm [lindex $body end]]]
 373         }
 374
 375         default {
 376                 error "git-version >= x"
 377         }
 378
 379         }
 380 }
 381
 382 if {[git-version < 1.5]} {
 383         catch {wm withdraw .}
 384         error_popup "[appname] requires Git 1.5.0 or later.
 385
 386 You are using [git-version]:
 387
 388 [git --version]"
 389         exit 1
 390 }
 391
 392 ######################################################################
 393 ##
 394 ## repository setup
 395
 396 if {[catch {
 397                 set _gitdir $env(GIT_DIR)
 398                 set _prefix {}
 399                 }]
 400         && [catch {
 401                 set _gitdir [git rev-parse --git-dir]
 402                 set _prefix [git rev-parse --show-prefix]
 403         } err]} {
 404         catch {wm withdraw .}
 405         error_popup "Cannot find the git directory:\n\n$err"
 406         exit 1
 407 }
 408 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
 409         catch {set _gitdir [exec cygpath --unix $_gitdir]}
 410 }
 411 if {![file isdirectory $_gitdir]} {
 412         catch {wm withdraw .}
 413         error_popup "Git directory not found:\n\n$_gitdir"
 414         exit 1
 415 }
 416 if {[lindex [file split $_gitdir] end] ne {.git}} {
 417         catch {wm withdraw .}
 418         error_popup "Cannot use funny .git directory:\n\n$_gitdir"
 419         exit 1
 420 }
 421 if {[catch {cd [file dirname $_gitdir]} err]} {
 422         catch {wm withdraw .}
 423         error_popup "No working directory [file dirname $_gitdir]:\n\n$err"
 424         exit 1
 425 }
 426 set _reponame [lindex [file split \
 427         [file normalize [file dirname $_gitdir]]] \
 428         end]
 429
 430 ######################################################################
 431 ##
 432 ## global init
 433
 434 set current_diff_path {}
 435 set current_diff_side {}
 436 set diff_actions [list]
 437 set ui_status_value {Initializing...}
 438
 439 set HEAD {}
 440 set PARENT {}
 441 set MERGE_HEAD [list]
 442 set commit_type {}
 443 set empty_tree {}
 444 set current_branch {}
 445 set current_diff_path {}
 446 set selected_commit_type new
 447
 448 ######################################################################
 449 ##
 450 ## task management
 451
 452 set rescan_active 0
 453 set diff_active 0
 454 set last_clicked {}
 455
 456 set disable_on_lock [list]
 457 set index_lock_type none
 458
 459 proc lock_index {type} {
 460         global index_lock_type disable_on_lock
 461
 462         if {$index_lock_type eq {none}} {
 463                 set index_lock_type $type
 464                 foreach w $disable_on_lock {
 465                         uplevel #0 $w disabled
 466                 }
 467                 return 1
 468         } elseif {$index_lock_type eq "begin-$type"} {
 469                 set index_lock_type $type
 470                 return 1
 471         }
 472         return 0
 473 }
 474
 475 proc unlock_index {} {
 476         global index_lock_type disable_on_lock
 477
 478         set index_lock_type none
 479         foreach w $disable_on_lock {
 480                 uplevel #0 $w normal
 481         }
 482 }
 483
 484 ######################################################################
 485 ##
 486 ## status
 487
 488 proc repository_state {ctvar hdvar mhvar} {
 489         global current_branch
 490         upvar $ctvar ct $hdvar hd $mhvar mh
 491
 492         set mh [list]
 493
 494         set current_branch [current-branch]
 495         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
 496                 set hd {}
 497                 set ct initial
 498                 return
 499         }
 500
 501         set merge_head [gitdir MERGE_HEAD]
 502         if {[file exists $merge_head]} {
 503                 set ct merge
 504                 set fd_mh [open $merge_head r]
 505                 while {[gets $fd_mh line] >= 0} {
 506                         lappend mh $line
 507                 }
 508                 close $fd_mh
 509                 return
 510         }
 511
 512         set ct normal
 513 }
 514
 515 proc PARENT {} {
 516         global PARENT empty_tree
 517
 518         set p [lindex $PARENT 0]
 519         if {$p ne {}} {
 520                 return $p
 521         }
 522         if {$empty_tree eq {}} {
 523                 set empty_tree [git mktree << {}]
 524         }
 525         return $empty_tree
 526 }
 527
 528 proc rescan {after {honor_trustmtime 1}} {
 529         global HEAD PARENT MERGE_HEAD commit_type
 530         global ui_index ui_workdir ui_comm
 531         global rescan_active file_states
 532         global repo_config
 533
 534         if {$rescan_active > 0 || ![lock_index read]} return
 535
 536         repository_state newType newHEAD newMERGE_HEAD
 537         if {[string match amend* $commit_type]
 538                 && $newType eq {normal}
 539                 && $newHEAD eq $HEAD} {
 540         } else {
 541                 set HEAD $newHEAD
 542                 set PARENT $newHEAD
 543                 set MERGE_HEAD $newMERGE_HEAD
 544                 set commit_type $newType
 545         }
 546
 547         array unset file_states
 548
 549         if {![$ui_comm edit modified]
 550                 || [string trim [$ui_comm get 0.0 end]] eq {}} {
 551                 if {[string match amend* $commit_type]} {
 552                 } elseif {[load_message GITGUI_MSG]} {
 553                 } elseif {[load_message MERGE_MSG]} {
 554                 } elseif {[load_message SQUASH_MSG]} {
 555                 }
 556                 $ui_comm edit reset
 557                 $ui_comm edit modified false
 558         }
 559
 560         if {[is_enabled branch]} {
 561                 load_all_heads
 562                 populate_branch_menu
 563         }
 564
 565         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
 566                 rescan_stage2 {} $after
 567         } else {
 568                 set rescan_active 1
 569                 ui_status {Refreshing file status...}
 570                 set cmd [list git update-index]
 571                 lappend cmd -q
 572                 lappend cmd --unmerged
 573                 lappend cmd --ignore-missing
 574                 lappend cmd --refresh
 575                 set fd_rf [open "| $cmd" r]
 576                 fconfigure $fd_rf -blocking 0 -translation binary
 577                 fileevent $fd_rf readable \
 578                         [list rescan_stage2 $fd_rf $after]
 579         }
 580 }
 581
 582 proc rescan_stage2 {fd after} {
 583         global rescan_active buf_rdi buf_rdf buf_rlo
 584
 585         if {$fd ne {}} {
 586                 read $fd
 587                 if {![eof $fd]} return
 588                 close $fd
 589         }
 590
 591         set ls_others [list | git ls-files --others -z \
 592                 --exclude-per-directory=.gitignore]
 593         set info_exclude [gitdir info exclude]
 594         if {[file readable $info_exclude]} {
 595                 lappend ls_others "--exclude-from=$info_exclude"
 596         }
 597
 598         set buf_rdi {}
 599         set buf_rdf {}
 600         set buf_rlo {}
 601
 602         set rescan_active 3
 603         ui_status {Scanning for modified files ...}
 604         set fd_di [open "| git diff-index --cached -z [PARENT]" r]
 605         set fd_df [open "| git diff-files -z" r]
 606         set fd_lo [open $ls_others r]
 607
 608         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
 609         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
 610         fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
 611         fileevent $fd_di readable [list read_diff_index $fd_di $after]
 612         fileevent $fd_df readable [list read_diff_files $fd_df $after]
 613         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
 614 }
 615
 616 proc load_message {file} {
 617         global ui_comm
 618
 619         set f [gitdir $file]
 620         if {[file isfile $f]} {
 621                 if {[catch {set fd [open $f r]}]} {
 622                         return 0
 623                 }
 624                 set content [string trim [read $fd]]
 625                 close $fd
 626                 regsub -all -line {[ \r\t]+$} $content {} content
 627                 $ui_comm delete 0.0 end
 628                 $ui_comm insert end $content
 629                 return 1
 630         }
 631         return 0
 632 }
 633
 634 proc read_diff_index {fd after} {
 635         global buf_rdi
 636
 637         append buf_rdi [read $fd]
 638         set c 0
 639         set n [string length $buf_rdi]
 640         while {$c < $n} {
 641                 set z1 [string first "\0" $buf_rdi $c]
 642                 if {$z1 == -1} break
 643                 incr z1
 644                 set z2 [string first "\0" $buf_rdi $z1]
 645                 if {$z2 == -1} break
 646
 647                 incr c
 648                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
 649                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
 650                 merge_state \
 651                         [encoding convertfrom $p] \
 652                         [lindex $i 4]? \
 653                         [list [lindex $i 0] [lindex $i 2]] \
 654                         [list]
 655                 set c $z2
 656                 incr c
 657         }
 658         if {$c < $n} {
 659                 set buf_rdi [string range $buf_rdi $c end]
 660         } else {
 661                 set buf_rdi {}
 662         }
 663
 664         rescan_done $fd buf_rdi $after
 665 }
 666
 667 proc read_diff_files {fd after} {
 668         global buf_rdf
 669
 670         append buf_rdf [read $fd]
 671         set c 0
 672         set n [string length $buf_rdf]
 673         while {$c < $n} {
 674                 set z1 [string first "\0" $buf_rdf $c]
 675                 if {$z1 == -1} break
 676                 incr z1
 677                 set z2 [string first "\0" $buf_rdf $z1]
 678                 if {$z2 == -1} break
 679
 680                 incr c
 681                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
 682                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
 683                 merge_state \
 684                         [encoding convertfrom $p] \
 685                         ?[lindex $i 4] \
 686                         [list] \
 687                         [list [lindex $i 0] [lindex $i 2]]
 688                 set c $z2
 689                 incr c
 690         }
 691         if {$c < $n} {
 692                 set buf_rdf [string range $buf_rdf $c end]
 693         } else {
 694                 set buf_rdf {}
 695         }
 696
 697         rescan_done $fd buf_rdf $after
 698 }
 699
 700 proc read_ls_others {fd after} {
 701         global buf_rlo
 702
 703         append buf_rlo [read $fd]
 704         set pck [split $buf_rlo "\0"]
 705         set buf_rlo [lindex $pck end]
 706         foreach p [lrange $pck 0 end-1] {
 707                 merge_state [encoding convertfrom $p] ?O
 708         }
 709         rescan_done $fd buf_rlo $after
 710 }
 711
 712 proc rescan_done {fd buf after} {
 713         global rescan_active current_diff_path
 714         global file_states repo_config
 715         upvar $buf to_clear
 716
 717         if {![eof $fd]} return
 718         set to_clear {}
 719         close $fd
 720         if {[incr rescan_active -1] > 0} return
 721
 722         prune_selection
 723         unlock_index
 724         display_all_files
 725         if {$current_diff_path ne {}} reshow_diff
 726         uplevel #0 $after
 727 }
 728
 729 proc prune_selection {} {
 730         global file_states selected_paths
 731
 732         foreach path [array names selected_paths] {
 733                 if {[catch {set still_here $file_states($path)}]} {
 734                         unset selected_paths($path)
 735                 }
 736         }
 737 }
 738
 739 ######################################################################
 740 ##
 741 ## ui helpers
 742
 743 proc mapicon {w state path} {
 744         global all_icons
 745
 746         if {[catch {set r $all_icons($state$w)}]} {
 747                 puts "error: no icon for $w state={$state} $path"
 748                 return file_plain
 749         }
 750         return $r
 751 }
 752
 753 proc mapdesc {state path} {
 754         global all_descs
 755
 756         if {[catch {set r $all_descs($state)}]} {
 757                 puts "error: no desc for state={$state} $path"
 758                 return $state
 759         }
 760         return $r
 761 }
 762
 763 proc ui_status {msg} {
 764         set ::ui_status_value $msg
 765 }
 766
 767 proc ui_ready {{test {}}} {
 768         if {$test eq {} || $::ui_status_value eq $test} {
 769                 ui_status Ready.
 770         }
 771 }
 772
 773 proc escape_path {path} {
 774         regsub -all {\\} $path "\\\\" path
 775         regsub -all "\n" $path "\\n" path
 776         return $path
 777 }
 778
 779 proc short_path {path} {
 780         return [escape_path [lindex [file split $path] end]]
 781 }
 782
 783 set next_icon_id 0
 784 set null_sha1 [string repeat 0 40]
 785
 786 proc merge_state {path new_state {head_info {}} {index_info {}}} {
 787         global file_states next_icon_id null_sha1
 788
 789         set s0 [string index $new_state 0]
 790         set s1 [string index $new_state 1]
 791
 792         if {[catch {set info $file_states($path)}]} {
 793                 set state __
 794                 set icon n[incr next_icon_id]
 795         } else {
 796                 set state [lindex $info 0]
 797                 set icon [lindex $info 1]
 798                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
 799                 if {$index_info eq {}} {set index_info [lindex $info 3]}
 800         }
 801
 802         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
 803         elseif {$s0 eq {_}} {set s0 _}
 804
 805         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
 806         elseif {$s1 eq {_}} {set s1 _}
 807
 808         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
 809                 set head_info [list 0 $null_sha1]
 810         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
 811                 && $head_info eq {}} {
 812                 set head_info $index_info
 813         }
 814
 815         set file_states($path) [list $s0$s1 $icon \
 816                 $head_info $index_info \
 817                 ]
 818         return $state
 819 }
 820
 821 proc display_file_helper {w path icon_name old_m new_m} {
 822         global file_lists
 823
 824         if {$new_m eq {_}} {
 825                 set lno [lsearch -sorted -exact $file_lists($w) $path]
 826                 if {$lno >= 0} {
 827                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
 828                         incr lno
 829                         $w conf -state normal
 830                         $w delete $lno.0 [expr {$lno + 1}].0
 831                         $w conf -state disabled
 832                 }
 833         } elseif {$old_m eq {_} && $new_m ne {_}} {
 834                 lappend file_lists($w) $path
 835                 set file_lists($w) [lsort -unique $file_lists($w)]
 836                 set lno [lsearch -sorted -exact $file_lists($w) $path]
 837                 incr lno
 838                 $w conf -state normal
 839                 $w image create $lno.0 \
 840                         -align center -padx 5 -pady 1 \
 841                         -name $icon_name \
 842                         -image [mapicon $w $new_m $path]
 843                 $w insert $lno.1 "[escape_path $path]\n"
 844                 $w conf -state disabled
 845         } elseif {$old_m ne $new_m} {
 846                 $w conf -state normal
 847                 $w image conf $icon_name -image [mapicon $w $new_m $path]
 848                 $w conf -state disabled
 849         }
 850 }
 851
 852 proc display_file {path state} {
 853         global file_states selected_paths
 854         global ui_index ui_workdir
 855
 856         set old_m [merge_state $path $state]
 857         set s $file_states($path)
 858         set new_m [lindex $s 0]
 859         set icon_name [lindex $s 1]
 860
 861         set o [string index $old_m 0]
 862         set n [string index $new_m 0]
 863         if {$o eq {U}} {
 864                 set o _
 865         }
 866         if {$n eq {U}} {
 867                 set n _
 868         }
 869         display_file_helper     $ui_index $path $icon_name $o $n
 870
 871         if {[string index $old_m 0] eq {U}} {
 872                 set o U
 873         } else {
 874                 set o [string index $old_m 1]
 875         }
 876         if {[string index $new_m 0] eq {U}} {
 877                 set n U
 878         } else {
 879                 set n [string index $new_m 1]
 880         }
 881         display_file_helper     $ui_workdir $path $icon_name $o $n
 882
 883         if {$new_m eq {__}} {
 884                 unset file_states($path)
 885                 catch {unset selected_paths($path)}
 886         }
 887 }
 888
 889 proc display_all_files_helper {w path icon_name m} {
 890         global file_lists
 891
 892         lappend file_lists($w) $path
 893         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
 894         $w image create end \
 895                 -align center -padx 5 -pady 1 \
 896                 -name $icon_name \
 897                 -image [mapicon $w $m $path]
 898         $w insert end "[escape_path $path]\n"
 899 }
 900
 901 proc display_all_files {} {
 902         global ui_index ui_workdir
 903         global file_states file_lists
 904         global last_clicked
 905
 906         $ui_index conf -state normal
 907         $ui_workdir conf -state normal
 908
 909         $ui_index delete 0.0 end
 910         $ui_workdir delete 0.0 end
 911         set last_clicked {}
 912
 913         set file_lists($ui_index) [list]
 914         set file_lists($ui_workdir) [list]
 915
 916         foreach path [lsort [array names file_states]] {
 917                 set s $file_states($path)
 918                 set m [lindex $s 0]
 919                 set icon_name [lindex $s 1]
 920
 921                 set s [string index $m 0]
 922                 if {$s ne {U} && $s ne {_}} {
 923                         display_all_files_helper $ui_index $path \
 924                                 $icon_name $s
 925                 }
 926
 927                 if {[string index $m 0] eq {U}} {
 928                         set s U
 929                 } else {
 930                         set s [string index $m 1]
 931                 }
 932                 if {$s ne {_}} {
 933                         display_all_files_helper $ui_workdir $path \
 934                                 $icon_name $s
 935                 }
 936         }
 937
 938         $ui_index conf -state disabled
 939         $ui_workdir conf -state disabled
 940 }
 941
 942 ######################################################################
 943 ##
 944 ## icons
 945
 946 set filemask {
 947 #define mask_width 14
 948 #define mask_height 15
 949 static unsigned char mask_bits[] = {
 950    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
 951    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
 952    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
 953 }
 954
 955 image create bitmap file_plain -background white -foreground black -data {
 956 #define plain_width 14
 957 #define plain_height 15
 958 static unsigned char plain_bits[] = {
 959    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
 960    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
 961    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
 962 } -maskdata $filemask
 963
 964 image create bitmap file_mod -background white -foreground blue -data {
 965 #define mod_width 14
 966 #define mod_height 15
 967 static unsigned char mod_bits[] = {
 968    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
 969    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
 970    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
 971 } -maskdata $filemask
 972
 973 image create bitmap file_fulltick -background white -foreground "#007000" -data {
 974 #define file_fulltick_width 14
 975 #define file_fulltick_height 15
 976 static unsigned char file_fulltick_bits[] = {
 977    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
 978    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
 979    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
 980 } -maskdata $filemask
 981
 982 image create bitmap file_parttick -background white -foreground "#005050" -data {
 983 #define parttick_width 14
 984 #define parttick_height 15
 985 static unsigned char parttick_bits[] = {
 986    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
 987    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
 988    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
 989 } -maskdata $filemask
 990
 991 image create bitmap file_question -background white -foreground black -data {
 992 #define file_question_width 14
 993 #define file_question_height 15
 994 static unsigned char file_question_bits[] = {
 995    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
 996    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
 997    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
 998 } -maskdata $filemask
 999
1000 image create bitmap file_removed -background white -foreground red -data {
1001 #define file_removed_width 14
1002 #define file_removed_height 15
1003 static unsigned char file_removed_bits[] = {
1004    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1005    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1006    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1007 } -maskdata $filemask
1008
1009 image create bitmap file_merge -background white -foreground blue -data {
1010 #define file_merge_width 14
1011 #define file_merge_height 15
1012 static unsigned char file_merge_bits[] = {
1013    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1014    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1015    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1016 } -maskdata $filemask
1017
1018 set file_dir_data {
1019 #define file_width 18
1020 #define file_height 18
1021 static unsigned char file_bits[] = {
1022   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0xf8, 0x03, 0x00,
1023   0x0c, 0x03, 0x00, 0x04, 0xfe, 0x00, 0x06, 0x80, 0x00, 0xff, 0x9f, 0x00,
1024   0x03, 0x98, 0x00, 0x02, 0x90, 0x00, 0x06, 0xb0, 0x00, 0x04, 0xa0, 0x00,
1025   0x0c, 0xe0, 0x00, 0x08, 0xc0, 0x00, 0xf8, 0xff, 0x00, 0x00, 0x00, 0x00,
1026   0x00, 0x00, 0x00, 0x00, 0x00, 0x00};
1027 }
1028 image create bitmap file_dir -background white -foreground blue \
1029         -data $file_dir_data -maskdata $file_dir_data
1030 unset file_dir_data
1031
1032 set file_uplevel_data {
1033 #define up_width 15
1034 #define up_height 15
1035 static unsigned char up_bits[] = {
1036   0x80, 0x00, 0xc0, 0x01, 0xe0, 0x03, 0xf0, 0x07, 0xf8, 0x0f, 0xfc, 0x1f,
1037   0xfe, 0x3f, 0xc0, 0x01, 0xc0, 0x01, 0xc0, 0x01, 0xc0, 0x01, 0xc0, 0x01,
1038   0xc0, 0x01, 0xc0, 0x01, 0x00, 0x00};
1039 }
1040 image create bitmap file_uplevel -background white -foreground red \
1041         -data $file_uplevel_data -maskdata $file_uplevel_data
1042 unset file_uplevel_data
1043
1044 set ui_index .vpane.files.index.list
1045 set ui_workdir .vpane.files.workdir.list
1046
1047 set all_icons(_$ui_index)   file_plain
1048 set all_icons(A$ui_index)   file_fulltick
1049 set all_icons(M$ui_index)   file_fulltick
1050 set all_icons(D$ui_index)   file_removed
1051 set all_icons(U$ui_index)   file_merge
1052
1053 set all_icons(_$ui_workdir) file_plain
1054 set all_icons(M$ui_workdir) file_mod
1055 set all_icons(D$ui_workdir) file_question
1056 set all_icons(U$ui_workdir) file_merge
1057 set all_icons(O$ui_workdir) file_plain
1058
1059 set max_status_desc 0
1060 foreach i {
1061                 {__ "Unmodified"}
1062
1063                 {_M "Modified, not staged"}
1064                 {M_ "Staged for commit"}
1065                 {MM "Portions staged for commit"}
1066                 {MD "Staged for commit, missing"}
1067
1068                 {_O "Untracked, not staged"}
1069                 {A_ "Staged for commit"}
1070                 {AM "Portions staged for commit"}
1071                 {AD "Staged for commit, missing"}
1072
1073                 {_D "Missing"}
1074                 {D_ "Staged for removal"}
1075                 {DO "Staged for removal, still present"}
1076
1077                 {U_ "Requires merge resolution"}
1078                 {UU "Requires merge resolution"}
1079                 {UM "Requires merge resolution"}
1080                 {UD "Requires merge resolution"}
1081         } {
1082         if {$max_status_desc < [string length [lindex $i 1]]} {
1083                 set max_status_desc [string length [lindex $i 1]]
1084         }
1085         set all_descs([lindex $i 0]) [lindex $i 1]
1086 }
1087 unset i
1088
1089 ######################################################################
1090 ##
1091 ## util
1092
1093 proc bind_button3 {w cmd} {
1094         bind $w <Any-Button-3> $cmd
1095         if {[is_MacOSX]} {
1096                 bind $w <Control-Button-1> $cmd
1097         }
1098 }
1099
1100 proc scrollbar2many {list mode args} {
1101         foreach w $list {eval $w $mode $args}
1102 }
1103
1104 proc many2scrollbar {list mode sb top bottom} {
1105         $sb set $top $bottom
1106         foreach w $list {$w $mode moveto $top}
1107 }
1108
1109 proc incr_font_size {font {amt 1}} {
1110         set sz [font configure $font -size]
1111         incr sz $amt
1112         font configure $font -size $sz
1113         font configure ${font}bold -size $sz
1114         font configure ${font}italic -size $sz
1115 }
1116
1117 ######################################################################
1118 ##
1119 ## ui commands
1120
1121 set starting_gitk_msg {Starting gitk... please wait...}
1122
1123 proc do_gitk {revs} {
1124         global env starting_gitk_msg
1125
1126         # -- Always start gitk through whatever we were loaded with.  This
1127         #    lets us bypass using shell process on Windows systems.
1128         #
1129         set cmd [list [info nameofexecutable]]
1130         set exe [gitexec gitk]
1131         lappend cmd $exe
1132         if {$revs ne {}} {
1133                 append cmd { }
1134                 append cmd $revs
1135         }
1136
1137         if {! [file exists $exe]} {
1138                 error_popup "Unable to start gitk:\n\n$exe does not exist"
1139         } else {
1140                 eval exec $cmd &
1141                 ui_status $starting_gitk_msg
1142                 after 10000 {
1143                         ui_ready $starting_gitk_msg
1144                 }
1145         }
1146 }
1147
1148 set is_quitting 0
1149
1150 proc do_quit {} {
1151         global ui_comm is_quitting repo_config commit_type
1152
1153         if {$is_quitting} return
1154         set is_quitting 1
1155
1156         if {[winfo exists $ui_comm]} {
1157                 # -- Stash our current commit buffer.
1158                 #
1159                 set save [gitdir GITGUI_MSG]
1160                 set msg [string trim [$ui_comm get 0.0 end]]
1161                 regsub -all -line {[ \r\t]+$} $msg {} msg
1162                 if {(![string match amend* $commit_type]
1163                         || [$ui_comm edit modified])
1164                         && $msg ne {}} {
1165                         catch {
1166                                 set fd [open $save w]
1167                                 puts -nonewline $fd $msg
1168                                 close $fd
1169                         }
1170                 } else {
1171                         catch {file delete $save}
1172                 }
1173
1174                 # -- Stash our current window geometry into this repository.
1175                 #
1176                 set cfg_geometry [list]
1177                 lappend cfg_geometry [wm geometry .]
1178                 lappend cfg_geometry [lindex [.vpane sash coord 0] 1]
1179                 lappend cfg_geometry [lindex [.vpane.files sash coord 0] 0]
1180                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
1181                         set rc_geometry {}
1182                 }
1183                 if {$cfg_geometry ne $rc_geometry} {
1184                         catch {git config gui.geometry $cfg_geometry}
1185                 }
1186         }
1187
1188         destroy .
1189 }
1190
1191 proc do_rescan {} {
1192         rescan ui_ready
1193 }
1194
1195 proc do_commit {} {
1196         commit_tree
1197 }
1198
1199 proc toggle_or_diff {w x y} {
1200         global file_states file_lists current_diff_path ui_index ui_workdir
1201         global last_clicked selected_paths
1202
1203         set pos [split [$w index @$x,$y] .]
1204         set lno [lindex $pos 0]
1205         set col [lindex $pos 1]
1206         set path [lindex $file_lists($w) [expr {$lno - 1}]]
1207         if {$path eq {}} {
1208                 set last_clicked {}
1209                 return
1210         }
1211
1212         set last_clicked [list $w $lno]
1213         array unset selected_paths
1214         $ui_index tag remove in_sel 0.0 end
1215         $ui_workdir tag remove in_sel 0.0 end
1216
1217         if {$col == 0} {
1218                 if {$current_diff_path eq $path} {
1219                         set after {reshow_diff;}
1220                 } else {
1221                         set after {}
1222                 }
1223                 if {$w eq $ui_index} {
1224                         update_indexinfo \
1225                                 "Unstaging [short_path $path] from commit" \
1226                                 [list $path] \
1227                                 [concat $after [list ui_ready]]
1228                 } elseif {$w eq $ui_workdir} {
1229                         update_index \
1230                                 "Adding [short_path $path]" \
1231                                 [list $path] \
1232                                 [concat $after [list ui_ready]]
1233                 }
1234         } else {
1235                 show_diff $path $w $lno
1236         }
1237 }
1238
1239 proc add_one_to_selection {w x y} {
1240         global file_lists last_clicked selected_paths
1241
1242         set lno [lindex [split [$w index @$x,$y] .] 0]
1243         set path [lindex $file_lists($w) [expr {$lno - 1}]]
1244         if {$path eq {}} {
1245                 set last_clicked {}
1246                 return
1247         }
1248
1249         if {$last_clicked ne {}
1250                 && [lindex $last_clicked 0] ne $w} {
1251                 array unset selected_paths
1252                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
1253         }
1254
1255         set last_clicked [list $w $lno]
1256         if {[catch {set in_sel $selected_paths($path)}]} {
1257                 set in_sel 0
1258         }
1259         if {$in_sel} {
1260                 unset selected_paths($path)
1261                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
1262         } else {
1263                 set selected_paths($path) 1
1264                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
1265         }
1266 }
1267
1268 proc add_range_to_selection {w x y} {
1269         global file_lists last_clicked selected_paths
1270
1271         if {[lindex $last_clicked 0] ne $w} {
1272                 toggle_or_diff $w $x $y
1273                 return
1274         }
1275
1276         set lno [lindex [split [$w index @$x,$y] .] 0]
1277         set lc [lindex $last_clicked 1]
1278         if {$lc < $lno} {
1279                 set begin $lc
1280                 set end $lno
1281         } else {
1282                 set begin $lno
1283                 set end $lc
1284         }
1285
1286         foreach path [lrange $file_lists($w) \
1287                 [expr {$begin - 1}] \
1288                 [expr {$end - 1}]] {
1289                 set selected_paths($path) 1
1290         }
1291         $w tag add in_sel $begin.0 [expr {$end + 1}].0
1292 }
1293
1294 ######################################################################
1295 ##
1296 ## config defaults
1297
1298 set cursor_ptr arrow
1299 font create font_diff -family Courier -size 10
1300 font create font_ui
1301 catch {
1302         label .dummy
1303         eval font configure font_ui [font actual [.dummy cget -font]]
1304         destroy .dummy
1305 }
1306
1307 font create font_uiitalic
1308 font create font_uibold
1309 font create font_diffbold
1310 font create font_diffitalic
1311
1312 foreach class {Button Checkbutton Entry Label
1313                 Labelframe Listbox Menu Message
1314                 Radiobutton Spinbox Text} {
1315         option add *$class.font font_ui
1316 }
1317 unset class
1318
1319 if {[is_Windows] || [is_MacOSX]} {
1320         option add *Menu.tearOff 0
1321 }
1322
1323 if {[is_MacOSX]} {
1324         set M1B M1
1325         set M1T Cmd
1326 } else {
1327         set M1B Control
1328         set M1T Ctrl
1329 }
1330
1331 proc apply_config {} {
1332         global repo_config font_descs
1333
1334         foreach option $font_descs {
1335                 set name [lindex $option 0]
1336                 set font [lindex $option 1]
1337                 if {[catch {
1338                         foreach {cn cv} $repo_config(gui.$name) {
1339                                 font configure $font $cn $cv
1340                         }
1341                         } err]} {
1342                         error_popup "Invalid font specified in gui.$name:\n\n$err"
1343                 }
1344                 foreach {cn cv} [font configure $font] {
1345                         font configure ${font}bold $cn $cv
1346                         font configure ${font}italic $cn $cv
1347                 }
1348                 font configure ${font}bold -weight bold
1349                 font configure ${font}italic -slant italic
1350         }
1351 }
1352
1353 set default_config(merge.diffstat) true
1354 set default_config(merge.summary) false
1355 set default_config(merge.verbosity) 2
1356 set default_config(user.name) {}
1357 set default_config(user.email) {}
1358
1359 set default_config(gui.matchtrackingbranch) false
1360 set default_config(gui.pruneduringfetch) false
1361 set default_config(gui.trustmtime) false
1362 set default_config(gui.diffcontext) 5
1363 set default_config(gui.newbranchtemplate) {}
1364 set default_config(gui.fontui) [font configure font_ui]
1365 set default_config(gui.fontdiff) [font configure font_diff]
1366 set font_descs {
1367         {fontui   font_ui   {Main Font}}
1368         {fontdiff font_diff {Diff/Console Font}}
1369 }
1370 load_config 0
1371 apply_config
1372
1373 ######################################################################
1374 ##
1375 ## feature option selection
1376
1377 if {[regexp {^git-(.+)$} [appname] _junk subcommand]} {
1378         unset _junk
1379 } else {
1380         set subcommand gui
1381 }
1382 if {$subcommand eq {gui.sh}} {
1383         set subcommand gui
1384 }
1385 if {$subcommand eq {gui} && [llength $argv] > 0} {
1386         set subcommand [lindex $argv 0]
1387         set argv [lrange $argv 1 end]
1388 }
1389
1390 enable_option multicommit
1391 enable_option branch
1392 enable_option transport
1393
1394 switch -- $subcommand {
1395 browser -
1396 blame {
1397         disable_option multicommit
1398         disable_option branch
1399         disable_option transport
1400 }
1401 citool {
1402         enable_option singlecommit
1403
1404         disable_option multicommit
1405         disable_option branch
1406         disable_option transport
1407 }
1408 }
1409
1410 ######################################################################
1411 ##
1412 ## ui construction
1413
1414 set ui_comm {}
1415
1416 # -- Menu Bar
1417 #
1418 menu .mbar -tearoff 0
1419 .mbar add cascade -label Repository -menu .mbar.repository
1420 .mbar add cascade -label Edit -menu .mbar.edit
1421 if {[is_enabled branch]} {
1422         .mbar add cascade -label Branch -menu .mbar.branch
1423 }
1424 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
1425         .mbar add cascade -label Commit -menu .mbar.commit
1426 }
1427 if {[is_enabled transport]} {
1428         .mbar add cascade -label Merge -menu .mbar.merge
1429         .mbar add cascade -label Fetch -menu .mbar.fetch
1430         .mbar add cascade -label Push -menu .mbar.push
1431 }
1432 . configure -menu .mbar
1433
1434 # -- Repository Menu
1435 #
1436 menu .mbar.repository
1437
1438 .mbar.repository add command \
1439         -label {Browse Current Branch} \
1440         -command {browser::new $current_branch}
1441 trace add variable current_branch write ".mbar.repository entryconf [.mbar.repository index last] -label \"Browse \$current_branch\" ;#"
1442 .mbar.repository add separator
1443
1444 .mbar.repository add command \
1445         -label {Visualize Current Branch} \
1446         -command {do_gitk $current_branch}
1447 trace add variable current_branch write ".mbar.repository entryconf [.mbar.repository index last] -label \"Visualize \$current_branch\" ;#"
1448 .mbar.repository add command \
1449         -label {Visualize All Branches} \
1450         -command {do_gitk --all}
1451 .mbar.repository add separator
1452
1453 if {[is_enabled multicommit]} {
1454         .mbar.repository add command -label {Database Statistics} \
1455                 -command do_stats
1456
1457         .mbar.repository add command -label {Compress Database} \
1458                 -command do_gc
1459
1460         .mbar.repository add command -label {Verify Database} \
1461                 -command do_fsck_objects
1462
1463         .mbar.repository add separator
1464
1465         if {[is_Cygwin]} {
1466                 .mbar.repository add command \
1467                         -label {Create Desktop Icon} \
1468                         -command do_cygwin_shortcut
1469         } elseif {[is_Windows]} {
1470                 .mbar.repository add command \
1471                         -label {Create Desktop Icon} \
1472                         -command do_windows_shortcut
1473         } elseif {[is_MacOSX]} {
1474                 .mbar.repository add command \
1475                         -label {Create Desktop Icon} \
1476                         -command do_macosx_app
1477         }
1478 }
1479
1480 .mbar.repository add command -label Quit \
1481         -command do_quit \
1482         -accelerator $M1T-Q
1483
1484 # -- Edit Menu
1485 #
1486 menu .mbar.edit
1487 .mbar.edit add command -label Undo \
1488         -command {catch {[focus] edit undo}} \
1489         -accelerator $M1T-Z
1490 .mbar.edit add command -label Redo \
1491         -command {catch {[focus] edit redo}} \
1492         -accelerator $M1T-Y
1493 .mbar.edit add separator
1494 .mbar.edit add command -label Cut \
1495         -command {catch {tk_textCut [focus]}} \
1496         -accelerator $M1T-X
1497 .mbar.edit add command -label Copy \
1498         -command {catch {tk_textCopy [focus]}} \
1499         -accelerator $M1T-C
1500 .mbar.edit add command -label Paste \
1501         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
1502         -accelerator $M1T-V
1503 .mbar.edit add command -label Delete \
1504         -command {catch {[focus] delete sel.first sel.last}} \
1505         -accelerator Del
1506 .mbar.edit add separator
1507 .mbar.edit add command -label {Select All} \
1508         -command {catch {[focus] tag add sel 0.0 end}} \
1509         -accelerator $M1T-A
1510
1511 # -- Branch Menu
1512 #
1513 if {[is_enabled branch]} {
1514         menu .mbar.branch
1515
1516         .mbar.branch add command -label {Create...} \
1517                 -command branch_create::dialog \
1518                 -accelerator $M1T-N
1519         lappend disable_on_lock [list .mbar.branch entryconf \
1520                 [.mbar.branch index last] -state]
1521
1522         .mbar.branch add command -label {Rename...} \
1523                 -command branch_rename::dialog
1524         lappend disable_on_lock [list .mbar.branch entryconf \
1525                 [.mbar.branch index last] -state]
1526
1527         .mbar.branch add command -label {Delete...} \
1528                 -command branch_delete::dialog
1529         lappend disable_on_lock [list .mbar.branch entryconf \
1530                 [.mbar.branch index last] -state]
1531
1532         .mbar.branch add command -label {Reset...} \
1533                 -command merge::reset_hard
1534         lappend disable_on_lock [list .mbar.branch entryconf \
1535                 [.mbar.branch index last] -state]
1536 }
1537
1538 # -- Commit Menu
1539 #
1540 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
1541         menu .mbar.commit
1542
1543         .mbar.commit add radiobutton \
1544                 -label {New Commit} \
1545                 -command do_select_commit_type \
1546                 -variable selected_commit_type \
1547                 -value new
1548         lappend disable_on_lock \
1549                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1550
1551         .mbar.commit add radiobutton \
1552                 -label {Amend Last Commit} \
1553                 -command do_select_commit_type \
1554                 -variable selected_commit_type \
1555                 -value amend
1556         lappend disable_on_lock \
1557                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1558
1559         .mbar.commit add separator
1560
1561         .mbar.commit add command -label Rescan \
1562                 -command do_rescan \
1563                 -accelerator F5
1564         lappend disable_on_lock \
1565                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1566
1567         .mbar.commit add command -label {Add To Commit} \
1568                 -command do_add_selection
1569         lappend disable_on_lock \
1570                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1571
1572         .mbar.commit add command -label {Add Existing To Commit} \
1573                 -command do_add_all \
1574                 -accelerator $M1T-I
1575         lappend disable_on_lock \
1576                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1577
1578         .mbar.commit add command -label {Unstage From Commit} \
1579                 -command do_unstage_selection
1580         lappend disable_on_lock \
1581                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1582
1583         .mbar.commit add command -label {Revert Changes} \
1584                 -command do_revert_selection
1585         lappend disable_on_lock \
1586                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1587
1588         .mbar.commit add separator
1589
1590         .mbar.commit add command -label {Sign Off} \
1591                 -command do_signoff \
1592                 -accelerator $M1T-S
1593
1594         .mbar.commit add command -label Commit \
1595                 -command do_commit \
1596                 -accelerator $M1T-Return
1597         lappend disable_on_lock \
1598                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1599 }
1600
1601 # -- Merge Menu
1602 #
1603 if {[is_enabled branch]} {
1604         menu .mbar.merge
1605         .mbar.merge add command -label {Local Merge...} \
1606                 -command merge::dialog
1607         lappend disable_on_lock \
1608                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
1609         .mbar.merge add command -label {Abort Merge...} \
1610                 -command merge::reset_hard
1611         lappend disable_on_lock \
1612                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
1613
1614 }
1615
1616 # -- Transport Menu
1617 #
1618 if {[is_enabled transport]} {
1619         menu .mbar.fetch
1620
1621         menu .mbar.push
1622         .mbar.push add command -label {Push...} \
1623                 -command do_push_anywhere \
1624                 -accelerator $M1T-P
1625         .mbar.push add command -label {Delete...} \
1626                 -command remote_branch_delete::dialog
1627 }
1628
1629 if {[is_MacOSX]} {
1630         # -- Apple Menu (Mac OS X only)
1631         #
1632         .mbar add cascade -label Apple -menu .mbar.apple
1633         menu .mbar.apple
1634
1635         .mbar.apple add command -label "About [appname]" \
1636                 -command do_about
1637         .mbar.apple add command -label "Options..." \
1638                 -command do_options
1639 } else {
1640         # -- Edit Menu
1641         #
1642         .mbar.edit add separator
1643         .mbar.edit add command -label {Options...} \
1644                 -command do_options
1645
1646         # -- Tools Menu
1647         #
1648         if {[is_Cygwin] && [file exists /usr/local/miga/lib/gui-miga]} {
1649         proc do_miga {} {
1650                 if {![lock_index update]} return
1651                 set cmd [list sh --login -c "/usr/local/miga/lib/gui-miga \"[pwd]\""]
1652                 set miga_fd [open "|$cmd" r]
1653                 fconfigure $miga_fd -blocking 0
1654                 fileevent $miga_fd readable [list miga_done $miga_fd]
1655                 ui_status {Running miga...}
1656         }
1657         proc miga_done {fd} {
1658                 read $fd 512
1659                 if {[eof $fd]} {
1660                         close $fd
1661                         unlock_index
1662                         rescan ui_ready
1663                 }
1664         }
1665         .mbar add cascade -label Tools -menu .mbar.tools
1666         menu .mbar.tools
1667         .mbar.tools add command -label "Migrate" \
1668                 -command do_miga
1669         lappend disable_on_lock \
1670                 [list .mbar.tools entryconf [.mbar.tools index last] -state]
1671         }
1672 }
1673
1674 # -- Help Menu
1675 #
1676 .mbar add cascade -label Help -menu .mbar.help
1677 menu .mbar.help
1678
1679 if {![is_MacOSX]} {
1680         .mbar.help add command -label "About [appname]" \
1681                 -command do_about
1682 }
1683
1684 set browser {}
1685 catch {set browser $repo_config(instaweb.browser)}
1686 set doc_path [file dirname [gitexec]]
1687 set doc_path [file join $doc_path Documentation index.html]
1688
1689 if {[is_Cygwin]} {
1690         set doc_path [exec cygpath --mixed $doc_path]
1691 }
1692
1693 if {$browser eq {}} {
1694         if {[is_MacOSX]} {
1695                 set browser open
1696         } elseif {[is_Cygwin]} {
1697                 set program_files [file dirname [exec cygpath --windir]]
1698                 set program_files [file join $program_files {Program Files}]
1699                 set firefox [file join $program_files {Mozilla Firefox} firefox.exe]
1700                 set ie [file join $program_files {Internet Explorer} IEXPLORE.EXE]
1701                 if {[file exists $firefox]} {
1702                         set browser $firefox
1703                 } elseif {[file exists $ie]} {
1704                         set browser $ie
1705                 }
1706                 unset program_files firefox ie
1707         }
1708 }
1709
1710 if {[file isfile $doc_path]} {
1711         set doc_url "file:$doc_path"
1712 } else {
1713         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
1714 }
1715
1716 if {$browser ne {}} {
1717         .mbar.help add command -label {Online Documentation} \
1718                 -command [list exec $browser $doc_url &]
1719 }
1720 unset browser doc_path doc_url
1721
1722 # -- Standard bindings
1723 #
1724 wm protocol . WM_DELETE_WINDOW do_quit
1725 bind all <$M1B-Key-q> do_quit
1726 bind all <$M1B-Key-Q> do_quit
1727 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
1728 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
1729
1730 set subcommand_args {}
1731 proc usage {} {
1732         puts stderr "usage: $::argv0 $::subcommand $::subcommand_args"
1733         exit 1
1734 }
1735
1736 # -- Not a normal commit type invocation?  Do that instead!
1737 #
1738 switch -- $subcommand {
1739 browser {
1740         set subcommand_args {rev?}
1741         switch [llength $argv] {
1742         0 { set current_branch [current-branch] }
1743         1 { set current_branch [lindex $argv 0] }
1744         default usage
1745         }
1746         browser::new $current_branch
1747         return
1748 }
1749 blame {
1750         set subcommand_args {rev? path?}
1751         set head {}
1752         set path {}
1753         set is_path 0
1754         foreach a $argv {
1755                 if {$is_path || [file exists $_prefix$a]} {
1756                         if {$path ne {}} usage
1757                         set path $_prefix$a
1758                         break
1759                 } elseif {$a eq {--}} {
1760                         if {$path ne {}} {
1761                                 if {$head ne {}} usage
1762                                 set head $path
1763                                 set path {}
1764                         }
1765                         set is_path 1
1766                 } elseif {$head eq {}} {
1767                         if {$head ne {}} usage
1768                         set head $a
1769                 } else {
1770                         usage
1771                 }
1772         }
1773         unset is_path
1774
1775         if {$head eq {}} {
1776                 set current_branch [current-branch]
1777         } else {
1778                 set current_branch $head
1779         }
1780
1781         if {$path eq {}} usage
1782         blame::new $head $path
1783         return
1784 }
1785 citool -
1786 gui {
1787         if {[llength $argv] != 0} {
1788                 puts -nonewline stderr "usage: $argv0"
1789                 if {$subcommand ne {gui} && [appname] ne "git-$subcommand"} {
1790                         puts -nonewline stderr " $subcommand"
1791                 }
1792                 puts stderr {}
1793                 exit 1
1794         }
1795         # fall through to setup UI for commits
1796 }
1797 default {
1798         puts stderr "usage: $argv0 \[{blame|browser|citool}\]"
1799         exit 1
1800 }
1801 }
1802
1803 # -- Branch Control
1804 #
1805 frame .branch \
1806         -borderwidth 1 \
1807         -relief sunken
1808 label .branch.l1 \
1809         -text {Current Branch:} \
1810         -anchor w \
1811         -justify left
1812 label .branch.cb \
1813         -textvariable current_branch \
1814         -anchor w \
1815         -justify left
1816 pack .branch.l1 -side left
1817 pack .branch.cb -side left -fill x
1818 pack .branch -side top -fill x
1819
1820 # -- Main Window Layout
1821 #
1822 panedwindow .vpane -orient vertical
1823 panedwindow .vpane.files -orient horizontal
1824 .vpane add .vpane.files -sticky nsew -height 100 -width 200
1825 pack .vpane -anchor n -side top -fill both -expand 1
1826
1827 # -- Index File List
1828 #
1829 frame .vpane.files.index -height 100 -width 200
1830 label .vpane.files.index.title -text {Staged Changes (Will Be Committed)} \
1831         -background lightgreen
1832 text $ui_index -background white -borderwidth 0 \
1833         -width 20 -height 10 \
1834         -wrap none \
1835         -cursor $cursor_ptr \
1836         -xscrollcommand {.vpane.files.index.sx set} \
1837         -yscrollcommand {.vpane.files.index.sy set} \
1838         -state disabled
1839 scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
1840 scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
1841 pack .vpane.files.index.title -side top -fill x
1842 pack .vpane.files.index.sx -side bottom -fill x
1843 pack .vpane.files.index.sy -side right -fill y
1844 pack $ui_index -side left -fill both -expand 1
1845 .vpane.files add .vpane.files.index -sticky nsew
1846
1847 # -- Working Directory File List
1848 #
1849 frame .vpane.files.workdir -height 100 -width 200
1850 label .vpane.files.workdir.title -text {Unstaged Changes (Will Not Be Committed)} \
1851         -background lightsalmon
1852 text $ui_workdir -background white -borderwidth 0 \
1853         -width 20 -height 10 \
1854         -wrap none \
1855         -cursor $cursor_ptr \
1856         -xscrollcommand {.vpane.files.workdir.sx set} \
1857         -yscrollcommand {.vpane.files.workdir.sy set} \
1858         -state disabled
1859 scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
1860 scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
1861 pack .vpane.files.workdir.title -side top -fill x
1862 pack .vpane.files.workdir.sx -side bottom -fill x
1863 pack .vpane.files.workdir.sy -side right -fill y
1864 pack $ui_workdir -side left -fill both -expand 1
1865 .vpane.files add .vpane.files.workdir -sticky nsew
1866
1867 foreach i [list $ui_index $ui_workdir] {
1868         $i tag conf in_diff -background lightgray
1869         $i tag conf in_sel  -background lightgray
1870 }
1871 unset i
1872
1873 # -- Diff and Commit Area
1874 #
1875 frame .vpane.lower -height 300 -width 400
1876 frame .vpane.lower.commarea
1877 frame .vpane.lower.diff -relief sunken -borderwidth 1
1878 pack .vpane.lower.commarea -side top -fill x
1879 pack .vpane.lower.diff -side bottom -fill both -expand 1
1880 .vpane add .vpane.lower -sticky nsew
1881
1882 # -- Commit Area Buttons
1883 #
1884 frame .vpane.lower.commarea.buttons
1885 label .vpane.lower.commarea.buttons.l -text {} \
1886         -anchor w \
1887         -justify left
1888 pack .vpane.lower.commarea.buttons.l -side top -fill x
1889 pack .vpane.lower.commarea.buttons -side left -fill y
1890
1891 button .vpane.lower.commarea.buttons.rescan -text {Rescan} \
1892         -command do_rescan
1893 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
1894 lappend disable_on_lock \
1895         {.vpane.lower.commarea.buttons.rescan conf -state}
1896
1897 button .vpane.lower.commarea.buttons.incall -text {Add Existing} \
1898         -command do_add_all
1899 pack .vpane.lower.commarea.buttons.incall -side top -fill x
1900 lappend disable_on_lock \
1901         {.vpane.lower.commarea.buttons.incall conf -state}
1902
1903 button .vpane.lower.commarea.buttons.signoff -text {Sign Off} \
1904         -command do_signoff
1905 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
1906
1907 button .vpane.lower.commarea.buttons.commit -text {Commit} \
1908         -command do_commit
1909 pack .vpane.lower.commarea.buttons.commit -side top -fill x
1910 lappend disable_on_lock \
1911         {.vpane.lower.commarea.buttons.commit conf -state}
1912
1913 button .vpane.lower.commarea.buttons.push -text {Push} \
1914         -command do_push_anywhere
1915 pack .vpane.lower.commarea.buttons.push -side top -fill x
1916
1917 # -- Commit Message Buffer
1918 #
1919 frame .vpane.lower.commarea.buffer
1920 frame .vpane.lower.commarea.buffer.header
1921 set ui_comm .vpane.lower.commarea.buffer.t
1922 set ui_coml .vpane.lower.commarea.buffer.header.l
1923 radiobutton .vpane.lower.commarea.buffer.header.new \
1924         -text {New Commit} \
1925         -command do_select_commit_type \
1926         -variable selected_commit_type \
1927         -value new
1928 lappend disable_on_lock \
1929         [list .vpane.lower.commarea.buffer.header.new conf -state]
1930 radiobutton .vpane.lower.commarea.buffer.header.amend \
1931         -text {Amend Last Commit} \
1932         -command do_select_commit_type \
1933         -variable selected_commit_type \
1934         -value amend
1935 lappend disable_on_lock \
1936         [list .vpane.lower.commarea.buffer.header.amend conf -state]
1937 label $ui_coml \
1938         -anchor w \
1939         -justify left
1940 proc trace_commit_type {varname args} {
1941         global ui_coml commit_type
1942         switch -glob -- $commit_type {
1943         initial       {set txt {Initial Commit Message:}}
1944         amend         {set txt {Amended Commit Message:}}
1945         amend-initial {set txt {Amended Initial Commit Message:}}
1946         amend-merge   {set txt {Amended Merge Commit Message:}}
1947         merge         {set txt {Merge Commit Message:}}
1948         *             {set txt {Commit Message:}}
1949         }
1950         $ui_coml conf -text $txt
1951 }
1952 trace add variable commit_type write trace_commit_type
1953 pack $ui_coml -side left -fill x
1954 pack .vpane.lower.commarea.buffer.header.amend -side right
1955 pack .vpane.lower.commarea.buffer.header.new -side right
1956
1957 text $ui_comm -background white -borderwidth 1 \
1958         -undo true \
1959         -maxundo 20 \
1960         -autoseparators true \
1961         -relief sunken \
1962         -width 75 -height 9 -wrap none \
1963         -font font_diff \
1964         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
1965 scrollbar .vpane.lower.commarea.buffer.sby \
1966         -command [list $ui_comm yview]
1967 pack .vpane.lower.commarea.buffer.header -side top -fill x
1968 pack .vpane.lower.commarea.buffer.sby -side right -fill y
1969 pack $ui_comm -side left -fill y
1970 pack .vpane.lower.commarea.buffer -side left -fill y
1971
1972 # -- Commit Message Buffer Context Menu
1973 #
1974 set ctxm .vpane.lower.commarea.buffer.ctxm
1975 menu $ctxm -tearoff 0
1976 $ctxm add command \
1977         -label {Cut} \
1978         -command {tk_textCut $ui_comm}
1979 $ctxm add command \
1980         -label {Copy} \
1981         -command {tk_textCopy $ui_comm}
1982 $ctxm add command \
1983         -label {Paste} \
1984         -command {tk_textPaste $ui_comm}
1985 $ctxm add command \
1986         -label {Delete} \
1987         -command {$ui_comm delete sel.first sel.last}
1988 $ctxm add separator
1989 $ctxm add command \
1990         -label {Select All} \
1991         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
1992 $ctxm add command \
1993         -label {Copy All} \
1994         -command {
1995                 $ui_comm tag add sel 0.0 end
1996                 tk_textCopy $ui_comm
1997                 $ui_comm tag remove sel 0.0 end
1998         }
1999 $ctxm add separator
2000 $ctxm add command \
2001         -label {Sign Off} \
2002         -command do_signoff
2003 bind_button3 $ui_comm "tk_popup $ctxm %X %Y"
2004
2005 # -- Diff Header
2006 #
2007 proc trace_current_diff_path {varname args} {
2008         global current_diff_path diff_actions file_states
2009         if {$current_diff_path eq {}} {
2010                 set s {}
2011                 set f {}
2012                 set p {}
2013                 set o disabled
2014         } else {
2015                 set p $current_diff_path
2016                 set s [mapdesc [lindex $file_states($p) 0] $p]
2017                 set f {File:}
2018                 set p [escape_path $p]
2019                 set o normal
2020         }
2021
2022         .vpane.lower.diff.header.status configure -text $s
2023         .vpane.lower.diff.header.file configure -text $f
2024         .vpane.lower.diff.header.path configure -text $p
2025         foreach w $diff_actions {
2026                 uplevel #0 $w $o
2027         }
2028 }
2029 trace add variable current_diff_path write trace_current_diff_path
2030
2031 frame .vpane.lower.diff.header -background gold
2032 label .vpane.lower.diff.header.status \
2033         -background gold \
2034         -width $max_status_desc \
2035         -anchor w \
2036         -justify left
2037 label .vpane.lower.diff.header.file \
2038         -background gold \
2039         -anchor w \
2040         -justify left
2041 label .vpane.lower.diff.header.path \
2042         -background gold \
2043         -anchor w \
2044         -justify left
2045 pack .vpane.lower.diff.header.status -side left
2046 pack .vpane.lower.diff.header.file -side left
2047 pack .vpane.lower.diff.header.path -fill x
2048 set ctxm .vpane.lower.diff.header.ctxm
2049 menu $ctxm -tearoff 0
2050 $ctxm add command \
2051         -label {Copy} \
2052         -command {
2053                 clipboard clear
2054                 clipboard append \
2055                         -format STRING \
2056                         -type STRING \
2057                         -- $current_diff_path
2058         }
2059 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2060 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
2061
2062 # -- Diff Body
2063 #
2064 frame .vpane.lower.diff.body
2065 set ui_diff .vpane.lower.diff.body.t
2066 text $ui_diff -background white -borderwidth 0 \
2067         -width 80 -height 15 -wrap none \
2068         -font font_diff \
2069         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
2070         -yscrollcommand {.vpane.lower.diff.body.sby set} \
2071         -state disabled
2072 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
2073         -command [list $ui_diff xview]
2074 scrollbar .vpane.lower.diff.body.sby -orient vertical \
2075         -command [list $ui_diff yview]
2076 pack .vpane.lower.diff.body.sbx -side bottom -fill x
2077 pack .vpane.lower.diff.body.sby -side right -fill y
2078 pack $ui_diff -side left -fill both -expand 1
2079 pack .vpane.lower.diff.header -side top -fill x
2080 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
2081
2082 $ui_diff tag conf d_cr -elide true
2083 $ui_diff tag conf d_@ -foreground blue -font font_diffbold
2084 $ui_diff tag conf d_+ -foreground {#00a000}
2085 $ui_diff tag conf d_- -foreground red
2086
2087 $ui_diff tag conf d_++ -foreground {#00a000}
2088 $ui_diff tag conf d_-- -foreground red
2089 $ui_diff tag conf d_+s \
2090         -foreground {#00a000} \
2091         -background {#e2effa}
2092 $ui_diff tag conf d_-s \
2093         -foreground red \
2094         -background {#e2effa}
2095 $ui_diff tag conf d_s+ \
2096         -foreground {#00a000} \
2097         -background ivory1
2098 $ui_diff tag conf d_s- \
2099         -foreground red \
2100         -background ivory1
2101
2102 $ui_diff tag conf d<<<<<<< \
2103         -foreground orange \
2104         -font font_diffbold
2105 $ui_diff tag conf d======= \
2106         -foreground orange \
2107         -font font_diffbold
2108 $ui_diff tag conf d>>>>>>> \
2109         -foreground orange \
2110         -font font_diffbold
2111
2112 $ui_diff tag raise sel
2113
2114 # -- Diff Body Context Menu
2115 #
2116 set ctxm .vpane.lower.diff.body.ctxm
2117 menu $ctxm -tearoff 0
2118 $ctxm add command \
2119         -label {Refresh} \
2120         -command reshow_diff
2121 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2122 $ctxm add command \
2123         -label {Copy} \
2124         -command {tk_textCopy $ui_diff}
2125 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2126 $ctxm add command \
2127         -label {Select All} \
2128         -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
2129 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2130 $ctxm add command \
2131         -label {Copy All} \
2132         -command {
2133                 $ui_diff tag add sel 0.0 end
2134                 tk_textCopy $ui_diff
2135                 $ui_diff tag remove sel 0.0 end
2136         }
2137 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2138 $ctxm add separator
2139 $ctxm add command \
2140         -label {Apply/Reverse Hunk} \
2141         -command {apply_hunk $cursorX $cursorY}
2142 set ui_diff_applyhunk [$ctxm index last]
2143 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
2144 $ctxm add separator
2145 $ctxm add command \
2146         -label {Decrease Font Size} \
2147         -command {incr_font_size font_diff -1}
2148 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2149 $ctxm add command \
2150         -label {Increase Font Size} \
2151         -command {incr_font_size font_diff 1}
2152 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2153 $ctxm add separator
2154 $ctxm add command \
2155         -label {Show Less Context} \
2156         -command {if {$repo_config(gui.diffcontext) >= 1} {
2157                 incr repo_config(gui.diffcontext) -1
2158                 reshow_diff
2159         }}
2160 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2161 $ctxm add command \
2162         -label {Show More Context} \
2163         -command {if {$repo_config(gui.diffcontext) < 99} {
2164                 incr repo_config(gui.diffcontext)
2165                 reshow_diff
2166         }}
2167 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2168 $ctxm add separator
2169 $ctxm add command -label {Options...} \
2170         -command do_options
2171 bind_button3 $ui_diff "
2172         set cursorX %x
2173         set cursorY %y
2174         if {\$ui_index eq \$current_diff_side} {
2175                 $ctxm entryconf $ui_diff_applyhunk -label {Unstage Hunk From Commit}
2176         } else {
2177                 $ctxm entryconf $ui_diff_applyhunk -label {Stage Hunk For Commit}
2178         }
2179         tk_popup $ctxm %X %Y
2180 "
2181 unset ui_diff_applyhunk
2182
2183 # -- Status Bar
2184 #
2185 label .status -textvariable ui_status_value \
2186         -anchor w \
2187         -justify left \
2188         -borderwidth 1 \
2189         -relief sunken
2190 pack .status -anchor w -side bottom -fill x
2191
2192 # -- Load geometry
2193 #
2194 catch {
2195 set gm $repo_config(gui.geometry)
2196 wm geometry . [lindex $gm 0]
2197 .vpane sash place 0 \
2198         [lindex [.vpane sash coord 0] 0] \
2199         [lindex $gm 1]
2200 .vpane.files sash place 0 \
2201         [lindex $gm 2] \
2202         [lindex [.vpane.files sash coord 0] 1]
2203 unset gm
2204 }
2205
2206 # -- Key Bindings
2207 #
2208 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
2209 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
2210 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
2211 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
2212 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
2213 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
2214 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
2215 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
2216 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
2217 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
2218 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
2219
2220 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
2221 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
2222 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
2223 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
2224 bind $ui_diff <$M1B-Key-v> {break}
2225 bind $ui_diff <$M1B-Key-V> {break}
2226 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
2227 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
2228 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
2229 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
2230 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
2231 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
2232 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
2233 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
2234 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
2235 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
2236 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
2237 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
2238 bind $ui_diff <Button-1>   {focus %W}
2239
2240 if {[is_enabled branch]} {
2241         bind . <$M1B-Key-n> branch_create::dialog
2242         bind . <$M1B-Key-N> branch_create::dialog
2243 }
2244 if {[is_enabled transport]} {
2245         bind . <$M1B-Key-p> do_push_anywhere
2246         bind . <$M1B-Key-P> do_push_anywhere
2247 }
2248
2249 bind .   <Key-F5>     do_rescan
2250 bind .   <$M1B-Key-r> do_rescan
2251 bind .   <$M1B-Key-R> do_rescan
2252 bind .   <$M1B-Key-s> do_signoff
2253 bind .   <$M1B-Key-S> do_signoff
2254 bind .   <$M1B-Key-i> do_add_all
2255 bind .   <$M1B-Key-I> do_add_all
2256 bind .   <$M1B-Key-Return> do_commit
2257 foreach i [list $ui_index $ui_workdir] {
2258         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
2259         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
2260         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
2261 }
2262 unset i
2263
2264 set file_lists($ui_index) [list]
2265 set file_lists($ui_workdir) [list]
2266
2267 wm title . "[appname] ([reponame]) [file normalize [file dirname [gitdir]]]"
2268 focus -force $ui_comm
2269
2270 # -- Warn the user about environmental problems.  Cygwin's Tcl
2271 #    does *not* pass its env array onto any processes it spawns.
2272 #    This means that git processes get none of our environment.
2273 #
2274 if {[is_Cygwin]} {
2275         set ignored_env 0
2276         set suggest_user {}
2277         set msg "Possible environment issues exist.
2278
2279 The following environment variables are probably
2280 going to be ignored by any Git subprocess run
2281 by [appname]:
2282
2283 "
2284         foreach name [array names env] {
2285                 switch -regexp -- $name {
2286                 {^GIT_INDEX_FILE$} -
2287                 {^GIT_OBJECT_DIRECTORY$} -
2288                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
2289                 {^GIT_DIFF_OPTS$} -
2290                 {^GIT_EXTERNAL_DIFF$} -
2291                 {^GIT_PAGER$} -
2292                 {^GIT_TRACE$} -
2293                 {^GIT_CONFIG$} -
2294                 {^GIT_CONFIG_LOCAL$} -
2295                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
2296                         append msg " - $name\n"
2297                         incr ignored_env
2298                 }
2299                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
2300                         append msg " - $name\n"
2301                         incr ignored_env
2302                         set suggest_user $name
2303                 }
2304                 }
2305         }
2306         if {$ignored_env > 0} {
2307                 append msg "
2308 This is due to a known issue with the
2309 Tcl binary distributed by Cygwin."
2310
2311                 if {$suggest_user ne {}} {
2312                         append msg "
2313
2314 A good replacement for $suggest_user
2315 is placing values for the user.name and
2316 user.email settings into your personal
2317 ~/.gitconfig file.
2318 "
2319                 }
2320                 warn_popup $msg
2321         }
2322         unset ignored_env msg suggest_user name
2323 }
2324
2325 # -- Only initialize complex UI if we are going to stay running.
2326 #
2327 if {[is_enabled transport]} {
2328         load_all_remotes
2329         load_all_heads
2330
2331         populate_branch_menu
2332         populate_fetch_menu
2333         populate_push_menu
2334 }
2335
2336 # -- Only suggest a gc run if we are going to stay running.
2337 #
2338 if {[is_enabled multicommit]} {
2339         set object_limit 2000
2340         if {[is_Windows]} {set object_limit 200}
2341         regexp {^([0-9]+) objects,} [git count-objects] _junk objects_current
2342         if {$objects_current >= $object_limit} {
2343                 if {[ask_popup \
2344                         "This repository currently has $objects_current loose objects.
2345
2346 To maintain optimal performance it is strongly recommended that you compress the database when more than $object_limit loose objects exist.
2347
2348 Compress the database now?"] eq yes} {
2349                         do_gc
2350                 }
2351         }
2352         unset object_limit _junk objects_current
2353 }
2354
2355 lock_index begin-read
2356 after 1 do_rescan