+AC_PROG_RANLIB
+
+# Mild abuse of the '--enable' option format to allow manual
+# specification of setuid or setgid setup in pterm.
+setidtype=none
+AC_ARG_ENABLE([setuid],
+ [AS_HELP_STRING([--enable-setuid=USER],
+ [make pterm setuid to a given user])],
+ [case "$enableval" in
+ no) setidtype=none;;
+ *) setidtype=setuid; setidval="$enableval";;
+ esac])
+AC_ARG_ENABLE([setgid],
+ [AS_HELP_STRING([--enable-setgid=GROUP],
+ [make pterm setgid to a given group])],
+ [case "$enableval" in
+ no) setidtype=none;;
+ *) setidtype=setgid; setidval="$enableval";;
+ esac])
+AM_CONDITIONAL(HAVE_SETID_CMD, [test "$setidtype" != "none"])
+AS_IF([test "x$setidtype" = "xsetuid"],
+ [SETID_CMD="chown $setidval"; SETID_MODE="4755"])
+AS_IF([test "x$setidtype" = "xsetgid"],
+ [SETID_CMD="chgrp $setidval"; SETID_MODE="2755"])
+AC_SUBST(SETID_CMD)
+AC_SUBST(SETID_MODE)
+
+AC_ARG_WITH([gssapi],
+ [AS_HELP_STRING([--without-gssapi],
+ [disable GSSAPI support])],
+ [],
+ [with_gssapi=yes])
+
+WITH_GSSAPI=
+AS_IF([test "x$with_gssapi" != xno],
+ [AC_DEFINE([WITH_GSSAPI], [1], [Define if building with GSSAPI support.])])
+
+AC_ARG_WITH([gtk],
+ [AS_HELP_STRING([--with-gtk=VER],
+ [specify GTK version to use (`1' or `2')])
+AS_HELP_STRING([--without-gtk],
+ [do not use GTK (build command-line tools only)])],
+ [gtk_version_desired="$withval"],
+ [gtk_version_desired="any"])
+
+case "$gtk_version_desired" in
+ 1 | 2 | any | no) ;;
+ yes) gtk_version_desired="any" ;;
+ *) AC_ERROR([Invalid GTK version specified])
+esac
+
+AC_CHECK_HEADERS([utmpx.h sys/select.h],,,[
+#include <sys/types.h>
+#include <utmp.h>])