lib/blame.tcl

   1 # git-gui blame viewer
   2 # Copyright (C) 2006, 2007 Shawn Pearce
   3
   4 class blame {
   5
   6 image create photo ::blame::img_back_arrow -data {R0lGODlhGAAYAIUAAPwCBEzKXFTSZIz+nGzmhGzqfGTidIT+nEzGXHTqhGzmfGzifFzadETCVES+VARWDFzWbHzyjAReDGTadFTOZDSyRDyyTCymPARaFGTedFzSbDy2TCyqRCyqPARaDAyCHES6VDy6VCyiPAR6HCSeNByWLARyFARiDARqFGTifARiFAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAACH5BAEAAAAALAAAAAAYABgAAAajQIBwSCwaj8ikcsk0BppJwRPqHEypQwHBis0WDAdEFyBIKBaMAKLBdjQeSkFBYTBAIvgEoS6JmhUTEwIUDQ4VFhcMGEhyCgoZExoUaxsWHB0THkgfAXUGAhoBDSAVFR0XBnCbDRmgog0hpSIiDJpJIyEQhBUcJCIlwA22SSYVogknEg8eD82qSigdDSknY0IqJQXPYxIl1dZCGNvWw+Dm510GQQAh/mhDcmVhdGVkIGJ5IEJNUFRvR0lGIFBybyB2ZXJzaW9uIDIuNQ0KqSBEZXZlbENvciAxOTk3LDE5OTguIEFsbCByaWdodHMgcmVzZXJ2ZWQuDQpodHRwOi8vd3d3LmRldmVsY29yLmNvbQA7}
   7
   8 field commit    ; # input commit to blame
   9 field path      ; # input filename to view in $commit
  10 field history {}; # viewer history: {commit path}
  11
  12 field w          ; # top window in this viewer
  13 field w_back     ; # our back button
  14 field w_path     ; # label showing the current file path
  15 field w_line     ; # text column: all line numbers
  16 field w_cgrp     ; # text column: abbreviated commit SHA-1s
  17 field w_load     ; # text column: loaded indicator
  18 field w_file     ; # text column: actual file data
  19 field w_cmit     ; # pane showing commit message
  20 field status     ; # text variable bound to status bar
  21 field old_height ; # last known height of $w.file_pane
  22
  23 field current_fd       {} ; # background process running
  24 field highlight_line   -1 ; # current line selected
  25 field highlight_commit {} ; # sha1 of commit selected
  26
  27 field total_lines       0  ; # total length of file
  28 field blame_lines       0  ; # number of lines computed
  29 field commit_count      0  ; # number of commits in $commit_list
  30 field commit_list      {}  ; # list of commit sha1 in receipt order
  31 field order                ; # array commit -> receipt order
  32 field header               ; # array commit,key -> header field
  33 field line_commit          ; # array line -> sha1 commit
  34 field line_file            ; # array line -> file name
  35
  36 field r_commit      ; # commit currently being parsed
  37 field r_orig_line   ; # original line number
  38 field r_final_line  ; # final line number
  39 field r_line_count  ; # lines in this region
  40
  41 field tooltip_wm     {} ; # Current tooltip toplevel, if open
  42 field tooltip_timer  {} ; # Current timer event for our tooltip
  43 field tooltip_commit {} ; # Commit in tooltip
  44 field tooltip_text   {} ; # Text in current tooltip
  45
  46 variable active_color #98e1a0
  47 variable group_colors {
  48         #cbcbcb
  49         #e1e1e1
  50 }
  51
  52 constructor new {i_commit i_path} {
  53         variable active_color
  54         global cursor_ptr
  55
  56         set commit $i_commit
  57         set path   $i_path
  58
  59         make_toplevel top w
  60         wm title $top "[appname] ([reponame]): File Viewer"
  61
  62         frame $w.header -background orange
  63         label $w.header.commit_l \
  64                 -text {Commit:} \
  65                 -background orange \
  66                 -anchor w \
  67                 -justify left
  68         set w_back $w.header.commit_b
  69         button $w_back \
  70                 -command [cb _history_menu] \
  71                 -image ::blame::img_back_arrow \
  72                 -borderwidth 0 \
  73                 -relief flat \
  74                 -state disabled \
  75                 -background orange \
  76                 -activebackground orange
  77         label $w.header.commit \
  78                 -textvariable @commit \
  79                 -background orange \
  80                 -anchor w \
  81                 -justify left
  82         label $w.header.path_l \
  83                 -text {File:} \
  84                 -background orange \
  85                 -anchor w \
  86                 -justify left
  87         set w_path $w.header.path
  88         label $w_path \
  89                 -background orange \
  90                 -anchor w \
  91                 -justify left
  92         pack $w.header.commit_l -side left
  93         pack $w_back -side left
  94         pack $w.header.commit -side left
  95         pack $w_path -fill x -side right
  96         pack $w.header.path_l -side right
  97
  98         panedwindow $w.file_pane -orient vertical
  99         frame $w.file_pane.out
 100         frame $w.file_pane.cm
 101         $w.file_pane add $w.file_pane.out \
 102                 -sticky nsew \
 103                 -minsize 100 \
 104                 -height 100 \
 105                 -width 100
 106         $w.file_pane add $w.file_pane.cm \
 107                 -sticky nsew \
 108                 -minsize 25 \
 109                 -height 25 \
 110                 -width 100
 111
 112         set w_load $w.file_pane.out.loaded_t
 113         text $w_load \
 114                 -background white -borderwidth 0 \
 115                 -state disabled \
 116                 -wrap none \
 117                 -height 40 \
 118                 -width 1 \
 119                 -font font_diff
 120         $w_load tag conf annotated -background grey
 121
 122         set w_line $w.file_pane.out.linenumber_t
 123         text $w_line \
 124                 -background white -borderwidth 0 \
 125                 -state disabled \
 126                 -wrap none \
 127                 -height 40 \
 128                 -width 5 \
 129                 -font font_diff
 130         $w_line tag conf linenumber -justify right
 131
 132         set w_cgrp $w.file_pane.out.commit_t
 133         text $w_cgrp \
 134                 -background white -borderwidth 0 \
 135                 -state disabled \
 136                 -wrap none \
 137                 -height 40 \
 138                 -width 4 \
 139                 -font font_diff
 140         $w_cgrp tag conf curr_commit
 141         $w_cgrp tag conf prior_commit \
 142                 -foreground blue \
 143                 -underline 1
 144         $w_cgrp tag bind prior_commit \
 145                 <Button-1> \
 146                 "[cb _load_commit @%x,%y];break"
 147
 148         set w_file $w.file_pane.out.file_t
 149         text $w_file \
 150                 -background white -borderwidth 0 \
 151                 -state disabled \
 152                 -wrap none \
 153                 -height 40 \
 154                 -width 80 \
 155                 -xscrollcommand [list $w.file_pane.out.sbx set] \
 156                 -font font_diff
 157
 158         scrollbar $w.file_pane.out.sbx \
 159                 -orient h \
 160                 -command [list $w_file xview]
 161         scrollbar $w.file_pane.out.sby \
 162                 -orient v \
 163                 -command [list scrollbar2many [list \
 164                 $w_load \
 165                 $w_line \
 166                 $w_cgrp \
 167                 $w_file \
 168                 ] yview]
 169         grid \
 170                 $w_cgrp \
 171                 $w_line \
 172                 $w_load \
 173                 $w_file \
 174                 $w.file_pane.out.sby \
 175                 -sticky nsew
 176         grid conf $w.file_pane.out.sbx -column 3 -sticky we
 177         grid columnconfigure $w.file_pane.out 3 -weight 1
 178         grid rowconfigure $w.file_pane.out 0 -weight 1
 179
 180         set w_cmit $w.file_pane.cm.t
 181         text $w_cmit \
 182                 -background white -borderwidth 0 \
 183                 -state disabled \
 184                 -wrap none \
 185                 -height 10 \
 186                 -width 80 \
 187                 -xscrollcommand [list $w.file_pane.cm.sbx set] \
 188                 -yscrollcommand [list $w.file_pane.cm.sby set] \
 189                 -font font_diff
 190         $w_cmit tag conf header_key \
 191                 -tabs {3c} \
 192                 -background $active_color \
 193                 -font font_uibold
 194         $w_cmit tag conf header_val \
 195                 -background $active_color \
 196                 -font font_ui
 197         $w_cmit tag raise sel
 198         scrollbar $w.file_pane.cm.sbx \
 199                 -orient h \
 200                 -command [list $w_cmit xview]
 201         scrollbar $w.file_pane.cm.sby \
 202                 -orient v \
 203                 -command [list $w_cmit yview]
 204         pack $w.file_pane.cm.sby -side right -fill y
 205         pack $w.file_pane.cm.sbx -side bottom -fill x
 206         pack $w_cmit -expand 1 -fill both
 207
 208         frame $w.status \
 209                 -borderwidth 1 \
 210                 -relief sunken
 211         label $w.status.l \
 212                 -textvariable @status \
 213                 -anchor w \
 214                 -justify left
 215         pack $w.status.l -side left
 216
 217         menu $w.ctxm -tearoff 0
 218         $w.ctxm add command \
 219                 -label "Copy Commit" \
 220                 -command [cb _copycommit]
 221
 222         foreach i [list \
 223                 $w_cgrp \
 224                 $w_load \
 225                 $w_line \
 226                 $w_file] {
 227                 $i conf -cursor $cursor_ptr
 228                 $i conf -yscrollcommand \
 229                         [list many2scrollbar [list \
 230                         $w_cgrp \
 231                         $w_load \
 232                         $w_line \
 233                         $w_file \
 234                         ] yview $w.file_pane.out.sby]
 235                 bind $i <Button-1> "
 236                         [cb _hide_tooltip]
 237                         [cb _click $i @%x,%y]
 238                         focus $i
 239                 "
 240                 bind $i <Any-Motion>  [cb _show_tooltip $i @%x,%y]
 241                 bind $i <Any-Enter>   [cb _hide_tooltip]
 242                 bind $i <Any-Leave>   [cb _hide_tooltip]
 243                 bind_button3 $i "
 244                         [cb _hide_tooltip]
 245                         set cursorX %x
 246                         set cursorY %y
 247                         set cursorW %W
 248                         tk_popup $w.ctxm %X %Y
 249                 "
 250         }
 251
 252         foreach i [list \
 253                 $w_cgrp \
 254                 $w_load \
 255                 $w_line \
 256                 $w_file \
 257                 $w_cmit] {
 258                 bind $i <Key-Up>        {catch {%W yview scroll -1 units};break}
 259                 bind $i <Key-Down>      {catch {%W yview scroll  1 units};break}
 260                 bind $i <Key-Left>      {catch {%W xview scroll -1 units};break}
 261                 bind $i <Key-Right>     {catch {%W xview scroll  1 units};break}
 262                 bind $i <Key-k>         {catch {%W yview scroll -1 units};break}
 263                 bind $i <Key-j>         {catch {%W yview scroll  1 units};break}
 264                 bind $i <Key-h>         {catch {%W xview scroll -1 units};break}
 265                 bind $i <Key-l>         {catch {%W xview scroll  1 units};break}
 266                 bind $i <Control-Key-b> {catch {%W yview scroll -1 pages};break}
 267                 bind $i <Control-Key-f> {catch {%W yview scroll  1 pages};break}
 268         }
 269
 270         bind $w_cmit <Button-1> [list focus $w_cmit]
 271         bind $top <Visibility> [list focus $top]
 272         bind $w_file <Destroy> [list delete_this $this]
 273
 274         grid configure $w.header -sticky ew
 275         grid configure $w.file_pane -sticky nsew
 276         grid configure $w.status -sticky ew
 277         grid columnconfigure $top 0 -weight 1
 278         grid rowconfigure $top 0 -weight 0
 279         grid rowconfigure $top 1 -weight 1
 280         grid rowconfigure $top 2 -weight 0
 281
 282         set req_w [winfo reqwidth  $top]
 283         set req_h [winfo reqheight $top]
 284         if {$req_w < 600} {set req_w 600}
 285         if {$req_h < 400} {set req_h 400}
 286         set g "${req_w}x${req_h}"
 287         wm geometry $top $g
 288         update
 289
 290         set old_height [winfo height $w.file_pane]
 291         $w.file_pane sash place 0 \
 292                 [lindex [$w.file_pane sash coord 0] 0] \
 293                 [expr {int($old_height * 0.70)}]
 294         bind $w.file_pane <Configure> \
 295         "if {{$w.file_pane} eq {%W}} {[cb _resize %h]}"
 296
 297         _load $this
 298 }
 299
 300 method _load {} {
 301         _hide_tooltip $this
 302
 303         if {$total_lines != 0 || $current_fd ne {}} {
 304                 if {$current_fd ne {}} {
 305                         catch {close $current_fd}
 306                         set current_fd {}
 307                 }
 308
 309                 set highlight_line -1
 310                 set highlight_commit {}
 311                 set total_lines 0
 312                 set blame_lines 0
 313                 set commit_count 0
 314                 set commit_list {}
 315                 array unset order
 316                 array unset line_commit
 317                 array unset line_file
 318
 319                 $w_load conf -state normal
 320                 $w_cgrp conf -state normal
 321                 $w_line conf -state normal
 322                 $w_file conf -state normal
 323
 324                 $w_load delete 0.0 end
 325                 $w_cgrp delete 0.0 end
 326                 $w_line delete 0.0 end
 327                 $w_file delete 0.0 end
 328
 329                 $w_load conf -state disabled
 330                 $w_cgrp conf -state disabled
 331                 $w_line conf -state disabled
 332                 $w_file conf -state disabled
 333         }
 334
 335         if {[winfo exists $w.status.c]} {
 336                 $w.status.c coords bar 0 0 0 20
 337         } else {
 338                 canvas $w.status.c \
 339                         -width 100 \
 340                         -height [expr {int([winfo reqheight $w.status.l] * 0.6)}] \
 341                         -borderwidth 1 \
 342                         -relief groove \
 343                         -highlightt 0
 344                 $w.status.c create rectangle 0 0 0 20 -tags bar -fill navy
 345                 pack $w.status.c -side right
 346         }
 347
 348         if {$history eq {}} {
 349                 $w_back conf -state disabled
 350         } else {
 351                 $w_back conf -state normal
 352         }
 353         lappend history [list $commit $path]
 354
 355         set status "Loading $commit:[escape_path $path]..."
 356         $w_path conf -text [escape_path $path]
 357         if {$commit eq {}} {
 358                 set fd [open $path r]
 359         } else {
 360                 set cmd [list git cat-file blob "$commit:$path"]
 361                 set fd [open "| $cmd" r]
 362         }
 363         fconfigure $fd -blocking 0 -translation lf -encoding binary
 364         fileevent $fd readable [cb _read_file $fd]
 365         set current_fd $fd
 366 }
 367
 368 method _history_menu {} {
 369         set m $w.backmenu
 370         if {[winfo exists $m]} {
 371                 $m delete 0 end
 372         } else {
 373                 menu $m -tearoff 0
 374         }
 375
 376         for {set i [expr {[llength $history] - 2}]
 377                 } {$i >= 0} {incr i -1} {
 378                 set e [lindex $history $i]
 379                 set c [lindex $e 0]
 380                 set f [lindex $e 1]
 381
 382                 if {[regexp {^[0-9a-f]{40}$} $c]} {
 383                         set t [string range $c 0 8]...
 384                 } else {
 385                         set t $c
 386                 }
 387                 if {![catch {set summary $header($c,summary)}]} {
 388                         append t " $summary"
 389                 }
 390
 391                 $m add command -label $t -command [cb _goback $i $c $f]
 392         }
 393         set X [winfo rootx $w_back]
 394         set Y [expr {[winfo rooty $w_back] + [winfo height $w_back]}]
 395         tk_popup $m $X $Y
 396 }
 397
 398 method _goback {i c f} {
 399         set history [lrange $history 0 [expr {$i - 1}]]
 400         set commit $c
 401         set path $f
 402         _load $this
 403 }
 404
 405 method _read_file {fd} {
 406         if {$fd ne $current_fd} {
 407                 catch {close $fd}
 408                 return
 409         }
 410
 411         $w_load conf -state normal
 412         $w_cgrp conf -state normal
 413         $w_line conf -state normal
 414         $w_file conf -state normal
 415         while {[gets $fd line] >= 0} {
 416                 regsub "\r\$" $line {} line
 417                 incr total_lines
 418
 419                 if {$total_lines > 1} {
 420                         $w_load insert end "\n"
 421                         $w_cgrp insert end "\n"
 422                         $w_line insert end "\n"
 423                         $w_file insert end "\n"
 424                 }
 425
 426                 $w_line insert end "$total_lines" linenumber
 427                 $w_file insert end "$line"
 428         }
 429         $w_load conf -state disabled
 430         $w_cgrp conf -state disabled
 431         $w_line conf -state disabled
 432         $w_file conf -state disabled
 433
 434         if {[eof $fd]} {
 435                 close $fd
 436                 _status $this
 437                 set cmd {nice git blame -M -C --incremental}
 438                 if {$commit eq {}} {
 439                         lappend cmd --contents $path
 440                 } else {
 441                         lappend cmd $commit
 442                 }
 443                 lappend cmd -- $path
 444                 set fd [open "| $cmd" r]
 445                 fconfigure $fd -blocking 0 -translation lf -encoding binary
 446                 fileevent $fd readable [cb _read_blame $fd]
 447                 set current_fd $fd
 448         }
 449 } ifdeleted { catch {close $fd} }
 450
 451 method _read_blame {fd} {
 452         variable group_colors
 453
 454         if {$fd ne $current_fd} {
 455                 catch {close $fd}
 456                 return
 457         }
 458
 459         $w_cgrp conf -state normal
 460         while {[gets $fd line] >= 0} {
 461                 if {[regexp {^([a-z0-9]{40}) (\d+) (\d+) (\d+)$} $line line \
 462                         cmit original_line final_line line_count]} {
 463                         set r_commit     $cmit
 464                         set r_orig_line  $original_line
 465                         set r_final_line $final_line
 466                         set r_line_count $line_count
 467
 468                         if {[catch {set g $order($cmit)}]} {
 469                                 set bg [lindex $group_colors 0]
 470                                 set group_colors [lrange $group_colors 1 end]
 471                                 lappend group_colors $bg
 472
 473                                 $w_cgrp tag conf g$cmit -background $bg
 474                                 $w_line tag conf g$cmit -background $bg
 475                                 $w_file tag conf g$cmit -background $bg
 476
 477                                 set order($cmit) $commit_count
 478                                 incr commit_count
 479                                 lappend commit_list $cmit
 480                         }
 481                 } elseif {[string match {filename *} $line]} {
 482                         set file [string range $line 9 end]
 483                         set n    $r_line_count
 484                         set lno  $r_final_line
 485                         set cmit $r_commit
 486
 487                         if {[regexp {^0{40}$} $cmit]} {
 488                                 set commit_abbr work
 489                                 set commit_type curr_commit
 490                         } elseif {$cmit eq $commit} {
 491                                 set commit_abbr this
 492                                 set commit_type curr_commit
 493                         } else {
 494                                 set commit_type prior_commit
 495                                 set commit_abbr [string range $cmit 0 4]
 496                         }
 497
 498                         set author_abbr {}
 499                         set a_name {}
 500                         catch {set a_name $header($cmit,author)}
 501                         while {$a_name ne {}} {
 502                                 if {![regexp {^([[:upper:]])} $a_name _a]} break
 503                                 append author_abbr $_a
 504                                 unset _a
 505                                 if {![regsub \
 506                                         {^[[:upper:]][^\s]*\s+} \
 507                                         $a_name {} a_name ]} break
 508                         }
 509                         if {$author_abbr eq {}} {
 510                                 set author_abbr { |}
 511                         } else {
 512                                 set author_abbr [string range $author_abbr 0 3]
 513                                 while {[string length $author_abbr] < 4} {
 514                                         set author_abbr " $author_abbr"
 515                                 }
 516                         }
 517                         unset a_name
 518
 519                         set first_lno $lno
 520                         while {
 521                            ![catch {set ncmit $line_commit([expr {$first_lno - 1}])}]
 522                         && ![catch {set nfile $line_file([expr {$first_lno - 1}])}]
 523                         && $ncmit eq $cmit
 524                         && $nfile eq $file
 525                         } {
 526                                 incr first_lno -1
 527                         }
 528
 529                         while {$n > 0} {
 530                                 set lno_e "$lno.0 lineend + 1c"
 531                                 if {[catch {set g g$line_commit($lno)}]} {
 532                                         $w_load tag add annotated $lno.0 $lno_e
 533                                 } else {
 534                                         $w_cgrp tag remove g$g $lno.0 $lno_e
 535                                         $w_line tag remove g$g $lno.0 $lno_e
 536                                         $w_file tag remove g$g $lno.0 $lno_e
 537
 538                                         $w_cgrp tag remove a$g $lno.0 $lno_e
 539                                         $w_line tag remove a$g $lno.0 $lno_e
 540                                         $w_file tag remove a$g $lno.0 $lno_e
 541                                 }
 542
 543                                 set line_commit($lno) $cmit
 544                                 set line_file($lno)   $file
 545
 546                                 $w_cgrp delete $lno.0 "$lno.0 lineend"
 547                                 if {$lno == $first_lno} {
 548                                         $w_cgrp insert $lno.0 $commit_abbr $commit_type
 549                                 } elseif {$lno == [expr {$first_lno + 1}]} {
 550                                         $w_cgrp insert $lno.0 $author_abbr
 551                                 } else {
 552                                         $w_cgrp insert $lno.0 { |}
 553                                 }
 554
 555                                 $w_cgrp tag add g$cmit $lno.0 $lno_e
 556                                 $w_line tag add g$cmit $lno.0 $lno_e
 557                                 $w_file tag add g$cmit $lno.0 $lno_e
 558
 559                                 $w_cgrp tag add a$cmit $lno.0 $lno_e
 560                                 $w_line tag add a$cmit $lno.0 $lno_e
 561                                 $w_file tag add a$cmit $lno.0 $lno_e
 562
 563                                 if {$highlight_line == -1} {
 564                                         if {[lindex [$w_file yview] 0] == 0} {
 565                                                 $w_file see $lno.0
 566                                                 _showcommit $this $lno
 567                                         }
 568                                 } elseif {$highlight_line == $lno} {
 569                                         _showcommit $this $lno
 570                                 }
 571
 572                                 incr n -1
 573                                 incr lno
 574                                 incr blame_lines
 575                         }
 576
 577                         while {
 578                            ![catch {set ncmit $line_commit($lno)}]
 579                         && ![catch {set nfile $line_file($lno)}]
 580                         && $ncmit eq $cmit
 581                         && $nfile eq $file
 582                         } {
 583                                 $w_cgrp delete $lno.0 "$lno.0 lineend"
 584
 585                                 if {$lno == $first_lno} {
 586                                         $w_cgrp insert $lno.0 $commit_abbr $commit_type
 587                                 } elseif {$lno == [expr {$first_lno + 1}]} {
 588                                         $w_cgrp insert $lno.0 $author_abbr
 589                                 } else {
 590                                         $w_cgrp insert $lno.0 { |}
 591                                 }
 592                                 incr lno
 593                         }
 594
 595                 } elseif {[regexp {^([a-z-]+) (.*)$} $line line key data]} {
 596                         set header($r_commit,$key) $data
 597                 }
 598         }
 599         $w_cgrp conf -state disabled
 600
 601         if {[eof $fd]} {
 602                 close $fd
 603                 set current_fd {}
 604                 set status {Annotation complete.}
 605                 destroy $w.status.c
 606         } else {
 607                 _status $this
 608         }
 609 } ifdeleted { catch {close $fd} }
 610
 611 method _status {} {
 612         set have  $blame_lines
 613         set total $total_lines
 614         set pdone 0
 615         if {$total} {set pdone [expr {100 * $have / $total}]}
 616
 617         set status [format \
 618                 "Loading annotations... %i of %i lines annotated (%2i%%)" \
 619                 $have $total $pdone]
 620         $w.status.c coords bar 0 0 $pdone 20
 621 }
 622
 623 method _click {cur_w pos} {
 624         set lno [lindex [split [$cur_w index $pos] .] 0]
 625         if {$lno eq {}} return
 626         _showcommit $this $lno
 627 }
 628
 629 method _load_commit {pos} {
 630         set lno [lindex [split [$w_cgrp index $pos] .] 0]
 631         if {[catch {set cmit $line_commit($lno)}]} return
 632         if {[catch {set file $line_file($lno)  }]} return
 633
 634         set commit $cmit
 635         set path $file
 636         _load $this
 637 }
 638
 639 method _showcommit {lno} {
 640         global repo_config
 641         variable active_color
 642
 643         if {$highlight_commit ne {}} {
 644                 set cmit $highlight_commit
 645                 $w_cgrp tag conf a$cmit -background {}
 646                 $w_line tag conf a$cmit -background {}
 647                 $w_file tag conf a$cmit -background {}
 648         }
 649
 650         $w_cmit conf -state normal
 651         $w_cmit delete 0.0 end
 652         if {[catch {set cmit $line_commit($lno)}]} {
 653                 set cmit {}
 654                 $w_cmit insert end "Loading annotation..."
 655         } else {
 656                 $w_cgrp tag conf a$cmit -background $active_color
 657                 $w_line tag conf a$cmit -background $active_color
 658                 $w_file tag conf a$cmit -background $active_color
 659
 660                 set author_name {}
 661                 set author_email {}
 662                 set author_time {}
 663                 catch {set author_name $header($cmit,author)}
 664                 catch {set author_email $header($cmit,author-mail)}
 665                 catch {set author_time [clock format \
 666                         $header($cmit,author-time) \
 667                         -format {%Y-%m-%d %H:%M:%S}
 668                 ]}
 669
 670                 set committer_name {}
 671                 set committer_email {}
 672                 set committer_time {}
 673                 catch {set committer_name $header($cmit,committer)}
 674                 catch {set committer_email $header($cmit,committer-mail)}
 675                 catch {set committer_time [clock format \
 676                         $header($cmit,committer-time) \
 677                         -format {%Y-%m-%d %H:%M:%S}
 678                 ]}
 679
 680                 if {[catch {set msg $header($cmit,message)}]} {
 681                         set msg {}
 682                         catch {
 683                                 set fd [open "| git cat-file commit $cmit" r]
 684                                 fconfigure $fd -encoding binary -translation lf
 685                                 if {[catch {set enc $repo_config(i18n.commitencoding)}]} {
 686                                         set enc utf-8
 687                                 }
 688                                 while {[gets $fd line] > 0} {
 689                                         if {[string match {encoding *} $line]} {
 690                                                 set enc [string tolower [string range $line 9 end]]
 691                                         }
 692                                 }
 693                                 set msg [encoding convertfrom $enc [read $fd]]
 694                                 set msg [string trim $msg]
 695                                 close $fd
 696
 697                                 set author_name [encoding convertfrom $enc $author_name]
 698                                 set committer_name [encoding convertfrom $enc $committer_name]
 699
 700                                 set header($cmit,author) $author_name
 701                                 set header($cmit,committer) $committer_name
 702                         }
 703                         set header($cmit,message) $msg
 704                 }
 705
 706                 $w_cmit insert end "commit $cmit\n" header_key
 707                 $w_cmit insert end "Author:\t" header_key
 708                 $w_cmit insert end "$author_name $author_email" header_val
 709                 $w_cmit insert end "$author_time\n" header_val
 710
 711                 $w_cmit insert end "Committer:\t" header_key
 712                 $w_cmit insert end "$committer_name $committer_email" header_val
 713                 $w_cmit insert end "$committer_time\n" header_val
 714
 715                 if {$line_file($lno) ne $path} {
 716                         $w_cmit insert end "Original File:\t" header_key
 717                         $w_cmit insert end "[escape_path $line_file($lno)]\n" header_val
 718                 }
 719
 720                 $w_cmit insert end "\n$msg"
 721         }
 722         $w_cmit conf -state disabled
 723
 724         set highlight_line $lno
 725         set highlight_commit $cmit
 726
 727         if {$highlight_commit eq $tooltip_commit} {
 728                 _hide_tooltip $this
 729         }
 730 }
 731
 732 method _copycommit {} {
 733         set pos @$::cursorX,$::cursorY
 734         set lno [lindex [split [$::cursorW index $pos] .] 0]
 735         if {![catch {set commit $line_commit($lno)}]} {
 736                 clipboard clear
 737                 clipboard append \
 738                         -format STRING \
 739                         -type STRING \
 740                         -- $commit
 741         }
 742 }
 743
 744 method _show_tooltip {cur_w pos} {
 745         set lno [lindex [split [$cur_w index $pos] .] 0]
 746         if {[catch {set cmit $line_commit($lno)}]} {
 747                 _hide_tooltip $this
 748                 return
 749         }
 750
 751         if {$cmit eq $highlight_commit} {
 752                 _hide_tooltip $this
 753                 return
 754         }
 755
 756         if {$cmit eq $tooltip_commit} {
 757                 _position_tooltip $this
 758         } elseif {$tooltip_wm ne {}} {
 759                 _open_tooltip $this $cur_w
 760         } elseif {$tooltip_timer eq {}} {
 761                 set tooltip_timer [after 1000 [cb _open_tooltip $cur_w]]
 762         }
 763 }
 764
 765 method _open_tooltip {cur_w} {
 766         set tooltip_timer {}
 767         set pos_x [winfo pointerx $cur_w]
 768         set pos_y [winfo pointery $cur_w]
 769         if {[winfo containing $pos_x $pos_y] ne $cur_w} {
 770                 _hide_tooltip $this
 771                 return
 772         }
 773
 774         set pos @[join [list \
 775                 [expr {$pos_x - [winfo rootx $cur_w]}] \
 776                 [expr {$pos_y - [winfo rooty $cur_w]}]] ,]
 777         set lno [lindex [split [$cur_w index $pos] .] 0]
 778         set cmit $line_commit($lno)
 779
 780         set author_name {}
 781         set author_email {}
 782         set author_time {}
 783         catch {set author_name $header($cmit,author)}
 784         catch {set author_email $header($cmit,author-mail)}
 785         catch {set author_time [clock format \
 786                 $header($cmit,author-time) \
 787                 -format {%Y-%m-%d %H:%M:%S}
 788         ]}
 789
 790         set committer_name {}
 791         set committer_email {}
 792         set committer_time {}
 793         catch {set committer_name $header($cmit,committer)}
 794         catch {set committer_email $header($cmit,committer-mail)}
 795         catch {set committer_time [clock format \
 796                 $header($cmit,committer-time) \
 797                 -format {%Y-%m-%d %H:%M:%S}
 798         ]}
 799
 800         set summary {}
 801         catch {set summary $header($cmit,summary)}
 802
 803         set tooltip_commit $cmit
 804         set tooltip_text "commit $cmit
 805 $author_name $author_email  $author_time
 806 $summary"
 807
 808         set file $line_file($lno)
 809         if {$file ne $path} {
 810                 append tooltip_text "
 811
 812 Original File: $file"
 813         }
 814
 815         if {$tooltip_wm ne "$cur_w.tooltip"} {
 816                 _hide_tooltip $this
 817
 818                 set tooltip_wm [toplevel $cur_w.tooltip -borderwidth 1]
 819                 wm overrideredirect $tooltip_wm 1
 820                 wm transient $tooltip_wm [winfo toplevel $cur_w]
 821                 pack [label $tooltip_wm.label \
 822                         -background lightyellow \
 823                         -foreground black \
 824                         -textvariable @tooltip_text \
 825                         -justify left]
 826         }
 827         _position_tooltip $this
 828 }
 829
 830 method _position_tooltip {} {
 831         set req_w [winfo reqwidth  $tooltip_wm.label]
 832         set req_h [winfo reqheight $tooltip_wm.label]
 833         set pos_x [expr {[winfo pointerx .] +  5}]
 834         set pos_y [expr {[winfo pointery .] + 10}]
 835
 836         set g "${req_w}x${req_h}"
 837         if {$pos_x >= 0} {append g +}
 838         append g $pos_x
 839         if {$pos_y >= 0} {append g +}
 840         append g $pos_y
 841
 842         wm geometry $tooltip_wm $g
 843         raise $tooltip_wm
 844 }
 845
 846 method _hide_tooltip {} {
 847         if {$tooltip_wm ne {}} {
 848                 destroy $tooltip_wm
 849                 set tooltip_wm {}
 850                 set tooltip_commit {}
 851         }
 852         if {$tooltip_timer ne {}} {
 853                 after cancel $tooltip_timer
 854                 set tooltip_timer {}
 855         }
 856 }
 857
 858 method _resize {new_height} {
 859         set diff [expr {$new_height - $old_height}]
 860         if {$diff == 0} return
 861
 862         set my [expr {[winfo height $w.file_pane] - 25}]
 863         set o [$w.file_pane sash coord 0]
 864         set ox [lindex $o 0]
 865         set oy [expr {[lindex $o 1] + $diff}]
 866         if {$oy < 0}   {set oy 0}
 867         if {$oy > $my} {set oy $my}
 868         $w.file_pane sash place 0 $ox $oy
 869
 870         set old_height $new_height
 871 }
 872
 873 }