windows/putty.iss

   1 ; -*- no -*-\r
   2 ;\r
   3 ; -- Legacy Inno Setup installer script for PuTTY and its related tools.\r
   4 ;    Last tested with Inno Setup 5.5.9.\r
   5 ;    (New work should go to the MSI installer; see installer.wxs.)\r
   6 ;\r
   7 ; TODO for future releases:\r
   8 ;\r
   9 ;  - It might be nice to have an option to add PSCP, Plink and PSFTP to\r
  10 ;    the PATH. See wish `installer-addpath'.\r
  11 ;\r
  12 ;  - Maybe a "custom" installation might be useful? Hassle with\r
  13 ;    UninstallDisplayIcon, though.\r
  14 \r
  15 [Setup]\r
  16 AppName=PuTTY\r
  17 AppVerName=PuTTY version 0.67\r
  18 VersionInfoTextVersion=Release 0.67\r
  19 AppVersion=0.67\r
  20 VersionInfoVersion=0.67.0.0\r
  21 AppPublisher=Simon Tatham\r
  22 AppPublisherURL=http://www.chiark.greenend.org.uk/~sgtatham/putty/\r
  23 AppReadmeFile={app}\README.txt\r
  24 DefaultDirName={pf}\PuTTY\r
  25 DefaultGroupName=PuTTY\r
  26 SetupIconFile=puttyins.ico\r
  27 UninstallDisplayIcon={app}\putty.exe\r
  28 ChangesAssociations=yes\r
  29 ;ChangesEnvironment=yes -- when PATH munging is sorted (probably)\r
  30 Compression=zip/9\r
  31 AllowNoIcons=yes\r
  32 OutputBaseFilename=installer\r
  33 \r
  34 [Files]\r
  35 ; We flag all files with "restartreplace" et al primarily for the benefit\r
  36 ; of unattended un/installations/upgrades, when the user is running one\r
  37 ; of the apps at a time. Without it, the operation will fail noisily in\r
  38 ; this situation.\r
  39 ; This does mean that the user will be prompted to restart their machine\r
  40 ; if any of the files _were_ open during installation (or, if /VERYSILENT\r
  41 ; is used, the machine will be restarted automatically!). The /NORESTART\r
  42 ; flag avoids this.\r
  43 ; It might be nicer to have a "no worries, replace the file next time you\r
  44 ; reboot" option, but the developers have no interest in adding one.\r
  45 ; NB: apparently, using long (non-8.3) filenames with restartreplace is a\r
  46 ; bad idea. (Not that we do.)\r
  47 Source: "build32\putty.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete\r
  48 Source: "build32\pageant.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete\r
  49 Source: "build32\puttygen.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete\r
  50 Source: "build32\pscp.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete\r
  51 Source: "build32\psftp.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete\r
  52 Source: "build32\plink.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete\r
  53 Source: "website.url"; DestDir: "{app}"; Flags: restartreplace uninsrestartdelete\r
  54 Source: "..\doc\putty.chm"; DestDir: "{app}"; Flags: restartreplace uninsrestartdelete\r
  55 Source: "..\doc\putty.hlp"; DestDir: "{app}"; Flags: restartreplace uninsrestartdelete\r
  56 Source: "..\doc\putty.cnt"; DestDir: "{app}"; Flags: restartreplace uninsrestartdelete\r
  57 Source: "..\LICENCE"; DestDir: "{app}"; Flags: restartreplace uninsrestartdelete\r
  58 Source: "README.txt"; DestDir: "{app}"; Flags: isreadme restartreplace uninsrestartdelete\r
  59 \r
  60 [Icons]\r
  61 Name: "{group}\PuTTY"; Filename: "{app}\putty.exe"\r
  62 ; We have to fall back from the .chm to the older .hlp file on some Windows\r
  63 ; versions.\r
  64 Name: "{group}\PuTTY Manual"; Filename: "{app}\putty.chm"; MinVersion: 4.1,5.0\r
  65 Name: "{group}\PuTTY Manual"; Filename: "{app}\putty.hlp"; OnlyBelowVersion: 4.1,5.0\r
  66 Name: "{group}\PuTTY Web Site"; Filename: "{app}\website.url"\r
  67 Name: "{group}\PSFTP"; Filename: "{app}\psftp.exe"\r
  68 Name: "{group}\PuTTYgen"; Filename: "{app}\puttygen.exe"\r
  69 Name: "{group}\Pageant"; Filename: "{app}\pageant.exe"\r
  70 Name: "{commondesktop}\PuTTY"; Filename: "{app}\putty.exe"; Tasks: desktopicon\common\r
  71 Name: "{userdesktop}\PuTTY"; Filename: "{app}\putty.exe"; Tasks: desktopicon\user\r
  72 ; Putting this in {commonappdata} doesn't seem to work, on 98SE at least.\r
  73 Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\PuTTY"; Filename: "{app}\putty.exe"; Tasks: quicklaunchicon\r
  74 \r
  75 [Tasks]\r
  76 Name: desktopicon; Description: "Create a &desktop icon for PuTTY"; GroupDescription: "Additional icons:"; Flags: unchecked\r
  77 Name: desktopicon\common; Description: "For all users"; GroupDescription: "Additional icons:"; Flags: exclusive unchecked\r
  78 Name: desktopicon\user; Description: "For the current user only"; GroupDescription: "Additional icons:"; Flags: exclusive unchecked\r
  79 Name: quicklaunchicon; Description: "Create a &Quick Launch icon for PuTTY (current user only)"; GroupDescription: "Additional icons:"; Flags: unchecked\r
  80 Name: associate; Description: "&Associate .PPK files (PuTTY Private Key) with Pageant and PuTTYgen"; GroupDescription: "Other tasks:"\r
  81 \r
  82 [Registry]\r
  83 Root: HKCR; Subkey: ".ppk"; ValueType: string; ValueName: ""; ValueData: "PuTTYPrivateKey"; Flags: uninsdeletevalue; Tasks: associate\r
  84 Root: HKCR; Subkey: "PuTTYPrivateKey"; ValueType: string; ValueName: ""; ValueData: "PuTTY Private Key File"; Flags: uninsdeletekey; Tasks: associate\r
  85 Root: HKCR; Subkey: "PuTTYPrivateKey\DefaultIcon"; ValueType: string; ValueName: ""; ValueData: "{app}\pageant.exe,0"; Tasks: associate\r
  86 Root: HKCR; Subkey: "PuTTYPrivateKey\shell\open\command"; ValueType: string; ValueName: ""; ValueData: """{app}\pageant.exe"" ""%1"""; Tasks: associate\r
  87 Root: HKCR; Subkey: "PuTTYPrivateKey\shell\edit"; ValueType: string; ValueName: ""; ValueData: "&Edit"; Tasks: associate\r
  88 Root: HKCR; Subkey: "PuTTYPrivateKey\shell\edit\command"; ValueType: string; ValueName: ""; ValueData: """{app}\puttygen.exe"" ""%1"""; Tasks: associate\r
  89 ; Add to PATH on NT-class OS?\r
  90 \r
  91 [Messages]\r
  92 ; Since it's possible for the user to be asked to restart their computer,\r
  93 ; we should override the default messages to explain exactly why, so they\r
  94 ; can make an informed decision. (Especially as 95% of users won't need or\r
  95 ; want to restart; see rant above.)\r
  96 FinishedRestartLabel=One or more [name] programs are still running. Setup will not replace these program files until you restart your computer. Would you like to restart now?\r
  97 ; This message is popped up in a message box on a /SILENT install.\r
  98 FinishedRestartMessage=One or more [name] programs are still running.%nSetup will not replace these program files until you restart your computer.%n%nWould you like to restart now?\r
  99 ; ...and this comes up if you try to uninstall.\r
 100 UninstalledAndNeedsRestart=One or more %1 programs are still running.%nThe program files will not be removed until your computer is restarted.%n%nWould you like to restart now?\r
 101 ; Old versions of this installer used to prompt to remove saved settings\r
 102 ; and the like after the point this message was printed, so it seems\r
 103 ; polite to warn people that that no longer happens.\r
 104 ConfirmUninstall=Are you sure you want to completely remove %1 and all of its components?%n%nNote that this will not remove any saved sessions or random seed file that %1 has created. These are harmless to leave on your system, but if you want to remove them, you should answer No here and run 'putty.exe -cleanup' before you uninstall.\r