wire-format.lisp

   1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   2 ;;;                                                                  ;;;
   3 ;;; Free Software published under an MIT-like license. See LICENSE   ;;;
   4 ;;;                                                                  ;;;
   5 ;;; Copyright (c) 2012 Google, Inc.  All rights reserved.            ;;;
   6 ;;;                                                                  ;;;
   7 ;;; Original author: Scott McKay                                     ;;;
   8 ;;;                                                                  ;;;
   9 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  10
  11 (in-package "PROTO-IMPL")
  12
  13
  14 ;;; Protocol buffers wire format
  15
  16 ;;; Utilities
  17
  18 (eval-when (:compile-toplevel :load-toplevel :execute)
  19
  20 ;; If you need to debug the (de)serializer, (pushnew :debug-serialization *features*)
  21 ;; Otherwise, we try to make (de)serialization as fast as possible,
  22 ;; risking life and limb to do so
  23 (defparameter $optimize-serialization
  24   #+debug-serialization $optimize-default
  25   #-debug-serialization $optimize-fast-unsafe)
  26
  27 (defconstant $wire-type-varint 0)
  28 (defconstant $wire-type-64bit  1)
  29 (defconstant $wire-type-string 2)
  30 (defconstant $wire-type-start-group 3)          ;supposedly deprecated, but no such luck
  31 (defconstant $wire-type-end-group   4)          ;supposedly deprecated
  32 (defconstant $wire-type-32bit  5)
  33
  34 )       ;eval-when
  35
  36
  37 (defun make-tag (type index)
  38   "Given a wire type or the name of a Protobufs type and a field index,
  39    return the tag that encodes both of them."
  40   (locally (declare #.$optimize-serialization)
  41     (if (typep type 'fixnum)
  42       (ilogior type (iash index 3))
  43       (let ((type (ecase type
  44                     ((:int32 :uint32) $wire-type-varint)
  45                     ((:int64 :uint64) $wire-type-varint)
  46                     ((:sint32 :sint64) $wire-type-varint)
  47                     ((:fixed32 :sfixed32) $wire-type-32bit)
  48                     ((:fixed64 :sfixed64) $wire-type-64bit)
  49                     ((:string :bytes) $wire-type-string)
  50                     ((:bool) $wire-type-varint)
  51                     ((:float) $wire-type-32bit)
  52                     ((:double) $wire-type-64bit)
  53                     ;; A few of our homegrown types
  54                     ((:symbol) $wire-type-string)
  55                     ((:date :time :datetime :timestamp) $wire-type-64bit))))
  56         (ilogior type (iash index 3))))))
  57
  58 (define-compiler-macro make-tag (&whole form type index)
  59   (setq type (fold-symbol type))
  60   (cond ((typep type 'fixnum)
  61          `(ilogior ,type (iash ,index 3)))
  62         ((keywordp type)
  63          (let ((type (ecase type
  64                        ((:int32 :uint32) $wire-type-varint)
  65                        ((:int64 :uint64) $wire-type-varint)
  66                        ((:sint32 :sint64) $wire-type-varint)
  67                        ((:fixed32 :sfixed32) $wire-type-32bit)
  68                        ((:fixed64 :sfixed64) $wire-type-64bit)
  69                        ((:string :bytes) $wire-type-string)
  70                        ((:bool) $wire-type-varint)
  71                        ((:float) $wire-type-32bit)
  72                        ((:double) $wire-type-64bit)
  73                        ;; A few of our homegrown types
  74                        ((:symbol) $wire-type-string)
  75                        ((:date :time :datetime :timestamp) $wire-type-64bit))))
  76            `(ilogior ,type (iash ,index 3))))
  77         (t form)))
  78
  79 (defun fold-symbol (x)
  80   "Given an expression 'x', constant-fold it until it can be folded no more."
  81   (let ((last '#:last))
  82     (loop
  83       (cond ((eq x last) (return x))
  84             ((and (listp x)
  85                   (eq (first x) 'quote)
  86                   (constantp (second x)))
  87              (shiftf last x (second x)))
  88             ((and (symbolp x)
  89                   (boundp x))
  90              (shiftf last x (symbol-value x)))
  91             (t (return x))))))
  92
  93
  94 (defmacro gen-zig-zag (bits)
  95   "Generate 32- or 64-bit versions of zig-zag encoder/decoder."
  96   (assert (and (plusp bits) (zerop (mod bits 8))))
  97   (let* ((zig-zag-encode (fintern "~A~A" 'zig-zag-encode bits))
  98          (zig-zag-decode (fintern "~A~A" 'zig-zag-decode bits))
  99          (zig-zag-shift (1+ (- bits))))
 100     `(progn
 101        (defun ,zig-zag-encode (val)
 102          (declare #.$optimize-serialization)
 103          (declare (type (signed-byte ,bits) val))
 104          (logxor (ash val 1) (ash val ,zig-zag-shift)))
 105        (define-compiler-macro ,zig-zag-encode (&whole form val)
 106          (if (atom val)
 107            `(locally (declare #.$optimize-serialization
 108                               (type (signed-byte ,',bits) ,val))
 109               (logxor (ash ,val 1) (ash ,val ,',zig-zag-shift)))
 110            form))
 111        (defun ,zig-zag-decode (val)
 112          (declare #.$optimize-serialization)
 113          (declare (type (unsigned-byte ,bits) val))
 114          (logxor (ash val -1) (- (logand val 1))))
 115        (define-compiler-macro ,zig-zag-decode (&whole form val)
 116          (if (atom val)
 117            `(locally (declare #.$optimize-serialization
 118                               (type (unsigned-byte ,',bits) ,val))
 119               (logxor (ash ,val -1) (- (logand ,val 1))))
 120            form)))))
 121
 122 (gen-zig-zag 32)
 123 (gen-zig-zag 64)
 124
 125
 126 ;;; Serializers
 127
 128 ;; Serialize 'val' of primitive type 'type' into the buffer
 129 (defun serialize-prim (val type tag buffer index)
 130   "Serializes a Protobufs primitive (scalar) value into the buffer at the given index.
 131    The value is given by 'val', the primitive type by 'type'.
 132    Modifies the buffer in place, and returns the new index into the buffer.
 133    Watch out, this function turns off most type checking and all array bounds checking."
 134   (declare (type (unsigned-byte 32) tag)
 135            (type fixnum index))
 136   (locally (declare #.$optimize-serialization)
 137     (let ((idx (encode-uint32 tag buffer index)))
 138       (declare (type fixnum idx))
 139       (ecase type
 140         ((:int32 :uint32)
 141          (encode-uint32 (ldb (byte 32 0) val) buffer idx))
 142         ((:int64 :uint64)
 143          (encode-uint64 (ldb (byte 64 0) val) buffer idx))
 144         ((:sint32)
 145          (encode-uint32 (zig-zag-encode32 val) buffer idx))
 146         ((:sint64)
 147          (encode-uint64 (zig-zag-encode64 val) buffer idx))
 148         ((:fixed32)
 149          (encode-fixed32 val buffer idx))
 150         ((:sfixed32)
 151          (encode-sfixed32 val buffer idx))
 152         ((:fixed64)
 153          (encode-fixed64 val buffer idx))
 154         ((:sfixed64)
 155          (encode-sfixed64 val buffer idx))
 156         ((:string)
 157          (encode-string val buffer idx))
 158         ((:bytes)
 159          (encode-octets val buffer idx))
 160         ((:bool)
 161          (encode-uint32 (if val 1 0) buffer idx))
 162         ((:float)
 163          (encode-single val buffer idx))
 164         ((:double)
 165          (encode-double val buffer idx))
 166         ;; A few of our homegrown types
 167         ((:symbol)
 168          (let ((val (if (keywordp val)
 169                       (string val)
 170                       ;; Non-keyword symbols are consy, avoid them if possible
 171                       (format nil "~A:~A" (package-name (symbol-package val)) (symbol-name val)))))
 172            (encode-string val buffer idx)))
 173         ((:date :time :datetime :timestamp)
 174          (encode-uint64 (ldb (byte 64 0) val) buffer idx))))))
 175
 176 (define-compiler-macro serialize-prim (&whole form val type tag buffer index)
 177   (setq type (fold-symbol type)
 178         tag  (fold-symbol tag))
 179   (if (member type '(:int32 :uint32 :int64 :uint64 :sint32 :sint64
 180                      :fixed32 :sfixed32 :fixed64 :sfixed64
 181                      :string :bytes :bool :float :double))
 182     `(locally (declare #.$optimize-serialization
 183                        (type (simple-array (unsigned-byte 8)) ,buffer)
 184                        ;; 'tag' is a constant, no need to declare its type
 185                        (type fixnum ,index))
 186        (let ((idx (encode-uint32 ,tag ,buffer ,index)))
 187          (declare (type fixnum idx))
 188          ,(ecase type
 189             ((:int32 )
 190              `(encode-uint32 (ldb (byte 32 0) ,val) ,buffer idx))
 191             ((:int64)
 192              `(encode-uint64 (ldb (byte 64 0) ,val) ,buffer idx))
 193             ((:uint32)
 194              `(encode-uint32 ,val ,buffer idx))
 195             ((:uint64)
 196              `(encode-uint64 ,val ,buffer idx))
 197             ((:sint32)
 198              `(encode-uint32 (zig-zag-encode32 ,val) ,buffer idx))
 199             ((:sint64)
 200              `(encode-uint64 (zig-zag-encode64 ,val) ,buffer idx))
 201             ((:fixed32)
 202              `(encode-fixed32 ,val ,buffer idx))
 203             ((:sfixed32)
 204              `(encode-sfixed32 ,val ,buffer idx))
 205             ((:fixed64)
 206              `(encode-fixed64 ,val ,buffer idx))
 207             ((:sfixed64)
 208              `(encode-sfixed64 ,val ,buffer idx))
 209             ((:string)
 210              `(encode-string ,val ,buffer idx))
 211             ((:bytes)
 212              `(encode-octets ,val ,buffer idx))
 213             ((:bool)
 214              `(encode-uint32 (if ,val 1 0) ,buffer idx))
 215             ((:float)
 216              `(encode-single ,val ,buffer idx))
 217             ((:double)
 218              `(encode-double ,val ,buffer idx)))))
 219     form))
 220
 221 (defun serialize-packed (values type tag buffer index &optional vectorp)
 222   "Serializes a set of packed values into the buffer at the given index.
 223    The values are given by 'values', the primitive type by 'type'.
 224    Modifies the buffer in place, and returns the new index into the buffer.
 225    Watch out, this function turns off most type checking and all array bounds checking."
 226   (declare (ignore vectorp)
 227            (type (simple-array (unsigned-byte 8)) buffer)
 228            (type (unsigned-byte 32) tag)
 229            (type fixnum index))
 230   (locally (declare #.$optimize-serialization)
 231     (let ((idx (encode-uint32 tag buffer index)))
 232       (declare (type fixnum idx))
 233       (multiple-value-bind (full-len len)
 234           (packed-size values type tag)
 235         (declare (type fixnum len) (ignore full-len))
 236         (setq idx (encode-uint32 len buffer idx)))
 237       (ecase type
 238         ((:int32 :uint32)
 239          (map () #'(lambda (val) (setq idx (encode-uint32 (ldb (byte 32 0) val) buffer idx))) values))
 240         ((:int64 :uint64)
 241          (map () #'(lambda (val) (setq idx (encode-uint64 (ldb (byte 64 0) val) buffer idx))) values))
 242         ((:sint32)
 243          (map () #'(lambda (val) (setq idx (encode-uint32 (zig-zag-encode32 val) buffer idx))) values))
 244         ((:sint64)
 245          (map () #'(lambda (val) (setq idx (encode-uint64 (zig-zag-encode64 val) buffer idx))) values))
 246         ((:fixed32)
 247          (map () #'(lambda (val) (setq idx (encode-fixed32 val buffer idx))) values))
 248         ((:sfixed32)
 249          (map () #'(lambda (val) (setq idx (encode-sfixed32 val buffer idx))) values))
 250         ((:fixed64)
 251          (map () #'(lambda (val) (setq idx (encode-fixed64 val buffer idx))) values))
 252         ((:sfixed64)
 253          (map () #'(lambda (val) (setq idx (encode-sfixed64 val buffer idx))) values))
 254         ((:bool)
 255          (map () #'(lambda (val) (setq idx (encode-uint32 (if val 1 0) buffer idx))) values))
 256         ((:float)
 257          (map () #'(lambda (val) (setq idx (encode-single val buffer idx))) values))
 258         ((:double)
 259          (map () #'(lambda (val) (setq idx (encode-double val buffer idx))) values)))
 260       idx)))
 261
 262 ;; The optimized serializers supply 'vectorp' so we can generate better code
 263 (define-compiler-macro serialize-packed (&whole form values type tag buffer index
 264                                          &optional (vectorp nil vectorp-p))
 265   (setq type (fold-symbol type)
 266         tag  (fold-symbol tag))
 267   (if (and vectorp-p
 268            `(member type '(:int32 :uint32 :int64 :uint64 :sint32 :sint64
 269                            :fixed32 :sfixed32 :fixed64 :sfixed64
 270                            :bool :float :double)))
 271     `(locally (declare #.$optimize-serialization
 272                        (type (simple-array (unsigned-byte 8)) ,buffer)
 273                        ;; 'tag' is a constant, no need to declare its type
 274                        (type fixnum ,index))
 275        (let ((idx (encode-uint32 ,tag ,buffer ,index)))
 276          (declare (type fixnum idx))
 277          (multiple-value-bind (full-len len)
 278              (packed-size ,values ,type ,tag)
 279            (declare (type fixnum len) (ignore full-len))
 280            (setq idx (encode-uint32 len ,buffer idx)))
 281          (,(if vectorp 'dovector 'dolist) (val ,values)
 282             ,(ecase type
 283                ((:int32)
 284                 `(setq idx (encode-uint32 (ldb (byte 32 0) val) ,buffer idx)))
 285                ((:int64)
 286                 `(setq idx (encode-uint64 (ldb (byte 64 0) val) ,buffer idx)))
 287                ((:uint32)
 288                 `(setq idx (encode-uint32 val ,buffer idx)))
 289                ((:uint64)
 290                 `(setq idx (encode-uint64 val ,buffer idx)))
 291                ((:sint32)
 292                 `(setq idx (encode-uint32 (zig-zag-encode32 val) ,buffer idx)))
 293                ((:sint64)
 294                 `(setq idx (encode-uint64 (zig-zag-encode64 val) ,buffer idx)))
 295                ((:fixed32)
 296                 `(setq idx (encode-fixed32 val ,buffer idx)))
 297                ((:sfixed32)
 298                 `(setq idx (encode-sfixed32 val ,buffer idx)))
 299                ((:fixed64)
 300                 `(setq idx (encode-fixed64 val ,buffer idx)))
 301                ((:sfixed64)
 302                 `(setq idx (encode-sfixed64 val ,buffer idx)))
 303                ((:bool)
 304                 `(setq idx (encode-uint32 (if val 1 0) ,buffer idx)))
 305                ((:float)
 306                 `(setq idx (encode-single val ,buffer idx)))
 307                ((:double)
 308                 `(setq idx (encode-double val ,buffer idx)))))
 309          idx))
 310     form))
 311
 312 (defun serialize-enum (val enum-values tag buffer index)
 313   "Serializes a Protobufs enum value into the buffer at the given index.
 314    The value is given by 'val', the enum values are in 'enum-values'.
 315    Modifies the buffer in place, and returns the new index into the buffer.
 316    Watch out, this function turns off most type checking and all array bounds checking."
 317   (declare (type list enum-values)
 318            (type (simple-array (unsigned-byte 8)) buffer)
 319            (type (unsigned-byte 32) tag)
 320            (type fixnum index))
 321   (locally (declare #.$optimize-serialization)
 322     (let* ((val (let ((e (find val enum-values :key #'proto-value)))
 323                   (and e (proto-index e))))
 324            (idx (encode-uint32 tag buffer index)))
 325       (declare (type (unsigned-byte 32) val)
 326                (type fixnum idx))
 327       (encode-uint32 (ldb (byte 32 0) val) buffer idx))))
 328
 329 (defun serialize-packed-enum (values enum-values tag buffer index)
 330   "Serializes Protobufs enum values into the buffer at the given index.
 331    The values are given by 'values', the enum values are in 'enum-values'.
 332    Modifies the buffer in place, and returns the new index into the buffer.
 333    Watch out, this function turns off most type checking and all array bounds checking."
 334   (declare (type list enum-values)
 335            (type (simple-array (unsigned-byte 8)) buffer)
 336            (type (unsigned-byte 32) tag)
 337            (type fixnum index))
 338   (locally (declare #.$optimize-serialization)
 339     (let ((idx (encode-uint32 tag buffer index)))
 340       (declare (type fixnum idx))
 341       (multiple-value-bind (full-len len)
 342           (packed-enum-size values enum-values tag)
 343         (declare (type fixnum len) (ignore full-len))
 344         (setq idx (encode-uint32 len buffer idx)))
 345       (map () #'(lambda (val)
 346                   (let ((val (let ((e (find val enum-values :key #'proto-value)))
 347                                (and e (proto-index e)))))
 348                     (declare (type (unsigned-byte 32) val))
 349                     (setq idx (encode-uint32 (ldb (byte 32 0) val) buffer idx)))) values)
 350       idx)))
 351
 352
 353 ;;; Deserializers
 354
 355 ;; Deserialize the next object of type 'type'
 356 (defun deserialize-prim (type buffer index)
 357   "Deserializes the next object of primitive type 'type'.
 358    Deserializes from the byte vector 'buffer' starting at 'index'.
 359    Returns the value and and the new index into the buffer.
 360    Watch out, this function turns off most type checking and all array bounds checking."
 361   (declare (type (simple-array (unsigned-byte 8)) buffer)
 362            (type fixnum index))
 363   (locally (declare #.$optimize-serialization)
 364     (ecase type
 365       ((:int32)
 366        (decode-int32 buffer index))
 367       ((:int64)
 368        (decode-int64 buffer index))
 369       ((:uint32)
 370        (decode-uint32 buffer index))
 371       ((:uint64)
 372        (decode-uint64 buffer index))
 373       ((:sint32)
 374        (multiple-value-bind (val idx)
 375            (decode-uint32 buffer index)
 376          (values (zig-zag-decode32 val) idx)))
 377       ((:sint64)
 378        (multiple-value-bind (val idx)
 379            (decode-uint64 buffer index)
 380          (values (zig-zag-decode64 val) idx)))
 381       ((:fixed32)
 382        (decode-fixed32 buffer index))
 383       ((:sfixed32)
 384        (decode-sfixed32 buffer index))
 385       ((:fixed64)
 386        (decode-fixed64 buffer index))
 387       ((:sfixed64)
 388        (decode-sfixed64 buffer index))
 389       ((:string)
 390        (decode-string buffer index))
 391       ((:bytes)
 392        (decode-octets buffer index))
 393       ((:bool)
 394        (multiple-value-bind (val idx)
 395            (decode-uint32 buffer index)
 396          (values (if (i= val 0) nil t) idx)))
 397       ((:float)
 398        (decode-single buffer index))
 399       ((:double)
 400        (decode-double buffer index))
 401       ;; A few of our homegrown types
 402       ((:symbol)
 403        ;; Note that this is consy, avoid it if possible
 404        (multiple-value-bind (val idx)
 405            (decode-string buffer index)
 406          (values (make-lisp-symbol val) idx)))
 407       ((:date :time :datetime :timestamp)
 408        (decode-uint64 buffer index)))))
 409
 410 (define-compiler-macro deserialize-prim (&whole form type buffer index)
 411   (setq type (fold-symbol type))
 412   (if (member type '(:int32 :uint32 :int64 :uint64 :sint32 :sint64
 413                      :fixed32 :sfixed32 :fixed64 :sfixed64
 414                      :string :bytes :bool :float :double))
 415     `(locally (declare #.$optimize-serialization
 416                        (type (simple-array (unsigned-byte 8)) ,buffer)
 417                        (type fixnum ,index))
 418        ,(ecase type
 419           ((:int32)
 420            `(decode-int32 ,buffer ,index))
 421           ((:int64)
 422            `(decode-int64 ,buffer ,index))
 423           ((:uint32)
 424            `(decode-uint32 ,buffer ,index))
 425           ((:uint64)
 426            `(decode-uint64 ,buffer ,index))
 427           ((:sint32)
 428            `(multiple-value-bind (val idx)
 429                 (decode-uint32 ,buffer ,index)
 430               (values (zig-zag-decode32 val) idx)))
 431           ((:sint64)
 432            `(multiple-value-bind (val idx)
 433                (decode-uint64 ,buffer ,index)
 434              (values (zig-zag-decode64 val) idx)))
 435           ((:fixed32)
 436            `(decode-fixed32 ,buffer ,index))
 437           ((:sfixed32)
 438            `(decode-sfixed32 ,buffer ,index))
 439           ((:fixed64)
 440            `(decode-fixed64 ,buffer ,index))
 441           ((:sfixed64)
 442            `(decode-sfixed64 ,buffer ,index))
 443           ((:string)
 444            `(decode-string ,buffer ,index))
 445           ((:bytes)
 446            `(decode-octets ,buffer ,index))
 447           ((:bool)
 448            `(multiple-value-bind (val idx)
 449                 (decode-uint32 ,buffer ,index)
 450               (values (if (i= val 0) nil t) idx)))
 451           ((:float)
 452            `(decode-single ,buffer ,index))
 453           ((:double)
 454            `(decode-double ,buffer ,index))))
 455     form))
 456
 457 (defun deserialize-packed (type buffer index)
 458   "Deserializes the next packed values of type 'type'.
 459    Deserializes from the byte vector 'buffer' starting at 'index'.
 460    Returns the value and and the new index into the buffer.
 461    Watch out, this function turns off most type checking and all array bounds checking."
 462   (declare (type (simple-array (unsigned-byte 8)) buffer)
 463            (type fixnum index))
 464   (locally (declare #.$optimize-serialization)
 465     (multiple-value-bind (len idx)
 466         (decode-uint32 buffer index)
 467       (declare (type (unsigned-byte 32) len)
 468                (type fixnum idx))
 469       (let ((end (i+ idx len)))
 470         (declare (type (unsigned-byte 32) end))
 471         (with-collectors ((values collect-value))
 472           (loop
 473             (when (>= idx end)
 474               (return-from deserialize-packed (values values idx)))
 475             (multiple-value-bind (val nidx)
 476                 (ecase type
 477                   ((:int32)
 478                    (decode-int32 buffer idx))
 479                   ((:int64)
 480                    (decode-int64 buffer idx))
 481                   ((:uint32)
 482                    (decode-uint32 buffer idx))
 483                   ((:uint64)
 484                    (decode-uint64 buffer idx))
 485                   ((:sint32)
 486                    (multiple-value-bind (val nidx)
 487                        (decode-uint32 buffer idx)
 488                      (values (zig-zag-decode32 val) nidx)))
 489                   ((:sint64)
 490                    (multiple-value-bind (val nidx)
 491                        (decode-uint64 buffer idx)
 492                      (values (zig-zag-decode64 val) nidx)))
 493                   ((:fixed32)
 494                    (decode-fixed32 buffer idx))
 495                   ((:sfixed32)
 496                    (decode-sfixed32 buffer idx))
 497                   ((:fixed64)
 498                    (decode-fixed64 buffer idx))
 499                   ((:sfixed64)
 500                    (decode-sfixed64 buffer idx))
 501                   ((:bool)
 502                    (multiple-value-bind (val nidx)
 503                        (decode-uint32 buffer idx)
 504                      (values (if (i= val 0) nil t) nidx)))
 505                   ((:float)
 506                    (decode-single buffer idx))
 507                   ((:double)
 508                    (decode-double buffer idx)))
 509               (collect-value val)
 510               (setq idx nidx))))))))
 511
 512 (define-compiler-macro deserialize-packed (&whole form type buffer index)
 513   (setq type (fold-symbol type))
 514   (if (member type '(:int32 :uint32 :int64 :uint64 :sint32 :sint64
 515                      :fixed32 :sfixed32 :fixed64 :sfixed64
 516                      :bool :float :double))
 517     `(locally (declare #.$optimize-serialization
 518                        (type (simple-array (unsigned-byte 8)) ,buffer)
 519                        (type fixnum ,index))
 520        (block deserialize-packed
 521          (multiple-value-bind (len idx)
 522              (decode-uint32 ,buffer ,index)
 523            (declare (type (unsigned-byte 32) len)
 524                     (type fixnum idx))
 525            (let ((end (i+ idx len)))
 526              (declare (type (unsigned-byte 32) end))
 527              (with-collectors ((values collect-value))
 528                (loop
 529                  (when (>= idx end)
 530                    (return-from deserialize-packed (values values idx)))
 531                  (multiple-value-bind (val nidx)
 532                      ,(ecase type
 533                         ((:int32)
 534                          `(decode-int32 ,buffer idx))
 535                         ((:int64)
 536                          `(decode-int64 ,buffer idx))
 537                         ((:uint32)
 538                          `(decode-uint32 ,buffer idx))
 539                         ((:uint64)
 540                          `(decode-uint64 ,buffer idx))
 541                         ((:sint32)
 542                          `(multiple-value-bind (val nidx)
 543                               (decode-uint32 ,buffer idx)
 544                             (values (zig-zag-decode32 val) nidx)))
 545                         ((:sint64)
 546                          `(multiple-value-bind (val nidx)
 547                               (decode-uint64 ,buffer idx)
 548                             (values (zig-zag-decode64 val) nidx)))
 549                         ((:fixed32)
 550                          `(decode-fixed32 ,buffer idx))
 551                         ((:sfixed32)
 552                          `(decode-sfixed32 ,buffer idx))
 553                         ((:fixed64)
 554                          `(decode-fixed64 ,buffer idx))
 555                         ((:sfixed64)
 556                          `(decode-sfixed64 ,buffer idx))
 557                         ((:bool)
 558                          `(multiple-value-bind (val nidx)
 559                               (decode-uint32 ,buffer idx)
 560                             (values (if (i= val 0) nil t) nidx)))
 561                         ((:float)
 562                          `(decode-single ,buffer idx))
 563                         ((:double)
 564                          `(decode-double ,buffer idx)))
 565                    (collect-value val)
 566                    (setq idx nidx))))))))
 567     form))
 568
 569 (defun deserialize-enum (enum-values buffer index)
 570   "Deserializes the next enum value take from 'enum-values'.
 571    Deserializes from the byte vector 'buffer' starting at 'index'.
 572    Returns the value and and the new index into the buffer.
 573    Watch out, this function turns off most type checking and all array bounds checking."
 574   (declare (type list enum-values)
 575            (type (simple-array (unsigned-byte 8)) buffer)
 576            (type fixnum index))
 577   (locally (declare #.$optimize-serialization)
 578     (multiple-value-bind (val idx)
 579         (decode-int32 buffer index)
 580       (let ((val (let ((e (find val enum-values :key #'proto-index)))
 581                    (and e (proto-value e)))))
 582         (values val idx)))))
 583
 584 (defun deserialize-packed-enum (enum-values buffer index)
 585   "Deserializes the next packed enum values given in 'enum-values'.
 586    Deserializes from the byte vector 'buffer' starting at 'index'.
 587    Returns the value and and the new index into the buffer.
 588    Watch out, this function turns off most type checking and all array bounds checking."
 589   (declare (type list enum-values)
 590            (type (simple-array (unsigned-byte 8)) buffer)
 591            (type fixnum index))
 592   (locally (declare #.$optimize-serialization)
 593     (multiple-value-bind (len idx)
 594         (decode-uint32 buffer index)
 595       (declare (type (unsigned-byte 32) len)
 596                (type fixnum idx))
 597       (let ((end (i+ idx len)))
 598         (declare (type (unsigned-byte 32) end))
 599         (with-collectors ((values collect-value))
 600           (loop
 601             (when (>= idx end)
 602               (return-from deserialize-packed-enum (values values idx)))
 603             (multiple-value-bind (val nidx)
 604                 (decode-int32 buffer idx)
 605               (let ((val (let ((e (find val enum-values :key #'proto-index)))
 606                            (and e (proto-value e)))))
 607                 (collect-value val)
 608                 (setq idx nidx)))))))))
 609
 610
 611 ;;; Object sizing
 612
 613 (defun prim-size (val type tag)
 614   "Returns the size in bytes that the primitive object will take when serialized.
 615    Watch out, this function turns off most type checking."
 616   (declare (type (unsigned-byte 32) tag))
 617   (locally (declare #.$optimize-serialization)
 618     (ecase type
 619       ((:int32 :uint32)
 620        (i+ (length32 tag) (length32 (ldb (byte 32 0) val))))
 621       ((:int64 :uint64)
 622        (i+ (length32 tag) (length64 (ldb (byte 64 0) val))))
 623       ((:sint32)
 624        (i+ (length32 tag) (length32 (zig-zag-encode32 val))))
 625       ((:sint64)
 626        (i+ (length32 tag) (length64 (zig-zag-encode64 val))))
 627       ((:fixed32 :sfixed32)
 628        (i+ (length32 tag) 4))
 629       ((:fixed64 :sfixed64)
 630        (i+ (length32 tag) 8))
 631       ((:string)
 632        (let ((len (babel:string-size-in-octets val :encoding :utf-8)))
 633          (i+ (length32 tag) (length32 len) len)))
 634       ((:bytes)
 635        (let ((len (length val)))
 636          (i+ (length32 tag) (length32 len) len)))
 637       ((:bool)
 638        (i+ (length32 tag) 1))
 639       ((:float)
 640        (i+ (length32 tag) 4))
 641       ((:double)
 642        (i+ (length32 tag) 8))
 643       ;; A few of our homegrown types
 644       ((:symbol)
 645        (let ((len (if (keywordp val)
 646                     (length (symbol-name val))
 647                     (i+ (length (package-name (symbol-package val))) 1 (length (symbol-name val))))))
 648          (i+ (length32 tag) (length32 len) len)))
 649       ((:date :time :datetime :timestamp)
 650        (i+ (length32 tag) 8)))))
 651
 652 (define-compiler-macro prim-size (&whole form val type tag)
 653   (setq type (fold-symbol type)
 654         tag  (fold-symbol tag))
 655   (if (member type '(:int32 :uint32 :int64 :uint64 :sint32 :sint64
 656                      :fixed32 :sfixed32 :fixed64 :sfixed64
 657                      :string :bytes :bool :float :double))
 658     `(locally (declare #.$optimize-serialization)
 659        ,(ecase type
 660           ((:int32)
 661            `(i+ (length32 ,tag) (length32 (ldb (byte 32 0) ,val))))
 662           ((:int64)
 663            `(i+ (length32 ,tag) (length64 (ldb (byte 64 0) ,val))))
 664           ((:uint32)
 665            `(i+ (length32 ,tag) (length32 ,val)))
 666           ((:uint64)
 667            `(i+ (length32 ,tag) (length64 ,val)))
 668           ((:sint32)
 669            `(i+ (length32 ,tag) (length32 (zig-zag-encode32 ,val))))
 670           ((:sint64)
 671            `(i+ (length32 ,tag) (length64 (zig-zag-encode64 ,val))))
 672           ((:fixed32 :sfixed32)
 673            `(i+ (length32 ,tag) 4))
 674           ((:fixed64 :sfixed64)
 675            `(i+ (length32 ,tag) 8))
 676           ((:string)
 677            `(let ((len (babel:string-size-in-octets ,val :encoding :utf-8)))
 678               (i+ (length32 ,tag) (length32 len) len)))
 679           ((:bytes)
 680            `(let ((len (length ,val)))
 681               (i+ (length32 ,tag) (length32 len) len)))
 682           ((:bool)
 683            `(i+ (length32 ,tag) 1))
 684           ((:float)
 685            `(i+ (length32 ,tag) 4))
 686           ((:double)
 687            `(i+ (length32 ,tag) 8))))
 688     form))
 689
 690 (defun packed-size (values type tag &optional vectorp)
 691   "Returns the size in bytes that the packed object will take when serialized.
 692    Watch out, this function turns off most type checking."
 693   (declare (ignore vectorp)
 694            (type (unsigned-byte 32) tag))
 695   (locally (declare #.$optimize-serialization)
 696     (let ((len (let ((len 0))
 697                  (declare (type fixnum len))
 698                  (map () #'(lambda (val)
 699                              (iincf len (ecase type
 700                                           ((:int32 :uint32) (length32 (ldb (byte 32 0) val)))
 701                                           ((:int64 :uint64) (length64 (ldb (byte 64 0) val)))
 702                                           ((:sint32) (length32 (zig-zag-encode32 val)))
 703                                           ((:sint64) (length64 (zig-zag-encode64 val)))
 704                                           ((:fixed32 :sfixed32) 4)
 705                                           ((:fixed64 :sfixed64) 8)
 706                                           ((:bool)   1)
 707                                           ((:float)  4)
 708                                           ((:double) 8)))) values)
 709                  len)))
 710       (declare (type (unsigned-byte 32) len))
 711       ;; Two value: the full size of the packed object, and the size
 712       ;; of just the payload
 713       (values (i+ (length32 tag) (length32 len) len) len))))
 714
 715 ;; The optimized serializers supply 'vectorp' so we can generate better code
 716 (define-compiler-macro packed-size (&whole form values type tag
 717                                     &optional (vectorp nil vectorp-p))
 718   (setq type (fold-symbol type)
 719         tag  (fold-symbol tag))
 720   (if (and vectorp-p
 721            (member type '(:int32 :uint32 :int64 :uint64 :sint32 :sint64
 722                           :fixed32 :sfixed32 :fixed64 :sfixed64
 723                           :bool :float :double)))
 724     `(locally (declare #.$optimize-serialization)
 725        (let ((len (let ((len 0))
 726                     (declare (type fixnum len))
 727                     (,(if vectorp 'dovector 'dolist) (val ,values)
 728                        (iincf len ,(ecase type
 729                                      ((:int32) `(length32 (ldb (byte 32 0) val)))
 730                                      ((:int64) `(length64 (ldb (byte 64 0) val)))
 731                                      ((:uint32) `(length32 val))
 732                                      ((:uint64) `(length64 val))
 733                                      ((:sint32) `(length32 (zig-zag-encode32 val)))
 734                                      ((:sint64) `(length64 (zig-zag-encode64 val)))
 735                                      ((:fixed32 :sfixed32) `4)
 736                                      ((:fixed64 :sfixed64) `8)
 737                                      ((:bool)   `1)
 738                                      ((:float)  `4)
 739                                      ((:double) `8))))
 740                     len)))
 741          (declare (type (unsigned-byte 32) len))
 742          (values (i+ (length32 (the (unsigned-byte 32) ,tag)) (length32 len) len) len)))
 743     form))
 744
 745 (defun enum-size (val enum-values tag)
 746   "Returns the size in bytes that the enum object will take when serialized."
 747   (declare (type list enum-values)
 748            (type (unsigned-byte 32) tag))
 749   (let ((idx (let ((e (find val enum-values :key #'proto-value)))
 750                (and e (proto-index e)))))
 751     (assert idx () "There is no enum value for ~S" val)
 752     (i+ (length32 tag) (length32 (ldb (byte 32 0) idx)))))
 753
 754 (defun packed-enum-size (values enum-values tag)
 755   "Returns the size in bytes that the enum values will take when serialized."
 756   (declare (type list enum-values)
 757            (type (unsigned-byte 32) tag))
 758   (let ((len (let ((len 0))
 759                (declare (type fixnum len))
 760                (map () #'(lambda (val)
 761                            (let ((idx (let ((e (find val enum-values :key #'proto-value)))
 762                                         (and e (proto-index e)))))
 763                              (assert idx () "There is no enum value for ~S" val)
 764                              (iincf len (length32 (ldb (byte 32 0) idx))))) values)
 765                len)))
 766     (declare (type (unsigned-byte 32) len))
 767     ;; Two value: the full size of the packed object, and the size
 768     ;; of just the payload
 769     (values (i+ (length32 tag) (length32 len) len) len)))
 770
 771 \f
 772 ;;; Wire-level encoders
 773 ;;; These are called at the lowest level, so arg types are assumed to be correct
 774
 775 (defmacro generate-integer-encoders (bits)
 776   "Generate 32- or 64-bit versions of integer encoders."
 777   (assert (and (plusp bits) (zerop (mod bits 8))))
 778   (let* ((encode-uint   (fintern "~A~A" 'encode-uint bits))
 779          (encode-fixed  (fintern "~A~A" 'encode-fixed bits))
 780          (encode-sfixed (fintern "~A~A" 'encode-sfixed bits))
 781          (bytes (/ bits 8))
 782          ;; Given bits, can we use fixnums safely?
 783          (fixnump (<= bits (integer-length most-negative-fixnum)))
 784          (ldb (if fixnump 'ildb 'ldb))
 785          (ash (if fixnump 'iash 'ash))
 786          (zerop-val (if fixnump '(i= val 0) '(zerop val))))
 787     `(progn
 788        (defun ,encode-uint (val buffer index)
 789          ,(format nil
 790                   "Encodes the unsigned ~A-bit integer 'val' as a varint into the buffer at the given index.~
 791                    ~&    Modifies the buffer, and returns the new index into the buffer.~
 792                    ~&    Watch out, this function turns off all type checking and array bounds checking." bits)
 793          (declare #.$optimize-serialization)
 794          (declare (type (unsigned-byte ,bits) val)
 795                   (type (simple-array (unsigned-byte 8)) buffer)
 796                   (type fixnum index))
 797          ;; Seven bits at a time, least significant bits first
 798          (loop do (let ((bits (,ldb (byte 7 0) val)))
 799                     (declare (type (unsigned-byte 8) bits))
 800                     (setq val (,ash val -7))
 801                     (setf (aref buffer index)
 802                           (ilogior bits (if ,zerop-val 0 128)))
 803                     (iincf index))
 804                until ,zerop-val)
 805          (values index buffer))                 ;return the buffer to improve 'trace'
 806        (defun ,encode-fixed (val buffer index)
 807          ,(format nil
 808                   "Encodes the unsigned ~A-bit integer 'val' as a fixed int into the buffer at the given index.~
 809                    ~&    Modifies the buffer, and returns the new index into the buffer.~
 810                    ~&    Watch out, this function turns off all type checking and array bounds checking." bits)
 811          (declare #.$optimize-serialization)
 812          (declare (type (unsigned-byte ,bits) val)
 813                   (type (simple-array (unsigned-byte 8)) buffer)
 814                   (type fixnum index))
 815          (loop repeat ,bytes doing
 816            (let ((byte (,ldb (byte 8 0) val)))
 817              (declare (type (unsigned-byte 8) byte))
 818              (setq val (,ash val -8))
 819              (setf (aref buffer index) byte)
 820              (iincf index)))
 821          (values index buffer))
 822        (defun ,encode-sfixed (val buffer index)
 823          ,(format nil
 824                   "Encodes the signed ~A-bit integer 'val' as a fixed int into the buffer at the given index.~
 825                    ~&    Modifies the buffer, and returns the new index into the buffer.~
 826                    ~&    Watch out, this function turns off all type checking and array bounds checking." bits)
 827          (declare #.$optimize-serialization)
 828          (declare (type (signed-byte ,bits) val)
 829                   (type (simple-array (unsigned-byte 8)) buffer)
 830                   (type fixnum index))
 831          (loop repeat ,bytes doing
 832            (let ((byte (,ldb (byte 8 0) val)))
 833              (declare (type (unsigned-byte 8) byte))
 834              (setq val (,ash val -8))
 835              (setf (aref buffer index) byte)
 836              (iincf index)))
 837          (values index buffer)))))
 838
 839 (generate-integer-encoders 32)
 840 (generate-integer-encoders 64)
 841
 842 (defun encode-single (val buffer index)
 843   "Encodes the single float 'val' into the buffer at the given index.
 844    Modifies the buffer, and returns the new index into the buffer.
 845    Watch out, this function turns off all type checking and array bounds checking."
 846   (declare #.$optimize-serialization)
 847   (declare (type single-float val)
 848            (type (simple-array (unsigned-byte 8)) buffer)
 849            (type fixnum index))
 850   (let ((bits (single-float-bits val)))
 851     (loop repeat 4 doing
 852       (let ((byte (ldb (byte 8 0) bits)))
 853         (declare (type (unsigned-byte 8) byte))
 854         (setq bits (ash bits -8))
 855         (setf (aref buffer index) byte)
 856         (iincf index))))
 857   (values index buffer))
 858
 859 (defun encode-double (val buffer index)
 860   "Encodes the double float 'val' into the buffer at the given index.
 861    Modifies the buffer, and returns the new index into the buffer.
 862    Watch out, this function turns off all type checking and array bounds checking."
 863   (declare #.$optimize-serialization)
 864   (declare (type double-float val)
 865            (type (simple-array (unsigned-byte 8)) buffer)
 866            (type fixnum index))
 867   (multiple-value-bind (low high)
 868       (double-float-bits val)
 869     (loop repeat 4 doing
 870       (let ((byte (ldb (byte 8 0) low)))
 871         (declare (type (unsigned-byte 8) byte))
 872         (setq low (ash low -8))
 873         (setf (aref buffer index) byte)
 874         (iincf index)))
 875     (loop repeat 4 doing
 876       (let ((byte (ldb (byte 8 0) high)))
 877         (declare (type (unsigned-byte 8) byte))
 878         (setq high (ash high -8))
 879         (setf (aref buffer index) byte)
 880         (iincf index))))
 881   (values index buffer))
 882
 883 (defun encode-string (string buffer index)
 884   "Encodes the octets into the buffer at the given index.
 885    Modifies the buffer, and returns the new index into the buffer.
 886    Watch out, this function turns off all type checking and array bounds checking."
 887   (declare #.$optimize-serialization)
 888   (declare (type (simple-array (unsigned-byte 8)) buffer)
 889            (type fixnum index))
 890   (let* ((octets (babel:string-to-octets string :encoding :utf-8))
 891          (len (length octets))
 892          (idx (encode-uint32 len buffer index)))
 893     (declare (type (array (unsigned-byte 8)) octets)
 894              (type fixnum len)
 895              (type (unsigned-byte 32) idx))
 896     (replace buffer octets :start1 idx)
 897     (values (i+ idx len) buffer)))
 898
 899 (defun encode-octets (octets buffer index)
 900   "Encodes the octets into the buffer at the given index.
 901    Modifies the buffer, and returns the new index into the buffer.
 902    Watch out, this function turns off all type checking and array bounds checking."
 903   (declare #.$optimize-serialization)
 904   (declare (type (array (unsigned-byte 8)) octets)
 905            (type (simple-array (unsigned-byte 8)) buffer)
 906            (type fixnum index))
 907   (let* ((len (length octets))
 908          (idx (encode-uint32 len buffer index)))
 909     (declare (type fixnum len)
 910              (type (unsigned-byte 32) idx))
 911     (replace buffer octets :start1 idx)
 912     (values (i+ idx len) buffer)))
 913
 914
 915 ;;; Wire-level decoders
 916 ;;; These are called at the lowest level, so arg types are assumed to be correct
 917
 918 ;; Decode the value from the buffer at the given index,
 919 ;; then return the value and new index into the buffer
 920 (defmacro generate-integer-decoders (bits)
 921   "Generate 32- or 64-bit versions of integer decoders."
 922   (assert (and (plusp bits) (zerop (mod bits 8))))
 923   (let* ((decode-uint (fintern "~A~A" 'decode-uint bits))
 924          (decode-int  (fintern "~A~A" 'decode-int bits))
 925          (decode-fixed  (fintern "~A~A" 'decode-fixed bits))
 926          (decode-sfixed (fintern "~A~A" 'decode-sfixed bits))
 927          (bytes (/ bits 8))
 928          ;; Given bits, can we use fixnums safely?
 929          (fixnump (<= bits (integer-length most-negative-fixnum)))
 930          (ldb (if fixnump 'ildb 'ldb))
 931          (ash (if fixnump 'iash 'ash))
 932          (decf (if fixnump 'idecf 'decf))
 933          (logior (if fixnump 'ilogior 'logior)))
 934     `(progn
 935        (defun ,decode-uint (buffer index)
 936          ,(format nil
 937                   "Decodes the next ~A-bit varint integer in the buffer at the given index.~
 938                    ~&    Returns both the decoded value and the new index into the buffer.~
 939                    ~&    Watch out, this function turns off all type checking and array bounds checking." bits)
 940          (declare #.$optimize-serialization)
 941          (declare (type (simple-array (unsigned-byte 8)) buffer)
 942                   (type fixnum index))
 943          ;; Seven bits at a time, least significant bits first
 944          (let ((val 0))
 945            (declare (type (unsigned-byte ,bits) val))
 946            (loop for places fixnum upfrom 0 by 7
 947                  for byte fixnum = (prog1 (aref buffer index) (iincf index))
 948                  do (let ((bits (ildb (byte 7 0) byte)))
 949                       (declare (type (unsigned-byte 8) bits))
 950                       (setq val (,logior val (,ash bits places))))
 951                  until (i< byte 128)
 952                  finally (progn
 953                            (assert (< val ,(ash 1 bits)) ()
 954                                    "The value ~D is longer than ~A bits" val ,bits)
 955                            (return (values val index))))))
 956        (defun ,decode-int (buffer index)
 957          ,(format nil
 958                   "Decodes the next ~A-bit varint integer in the buffer at the given index.~
 959                    ~&    Returns both the decoded value and the new index into the buffer.~
 960                    ~&    Watch out, this function turns off all type checking and array bounds checking." bits)
 961          (declare #.$optimize-serialization)
 962          (declare (type (simple-array (unsigned-byte 8)) buffer)
 963                   (type fixnum index))
 964          (multiple-value-bind (val index)
 965              (,decode-uint buffer index)
 966            ,@(when fixnump `((declare (type fixnum val))))
 967            (when (i= (,ldb (byte 1 ,(1- bits)) val) 1)
 968              (,decf val ,(ash 1 bits)))
 969            (values val index)))
 970        (defun ,decode-fixed (buffer index)
 971          ,(format nil
 972                   "Decodes the next ~A-bit unsigned fixed integer in the buffer at the given index.~
 973                    ~&    Returns both the decoded value and the new index into the buffer.~
 974                    ~&    Watch out, this function turns off all type checking and array bounds checking." bits)
 975          (declare #.$optimize-serialization)
 976          (declare (type (simple-array (unsigned-byte 8)) buffer)
 977                   (type fixnum index))
 978          ;; Eight bits at a time, least significant bits first
 979          (let ((val 0))
 980            ,@(when fixnump `((declare (type fixnum val))))
 981            (loop repeat ,bytes
 982                  for places fixnum upfrom 0 by 8
 983                  for byte fixnum = (prog1 (aref buffer index) (iincf index))
 984                  do (setq val (,logior val (,ash byte places))))
 985            (values val index)))
 986        (defun ,decode-sfixed (buffer index)
 987          ,(format nil
 988                   "Decodes the next ~A-bit signed fixed integer in the buffer at the given index.~
 989                    ~&    Returns both the decoded value and the new index into the buffer.~
 990                    ~&    Watch out, this function turns off all type checking and array bounds checking." bits)
 991          (declare #.$optimize-serialization)
 992          (declare (type (simple-array (unsigned-byte 8)) buffer)
 993                   (type fixnum index))
 994          ;; Eight bits at a time, least significant bits first
 995          (let ((val 0))
 996            ,@(when fixnump `((declare (type fixnum val))))
 997            (loop repeat ,bytes
 998                  for places fixnum upfrom 0 by 8
 999                  for byte fixnum = (prog1 (aref buffer index) (iincf index))
1000                  do (setq val (,logior val (,ash byte places))))
1001            (when (i= (,ldb (byte 1 ,(1- bits)) val) 1)  ;sign bit set, so negative value
1002              (,decf val ,(ash 1 bits)))
1003            (values val index))))))
1004
1005 (generate-integer-decoders 32)
1006 (generate-integer-decoders 64)
1007
1008 (defun decode-single (buffer index)
1009   "Decodes the next single float in the buffer at the given index.
1010    Returns both the decoded value and the new index into the buffer.
1011    Watch out, this function turns off all type checking and array bounds checking."
1012   (declare #.$optimize-serialization)
1013   (declare (type (simple-array (unsigned-byte 8)) buffer)
1014            (type fixnum index))
1015   ;; Eight bits at a time, least significant bits first
1016   (let ((bits 0))
1017     (loop repeat 4
1018           for places fixnum upfrom 0 by 8
1019           for byte fixnum = (prog1 (aref buffer index) (iincf index))
1020           do (setq bits (logior bits (ash byte places))))
1021     (when (i= (ldb (byte 1 31) bits) 1)             ;sign bit set, so negative value
1022       (decf bits #.(ash 1 32)))
1023     (values (make-single-float bits) index)))
1024
1025 (defun decode-double (buffer index)
1026   "Decodes the next double float in the buffer at the given index.
1027    Returns both the decoded value and the new index into the buffer.
1028    Watch out, this function turns off all type checking and array bounds checking."
1029   (declare #.$optimize-serialization)
1030   (declare (type (simple-array (unsigned-byte 8)) buffer)
1031            (type fixnum index))
1032   ;; Eight bits at a time, least significant bits first
1033   (let ((low  0)
1034         (high 0))
1035     (loop repeat 4
1036           for places fixnum upfrom 0 by 8
1037           for byte fixnum = (prog1 (aref buffer index) (iincf index))
1038           do (setq low (logior low (ash byte places))))
1039     (loop repeat 4
1040           for places fixnum upfrom 0 by 8
1041           for byte fixnum = (prog1 (aref buffer index) (iincf index))
1042           do (setq high (logior high (ash byte places))))
1043     ;; High bits are signed, but low bits are unsigned
1044     (when (i= (ldb (byte 1 31) high) 1)             ;sign bit set, so negative value
1045       (decf high #.(ash 1 32)))
1046     (values (make-double-float low high) index)))
1047
1048 (defun decode-string (buffer index)
1049   "Decodes the next UTF-8 encoded string in the buffer at the given index.
1050    Returns both the decoded string and the new index into the buffer.
1051    Watch out, this function turns off all type checking and array bounds checking."
1052   (declare #.$optimize-serialization)
1053   (declare (type (simple-array (unsigned-byte 8)) buffer)
1054            (type fixnum index))
1055   (multiple-value-bind (len idx)
1056       (decode-uint32 buffer index)
1057     (declare (type (unsigned-byte 32) len)
1058              (type fixnum idx))
1059     (values (babel:octets-to-string buffer :start idx :end (i+ idx len) :encoding :utf-8) (i+ idx len))))
1060
1061 (defun decode-octets (buffer index)
1062   "Decodes the next octets in the buffer at the given index.
1063    Returns both the decoded value and the new index into the buffer.
1064    Watch out, this function turns off all type checking and array bounds checking."
1065   (declare #.$optimize-serialization)
1066   (declare (type (simple-array (unsigned-byte 8)) buffer)
1067            (type fixnum index))
1068   (multiple-value-bind (len idx)
1069       (decode-uint32 buffer index)
1070     (declare (type (unsigned-byte 32) len)
1071              (type fixnum idx))
1072     (values (subseq buffer idx (i+ idx len)) (i+ idx len))))
1073
1074
1075 ;;; Wire-level lengths
1076 ;;; These are called at the lowest level, so arg types are assumed to be correct
1077
1078 (defmacro gen-length (bits)
1079   "Generate 32- or 64-bit versions of integer length functions."
1080   (assert (and (plusp bits) (zerop (mod bits 8))))
1081   (let* (;; Given bits, can we use fixnums safely?
1082          (fixnump (<= bits (integer-length most-negative-fixnum)))
1083          (ash (if fixnump 'iash 'ash))
1084          (zerop-val (if fixnump '(i= val 0) '(zerop val))))
1085     `(defun ,(fintern "~A~A" 'length bits) (val)
1086        ,(format nil "Returns the length that 'val' will take when encoded as a ~A-bit integer." bits)
1087        (declare #.$optimize-serialization)
1088        (declare (type (unsigned-byte ,bits) val))
1089        (let ((size 0))
1090          (declare (type fixnum size))
1091          (loop do (progn
1092                     (setq val (,ash val -7))
1093                     (iincf size))
1094                until ,zerop-val)
1095          size))))
1096
1097 (gen-length 32)
1098 (gen-length 64)
1099
1100
1101 ;;; Skipping elements
1102 ;;; This is called at the lowest level, so arg types are assumed to be correct
1103
1104 (defun skip-element (buffer index tag)
1105   "Skip an element in the buffer at the index of the given wire type.
1106    Returns the new index in the buffer.
1107    Watch out, this function turns off all type checking and all array bounds checking."
1108   (declare #.$optimize-serialization)
1109   (declare (type (simple-array (unsigned-byte 8)) buffer)
1110            (type fixnum index)
1111            (type (unsigned-byte 32) tag))
1112   (case (ilogand tag #x7)
1113     ((#.$wire-type-varint)
1114      (loop for byte fixnum = (prog1 (aref buffer index) (iincf index))
1115            until (i< byte 128))
1116      index)
1117     ((#.$wire-type-string)
1118      (multiple-value-bind (len idx)
1119          (decode-uint32 buffer index)
1120        (declare (type (unsigned-byte 32) len)
1121                 (type fixnum idx))
1122        (i+ idx len)))
1123     ((#.$wire-type-32bit)
1124      (i+ index 4))
1125     ((#.$wire-type-64bit)
1126      (i+ index 8))
1127     ((#.$wire-type-start-group)
1128      (loop (multiple-value-bind (new-tag idx)
1129                (decode-uint32 buffer index)
1130              (cond ((not (i= (ilogand new-tag #x7) $wire-type-end-group))
1131                     ;; If it's not the end of a group, skip the next element
1132                     (setq index (skip-element buffer idx new-tag)))
1133                    ;; If it's the end of the expected group, we're done
1134                    ((i= (i- tag $wire-type-start-group) (i- new-tag $wire-type-end-group))
1135                     (return idx))
1136                    (t
1137                     (assert (i= (i- tag $wire-type-start-group) (i- new-tag $wire-type-end-group)) ()
1138                             "Couldn't find a matching end group tag"))))))
1139     (t index)))